New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA/zpshde.F90 @ 13515

Last change on this file since 13515 was 13515, checked in by hadcv, 20 months ago

Tiling for tra_ldf

  • Property svn:keywords set to Id
File size: 27.6 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE domutl, ONLY : is_tile
20   USE phycst          ! physical constants
21   USE eosbn2          ! ocean equation of state
22   USE in_out_manager  ! I/O manager
23   USE lbclnk          ! lateral boundary conditions (or mpp link)
24   USE lib_mpp         ! MPP library
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35#  include "domzgr_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   ! TODO: NOT TESTED- requires zps
44   SUBROUTINE zps_hde( kt, Kmm, kjpt, pta, pgtu, pgtv,  &
45      &                               prd, pgru, pgrv )
46      !!
47      INTEGER                     , INTENT(in   )           ::  kt          ! ocean time-step index
48      INTEGER                     , INTENT(in   )           ::  Kmm         ! ocean time level index
49      INTEGER                     , INTENT(in   )           ::  kjpt        ! number of tracers
50      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   )           ::  pta         ! 4D tracers fields
51      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
52      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
53      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
54      !
55      INTEGER :: itrd, itgr
56      !!
57      IF( PRESENT(prd)  ) THEN ; itrd = is_tile(prd)  ; ELSE ; itrd = 0 ; ENDIF
58      IF( PRESENT(pgru) ) THEN ; itgr = is_tile(pgru) ; ELSE ; itgr = 0 ; ENDIF
59
60      CALL zps_hde_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), &
61         &                           prd, itrd,         pgru, pgrv, itgr )
62   END SUBROUTINE zps_hde
63
64
65   SUBROUTINE zps_hde_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt,   &
66      &                                 prd, ktrd, pgru, pgrv, ktgr )
67      !!----------------------------------------------------------------------
68      !!                     ***  ROUTINE zps_hde  ***
69      !!                   
70      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
71      !!      at u- and v-points with a linear interpolation for z-coordinate
72      !!      with partial steps.
73      !!
74      !! ** Method  :   In z-coord with partial steps, scale factors on last
75      !!      levels are different for each grid point, so that T, S and rd
76      !!      points are not at the same depth as in z-coord. To have horizontal
77      !!      gradients again, we interpolate T and S at the good depth :
78      !!      Linear interpolation of T, S   
79      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
80      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
81      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
82      !!         This formulation computes the two cases:
83      !!                 CASE 1                   CASE 2 
84      !!         k-1  ___ ___________   k-1   ___ ___________
85      !!                    Ti  T~                  T~  Ti+1
86      !!                  _____                        _____
87      !!         k        |   |Ti+1     k           Ti |   |
88      !!                  |   |____                ____|   |
89      !!              ___ |   |   |           ___  |   |   |
90      !!                 
91      !!      case 1->   e3w(i+1,:,:,Kmm) >= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) >= e3w(:,j,:,Kmm) ) then
92      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j,k,Kmm)
93      !!        ( t~ = t(i  ,j+1,k) + (e3w(i,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i,j+1,k,Kmm)  )
94      !!          or
95      !!      case 2->   e3w(i+1,:,:,Kmm) <= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) <= e3w(:,j,:,Kmm) ) then
96      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
97      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
98      !!          Idem for di(s) and dj(s)         
99      !!
100      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
101      !!      depth zh from interpolated T and S for the different formulations
102      !!      of the equation of state (eos).
103      !!      Gradient formulation for rho :
104      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
105      !!
106      !! ** Action  : compute for top interfaces
107      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
108      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
109      !!----------------------------------------------------------------------
110      INTEGER                                , INTENT(in   )           ::  kt          ! ocean time-step index
111      INTEGER                                , INTENT(in   )           ::  Kmm         ! ocean time level index
112      INTEGER                                , INTENT(in   )           ::  kjpt        ! number of tracers
113      INTEGER                                , INTENT(in   )           ::  ktta, ktgt, ktrd, ktgr
114      REAL(wp), DIMENSION(ST_2DT(ktta),jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
115      REAL(wp), DIMENSION(ST_2DT(ktgt)    ,kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
116      REAL(wp), DIMENSION(ST_2DT(ktrd),jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
117      REAL(wp), DIMENSION(ST_2DT(ktgr)         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
118      !
119      INTEGER  ::   ji, jj, jn                  ! Dummy loop indices
120      INTEGER  ::   iku, ikv, ikum1, ikvm1      ! partial step level (ocean bottom level) at u- and v-points
121      REAL(wp) ::   ze3wu, ze3wv, zmaxu, zmaxv  ! local scalars
122      REAL(wp), DIMENSION(ST_2D(nn_hls))      ::   zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
123      REAL(wp), DIMENSION(ST_2D(nn_hls),kjpt) ::   zti, ztj             !
124      !!----------------------------------------------------------------------
125      !
126      IF( ln_timing )   CALL timing_start( 'zps_hde')
127      !
128      pgtu(:,:,:) = 0._wp   ;   zti (:,:,:) = 0._wp   ;   zhi (:,:) = 0._wp
129      pgtv(:,:,:) = 0._wp   ;   ztj (:,:,:) = 0._wp   ;   zhj (:,:) = 0._wp
130      !
131      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
132         !
133         DO_2D( 1, 0, 1, 0 )
134            iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
135            ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
136!!gm BUG ? when applied to before fields, e3w(:,:,k,Kbb) should be used....
137            ze3wu = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
138            ze3wv = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
139            !
140            ! i- direction
141            IF( ze3wu >= 0._wp ) THEN      ! case 1
142               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
143               ! interpolated values of tracers
144               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
145               ! gradient of  tracers
146               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
147            ELSE                           ! case 2
148               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
149               ! interpolated values of tracers
150               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
151               ! gradient of tracers
152               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
153            ENDIF
154            !
155            ! j- direction
156            IF( ze3wv >= 0._wp ) THEN      ! case 1
157               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
158               ! interpolated values of tracers
159               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
160               ! gradient of tracers
161               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
162            ELSE                           ! case 2
163               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
164               ! interpolated values of tracers
165               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
166               ! gradient of tracers
167               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
168            ENDIF
169         END_2D
170      END DO
171      !
172      CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
173      !               
174      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
175         pgru(:,:) = 0._wp
176         pgrv(:,:) = 0._wp                ! depth of the partial step level
177         DO_2D( 1, 0, 1, 0 )
178            iku = mbku(ji,jj)
179            ikv = mbkv(ji,jj)
180            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
181            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
182            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)     ! i-direction: case 1
183            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)     ! -     -      case 2
184            ENDIF
185            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)     ! j-direction: case 1
186            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)     ! -     -      case 2
187            ENDIF
188         END_2D
189         !
190         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
191         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
192         !
193         DO_2D( 1, 0, 1, 0 )
194            iku = mbku(ji,jj)
195            ikv = mbkv(ji,jj)
196            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
197            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
198            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
199            ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
200            ENDIF
201            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
202            ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
203            ENDIF
204         END_2D
205         CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
206         !
207      END IF
208      !
209      IF( ln_timing )   CALL timing_stop( 'zps_hde')
210      !
211   END SUBROUTINE zps_hde_t
212
213
214   ! TODO: NOT TESTED- requires zps
215   SUBROUTINE zps_hde_isf( kt, Kmm, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
216      &                                   prd, pgru, pgrv, pgrui, pgrvi )
217      !!
218      INTEGER                     , INTENT(in   )           ::  kt           ! ocean time-step index
219      INTEGER                     , INTENT(in   )           ::  Kmm          ! ocean time level index
220      INTEGER                     , INTENT(in   )           ::  kjpt         ! number of tracers
221      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   )           ::  pta          ! 4D tracers fields
222      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
223      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
224      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
225      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
226      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
227      !
228      INTEGER :: itrd, itgr, itgri
229      !!
230      IF( PRESENT(prd)   ) THEN ; itrd  = is_tile(prd)   ; ELSE ; itrd  = 0 ; ENDIF
231      IF( PRESENT(pgru)  ) THEN ; itgr  = is_tile(pgru)  ; ELSE ; itgr  = 0 ; ENDIF
232      IF( PRESENT(pgrui) ) THEN ; itgri = is_tile(pgrui) ; ELSE ; itgri = 0 ; ENDIF
233
234      CALL zps_hde_isf_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), pgtui, pgtvi, is_tile(pgtui),  &
235      &                                  prd, itrd,         pgru, pgrv, itgr,          pgrui, pgrvi, itgri )
236   END SUBROUTINE zps_hde_isf
237
238
239   SUBROUTINE zps_hde_isf_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt, pgtui, pgtvi, ktgti,  &
240      &                                     prd, ktrd, pgru, pgrv, ktgr, pgrui, pgrvi, ktgri )
241      !!----------------------------------------------------------------------
242      !!                     ***  ROUTINE zps_hde_isf  ***
243      !!                   
244      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
245      !!      at u- and v-points with a linear interpolation for z-coordinate
246      !!      with partial steps for top (ice shelf) and bottom.
247      !!
248      !! ** Method  :   In z-coord with partial steps, scale factors on last
249      !!      levels are different for each grid point, so that T, S and rd
250      !!      points are not at the same depth as in z-coord. To have horizontal
251      !!      gradients again, we interpolate T and S at the good depth :
252      !!      For the bottom case:
253      !!      Linear interpolation of T, S   
254      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
255      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
256      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
257      !!         This formulation computes the two cases:
258      !!                 CASE 1                   CASE 2 
259      !!         k-1  ___ ___________   k-1   ___ ___________
260      !!                    Ti  T~                  T~  Ti+1
261      !!                  _____                        _____
262      !!         k        |   |Ti+1     k           Ti |   |
263      !!                  |   |____                ____|   |
264      !!              ___ |   |   |           ___  |   |   |
265      !!                 
266      !!      case 1->   e3w(i+1,j,k,Kmm) >= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) >= e3w(i,j,k,Kmm) ) then
267      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j  ,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j  ,k,Kmm)
268      !!        ( t~ = t(i  ,j+1,k) + (e3w(i  ,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i  ,j+1,k,Kmm)  )
269      !!          or
270      !!      case 2->   e3w(i+1,j,k,Kmm) <= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) <= e3w(i,j,k,Kmm) ) then
271      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j  ,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
272      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i  ,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
273      !!          Idem for di(s) and dj(s)         
274      !!
275      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
276      !!      depth zh from interpolated T and S for the different formulations
277      !!      of the equation of state (eos).
278      !!      Gradient formulation for rho :
279      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
280      !!
281      !!      For the top case (ice shelf): As for the bottom case but upside down
282      !!
283      !! ** Action  : compute for top and bottom interfaces
284      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
285      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
286      !!----------------------------------------------------------------------
287      INTEGER                                , INTENT(in   )           ::  kt           ! ocean time-step index
288      INTEGER                                , INTENT(in   )           ::  Kmm          ! ocean time level index
289      INTEGER                                , INTENT(in   )           ::  kjpt         ! number of tracers
290      INTEGER                                , INTENT(in   )           ::  ktta, ktgt, ktgti, ktrd, ktgr, ktgri
291      REAL(wp), DIMENSION(ST_2DT(ktta),jpk,kjpt), INTENT(in   )           ::  pta          ! 4D tracers fields
292      REAL(wp), DIMENSION(ST_2DT(ktgt)    ,kjpt), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
293      REAL(wp), DIMENSION(ST_2DT(ktgti)   ,kjpt), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
294      REAL(wp), DIMENSION(ST_2DT(ktrd),jpk     ), INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
295      REAL(wp), DIMENSION(ST_2DT(ktgr)         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
296      REAL(wp), DIMENSION(ST_2DT(ktgri)        ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
297      !
298      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
299      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
300      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
301      REAL(wp), DIMENSION(ST_2D(nn_hls))      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
302      REAL(wp), DIMENSION(ST_2D(nn_hls),kjpt) ::  zti, ztj             !
303      !!----------------------------------------------------------------------
304      !
305      IF( ln_timing )   CALL timing_start( 'zps_hde_isf')
306      !
307      pgtu (:,:,:) = 0._wp   ;   pgtv (:,:,:) =0._wp
308      pgtui(:,:,:) = 0._wp   ;   pgtvi(:,:,:) =0._wp
309      zti  (:,:,:) = 0._wp   ;   ztj  (:,:,:) =0._wp
310      zhi  (:,:  ) = 0._wp   ;   zhj  (:,:  ) =0._wp
311      !
312      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
313         !
314         DO_2D( 1, 0, 1, 0 )
315
316            iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
317            ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
318            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
319            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
320            !
321            ! i- direction
322            IF( ze3wu >= 0._wp ) THEN      ! case 1
323               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
324               ! interpolated values of tracers
325               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
326               ! gradient of  tracers
327               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
328            ELSE                           ! case 2
329               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
330               ! interpolated values of tracers
331               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
332               ! gradient of tracers
333               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
334            ENDIF
335            !
336            ! j- direction
337            IF( ze3wv >= 0._wp ) THEN      ! case 1
338               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
339               ! interpolated values of tracers
340               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
341               ! gradient of tracers
342               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
343            ELSE                           ! case 2
344               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
345               ! interpolated values of tracers
346               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
347               ! gradient of tracers
348               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
349            ENDIF
350
351         END_2D
352      END DO
353      !
354      CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
355
356      ! horizontal derivative of density anomalies (rd)
357      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
358         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
359         !
360         DO_2D( 1, 0, 1, 0 )
361
362            iku = mbku(ji,jj)
363            ikv = mbkv(ji,jj)
364            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
365            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
366            !
367            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
368            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
369            ENDIF
370            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
371            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
372            ENDIF
373
374         END_2D
375
376         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
377         ! step and store it in  zri, zrj for each  case
378         CALL eos( zti, zhi, zri )
379         CALL eos( ztj, zhj, zrj )
380
381         DO_2D( 1, 0, 1, 0 )
382            iku = mbku(ji,jj)
383            ikv = mbkv(ji,jj)
384            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
385            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
386
387            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
388            ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
389            ENDIF
390            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
391            ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
392            ENDIF
393
394         END_2D
395
396         CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
397         !
398      END IF
399      !
400      !     !==  (ISH)  compute grui and gruvi  ==!
401      !
402      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
403         DO_2D( 1, 0, 1, 0 )
404            iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
405            ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
406            !
407            ! (ISF) case partial step top and bottom in adjacent cell in vertical
408            ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
409            ! in this case e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm) is not the distance between Tj~ and Tj
410            ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
411            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
412            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
413
414            ! i- direction
415            IF( ze3wu >= 0._wp ) THEN      ! case 1
416               zmaxu = ze3wu / e3w(ji+1,jj,ikup1,Kmm)
417               ! interpolated values of tracers
418               zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
419               ! gradient of tracers
420               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
421            ELSE                           ! case 2
422               zmaxu = - ze3wu / e3w(ji,jj,ikup1,Kmm)
423               ! interpolated values of tracers
424               zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
425               ! gradient of  tracers
426               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
427            ENDIF
428            !
429            ! j- direction
430            IF( ze3wv >= 0._wp ) THEN      ! case 1
431               zmaxv =  ze3wv / e3w(ji,jj+1,ikvp1,Kmm)
432               ! interpolated values of tracers
433               ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
434               ! gradient of tracers
435               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
436            ELSE                           ! case 2
437               zmaxv =  - ze3wv / e3w(ji,jj,ikvp1,Kmm)
438               ! interpolated values of tracers
439               ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
440               ! gradient of tracers
441               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
442            ENDIF
443
444         END_2D
445         !
446      END DO
447      CALL lbc_lnk_multi( 'zpshde', pgtui(:,:,:), 'U', -1.0_wp , pgtvi(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
448
449      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
450         !
451         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
452         DO_2D( 1, 0, 1, 0 )
453
454            iku = miku(ji,jj)
455            ikv = mikv(ji,jj)
456            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
457            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
458            !
459            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
460            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
461            ENDIF
462
463            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
464            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
465            ENDIF
466
467         END_2D
468         !
469         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
470         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
471         !
472         DO_2D( 1, 0, 1, 0 )
473            iku = miku(ji,jj) 
474            ikv = mikv(ji,jj) 
475            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
476            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
477
478            IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
479            ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
480            ENDIF
481            IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
482            ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
483            ENDIF
484
485         END_2D
486         CALL lbc_lnk_multi( 'zpshde', pgrui, 'U', -1.0_wp , pgrvi, 'V', -1.0_wp )   ! Lateral boundary conditions
487         !
488      END IF 
489      !
490      IF( ln_timing )   CALL timing_stop( 'zps_hde_isf')
491      !
492   END SUBROUTINE zps_hde_isf_t
493
494   !!======================================================================
495END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.