New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2020/dev_r13508_HPC-09_communications_cleanup/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13508_HPC-09_communications_cleanup/src/OCE/TRA/traadv_fct.F90 @ 13904

Last change on this file since 13904 was 13904, checked in by francesca, 4 years ago

bug fixing on traadv_fct (cases 4 and 41) - ticket #2367

  • Property svn:keywords set to Id
File size: 35.3 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
40   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
41
42   !                                        ! tridiag solver associated indices:
43   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
44   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48#  include "domzgr_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
57      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
58      !!----------------------------------------------------------------------
59      !!                  ***  ROUTINE tra_adv_fct  ***
60      !!
61      !! **  Purpose :   Compute the now trend due to total advection of tracers
62      !!               and add it to the general trend of tracer equations
63      !!
64      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
65      !!               (choice through the value of kn_fct)
66      !!               - on the vertical the 4th order is a compact scheme
67      !!               - corrected flux (monotonic correction)
68      !!
69      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
70      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
71      !!             - poleward advective heat and salt transport (ln_diaptr=T)
72      !!----------------------------------------------------------------------
73      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
74      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
75      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
76      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
77      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
78      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
79      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
80      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
81      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
83      !
84      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
85      REAL(wp) ::   ztra                                     ! local scalar
86      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
87      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
88      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
89      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
90      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
91      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
92      !!----------------------------------------------------------------------
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
98      ENDIF
99      !! -- init to 0
100      zwi(:,:,:) = 0._wp
101      zwx(:,:,:) = 0._wp
102      zwy(:,:,:) = 0._wp
103      zwz(:,:,:) = 0._wp
104      ztu(:,:,:) = 0._wp
105      ztv(:,:,:) = 0._wp
106      zltu(:,:,:) = 0._wp
107      zltv(:,:,:) = 0._wp
108      ztw(:,:,:) = 0._wp
109      !
110      l_trd = .FALSE.            ! set local switches
111      l_hst = .FALSE.
112      l_ptr = .FALSE.
113      ll_zAimp = .FALSE.
114      IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
115      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE. 
116      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
117         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
118      !
119      IF( l_trd .OR. l_hst )  THEN
120         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
121         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
122      ENDIF
123      !
124      IF( l_ptr ) THEN 
125         ALLOCATE( zptry(jpi,jpj,jpk) )
126         zptry(:,:,:) = 0._wp
127      ENDIF
128      !
129      ! If adaptive vertical advection, check if it is needed on this PE at this time
130      IF( ln_zad_Aimp ) THEN
131         IF( MAXVAL( ABS( wi(:,:,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
132      END IF
133      ! If active adaptive vertical advection, build tridiagonal matrix
134      IF( ll_zAimp ) THEN
135         ALLOCATE(zwdia(jpi,jpj,jpk), zwinf(jpi,jpj,jpk),zwsup(jpi,jpj,jpk))
136         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
137            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
138            &                               / e3t(ji,jj,jk,Krhs)
139            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
140            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
141         END_3D
142      END IF
143      !
144      DO jn = 1, kjpt            !==  loop over the tracers  ==!
145         !
146         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
147         !                    !* upstream tracer flux in the i and j direction
148         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
149            ! upstream scheme
150            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
151            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
152            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
153            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
154            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
155            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
156         END_3D
157         !                               !* upstream tracer flux in the k direction *!
158         DO_3D( 1, 1, 1, 1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
159            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
160            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
161            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
162         END_3D
163         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
164            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
165               DO_2D( 1, 1, 1, 1 )
166                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
167               END_2D
168            ELSE                                        ! no cavities: only at the ocean surface
169               DO_2D( 1, 1, 1, 1 )
170                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
171               END_2D
172            ENDIF
173         ENDIF
174         !               
175         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )   !* trend and after field with monotonic scheme
176            !                               ! total intermediate advective trends
177            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
178               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
179               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
180            !                               ! update and guess with monotonic sheme
181            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
182               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
183            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
184               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
185         END_3D
186         
187         IF ( ll_zAimp ) THEN
188            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
189            !
190            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
191            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
192               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
193               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
194               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
195               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
196            END_3D
197            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
198               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
199                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
200            END_3D
201            !
202         END IF
203         !               
204         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
205            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
206         END IF
207         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
208         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
209         !
210         !        !==  anti-diffusive flux : high order minus low order  ==!
211         !
212         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
213         !
214         CASE(  2  )                   !- 2nd order centered
215            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
216               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
217               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
218            END_3D
219            !
220         CASE(  4  )                   !- 4th order centered
221            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
222            zltv(:,:,jpk) = 0._wp
223            DO jk = 1, jpkm1                 ! Laplacian
224               DO_2D( 1, 0, 1, 0 )                 ! 1st derivative (gradient)
225                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
226                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
227               END_2D
228               DO_2D( 0, 0, 0, 0 )                 ! 2nd derivative * 1/ 6
229                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
230                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
231               END_2D
232            END DO
233            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
234            !
235            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
236               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
237               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
238               !                                                        ! C4 minus upstream advective fluxes
239               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
240               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
241            END_3D
242            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp, zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
243            !
244         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
245            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
246            ztv(:,:,jpk) = 0._wp
247            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )    ! 1st derivative (gradient)
248               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
249               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
250            END_3D
251            IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
252            !
253            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
254               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
255               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
256               !                                                  ! C4 interpolation of T at u- & v-points (x2)
257               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
258               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
259               !                                                  ! C4 minus upstream advective fluxes
260               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
261               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
262            END_3D
263            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
264            !
265         END SELECT
266         !                     
267         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
268         !
269         CASE(  2  )                   !- 2nd order centered
270            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
271               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
272                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
273            END_3D
274            !
275         CASE(  4  )                   !- 4th order COMPACT
276            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
277            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
278               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
279            END_3D
280            !
281         END SELECT
282         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
283            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
284         ENDIF
285         !         
286         IF (nn_hls.EQ.1) THEN
287            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
288         ELSE
289            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
290         END IF
291         !
292         IF ( ll_zAimp ) THEN
293            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !* trend and after field with monotonic scheme
294               !                                                ! total intermediate advective trends
295               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
296                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
297                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
298               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
299            END_3D
300            !
301            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
302            !
303            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
304               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
305               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
306               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
307            END_3D
308         END IF
309         !
310         !        !==  monotonicity algorithm  ==!
311         !
312         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
313         !
314         !        !==  final trend with corrected fluxes  ==!
315         !
316         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
317            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
318               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
319               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
320            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
321            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
322         END_3D
323         !
324         IF ( ll_zAimp ) THEN
325            !
326            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
327            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
328               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
329               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
330               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
331               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
332            END_3D
333            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
334               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
335                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
336            END_3D
337         END IF         
338         ! NOT TESTED - NEED l_trd OR l_hst TRUE
339         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
340            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
341            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
342            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
343            !
344            IF( l_trd ) THEN              ! trend diagnostics
345               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
346               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
347               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
348            ENDIF
349            !                             ! heat/salt transport
350            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
351            !
352         ENDIF
353         ! NOT TESTED - NEED l_ptr TRUE
354         IF( l_ptr ) THEN              ! "Poleward" transports
355            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
356            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
357         ENDIF
358         !
359      END DO                     ! end of tracer loop
360      !
361      IF ( ll_zAimp ) THEN
362         DEALLOCATE( zwdia, zwinf, zwsup )
363      ENDIF
364      IF( l_trd .OR. l_hst ) THEN
365         DEALLOCATE( ztrdx, ztrdy, ztrdz )
366      ENDIF
367      IF( l_ptr ) THEN
368         DEALLOCATE( zptry )
369      ENDIF
370      !
371   END SUBROUTINE tra_adv_fct
372
373
374   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
375      !!---------------------------------------------------------------------
376      !!                    ***  ROUTINE nonosc  ***
377      !!     
378      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
379      !!       scheme and the before field by a nonoscillatory algorithm
380      !!
381      !! **  Method  :   ... ???
382      !!       warning : pbef and paft must be masked, but the boundaries
383      !!       conditions on the fluxes are not necessary zalezak (1979)
384      !!       drange (1995) multi-dimensional forward-in-time and upstream-
385      !!       in-space based differencing for fluid
386      !!----------------------------------------------------------------------
387      INTEGER                          , INTENT(in   ) ::   Kmm             ! time level index
388      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
389      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
390      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
391      !
392      INTEGER  ::   ji, jj, jk   ! dummy loop indices
393      INTEGER  ::   ikm1         ! local integer
394      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
395      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
396      REAL(dp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo, zbup, zbdo
397      !!----------------------------------------------------------------------
398      !
399      zbig  = 1.e+40_dp
400      zrtrn = 1.e-15_dp
401      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
402
403      ! Search local extrema
404      ! --------------------
405      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
406      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
407         &        paft * tmask - zbig * ( 1._wp - tmask )  )
408      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
409         &        paft * tmask + zbig * ( 1._wp - tmask )  )
410
411      DO jk = 1, jpkm1
412         ikm1 = MAX(jk-1,1)
413         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
414
415            ! search maximum in neighbourhood
416            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
417               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
418               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
419               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
420
421            ! search minimum in neighbourhood
422            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
423               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
424               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
425               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
426
427            ! positive part of the flux
428            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
429               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
430               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
431
432            ! negative part of the flux
433            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
434               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
435               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
436
437            ! up & down beta terms
438            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
439            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
440            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
441         END_2D
442      END DO
443      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
444
445      ! 3. monotonic flux in the i & j direction (paa & pbb)
446      ! ----------------------------------------
447      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
448         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
449         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
450         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
451         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
452
453         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
454         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
455         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
456         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
457
458      ! monotonic flux in the k direction, i.e. pcc
459      ! -------------------------------------------
460         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
461         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
462         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
463         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
464      END_3D
465      !
466   END SUBROUTINE nonosc
467
468
469   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
470      !!----------------------------------------------------------------------
471      !!                  ***  ROUTINE interp_4th_cpt_org  ***
472      !!
473      !! **  Purpose :   Compute the interpolation of tracer at w-point
474      !!
475      !! **  Method  :   4th order compact interpolation
476      !!----------------------------------------------------------------------
477      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
478      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
479      !
480      INTEGER :: ji, jj, jk   ! dummy loop integers
481      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
482      !!----------------------------------------------------------------------
483     
484      DO_3D( 1, 1, 1, 1, 3, jpkm1 )       !==  build the three diagonal matrix  ==!
485         zwd (ji,jj,jk) = 4._wp
486         zwi (ji,jj,jk) = 1._wp
487         zws (ji,jj,jk) = 1._wp
488         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
489         !
490         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
491            zwd (ji,jj,jk) = 1._wp
492            zwi (ji,jj,jk) = 0._wp
493            zws (ji,jj,jk) = 0._wp
494            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
495         ENDIF
496      END_3D
497      !
498      jk = 2                                    ! Switch to second order centered at top
499      DO_2D( 1, 1, 1, 1 )
500         zwd (ji,jj,jk) = 1._wp
501         zwi (ji,jj,jk) = 0._wp
502         zws (ji,jj,jk) = 0._wp
503         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
504      END_2D
505      !
506      !                       !==  tridiagonal solve  ==!
507      DO_2D( 1, 1, 1, 1 )           ! first recurrence
508         zwt(ji,jj,2) = zwd(ji,jj,2)
509      END_2D
510      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
511         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
512      END_3D
513      !
514      DO_2D( 1, 1, 1, 1 )           ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
515         pt_out(ji,jj,2) = zwrm(ji,jj,2)
516      END_2D
517      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
518         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
519      END_3D
520
521      DO_2D( 1, 1, 1, 1 )           ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
522         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
523      END_2D
524      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
525         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
526      END_3D
527      !   
528   END SUBROUTINE interp_4th_cpt_org
529   
530
531   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
532      !!----------------------------------------------------------------------
533      !!                  ***  ROUTINE interp_4th_cpt  ***
534      !!
535      !! **  Purpose :   Compute the interpolation of tracer at w-point
536      !!
537      !! **  Method  :   4th order compact interpolation
538      !!----------------------------------------------------------------------
539      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
540      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
541      !
542      INTEGER ::   ji, jj, jk   ! dummy loop integers
543      INTEGER ::   ikt, ikb     ! local integers
544      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
545      !!----------------------------------------------------------------------
546      !
547      !                      !==  build the three diagonal matrix & the RHS  ==!
548      !
549      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )    ! interior (from jk=3 to jpk-1)
550         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
551         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
552         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
553         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
554            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
555      END_3D
556      !
557!!gm
558!      SELECT CASE( kbc )               !* boundary condition
559!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
560!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
561!      END SELECT
562!!gm 
563      !
564      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
565         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
566      END IF
567      !
568      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! 2nd order centered at top & bottom
569         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
570         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
571         !
572         zwd (ji,jj,ikt) = 1._wp          ! top
573         zwi (ji,jj,ikt) = 0._wp
574         zws (ji,jj,ikt) = 0._wp
575         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
576         !
577         zwd (ji,jj,ikb) = 1._wp          ! bottom
578         zwi (ji,jj,ikb) = 0._wp
579         zws (ji,jj,ikb) = 0._wp
580         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
581      END_2D
582      !
583      !                       !==  tridiagonal solver  ==!
584      !
585      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
586         zwt(ji,jj,2) = zwd(ji,jj,2)
587      END_2D
588      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
589         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
590      END_3D
591      !
592      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
593         pt_out(ji,jj,2) = zwrm(ji,jj,2)
594      END_2D
595      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
596         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
597      END_3D
598
599      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
600         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
601      END_2D
602      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, 2, -1 )
603         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
604      END_3D
605      !   
606   END SUBROUTINE interp_4th_cpt
607
608
609   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
610      !!----------------------------------------------------------------------
611      !!                  ***  ROUTINE tridia_solver  ***
612      !!
613      !! **  Purpose :   solve a symmetric 3diagonal system
614      !!
615      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
616      !!     
617      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
618      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
619      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
620      !!             (        ...          )( ... )   ( ...  )
621      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
622      !!     
623      !!        M is decomposed in the product of an upper and lower triangular matrix.
624      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
625      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
626      !!        The solution is pta.
627      !!        The 3d array zwt is used as a work space array.
628      !!----------------------------------------------------------------------
629      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
630      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
631      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
632      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
633      !                                                           ! =0 pt at t-level
634      INTEGER ::   ji, jj, jk   ! dummy loop integers
635      INTEGER ::   kstart       ! local indices
636      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
637      !!----------------------------------------------------------------------
638      !
639      kstart =  1  + klev
640      !
641      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                         !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
642         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
643      END_2D
644      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
645         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
646      END_3D
647      !
648      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                        !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
649         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
650      END_2D
651      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
652         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
653      END_3D
654
655      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                       !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
656         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
657      END_2D
658      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, kstart, -1 )
659         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
660      END_3D
661      !
662   END SUBROUTINE tridia_solver
663
664   !!======================================================================
665END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.