New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2020/dev_r13508_HPC-09_loop_fusion/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13508_HPC-09_loop_fusion/src/OCE/TRA/traadv_fct.F90 @ 13922

Last change on this file since 13922 was 13922, checked in by francesca, 4 years ago

bug fixing on loop-fusion branch - ticket #2367
  • Property svn:keywords set to Id
File size: 35.4 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36   PUBLIC   tridia_solver      ! called by traadv_fct_lf.F90
37   PUBLIC   nonosc             ! called by traadv_fct_lf.F90 - key_agrif
38
39   LOGICAL  ::   l_trd   ! flag to compute trends
40   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
41   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
42   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
43
44   !                                        ! tridiag solver associated indices:
45   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
46   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50#  include "domzgr_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
53   !! $Id$
54   !! Software governed by the CeCILL license (see ./LICENSE)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
59      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE tra_adv_fct  ***
62      !!
63      !! **  Purpose :   Compute the now trend due to total advection of tracers
64      !!               and add it to the general trend of tracer equations
65      !!
66      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
67      !!               (choice through the value of kn_fct)
68      !!               - on the vertical the 4th order is a compact scheme
69      !!               - corrected flux (monotonic correction)
70      !!
71      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
72      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
73      !!             - poleward advective heat and salt transport (ln_diaptr=T)
74      !!----------------------------------------------------------------------
75      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
77      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
78      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
79      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
80      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
81      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
82      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
83      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
85      !
86      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
87      REAL(wp) ::   ztra                                     ! local scalar
88      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
89      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
90      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
91      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
92      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
93      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
94      !!----------------------------------------------------------------------
95      !
96      IF( kt == kit000 )  THEN
97         IF(lwp) WRITE(numout,*)
98         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
99         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
100      ENDIF
101      !! -- init to 0
102      zwi(:,:,:) = 0._wp
103      zwx(:,:,:) = 0._wp
104      zwy(:,:,:) = 0._wp
105      zwz(:,:,:) = 0._wp
106      ztu(:,:,:) = 0._wp
107      ztv(:,:,:) = 0._wp
108      zltu(:,:,:) = 0._wp
109      zltv(:,:,:) = 0._wp
110      ztw(:,:,:) = 0._wp
111      !
112      l_trd = .FALSE.            ! set local switches
113      l_hst = .FALSE.
114      l_ptr = .FALSE.
115      ll_zAimp = .FALSE.
116      IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
117      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE. 
118      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
119         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
120      !
121      IF( l_trd .OR. l_hst )  THEN
122         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
123         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
124      ENDIF
125      !
126      IF( l_ptr ) THEN 
127         ALLOCATE( zptry(jpi,jpj,jpk) )
128         zptry(:,:,:) = 0._wp
129      ENDIF
130      !
131      ! If adaptive vertical advection, check if it is needed on this PE at this time
132      IF( ln_zad_Aimp ) THEN
133         IF( MAXVAL( ABS( wi(:,:,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
134      END IF
135      ! If active adaptive vertical advection, build tridiagonal matrix
136      IF( ll_zAimp ) THEN
137         ALLOCATE(zwdia(jpi,jpj,jpk), zwinf(jpi,jpj,jpk),zwsup(jpi,jpj,jpk))
138         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
139            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
140            &                               / e3t(ji,jj,jk,Krhs)
141            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
142            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
143         END_3D
144      END IF
145      !
146      DO jn = 1, kjpt            !==  loop over the tracers  ==!
147         !
148         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
149         !                    !* upstream tracer flux in the i and j direction
150         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
151            ! upstream scheme
152            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
153            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
154            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
155            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
156            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
157            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
158         END_3D
159         !                               !* upstream tracer flux in the k direction *!
160         DO_3D( 1, 1, 1, 1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
161            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
162            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
163            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
164         END_3D
165         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
166            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
167               DO_2D( 1, 1, 1, 1 )
168                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
169               END_2D
170            ELSE                                        ! no cavities: only at the ocean surface
171               DO_2D( 1, 1, 1, 1 )
172                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
173               END_2D
174            ENDIF
175         ENDIF
176         !               
177         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )   !* trend and after field with monotonic scheme
178            !                               ! total intermediate advective trends
179            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
180               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
181               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
182            !                               ! update and guess with monotonic sheme
183            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
184               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
185            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
186               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
187         END_3D
188         
189         IF ( ll_zAimp ) THEN
190            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
191            !
192            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
193            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
194               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
195               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
196               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
197               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
198            END_3D
199            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
200               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
201                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
202            END_3D
203            !
204         END IF
205         !               
206         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
207            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
208         END IF
209         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
210         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
211         !
212         !        !==  anti-diffusive flux : high order minus low order  ==!
213         !
214         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
215         !
216         CASE(  2  )                   !- 2nd order centered
217            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
218               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
219               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
220            END_3D
221            !
222         CASE(  4  )                   !- 4th order centered
223            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
224            zltv(:,:,jpk) = 0._wp
225            DO jk = 1, jpkm1                 ! Laplacian
226               DO_2D( 1, 0, 1, 0 )                 ! 1st derivative (gradient)
227                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
228                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
229               END_2D
230               DO_2D( 0, 0, 0, 0 )                 ! 2nd derivative * 1/ 6
231                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
232                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
233               END_2D
234            END DO
235            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
236            !
237            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
238               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
239               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
240               !                                                        ! C4 minus upstream advective fluxes
241               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
242               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
243            END_3D
244            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp, zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)!
245            !
246         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
247            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
248            ztv(:,:,jpk) = 0._wp
249            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )    ! 1st derivative (gradient)
250               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
251               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
252            END_3D
253            !
254            IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
255            !
256            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
257               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
258               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
259               !                                                  ! C4 interpolation of T at u- & v-points (x2)
260               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
261               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
262               !                                                  ! C4 minus upstream advective fluxes
263               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
264               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
265            END_3D
266            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp, zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
267            !
268         END SELECT
269         !                     
270         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
271         !
272         CASE(  2  )                   !- 2nd order centered
273            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
274               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
275                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
276            END_3D
277            !
278         CASE(  4  )                   !- 4th order COMPACT
279            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
280            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
281               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
282            END_3D
283            !
284         END SELECT
285         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
286            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
287         ENDIF
288         !         
289         IF (nn_hls.EQ.1) THEN
290            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
291         ELSE
292            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
293         END IF
294         !
295         IF ( ll_zAimp ) THEN
296            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !* trend and after field with monotonic scheme
297               !                                                ! total intermediate advective trends
298               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
299                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
300                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
301               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
302            END_3D
303            !
304            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
305            !
306            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
307               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
308               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
309               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
310            END_3D
311         END IF
312         !
313         !        !==  monotonicity algorithm  ==!
314         !
315         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
316         !
317         !        !==  final trend with corrected fluxes  ==!
318         !
319         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
320            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
321               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
322               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
323            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
324            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
325         END_3D
326         !
327         IF ( ll_zAimp ) THEN
328            !
329            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
330            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
331               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
332               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
333               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
334               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
335            END_3D
336            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
337               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
338                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
339            END_3D
340         END IF         
341         ! NOT TESTED - NEED l_trd OR l_hst TRUE
342         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
343            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
344            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
345            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
346            !
347            IF( l_trd ) THEN              ! trend diagnostics
348               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
349               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
350               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
351            ENDIF
352            !                             ! heat/salt transport
353            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
354            !
355         ENDIF
356         ! NOT TESTED - NEED l_ptr TRUE
357         IF( l_ptr ) THEN              ! "Poleward" transports
358            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
359            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
360         ENDIF
361         !
362      END DO                     ! end of tracer loop
363      !
364      IF ( ll_zAimp ) THEN
365         DEALLOCATE( zwdia, zwinf, zwsup )
366      ENDIF
367      IF( l_trd .OR. l_hst ) THEN
368         DEALLOCATE( ztrdx, ztrdy, ztrdz )
369      ENDIF
370      IF( l_ptr ) THEN
371         DEALLOCATE( zptry )
372      ENDIF
373      !
374   END SUBROUTINE tra_adv_fct
375
376
377   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
378      !!---------------------------------------------------------------------
379      !!                    ***  ROUTINE nonosc  ***
380      !!     
381      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
382      !!       scheme and the before field by a nonoscillatory algorithm
383      !!
384      !! **  Method  :   ... ???
385      !!       warning : pbef and paft must be masked, but the boundaries
386      !!       conditions on the fluxes are not necessary zalezak (1979)
387      !!       drange (1995) multi-dimensional forward-in-time and upstream-
388      !!       in-space based differencing for fluid
389      !!----------------------------------------------------------------------
390      INTEGER                          , INTENT(in   ) ::   Kmm             ! time level index
391      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
392      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
393      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
394      !
395      INTEGER  ::   ji, jj, jk   ! dummy loop indices
396      INTEGER  ::   ikm1         ! local integer
397      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
398      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
399      REAL(dp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo, zbup, zbdo
400      !!----------------------------------------------------------------------
401      !
402      zbig  = 1.e+40_dp
403      zrtrn = 1.e-15_dp
404      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
405
406      ! Search local extrema
407      ! --------------------
408      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
409      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
410         &        paft * tmask - zbig * ( 1._wp - tmask )  )
411      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
412         &        paft * tmask + zbig * ( 1._wp - tmask )  )
413
414      DO jk = 1, jpkm1
415         ikm1 = MAX(jk-1,1)
416         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
417
418            ! search maximum in neighbourhood
419            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
420               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
421               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
422               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
423
424            ! search minimum in neighbourhood
425            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
426               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
427               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
428               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
429
430            ! positive part of the flux
431            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
432               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
433               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
434
435            ! negative part of the flux
436            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
437               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
438               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
439
440            ! up & down beta terms
441            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
442            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
443            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
444         END_2D
445      END DO
446      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
447
448      ! 3. monotonic flux in the i & j direction (paa & pbb)
449      ! ----------------------------------------
450      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
451         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
452         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
453         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
454         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
455
456         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
457         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
458         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
459         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
460
461      ! monotonic flux in the k direction, i.e. pcc
462      ! -------------------------------------------
463         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
464         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
465         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
466         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
467      END_3D
468      !
469   END SUBROUTINE nonosc
470
471
472   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
473      !!----------------------------------------------------------------------
474      !!                  ***  ROUTINE interp_4th_cpt_org  ***
475      !!
476      !! **  Purpose :   Compute the interpolation of tracer at w-point
477      !!
478      !! **  Method  :   4th order compact interpolation
479      !!----------------------------------------------------------------------
480      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
481      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
482      !
483      INTEGER :: ji, jj, jk   ! dummy loop integers
484      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
485      !!----------------------------------------------------------------------
486     
487      DO_3D( 1, 1, 1, 1, 3, jpkm1 )       !==  build the three diagonal matrix  ==!
488         zwd (ji,jj,jk) = 4._wp
489         zwi (ji,jj,jk) = 1._wp
490         zws (ji,jj,jk) = 1._wp
491         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
492         !
493         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
494            zwd (ji,jj,jk) = 1._wp
495            zwi (ji,jj,jk) = 0._wp
496            zws (ji,jj,jk) = 0._wp
497            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
498         ENDIF
499      END_3D
500      !
501      jk = 2                                    ! Switch to second order centered at top
502      DO_2D( 1, 1, 1, 1 )
503         zwd (ji,jj,jk) = 1._wp
504         zwi (ji,jj,jk) = 0._wp
505         zws (ji,jj,jk) = 0._wp
506         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
507      END_2D
508      !
509      !                       !==  tridiagonal solve  ==!
510      DO_2D( 1, 1, 1, 1 )           ! first recurrence
511         zwt(ji,jj,2) = zwd(ji,jj,2)
512      END_2D
513      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
514         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
515      END_3D
516      !
517      DO_2D( 1, 1, 1, 1 )           ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
518         pt_out(ji,jj,2) = zwrm(ji,jj,2)
519      END_2D
520      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
521         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
522      END_3D
523
524      DO_2D( 1, 1, 1, 1 )           ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
525         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
526      END_2D
527      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
528         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
529      END_3D
530      !   
531   END SUBROUTINE interp_4th_cpt_org
532   
533
534   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
535      !!----------------------------------------------------------------------
536      !!                  ***  ROUTINE interp_4th_cpt  ***
537      !!
538      !! **  Purpose :   Compute the interpolation of tracer at w-point
539      !!
540      !! **  Method  :   4th order compact interpolation
541      !!----------------------------------------------------------------------
542      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
543      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
544      !
545      INTEGER ::   ji, jj, jk   ! dummy loop integers
546      INTEGER ::   ikt, ikb     ! local integers
547      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
548      !!----------------------------------------------------------------------
549      !
550      !                      !==  build the three diagonal matrix & the RHS  ==!
551      !
552      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )    ! interior (from jk=3 to jpk-1)
553         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
554         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
555         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
556         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
557            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
558      END_3D
559      !
560!!gm
561!      SELECT CASE( kbc )               !* boundary condition
562!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
563!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
564!      END SELECT
565!!gm 
566      !
567      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
568         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
569      END IF
570      !
571      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! 2nd order centered at top & bottom
572         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
573         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
574         !
575         zwd (ji,jj,ikt) = 1._wp          ! top
576         zwi (ji,jj,ikt) = 0._wp
577         zws (ji,jj,ikt) = 0._wp
578         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
579         !
580         zwd (ji,jj,ikb) = 1._wp          ! bottom
581         zwi (ji,jj,ikb) = 0._wp
582         zws (ji,jj,ikb) = 0._wp
583         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
584      END_2D
585      !
586      !                       !==  tridiagonal solver  ==!
587      !
588      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
589         zwt(ji,jj,2) = zwd(ji,jj,2)
590      END_2D
591      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
592         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
593      END_3D
594      !
595      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
596         pt_out(ji,jj,2) = zwrm(ji,jj,2)
597      END_2D
598      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
599         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
600      END_3D
601
602      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
603         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
604      END_2D
605      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, 2, -1 )
606         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
607      END_3D
608      !   
609   END SUBROUTINE interp_4th_cpt
610
611
612   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
613      !!----------------------------------------------------------------------
614      !!                  ***  ROUTINE tridia_solver  ***
615      !!
616      !! **  Purpose :   solve a symmetric 3diagonal system
617      !!
618      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
619      !!     
620      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
621      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
622      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
623      !!             (        ...          )( ... )   ( ...  )
624      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
625      !!     
626      !!        M is decomposed in the product of an upper and lower triangular matrix.
627      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
628      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
629      !!        The solution is pta.
630      !!        The 3d array zwt is used as a work space array.
631      !!----------------------------------------------------------------------
632      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
633      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
634      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
635      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
636      !                                                           ! =0 pt at t-level
637      INTEGER ::   ji, jj, jk   ! dummy loop integers
638      INTEGER ::   kstart       ! local indices
639      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
640      !!----------------------------------------------------------------------
641      !
642      kstart =  1  + klev
643      !
644      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                         !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
645         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
646      END_2D
647      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
648         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
649      END_3D
650      !
651      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                        !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
652         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
653      END_2D
654      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
655         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
656      END_3D
657
658      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                       !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
659         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
660      END_2D
661      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, kstart, -1 )
662         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
663      END_3D
664      !
665   END SUBROUTINE tridia_solver
666
667   !!======================================================================
668END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.