source: NEMO/branches/2020/dev_r13648_ASINTER-04_laurent_bulk_ice/src/ICE/icedyn.F90 @ 14021

Last change on this file since 14021 was 14021, checked in by laurent, 5 months ago

Caught up with trunk rev 14020…

  • Property svn:keywords set to Id
File size: 15.8 KB
Line 
1MODULE icedyn
2   !!======================================================================
3   !!                     ***  MODULE  icedyn  ***
4   !!   Sea-Ice dynamics : master routine for sea ice dynamics
5   !!======================================================================
6   !! history :  4.0  ! 2018  (C. Rousset)  original code SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_dyn       : dynamics of sea ice
13   !!   ice_dyn_init  : initialization and namelist read
14   !!----------------------------------------------------------------------
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain
17   USE ice            ! sea-ice: variables
18   USE icedyn_rhg     ! sea-ice: rheology
19   USE icedyn_adv     ! sea-ice: advection
20   USE icedyn_rdgrft  ! sea-ice: ridging/rafting
21   USE icecor         ! sea-ice: corrections
22   USE icevar         ! sea-ice: operations
23   USE icectl         ! sea-ice: control prints
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! I/O manager library
27   USE lib_mpp        ! MPP library
28   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
29   USE lbclnk         ! lateral boundary conditions (or mpp links)
30   USE timing         ! Timing
31   USE fldread        ! read input fields
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   ice_dyn        ! called by icestp.F90
37   PUBLIC   ice_dyn_init   ! called by icestp.F90
38
39   INTEGER ::              nice_dyn   ! choice of the type of dynamics
40   !                                        ! associated indices:
41   INTEGER, PARAMETER ::   np_dynALL     = 1   ! full ice dynamics               (rheology + advection + ridging/rafting + correction)
42   INTEGER, PARAMETER ::   np_dynRHGADV  = 2   ! pure dynamics                   (rheology + advection)
43   INTEGER, PARAMETER ::   np_dynADV1D   = 3   ! only advection 1D - test case from Schar & Smolarkiewicz 1996
44   INTEGER, PARAMETER ::   np_dynADV2D   = 4   ! only advection 2D w prescribed vel.(rn_uvice + advection)
45   !
46   ! ** namelist (namdyn) **
47   LOGICAL  ::   ln_dynALL        ! full ice dynamics                      (rheology + advection + ridging/rafting + correction)
48   LOGICAL  ::   ln_dynRHGADV     ! no ridge/raft & no corrections         (rheology + advection)
49   LOGICAL  ::   ln_dynADV1D      ! only advection in 1D w ice convergence (test case from Schar & Smolarkiewicz 1996)
50   LOGICAL  ::   ln_dynADV2D      ! only advection in 2D w prescribed vel. (rn_uvice + advection)
51   REAL(wp) ::   rn_uice          !    prescribed u-vel (case np_dynADV1D & np_dynADV2D)
52   REAL(wp) ::   rn_vice          !    prescribed v-vel (case np_dynADV1D & np_dynADV2D)
53
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_icbmsk   ! structure of input grounded icebergs mask (file informations, fields read)
55
56   !! * Substitutions
57#  include "do_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (./LICENSE)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE ice_dyn( kt, Kmm )
66      !!-------------------------------------------------------------------
67      !!               ***  ROUTINE ice_dyn  ***
68      !!
69      !! ** Purpose :   this routine manages sea ice dynamics
70      !!
71      !! ** Action : - calculation of friction in case of landfast ice
72      !!             - call ice_dyn_rhg    = rheology
73      !!             - call ice_dyn_adv    = advection
74      !!             - call ice_dyn_rdgrft = ridging/rafting
75      !!             - call ice_cor        = corrections if fields are out of bounds
76      !!--------------------------------------------------------------------
77      INTEGER, INTENT(in) ::   kt     ! ice time step
78      INTEGER, INTENT(in) ::   Kmm    ! ocean time level index
79      !!
80      INTEGER  ::   ji, jj        ! dummy loop indices
81      REAL(wp) ::   zcoefu, zcoefv
82      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zdivu_i
83      !!--------------------------------------------------------------------
84      !
85      ! controls
86      IF( ln_timing )   CALL timing_start('ice_dyn')
87      !
88      IF( kt == nit000 .AND. lwp ) THEN
89         WRITE(numout,*)
90         WRITE(numout,*)'ice_dyn: sea-ice dynamics'
91         WRITE(numout,*)'~~~~~~~'
92      ENDIF
93      !
94      ! retrieve thickness from volume for landfast param. and UMx advection scheme
95      WHERE( a_i(:,:,:) >= epsi20 )
96         h_i(:,:,:) = v_i(:,:,:) / a_i_b(:,:,:)
97         h_s(:,:,:) = v_s(:,:,:) / a_i_b(:,:,:)
98      ELSEWHERE
99         h_i(:,:,:) = 0._wp
100         h_s(:,:,:) = 0._wp
101      END WHERE
102      !
103      WHERE( a_ip(:,:,:) >= epsi20 )
104         h_ip(:,:,:) = v_ip(:,:,:) / a_ip(:,:,:)
105         h_il(:,:,:) = v_il(:,:,:) / a_ip(:,:,:)
106      ELSEWHERE
107         h_ip(:,:,:) = 0._wp
108         h_il(:,:,:) = 0._wp
109      END WHERE
110      !
111      IF( ln_landfast_L16 ) THEN
112         CALL fld_read( kt, 1, sf_icbmsk )
113         icb_mask(:,:) = sf_icbmsk(1)%fnow(:,:,1)
114      ENDIF
115      !
116      SELECT CASE( nice_dyn )          !-- Set which dynamics is running
117
118      CASE ( np_dynALL )           !==  all dynamical processes  ==!
119         !
120         CALL ice_dyn_rhg   ( kt, Kmm )                                     ! -- rheology
121         CALL ice_dyn_adv   ( kt )                                          ! -- advection of ice
122         CALL ice_dyn_rdgrft( kt )                                          ! -- ridging/rafting
123         CALL ice_cor       ( kt , 1 )                                      ! -- Corrections
124         !
125      CASE ( np_dynRHGADV  )       !==  no ridge/raft & no corrections ==!
126         !
127         CALL ice_dyn_rhg   ( kt, Kmm )                                     ! -- rheology
128         CALL ice_dyn_adv   ( kt )                                          ! -- advection of ice
129         CALL Hpiling                                                       ! -- simple pile-up (replaces ridging/rafting)
130         CALL ice_var_zapsmall                                              ! -- zap small areas
131         !
132      CASE ( np_dynADV1D )         !==  pure advection ==!   (1D)
133         !
134         ! --- monotonicity test from Schar & Smolarkiewicz 1996 --- !
135         ! CFL = 0.5 at a distance from the bound of 1/6 of the basin length
136         ! Then for dx = 2m and dt = 1s => rn_uice = u (1/6th) = 1m/s
137         DO_2D( 1, 1, 1, 1 )
138            zcoefu = ( REAL(jpiglo+1)*0.5_wp - REAL(ji+nimpp-1) ) / ( REAL(jpiglo+1)*0.5_wp - 1._wp )
139            zcoefv = ( REAL(jpjglo+1)*0.5_wp - REAL(jj+njmpp-1) ) / ( REAL(jpjglo+1)*0.5_wp - 1._wp )
140            u_ice(ji,jj) = rn_uice * 1.5_wp * SIGN( 1.0_wp, zcoefu ) * ABS( zcoefu ) * umask(ji,jj,1)
141            v_ice(ji,jj) = rn_vice * 1.5_wp * SIGN( 1.0_wp, zcoefv ) * ABS( zcoefv ) * vmask(ji,jj,1)
142         END_2D
143         ! ---
144         CALL ice_dyn_adv   ( kt )                                          ! -- advection of ice
145         !
146      CASE ( np_dynADV2D )         !==  pure advection ==!   (2D w prescribed velocities)
147         !
148         u_ice(:,:) = rn_uice * umask(:,:,1)
149         v_ice(:,:) = rn_vice * vmask(:,:,1)
150         !CALL RANDOM_NUMBER(u_ice(:,:)) ; u_ice(:,:) = u_ice(:,:) * 0.1 + rn_uice * 0.9 * umask(:,:,1)
151         !CALL RANDOM_NUMBER(v_ice(:,:)) ; v_ice(:,:) = v_ice(:,:) * 0.1 + rn_vice * 0.9 * vmask(:,:,1)
152         ! ---
153         CALL ice_dyn_adv   ( kt )                                          ! -- advection of ice
154
155      END SELECT
156      !
157      !
158      ! diagnostics: divergence at T points
159      IF( iom_use('icediv') ) THEN
160         !
161         SELECT CASE( nice_dyn )
162
163         CASE ( np_dynADV1D , np_dynADV2D )
164
165            ALLOCATE( zdivu_i(jpi,jpj) )
166            DO_2D( 0, 0, 0, 0 )
167               zdivu_i(ji,jj) = ( e2u(ji,jj) * u_ice(ji,jj) - e2u(ji-1,jj) * u_ice(ji-1,jj)   &
168                  &             + e1v(ji,jj) * v_ice(ji,jj) - e1v(ji,jj-1) * v_ice(ji,jj-1) ) * r1_e1e2t(ji,jj)
169            END_2D
170            CALL lbc_lnk( 'icedyn', zdivu_i, 'T', 1.0_wp )
171            ! output
172            CALL iom_put( 'icediv' , zdivu_i )
173
174            DEALLOCATE( zdivu_i )
175
176         END SELECT
177         !
178      ENDIF
179      !
180      ! controls
181      IF( ln_timing )   CALL timing_stop ('ice_dyn')
182      !
183   END SUBROUTINE ice_dyn
184
185
186   SUBROUTINE Hpiling
187      !!-------------------------------------------------------------------
188      !!                  ***  ROUTINE Hpiling  ***
189      !!
190      !! ** Purpose : Simple conservative piling comparable with 1-cat models
191      !!
192      !! ** Method  : pile-up ice when no ridging/rafting
193      !!
194      !! ** input   : a_i
195      !!-------------------------------------------------------------------
196      INTEGER ::   jl         ! dummy loop indices
197      !!-------------------------------------------------------------------
198      ! controls
199      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'Hpiling', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
200      !
201      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
202      DO jl = 1, jpl
203         WHERE( at_i(:,:) > epsi20 )
204            a_i(:,:,jl) = a_i(:,:,jl) * (  1._wp + MIN( rn_amax_2d(:,:) - at_i(:,:) , 0._wp ) / at_i(:,:)  )
205         END WHERE
206      END DO
207      ! controls
208      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'Hpiling', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
209      !
210   END SUBROUTINE Hpiling
211
212
213   SUBROUTINE ice_dyn_init
214      !!-------------------------------------------------------------------
215      !!                  ***  ROUTINE ice_dyn_init  ***
216      !!
217      !! ** Purpose : Physical constants and parameters linked to the ice
218      !!      dynamics
219      !!
220      !! ** Method  :  Read the namdyn namelist and check the ice-dynamic
221      !!       parameter values called at the first timestep (nit000)
222      !!
223      !! ** input   :   Namelist namdyn
224      !!-------------------------------------------------------------------
225      INTEGER ::   ios, ioptio, ierror   ! Local integer output status for namelist read
226      !
227      CHARACTER(len=256) ::   cn_dir     ! Root directory for location of ice files
228      TYPE(FLD_N)        ::   sn_icbmsk  ! informations about the grounded icebergs field to be read
229      !!
230      NAMELIST/namdyn/ ln_dynALL, ln_dynRHGADV, ln_dynADV1D, ln_dynADV2D, rn_uice, rn_vice,  &
231         &             rn_ishlat ,                                                           &
232         &             ln_landfast_L16, rn_lf_depfra, rn_lf_bfr, rn_lf_relax, rn_lf_tensile, &
233         &             sn_icbmsk, cn_dir
234      !!-------------------------------------------------------------------
235      !
236      READ  ( numnam_ice_ref, namdyn, IOSTAT = ios, ERR = 901)
237901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn in reference namelist' )
238      READ  ( numnam_ice_cfg, namdyn, IOSTAT = ios, ERR = 902 )
239902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn in configuration namelist' )
240      IF(lwm) WRITE( numoni, namdyn )
241      !
242      IF(lwp) THEN                     ! control print
243         WRITE(numout,*)
244         WRITE(numout,*) 'ice_dyn_init: ice parameters for ice dynamics '
245         WRITE(numout,*) '~~~~~~~~~~~~'
246         WRITE(numout,*) '   Namelist namdyn:'
247         WRITE(numout,*) '      Full ice dynamics      (rhg + adv + ridge/raft + corr) ln_dynALL       = ', ln_dynALL
248         WRITE(numout,*) '      No ridge/raft & No cor (rhg + adv)                     ln_dynRHGADV    = ', ln_dynRHGADV
249         WRITE(numout,*) '      Advection 1D only      (Schar & Smolarkiewicz 1996)    ln_dynADV1D     = ', ln_dynADV1D
250         WRITE(numout,*) '      Advection 2D only      (rn_uvice + adv)                ln_dynADV2D     = ', ln_dynADV2D
251         WRITE(numout,*) '         with prescribed velocity given by   (u,v)_ice = (rn_uice,rn_vice)   = (', rn_uice,',',rn_vice,')'
252         WRITE(numout,*) '      lateral boundary condition for sea ice dynamics        rn_ishlat       = ', rn_ishlat
253         WRITE(numout,*) '      Landfast: param from Lemieux 2016                      ln_landfast_L16 = ', ln_landfast_L16
254         WRITE(numout,*) '         fraction of ocean depth that ice must reach         rn_lf_depfra    = ', rn_lf_depfra
255         WRITE(numout,*) '         maximum bottom stress per unit area of contact      rn_lf_bfr       = ', rn_lf_bfr
256         WRITE(numout,*) '         relax time scale (s-1) to reach static friction     rn_lf_relax     = ', rn_lf_relax
257         WRITE(numout,*) '         isotropic tensile strength                          rn_lf_tensile   = ', rn_lf_tensile
258         WRITE(numout,*)
259      ENDIF
260      !                             !== set the choice of ice dynamics ==!
261      ioptio = 0
262      !      !--- full dynamics                               (rheology + advection + ridging/rafting + correction)
263      IF( ln_dynALL    ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynALL       ;   ENDIF
264      !      !--- dynamics without ridging/rafting and corr   (rheology + advection)
265      IF( ln_dynRHGADV ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynRHGADV    ;   ENDIF
266      !      !--- advection 1D only - test case from Schar & Smolarkiewicz 1996
267      IF( ln_dynADV1D  ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynADV1D     ;   ENDIF
268      !      !--- advection 2D only with prescribed ice velocities (from namelist)
269      IF( ln_dynADV2D  ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynADV2D     ;   ENDIF
270      !
271      IF( ioptio /= 1 )    CALL ctl_stop( 'ice_dyn_init: one and only one ice dynamics option has to be defined ' )
272      !
273      !                                      !--- Lateral boundary conditions
274      IF     (      rn_ishlat == 0.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  free-slip'
275      ELSEIF (      rn_ishlat == 2.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  no-slip'
276      ELSEIF ( 0. < rn_ishlat .AND. rn_ishlat < 2. ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  partial-slip'
277      ELSEIF ( 2. < rn_ishlat                      ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  strong-slip'
278      ENDIF
279      !                                      !--- Landfast ice
280      IF( .NOT.ln_landfast_L16 )   tau_icebfr(:,:) = 0._wp
281      !
282      !                                      !--- allocate and fill structure for grounded icebergs mask
283      IF( ln_landfast_L16 ) THEN
284         ALLOCATE( sf_icbmsk(1), STAT=ierror )
285         IF( ierror > 0 ) THEN
286            CALL ctl_stop( 'ice_dyn_init: unable to allocate sf_icbmsk structure' ) ; RETURN
287         ENDIF
288         !
289         CALL fld_fill( sf_icbmsk, (/ sn_icbmsk /), cn_dir, 'ice_dyn_init',   &
290            &                                               'landfast ice is a function of read grounded icebergs', 'icedyn' )
291         !
292         ALLOCATE( sf_icbmsk(1)%fnow(jpi,jpj,1) )
293         IF( sf_icbmsk(1)%ln_tint )   ALLOCATE( sf_icbmsk(1)%fdta(jpi,jpj,1,2) )
294         IF( TRIM(sf_icbmsk(1)%clrootname) == 'NOT USED' ) sf_icbmsk(1)%fnow(:,:,1) = 0._wp   ! not used field  (set to 0)
295      ELSE
296         icb_mask(:,:) = 0._wp
297      ENDIF
298      !                                      !--- other init
299      CALL ice_dyn_rdgrft_init          ! set ice ridging/rafting parameters
300      CALL ice_dyn_rhg_init             ! set ice rheology parameters
301      CALL ice_dyn_adv_init             ! set ice advection parameters
302      !
303   END SUBROUTINE ice_dyn_init
304
305#else
306   !!----------------------------------------------------------------------
307   !!   Default option         Empty module           NO SI3 sea-ice model
308   !!----------------------------------------------------------------------
309#endif
310
311   !!======================================================================
312END MODULE icedyn
Note: See TracBrowser for help on using the repository browser.