New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13898_Tiling_Cleanup_MPI3/src/OCE/TRA/traadv.F90 @ 13906

Last change on this file since 13906 was 13906, checked in by mocavero, 4 years ago

Merge with dev_r13296_HPC-07_mocavero_mpi3
  • Property svn:keywords set to Id
File size: 19.6 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_init  : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   ! TEMP: [tiling] This change not necessary after extended haloes development
21   USE domain, ONLY : dom_tile
22   USE domvvl         ! variable vertical scale factors
23   USE sbcwave        ! wave module
24   USE sbc_oce        ! surface boundary condition: ocean
25   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
26   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
27   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
28   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
29   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
30   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
31   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
32   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
33   USE trd_oce        ! trends: ocean variables
34   USE trdtra         ! trends manager: tracers
35   USE diaptr         ! Poleward heat transport
36   !
37   USE in_out_manager ! I/O manager
38   USE iom            ! I/O module
39   USE prtctl         ! Print control
40   USE lib_mpp        ! MPP library
41   USE timing         ! Timing
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   tra_adv        ! called by step.F90
47   PUBLIC   tra_adv_init   ! called by nemogcm.F90
48
49   !                            !!* Namelist namtra_adv *
50   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
51   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
52   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
53   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
54   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
55   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
56   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
57   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
58   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
59   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
60
61   INTEGER ::   nadv             ! choice of the type of advection scheme
62   !                             ! associated indices:
63   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
64   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
65   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
66   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
67   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
68   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
69
70   !! * Substitutions
71#  include "do_loop_substitute.h90"
72#  include "domzgr_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
75   !! $Id$
76   !! Software governed by the CeCILL license (see ./LICENSE)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE tra_adv( kt, Kbb, Kmm, pts, Krhs )
81      !!----------------------------------------------------------------------
82      !!                  ***  ROUTINE tra_adv  ***
83      !!
84      !! ** Purpose :   compute the ocean tracer advection trend.
85      !!
86      !! ** Method  : - Update (uu(:,:,:,Krhs),vv(:,:,:,Krhs)) with the advection term following nadv
87      !!----------------------------------------------------------------------
88      INTEGER                                  , INTENT(in)    :: kt             ! ocean time-step index
89      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs ! time level indices
90      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers and RHS of tracer equation
91      !
92      INTEGER ::   ji, jj, jk   ! dummy loop index
93      ! TEMP: [tiling] This change not necessary and can be A2D(nn_hls) if using XIOS (subdomain support)
94      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zuu, zvv, zww   ! 3D workspace
95      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrdt, ztrds
96      ! TEMP: [tiling] This change not necessary after extra haloes development
97      LOGICAL :: lskip
98      !!----------------------------------------------------------------------
99      !
100      IF( ln_timing )   CALL timing_start('tra_adv')
101      !
102      lskip = .FALSE.
103
104      ! TEMP: [tiling] These changes not necessary if using XIOS (subdomain support)
105      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
106         ALLOCATE( zuu(jpi,jpj,jpk), zvv(jpi,jpj,jpk), zww(jpi,jpj,jpk) )
107      ENDIF
108
109      ! TEMP: [tiling] These changes not necessary after extra haloes development (lbc_lnk removed from tra_adv_*) and if XIOS has subdomain support (ldf_eiv_dia)
110      IF( nadv /= np_CEN .OR. (nadv == np_CEN .AND. nn_cen_h == 4) .OR. ln_ldfeiv_dia )  THEN
111         IF( ln_tile ) THEN
112            IF( ntile == 1 ) THEN
113               CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
114            ELSE
115               lskip = .TRUE.
116            ENDIF
117         ENDIF
118      ENDIF
119      IF( .NOT. lskip ) THEN
120         !                                         !==  effective transport  ==!
121         IF( ln_wave .AND. ln_sdw )  THEN
122            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
123               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * ( uu(ji,jj,jk,Kmm) + usd(ji,jj,jk) )
124               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * ( vv(ji,jj,jk,Kmm) + vsd(ji,jj,jk) )
125               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ( ww(ji,jj,jk)     + wsd(ji,jj,jk) )
126            END_3D
127         ELSE
128            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
129               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * uu(ji,jj,jk,Kmm)               ! eulerian transport only
130               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * vv(ji,jj,jk,Kmm)
131               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ww(ji,jj,jk)
132            END_3D
133         ENDIF
134         !
135         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
136            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
137               zuu(ji,jj,jk) = zuu(ji,jj,jk) + un_td(ji,jj,jk)
138               zvv(ji,jj,jk) = zvv(ji,jj,jk) + vn_td(ji,jj,jk)
139            END_3D
140         ENDIF
141         !
142         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
143            zuu(ji,jj,jpk) = 0._wp                                                      ! no transport trough the bottom
144            zvv(ji,jj,jpk) = 0._wp
145            zww(ji,jj,jpk) = 0._wp
146         END_2D
147         !
148         ! TEMP: [tiling] These changes not necessary if using XIOS (subdomain support)
149         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
150            &              CALL ldf_eiv_trp( kt, nit000, zuu(A2D(nn_hls),:), zvv(A2D(nn_hls),:), zww(A2D(nn_hls),:), &
151            &                                'TRA', Kmm, Krhs )   ! add the eiv transport (if necessary)
152         !
153         IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zuu(A2D(nn_hls),:), zvv(A2D(nn_hls),:), zww(A2D(nn_hls),:), &
154            &                                'TRA', Kmm       )   ! add the mle transport (if necessary)
155         !
156         ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
157         IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
158            CALL iom_put( "uocetr_eff", zuu )                                        ! output effective transport
159            CALL iom_put( "vocetr_eff", zvv )
160            CALL iom_put( "wocetr_eff", zww )
161         ENDIF
162         !
163   !!gm ???
164         ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
165         CALL dia_ptr( kt, Kmm, zvv(A2D(nn_hls),:) )                                    ! diagnose the effective MSF
166   !!gm ???
167         !
168
169         IF( l_trdtra )   THEN                    !* Save ta and sa trends
170            ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
171            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
172            ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
173         ENDIF
174         !
175         ! NOTE: [tiling-comms-merge] These lbc_lnk calls are still needed (pts in the zco case because zps_hde is not called in step, zuu/zvv/zww in all cases, I think because DO loop bounds need to be updated in DYN as done in TRA)
176         SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
177         !
178         CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
179            CALL tra_adv_cen    ( kt, nit000, 'TRA',         zuu, zvv, zww, Kmm, pts, jpts, Krhs, nn_cen_h, nn_cen_v )
180         CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
181            IF (nn_hls.EQ.2) THEN
182#if defined key_mpi3
183               CALL lbc_lnk_nc_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1., pts(:,:,:,:,Kmm), 'T', 1.)
184               CALL lbc_lnk_nc_multi( 'traadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1., zww(:,:,:), 'W', 1.)
185#else
186               CALL lbc_lnk_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1., pts(:,:,:,:,Kmm), 'T', 1.)
187               CALL lbc_lnk_multi( 'traadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1., zww(:,:,:), 'W', 1.)
188#endif
189            END IF
190            CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
191         CASE ( np_MUS )                                 ! MUSCL
192            ! NOTE: [tiling-comms-merge] I added this lbc_lnk as it did not validate against the trunk when using ln_zco
193#if defined key_mpi3
194            IF (nn_hls.EQ.2) CALL lbc_lnk_nc_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1.)
195#else
196            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1.)
197#endif
198            CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
199         CASE ( np_UBS )                                 ! UBS
200#if defined key_mpi3
201            IF (nn_hls.EQ.2) CALL lbc_lnk_nc_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1.)
202#else
203            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1.)
204#endif
205            CALL tra_adv_ubs    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_ubs_v   )
206         CASE ( np_QCK )                                 ! QUICKEST
207            IF (nn_hls.EQ.2) THEN
208#if defined key_mpi3
209               CALL lbc_lnk_nc_multi( 'traadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1.)
210               CALL lbc_lnk_nc_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1.)
211#else
212               CALL lbc_lnk_multi( 'traadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1.)
213               CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1.)
214#endif
215            END IF
216            CALL tra_adv_qck    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs )
217         !
218         END SELECT
219         !
220         IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
221            DO jk = 1, jpkm1
222               ztrdt(:,:,jk) = pts(:,:,jk,jp_tem,Krhs) - ztrdt(:,:,jk)
223               ztrds(:,:,jk) = pts(:,:,jk,jp_sal,Krhs) - ztrds(:,:,jk)
224            END DO
225            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_totad, ztrdt )
226            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_totad, ztrds )
227            DEALLOCATE( ztrdt, ztrds )
228         ENDIF
229
230         ! TEMP: [tiling] This change not necessary after extra haloes development (lbc_lnk removed from tra_adv_*) and if XIOS has subdomain support (ldf_eiv_dia)
231         IF( ln_tile .AND. ntile == 0 ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 1 )
232
233      ENDIF
234      !                                              ! print mean trends (used for debugging)
235      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' adv  - Ta: ', mask1=tmask, &
236         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
237
238      ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
239      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
240         DEALLOCATE( zuu, zvv, zww )
241      ENDIF
242      !
243      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
244      !
245   END SUBROUTINE tra_adv
246
247
248   SUBROUTINE tra_adv_init
249      !!---------------------------------------------------------------------
250      !!                  ***  ROUTINE tra_adv_init  ***
251      !!               
252      !! ** Purpose :   Control the consistency between namelist options for
253      !!              tracer advection schemes and set nadv
254      !!----------------------------------------------------------------------
255      INTEGER ::   ioptio, ios   ! Local integers
256      !
257      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
258         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
259         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
260         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
261         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
262         &                 ln_traadv_qck                             ! QCK
263      !!----------------------------------------------------------------------
264      !
265      !                                !==  Namelist  ==!
266      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
267901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist' )
268      !
269      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
270902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist' )
271      IF(lwm) WRITE( numond, namtra_adv )
272      !
273      IF(lwp) THEN                           ! Namelist print
274         WRITE(numout,*)
275         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
276         WRITE(numout,*) '~~~~~~~~~~~~'
277         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
278         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
279         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
280         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
281         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
282         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
283         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
284         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
285         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
286         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
287         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
288         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
289         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
290      ENDIF
291      !
292      !                                !==  Parameter control & set nadv ==!
293      ioptio = 0                       
294      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
295      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
296      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
297      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
298      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
299      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
300      !
301      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
302      !
303      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
304                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
305        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
306      ENDIF
307      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
308                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
309        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
310      ENDIF
311      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
312        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
313      ENDIF
314      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
315         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
316      ENDIF
317      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
318         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
319            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
320      ENDIF
321      !
322      !                                !==  Print the choice  ==! 
323      IF(lwp) THEN
324         WRITE(numout,*)
325         SELECT CASE ( nadv )
326         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
327         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
328            &                                                                        ' Vertical   order: ', nn_cen_v
329         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
330            &                                                                        ' Vertical   order: ', nn_fct_v
331         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
332         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
333         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
334         END SELECT
335      ENDIF
336      !
337      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
338      !
339   END SUBROUTINE tra_adv_init
340
341  !!======================================================================
342END MODULE traadv
Note: See TracBrowser for help on using the repository browser.