New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2020/dev_r13923_Tiling_Cleanup_MPI3_LoopFusion/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13923_Tiling_Cleanup_MPI3_LoopFusion/src/OCE/TRA/traadv_fct.F90 @ 13946

Last change on this file since 13946 was 13946, checked in by francesca, 4 years ago

Merge with dev_r13508_HPC-09_loop_fusion
  • Property svn:keywords set to Id
File size: 37.8 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36   PUBLIC   tridia_solver      ! called by traadv_fct_lf.F90
37   PUBLIC   nonosc             ! called by traadv_fct_lf.F90 - key_agrif
38
39   LOGICAL  ::   l_trd   ! flag to compute trends
40   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
41   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
42   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
43
44   !                                        ! tridiag solver associated indices:
45   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
46   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50#  include "domzgr_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
53   !! $Id$
54   !! Software governed by the CeCILL license (see ./LICENSE)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
59      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE tra_adv_fct  ***
62      !!
63      !! **  Purpose :   Compute the now trend due to total advection of tracers
64      !!               and add it to the general trend of tracer equations
65      !!
66      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
67      !!               (choice through the value of kn_fct)
68      !!               - on the vertical the 4th order is a compact scheme
69      !!               - corrected flux (monotonic correction)
70      !!
71      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
72      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
73      !!             - poleward advective heat and salt transport (ln_diaptr=T)
74      !!----------------------------------------------------------------------
75      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
77      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
78      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
79      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
80      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
81      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
82      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
83      ! TEMP: [tiling] This can be A2D(nn_hls) if using XIOS (subdomain support)
84      ! NOTE: [tiling-comms-merge] These were changed to INTENT(inout) but they are not modified, so it is reverted
85      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
86      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
87      !
88      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices
89      REAL(wp) ::   ztra                                     ! local scalar
90      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
91      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
92      REAL(wp), DIMENSION(A2D(nn_hls),jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
93      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
94      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
95      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
96      !!----------------------------------------------------------------------
97      !
98      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
99         IF( kt == kit000 )  THEN
100            IF(lwp) WRITE(numout,*)
101            IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
102            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
103         ENDIF
104         ! NOTE: [tiling-comms-merge] Bug fix- move array zeroing out of this IF block
105         !
106         l_trd = .FALSE.            ! set local switches
107         l_hst = .FALSE.
108         l_ptr = .FALSE.
109         ll_zAimp = .FALSE.
110         IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
111         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE.
112         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
113            &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
114         !
115      ENDIF
116
117      !! -- init to 0
118      zwi(:,:,:) = 0._wp
119      zwx(:,:,:) = 0._wp
120      zwy(:,:,:) = 0._wp
121      zwz(:,:,:) = 0._wp
122      ztu(:,:,:) = 0._wp
123      ztv(:,:,:) = 0._wp
124      zltu(:,:,:) = 0._wp
125      zltv(:,:,:) = 0._wp
126      ztw(:,:,:) = 0._wp
127      !
128      IF( l_trd .OR. l_hst )  THEN
129         ALLOCATE( ztrdx(A2D(nn_hls),jpk), ztrdy(A2D(nn_hls),jpk), ztrdz(A2D(nn_hls),jpk) )
130         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
131      ENDIF
132      !
133      IF( l_ptr ) THEN
134         ALLOCATE( zptry(A2D(nn_hls),jpk) )
135         zptry(:,:,:) = 0._wp
136      ENDIF
137      !
138      ! If adaptive vertical advection, check if it is needed on this PE at this time
139      IF( ln_zad_Aimp ) THEN
140         IF( MAXVAL( ABS( wi(A2D(nn_hls),:) ) ) > 0._wp ) ll_zAimp = .TRUE.
141      END IF
142      ! If active adaptive vertical advection, build tridiagonal matrix
143      IF( ll_zAimp ) THEN
144         ALLOCATE(zwdia(A2D(nn_hls),jpk), zwinf(A2D(nn_hls),jpk), zwsup(A2D(nn_hls),jpk))
145         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
146            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
147            &                               / e3t(ji,jj,jk,Krhs)
148            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
149            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
150         END_3D
151      END IF
152      !
153      DO jn = 1, kjpt            !==  loop over the tracers  ==!
154         !
155         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
156         !                    !* upstream tracer flux in the i and j direction
157         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
158            ! upstream scheme
159            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
160            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
161            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
162            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
163            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
164            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
165         END_3D
166         !                               !* upstream tracer flux in the k direction *!
167         DO_3D( 1, 1, 1, 1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
168            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
169            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
170            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
171         END_3D
172         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
173            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
174               DO_2D( 1, 1, 1, 1 )
175                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
176               END_2D
177            ELSE                                        ! no cavities: only at the ocean surface
178               DO_2D( 1, 1, 1, 1 )
179                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
180               END_2D
181            ENDIF
182         ENDIF
183         !               
184         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )   !* trend and after field with monotonic scheme
185            !                               ! total intermediate advective trends
186            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
187               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
188               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
189            !                               ! update and guess with monotonic sheme
190            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
191               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
192            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
193               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
194         END_3D
195         
196         IF ( ll_zAimp ) THEN
197            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
198            !
199            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
200            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
201               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
202               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
203               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
204               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
205            END_3D
206            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
207               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
208                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
209            END_3D
210            !
211         END IF
212         !
213         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
214            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
215         END IF
216         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
217         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
218         !
219         !        !==  anti-diffusive flux : high order minus low order  ==!
220         !
221         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
222         !
223         CASE(  2  )                   !- 2nd order centered
224            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
225               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
226               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
227            END_3D
228            !
229         CASE(  4  )                   !- 4th order centered
230            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
231            zltv(:,:,jpk) = 0._wp
232            DO jk = 1, jpkm1                 ! Laplacian
233               DO_2D( 1, 0, 1, 0 )                 ! 1st derivative (gradient)
234                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
235                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
236               END_2D
237               DO_2D( 0, 0, 0, 0 )                 ! 2nd derivative * 1/ 6
238                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
239                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
240               END_2D
241            END DO
242#if defined key_mpi3
243            CALL lbc_lnk_nc_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp, ncsten=.FALSE. )   ! Lateral boundary cond. (unchanged sgn)
244#else
245            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
246#endif
247            !
248            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
249               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
250               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
251               !                                                        ! C4 minus upstream advective fluxes
252               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
253               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
254            END_3D
255#if defined key_mpi3
256            IF (nn_hls.EQ.2) CALL lbc_lnk_nc_multi( 'traadv_fct', zwx, 'U', -1.0_wp, zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
257#else
258            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp, zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
259#endif
260            !
261         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
262            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
263            ztv(:,:,jpk) = 0._wp
264            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )    ! 1st derivative (gradient)
265               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
266               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
267            END_3D
268#if defined key_mpi3
269            IF (nn_hls.EQ.1) CALL lbc_lnk_nc_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
270#else
271            IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
272#endif
273            !
274            IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
275            !
276            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
277               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
278               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
279               !                                                  ! C4 interpolation of T at u- & v-points (x2)
280               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
281               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
282               !                                                  ! C4 minus upstream advective fluxes
283               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
284               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
285            END_3D
286#if defined key_mpi3
287            IF (nn_hls.EQ.2) CALL lbc_lnk_nc_multi( 'traadv_fct', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
288#else
289            IF (nn_hls.EQ.2) CALL lbc_lnk_multi( 'traadv_fct', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
290#endif
291            !
292         END SELECT
293         !                     
294         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
295         !
296         CASE(  2  )                   !- 2nd order centered
297            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
298               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
299                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
300            END_3D
301            !
302         CASE(  4  )                   !- 4th order COMPACT
303            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
304            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
305               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
306            END_3D
307            !
308         END SELECT
309         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
310            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
311         ENDIF
312         !
313         IF (nn_hls.EQ.1) THEN
314#if defined key_mpi3
315            CALL lbc_lnk_nc_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
316#else
317            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
318#endif
319         ELSE
320#if defined key_mpi3
321            CALL lbc_lnk_nc_multi( 'traadv_fct', zwi, 'T', 1.0_wp)
322#else
323            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
324#endif
325         END IF
326         !
327         IF (nn_hls.EQ.1) THEN
328            CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
329         ELSE
330            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
331         END IF
332         !
333         IF ( ll_zAimp ) THEN
334            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !* trend and after field with monotonic scheme
335               !                                                ! total intermediate advective trends
336               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
337                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
338                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
339               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
340            END_3D
341            !
342            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
343            !
344            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
345               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
346               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
347               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
348            END_3D
349         END IF
350         !
351         !        !==  monotonicity algorithm  ==!
352         !
353         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
354         !
355         !        !==  final trend with corrected fluxes  ==!
356         !
357         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
358            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
359               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
360               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
361            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
362            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
363         END_3D
364         !
365         IF ( ll_zAimp ) THEN
366            !
367            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
368            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
369               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
370               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
371               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
372               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
373            END_3D
374            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
375               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
376                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
377            END_3D
378         END IF
379         ! NOTE: [tiling-comms-merge] I tested this
380         ! NOT TESTED - NEED l_trd OR l_hst TRUE
381         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
382            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
383            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
384            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
385            !
386            IF( l_trd ) THEN              ! trend diagnostics
387               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
388               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
389               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
390            ENDIF
391            !                             ! heat/salt transport
392            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
393            !
394         ENDIF
395         ! NOTE: [tiling-comms-merge] I tested this
396         ! NOT TESTED - NEED l_ptr TRUE
397         IF( l_ptr ) THEN              ! "Poleward" transports
398            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
399            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
400         ENDIF
401         !
402      END DO                     ! end of tracer loop
403      !
404      IF ( ll_zAimp ) THEN
405         DEALLOCATE( zwdia, zwinf, zwsup )
406      ENDIF
407      IF( l_trd .OR. l_hst ) THEN
408         DEALLOCATE( ztrdx, ztrdy, ztrdz )
409      ENDIF
410      IF( l_ptr ) THEN
411         DEALLOCATE( zptry )
412      ENDIF
413      !
414   END SUBROUTINE tra_adv_fct
415
416
417   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
418      !!---------------------------------------------------------------------
419      !!                    ***  ROUTINE nonosc  ***
420      !!     
421      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
422      !!       scheme and the before field by a nonoscillatory algorithm
423      !!
424      !! **  Method  :   ... ???
425      !!       warning : pbef and paft must be masked, but the boundaries
426      !!       conditions on the fluxes are not necessary zalezak (1979)
427      !!       drange (1995) multi-dimensional forward-in-time and upstream-
428      !!       in-space based differencing for fluid
429      !!----------------------------------------------------------------------
430      INTEGER                         , INTENT(in   ) ::   Kmm             ! time level index
431      REAL(wp)                        , INTENT(in   ) ::   p2dt            ! tracer time-step
432      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pbef            ! before field
433      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(in   ) ::   paft            ! after field
434      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
435      !
436      INTEGER  ::   ji, jj, jk   ! dummy loop indices
437      INTEGER  ::   ikm1         ! local integer
438      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
439      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
440      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zbetup, zbetdo, zbup, zbdo
441      !!----------------------------------------------------------------------
442      !
443      zbig  = 1.e+40_dp
444      zrtrn = 1.e-15_dp
445      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
446
447      ! Search local extrema
448      ! --------------------
449      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
450      DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpk )
451         zbup(ji,jj,jk) = MAX( pbef(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
452            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) )  )
453         zbdo(ji,jj,jk) = MIN( pbef(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
454            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) )  )
455      END_3D
456
457      DO jk = 1, jpkm1
458         ikm1 = MAX(jk-1,1)
459         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
460
461            ! search maximum in neighbourhood
462            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
463               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
464               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
465               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
466
467            ! search minimum in neighbourhood
468            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
469               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
470               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
471               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
472
473            ! positive part of the flux
474            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
475               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
476               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
477
478            ! negative part of the flux
479            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
480               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
481               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
482
483            ! up & down beta terms
484            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
485            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
486            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
487         END_2D
488      END DO
489#if defined key_mpi3
490      IF (nn_hls.EQ.1) CALL lbc_lnk_nc_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
491#else
492      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
493#endif
494
495      ! 3. monotonic flux in the i & j direction (paa & pbb)
496      ! ----------------------------------------
497      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
498         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
499         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
500         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
501         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
502
503         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
504         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
505         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
506         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
507
508      ! monotonic flux in the k direction, i.e. pcc
509      ! -------------------------------------------
510         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
511         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
512         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
513         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
514      END_3D
515      !
516   END SUBROUTINE nonosc
517
518
519   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
520      !!----------------------------------------------------------------------
521      !!                  ***  ROUTINE interp_4th_cpt_org  ***
522      !!
523      !! **  Purpose :   Compute the interpolation of tracer at w-point
524      !!
525      !! **  Method  :   4th order compact interpolation
526      !!----------------------------------------------------------------------
527      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
528      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
529      !
530      INTEGER :: ji, jj, jk   ! dummy loop integers
531      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
532      !!----------------------------------------------------------------------
533     
534      DO_3D( 1, 1, 1, 1, 3, jpkm1 )       !==  build the three diagonal matrix  ==!
535         zwd (ji,jj,jk) = 4._wp
536         zwi (ji,jj,jk) = 1._wp
537         zws (ji,jj,jk) = 1._wp
538         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
539         !
540         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
541            zwd (ji,jj,jk) = 1._wp
542            zwi (ji,jj,jk) = 0._wp
543            zws (ji,jj,jk) = 0._wp
544            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
545         ENDIF
546      END_3D
547      !
548      jk = 2                                    ! Switch to second order centered at top
549      DO_2D( 1, 1, 1, 1 )
550         zwd (ji,jj,jk) = 1._wp
551         zwi (ji,jj,jk) = 0._wp
552         zws (ji,jj,jk) = 0._wp
553         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
554      END_2D
555      !
556      !                       !==  tridiagonal solve  ==!
557      DO_2D( 1, 1, 1, 1 )           ! first recurrence
558         zwt(ji,jj,2) = zwd(ji,jj,2)
559      END_2D
560      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
561         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
562      END_3D
563      !
564      DO_2D( 1, 1, 1, 1 )           ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
565         pt_out(ji,jj,2) = zwrm(ji,jj,2)
566      END_2D
567      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
568         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
569      END_3D
570
571      DO_2D( 1, 1, 1, 1 )           ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
572         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
573      END_2D
574      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
575         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
576      END_3D
577      !   
578   END SUBROUTINE interp_4th_cpt_org
579   
580
581   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
582      !!----------------------------------------------------------------------
583      !!                  ***  ROUTINE interp_4th_cpt  ***
584      !!
585      !! **  Purpose :   Compute the interpolation of tracer at w-point
586      !!
587      !! **  Method  :   4th order compact interpolation
588      !!----------------------------------------------------------------------
589      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
590      REAL(wp),DIMENSION(A2D(nn_hls)    ,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
591      !
592      INTEGER ::   ji, jj, jk   ! dummy loop integers
593      INTEGER ::   ikt, ikb     ! local integers
594      REAL(wp),DIMENSION(A2D(nn_hls),jpk) :: zwd, zwi, zws, zwrm, zwt
595      !!----------------------------------------------------------------------
596      !
597      !                      !==  build the three diagonal matrix & the RHS  ==!
598      !
599      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )    ! interior (from jk=3 to jpk-1)
600         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
601         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
602         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
603         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
604            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
605      END_3D
606      !
607!!gm
608!      SELECT CASE( kbc )               !* boundary condition
609!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
610!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
611!      END SELECT
612!!gm 
613      !
614      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
615         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
616      END IF
617      !
618      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! 2nd order centered at top & bottom
619         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
620         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
621         !
622         zwd (ji,jj,ikt) = 1._wp          ! top
623         zwi (ji,jj,ikt) = 0._wp
624         zws (ji,jj,ikt) = 0._wp
625         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
626         !
627         zwd (ji,jj,ikb) = 1._wp          ! bottom
628         zwi (ji,jj,ikb) = 0._wp
629         zws (ji,jj,ikb) = 0._wp
630         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
631      END_2D
632      !
633      !                       !==  tridiagonal solver  ==!
634      !
635      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
636         zwt(ji,jj,2) = zwd(ji,jj,2)
637      END_2D
638      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
639         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
640      END_3D
641      !
642      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
643         pt_out(ji,jj,2) = zwrm(ji,jj,2)
644      END_2D
645      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
646         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
647      END_3D
648
649      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
650         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
651      END_2D
652      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, 2, -1 )
653         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
654      END_3D
655      !   
656   END SUBROUTINE interp_4th_cpt
657
658
659   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
660      !!----------------------------------------------------------------------
661      !!                  ***  ROUTINE tridia_solver  ***
662      !!
663      !! **  Purpose :   solve a symmetric 3diagonal system
664      !!
665      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
666      !!     
667      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
668      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
669      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
670      !!             (        ...          )( ... )   ( ...  )
671      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
672      !!     
673      !!        M is decomposed in the product of an upper and lower triangular matrix.
674      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
675      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
676      !!        The solution is pta.
677      !!        The 3d array zwt is used as a work space array.
678      !!----------------------------------------------------------------------
679      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
680      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
681      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
682      INTEGER                    , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
683      !                                                             ! =0 pt at t-level
684      INTEGER ::   ji, jj, jk   ! dummy loop integers
685      INTEGER ::   kstart       ! local indices
686      REAL(wp),DIMENSION(A2D(nn_hls),jpk) ::   zwt   ! 3D work array
687      !!----------------------------------------------------------------------
688      !
689      kstart =  1  + klev
690      !
691      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                         !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
692         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
693      END_2D
694      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
695         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
696      END_3D
697      !
698      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                        !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
699         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
700      END_2D
701      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
702         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
703      END_3D
704
705      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                       !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
706         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
707      END_2D
708      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, kstart, -1 )
709         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
710      END_3D
711      !
712   END SUBROUTINE tridia_solver
713
714   !!======================================================================
715END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.