New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in NEMO/branches/2020/dev_r13923_Tiling_Cleanup_MPI3_LoopFusion/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13923_Tiling_Cleanup_MPI3_LoopFusion/src/OCE/TRA/zpshde.F90 @ 13946

Last change on this file since 13946 was 13946, checked in by francesca, 4 years ago

Merge with dev_r13508_HPC-09_loop_fusion
  • Property svn:keywords set to Id
File size: 29.9 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE domutl, ONLY : is_tile
20   USE phycst          ! physical constants
21   USE eosbn2          ! ocean equation of state
22   USE in_out_manager  ! I/O manager
23   USE lbclnk          ! lateral boundary conditions (or mpp link)
24   USE lib_mpp         ! MPP library
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35#  include "domzgr_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE zps_hde( kt, Kmm, kjpt, pta, pgtu, pgtv,  &
44      &                               prd, pgru, pgrv )
45      !!
46      INTEGER                     , INTENT(in   )           ::  kt          ! ocean time-step index
47      INTEGER                     , INTENT(in   )           ::  Kmm         ! ocean time level index
48      INTEGER                     , INTENT(in   )           ::  kjpt        ! number of tracers
49      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout)           ::  pta         ! 4D tracers fields
50      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
51      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout), OPTIONAL ::  prd         ! 3D density anomaly fields
52      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
53      !
54      INTEGER :: itrd, itgr
55      !!
56      IF( PRESENT(prd)  ) THEN ; itrd = is_tile(prd)  ; ELSE ; itrd = 0 ; ENDIF
57      IF( PRESENT(pgru) ) THEN ; itgr = is_tile(pgru) ; ELSE ; itgr = 0 ; ENDIF
58
59      CALL zps_hde_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), &
60         &                           prd, itrd,         pgru, pgrv, itgr )
61   END SUBROUTINE zps_hde
62
63
64   SUBROUTINE zps_hde_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt,   &
65      &                                 prd, ktrd, pgru, pgrv, ktgr )
66      !!----------------------------------------------------------------------
67      !!                     ***  ROUTINE zps_hde  ***
68      !!                   
69      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
70      !!      at u- and v-points with a linear interpolation for z-coordinate
71      !!      with partial steps.
72      !!
73      !! ** Method  :   In z-coord with partial steps, scale factors on last
74      !!      levels are different for each grid point, so that T, S and rd
75      !!      points are not at the same depth as in z-coord. To have horizontal
76      !!      gradients again, we interpolate T and S at the good depth :
77      !!      Linear interpolation of T, S   
78      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
79      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
80      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
81      !!         This formulation computes the two cases:
82      !!                 CASE 1                   CASE 2 
83      !!         k-1  ___ ___________   k-1   ___ ___________
84      !!                    Ti  T~                  T~  Ti+1
85      !!                  _____                        _____
86      !!         k        |   |Ti+1     k           Ti |   |
87      !!                  |   |____                ____|   |
88      !!              ___ |   |   |           ___  |   |   |
89      !!                 
90      !!      case 1->   e3w(i+1,:,:,Kmm) >= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) >= e3w(:,j,:,Kmm) ) then
91      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j,k,Kmm)
92      !!        ( t~ = t(i  ,j+1,k) + (e3w(i,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i,j+1,k,Kmm)  )
93      !!          or
94      !!      case 2->   e3w(i+1,:,:,Kmm) <= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) <= e3w(:,j,:,Kmm) ) then
95      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
96      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
97      !!          Idem for di(s) and dj(s)         
98      !!
99      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
100      !!      depth zh from interpolated T and S for the different formulations
101      !!      of the equation of state (eos).
102      !!      Gradient formulation for rho :
103      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
104      !!
105      !! ** Action  : compute for top interfaces
106      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
107      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
108      !!----------------------------------------------------------------------
109      INTEGER                                , INTENT(in   )           ::  kt          ! ocean time-step index
110      INTEGER                                , INTENT(in   )           ::  Kmm         ! ocean time level index
111      INTEGER                                , INTENT(in   )           ::  kjpt        ! number of tracers
112      INTEGER                                , INTENT(in   )           ::  ktta, ktgt, ktrd, ktgr
113      REAL(wp), DIMENSION(A2D_T(ktta),JPK,KJPT), INTENT(inout)           ::  pta         ! 4D tracers fields
114      REAL(wp), DIMENSION(A2D_T(ktgt)    ,KJPT), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
115      REAL(wp), DIMENSION(A2D_T(ktrd),JPK     ), INTENT(inout), OPTIONAL ::  prd         ! 3D density anomaly fields
116      REAL(wp), DIMENSION(A2D_T(ktgr)         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
117      !
118      INTEGER  ::   ji, jj, jn                  ! Dummy loop indices
119      INTEGER  ::   iku, ikv, ikum1, ikvm1      ! partial step level (ocean bottom level) at u- and v-points
120      REAL(wp) ::   ze3wu, ze3wv, zmaxu, zmaxv  ! local scalars
121      REAL(wp), DIMENSION(A2D(nn_hls))      ::   zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
122      REAL(wp), DIMENSION(A2D(nn_hls),kjpt) ::   zti, ztj             !
123      !!----------------------------------------------------------------------
124      !
125      IF( ln_timing )   CALL timing_start( 'zps_hde')
126      ! NOTE: [tiling-comms-merge] Some lbc_lnks in tra_adv and tra_ldf can be taken out in the zps case, because this lbc_lnk is called when zps_hde is called in the stp routine. In the zco case they are still needed.
127      IF (nn_hls.EQ.2) THEN
128#if defined key_mpi3
129         CALL lbc_lnk_nc_multi( 'zpshde', pta, 'T', 1.0_wp)
130#else
131         CALL lbc_lnk( 'zpshde', pta, 'T', 1.0_wp)
132#endif
133#if defined key_mpi3
134         IF(PRESENT(prd)) CALL lbc_lnk_nc_multi( 'zpshde', prd, 'T', 1.0_wp)
135#else
136         IF(PRESENT(prd)) CALL lbc_lnk( 'zpshde', prd, 'T', 1.0_wp)
137#endif
138      END IF
139      !
140      pgtu(:,:,:) = 0._wp   ;   zti (:,:,:) = 0._wp   ;   zhi (:,:) = 0._wp
141      pgtv(:,:,:) = 0._wp   ;   ztj (:,:,:) = 0._wp   ;   zhj (:,:) = 0._wp
142      !
143      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
144         !
145         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! Gradient of density at the last level
146            iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
147            ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
148!!gm BUG ? when applied to before fields, e3w(:,:,k,Kbb) should be used....
149            ze3wu = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
150            ze3wv = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
151            !
152            ! i- direction
153            IF( ze3wu >= 0._wp ) THEN      ! case 1
154               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
155               ! interpolated values of tracers
156               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
157               ! gradient of  tracers
158               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
159            ELSE                           ! case 2
160               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
161               ! interpolated values of tracers
162               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
163               ! gradient of tracers
164               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
165            ENDIF
166            !
167            ! j- direction
168            IF( ze3wv >= 0._wp ) THEN      ! case 1
169               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
170               ! interpolated values of tracers
171               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
172               ! gradient of tracers
173               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
174            ELSE                           ! case 2
175               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
176               ! interpolated values of tracers
177               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
178               ! gradient of tracers
179               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
180            ENDIF
181         END_2D
182      END DO
183      !
184#if defined key_mpi3
185      IF (nn_hls.EQ.1) CALL lbc_lnk_nc_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
186#else
187      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
188#endif
189      !               
190      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
191         pgru(:,:) = 0._wp
192         pgrv(:,:) = 0._wp                ! depth of the partial step level
193         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
194            iku = mbku(ji,jj)
195            ikv = mbkv(ji,jj)
196            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
197            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
198            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)     ! i-direction: case 1
199            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)     ! -     -      case 2
200            ENDIF
201            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)     ! j-direction: case 1
202            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)     ! -     -      case 2
203            ENDIF
204         END_2D
205         !
206         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
207         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
208         !
209         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! Gradient of density at the last level
210            iku = mbku(ji,jj)
211            ikv = mbkv(ji,jj)
212            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
213            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
214            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
215            ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
216            ENDIF
217            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
218            ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
219            ENDIF
220         END_2D
221#if defined key_mpi3
222         IF (nn_hls.EQ.1) CALL lbc_lnk_nc_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
223#else
224         IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
225#endif
226         !
227      END IF
228      !
229      IF( ln_timing )   CALL timing_stop( 'zps_hde')
230      !
231   END SUBROUTINE zps_hde_t
232
233
234   SUBROUTINE zps_hde_isf( kt, Kmm, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
235      &                                   prd, pgru, pgrv, pgrui, pgrvi )
236      !!
237      INTEGER                     , INTENT(in   )           ::  kt           ! ocean time-step index
238      INTEGER                     , INTENT(in   )           ::  Kmm          ! ocean time level index
239      INTEGER                     , INTENT(in   )           ::  kjpt         ! number of tracers
240      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout)           ::  pta          ! 4D tracers fields
241      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
242      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
243      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout), OPTIONAL ::  prd          ! 3D density anomaly fields
244      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
245      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
246      !
247      INTEGER :: itrd, itgr, itgri
248      !!
249      IF( PRESENT(prd)   ) THEN ; itrd  = is_tile(prd)   ; ELSE ; itrd  = 0 ; ENDIF
250      IF( PRESENT(pgru)  ) THEN ; itgr  = is_tile(pgru)  ; ELSE ; itgr  = 0 ; ENDIF
251      IF( PRESENT(pgrui) ) THEN ; itgri = is_tile(pgrui) ; ELSE ; itgri = 0 ; ENDIF
252
253      CALL zps_hde_isf_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), pgtui, pgtvi, is_tile(pgtui),  &
254      &                                  prd, itrd,         pgru, pgrv, itgr,          pgrui, pgrvi, itgri )
255   END SUBROUTINE zps_hde_isf
256
257
258   SUBROUTINE zps_hde_isf_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt, pgtui, pgtvi, ktgti,  &
259      &                                     prd, ktrd, pgru, pgrv, ktgr, pgrui, pgrvi, ktgri )
260      !!----------------------------------------------------------------------
261      !!                     ***  ROUTINE zps_hde_isf  ***
262      !!                   
263      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
264      !!      at u- and v-points with a linear interpolation for z-coordinate
265      !!      with partial steps for top (ice shelf) and bottom.
266      !!
267      !! ** Method  :   In z-coord with partial steps, scale factors on last
268      !!      levels are different for each grid point, so that T, S and rd
269      !!      points are not at the same depth as in z-coord. To have horizontal
270      !!      gradients again, we interpolate T and S at the good depth :
271      !!      For the bottom case:
272      !!      Linear interpolation of T, S   
273      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
274      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
275      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
276      !!         This formulation computes the two cases:
277      !!                 CASE 1                   CASE 2 
278      !!         k-1  ___ ___________   k-1   ___ ___________
279      !!                    Ti  T~                  T~  Ti+1
280      !!                  _____                        _____
281      !!         k        |   |Ti+1     k           Ti |   |
282      !!                  |   |____                ____|   |
283      !!              ___ |   |   |           ___  |   |   |
284      !!                 
285      !!      case 1->   e3w(i+1,j,k,Kmm) >= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) >= e3w(i,j,k,Kmm) ) then
286      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j  ,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j  ,k,Kmm)
287      !!        ( t~ = t(i  ,j+1,k) + (e3w(i  ,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i  ,j+1,k,Kmm)  )
288      !!          or
289      !!      case 2->   e3w(i+1,j,k,Kmm) <= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) <= e3w(i,j,k,Kmm) ) then
290      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j  ,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
291      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i  ,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
292      !!          Idem for di(s) and dj(s)         
293      !!
294      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
295      !!      depth zh from interpolated T and S for the different formulations
296      !!      of the equation of state (eos).
297      !!      Gradient formulation for rho :
298      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
299      !!
300      !!      For the top case (ice shelf): As for the bottom case but upside down
301      !!
302      !! ** Action  : compute for top and bottom interfaces
303      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
304      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
305      !!----------------------------------------------------------------------
306      INTEGER                                , INTENT(in   )           ::  kt           ! ocean time-step index
307      INTEGER                                , INTENT(in   )           ::  Kmm          ! ocean time level index
308      INTEGER                                , INTENT(in   )           ::  kjpt         ! number of tracers
309      INTEGER                                , INTENT(in   )           ::  ktta, ktgt, ktgti, ktrd, ktgr, ktgri
310      REAL(wp), DIMENSION(A2D_T(ktta),JPK,KJPT), INTENT(inout)           ::  pta          ! 4D tracers fields
311      REAL(wp), DIMENSION(A2D_T(ktgt)    ,KJPT), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
312      REAL(wp), DIMENSION(A2D_T(ktgti)   ,KJPT), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
313      REAL(wp), DIMENSION(A2D_T(ktrd),JPK     ), INTENT(inout), OPTIONAL ::  prd          ! 3D density anomaly fields
314      REAL(wp), DIMENSION(A2D_T(ktgr)         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
315      REAL(wp), DIMENSION(A2D_T(ktgri)        ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
316      !
317      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
318      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
319      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
320      REAL(wp), DIMENSION(A2D(nn_hls))      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
321      REAL(wp), DIMENSION(A2D(nn_hls),kjpt) ::  zti, ztj             !
322      !!----------------------------------------------------------------------
323      !
324      IF( ln_timing )   CALL timing_start( 'zps_hde_isf')
325      !
326      IF (nn_hls.EQ.2) THEN
327#if defined key_mpi3
328         CALL lbc_lnk_nc_multi( 'zpshde', pta, 'T', 1.0_wp)
329#else
330         CALL lbc_lnk( 'zpshde', pta, 'T', 1.0_wp)
331#endif
332#if defined key_mpi3
333         IF (PRESENT(prd)) CALL lbc_lnk_nc_multi( 'zpshde', prd, 'T', 1.0_wp)
334#else
335         IF (PRESENT(prd)) CALL lbc_lnk( 'zpshde', prd, 'T', 1.0_wp)
336#endif
337      END IF
338
339      pgtu (:,:,:) = 0._wp   ;   pgtv (:,:,:) =0._wp
340      pgtui(:,:,:) = 0._wp   ;   pgtvi(:,:,:) =0._wp
341      zti  (:,:,:) = 0._wp   ;   ztj  (:,:,:) =0._wp
342      zhi  (:,:  ) = 0._wp   ;   zhj  (:,:  ) =0._wp
343      !
344      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
345         !
346         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
347
348            iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
349            ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
350            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
351            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
352            !
353            ! i- direction
354            IF( ze3wu >= 0._wp ) THEN      ! case 1
355               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
356               ! interpolated values of tracers
357               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
358               ! gradient of  tracers
359               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
360            ELSE                           ! case 2
361               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
362               ! interpolated values of tracers
363               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
364               ! gradient of tracers
365               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
366            ENDIF
367            !
368            ! j- direction
369            IF( ze3wv >= 0._wp ) THEN      ! case 1
370               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
371               ! interpolated values of tracers
372               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
373               ! gradient of tracers
374               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
375            ELSE                           ! case 2
376               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
377               ! interpolated values of tracers
378               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
379               ! gradient of tracers
380               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
381            ENDIF
382
383         END_2D
384      END DO
385      !
386#if defined key_mpi3
387      IF (nn_hls.EQ.1) CALL lbc_lnk_nc_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
388#else
389      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
390#endif
391
392      ! horizontal derivative of density anomalies (rd)
393      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
394         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
395         !
396         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
397
398            iku = mbku(ji,jj)
399            ikv = mbkv(ji,jj)
400            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
401            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
402            !
403            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
404            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
405            ENDIF
406            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
407            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
408            ENDIF
409
410         END_2D
411
412         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
413         ! step and store it in  zri, zrj for each  case
414         CALL eos( zti, zhi, zri )
415         CALL eos( ztj, zhj, zrj )
416
417         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
418            iku = mbku(ji,jj)
419            ikv = mbkv(ji,jj)
420            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
421            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
422
423            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
424            ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
425            ENDIF
426            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
427            ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
428            ENDIF
429
430         END_2D
431
432#if defined key_mpi3
433         IF (nn_hls.EQ.1) CALL lbc_lnk_nc_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
434#else
435         IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
436#endif
437         !
438      END IF
439      !
440      !     !==  (ISH)  compute grui and gruvi  ==!
441      !
442      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
443         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
444            iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
445            ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
446            !
447            ! (ISF) case partial step top and bottom in adjacent cell in vertical
448            ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
449            ! in this case e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm) is not the distance between Tj~ and Tj
450            ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
451            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
452            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
453
454            ! i- direction
455            IF( ze3wu >= 0._wp ) THEN      ! case 1
456               zmaxu = ze3wu / e3w(ji+1,jj,ikup1,Kmm)
457               ! interpolated values of tracers
458               zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
459               ! gradient of tracers
460               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
461            ELSE                           ! case 2
462               zmaxu = - ze3wu / e3w(ji,jj,ikup1,Kmm)
463               ! interpolated values of tracers
464               zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
465               ! gradient of  tracers
466               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
467            ENDIF
468            !
469            ! j- direction
470            IF( ze3wv >= 0._wp ) THEN      ! case 1
471               zmaxv =  ze3wv / e3w(ji,jj+1,ikvp1,Kmm)
472               ! interpolated values of tracers
473               ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
474               ! gradient of tracers
475               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
476            ELSE                           ! case 2
477               zmaxv =  - ze3wv / e3w(ji,jj,ikvp1,Kmm)
478               ! interpolated values of tracers
479               ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
480               ! gradient of tracers
481               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
482            ENDIF
483
484         END_2D
485         !
486      END DO
487#if defined key_mpi3
488      IF (nn_hls.EQ.1) CALL lbc_lnk_nc_multi( 'zpshde', pgtui(:,:,:), 'U', -1.0_wp , pgtvi(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
489#else
490      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgtui(:,:,:), 'U', -1.0_wp , pgtvi(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
491#endif
492
493      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
494         !
495         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
496         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
497
498            iku = miku(ji,jj)
499            ikv = mikv(ji,jj)
500            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
501            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
502            !
503            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
504            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
505            ENDIF
506
507            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
508            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
509            ENDIF
510
511         END_2D
512         !
513         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
514         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
515         !
516         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
517            iku = miku(ji,jj) 
518            ikv = mikv(ji,jj) 
519            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
520            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
521
522            IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
523            ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
524            ENDIF
525            IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
526            ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
527            ENDIF
528
529         END_2D
530#if defined key_mpi3
531         IF (nn_hls.EQ.1) CALL lbc_lnk_nc_multi( 'zpshde', pgrui, 'U', -1.0_wp , pgrvi, 'V', -1.0_wp )   ! Lateral boundary conditions
532#else
533         IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgrui, 'U', -1.0_wp , pgrvi, 'V', -1.0_wp )   ! Lateral boundary conditions
534#endif
535         !
536      END IF 
537      !
538      IF( ln_timing )   CALL timing_stop( 'zps_hde_isf')
539      !
540   END SUBROUTINE zps_hde_isf_t
541
542   !!======================================================================
543END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.