New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in NEMO/branches/2020/dev_r13923_Tiling_Cleanup_MPI3_LoopFusion/src/TOP/TRP – NEMO

source: NEMO/branches/2020/dev_r13923_Tiling_Cleanup_MPI3_LoopFusion/src/TOP/TRP/trcadv.F90 @ 13946

Last change on this file since 13946 was 13946, checked in by francesca, 4 years ago

Merge with dev_r13508_HPC-09_loop_fusion
  • Property svn:keywords set to Id
File size: 16.2 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2010-06  (C. Ethe)   Adapted to passive tracers
8   !!            3.7  !  2014-05  (G. Madec, C. Ethe)  Add 2nd/4th order cases for CEN and FCT schemes
9   !!            4.0  !  2017-09  (G. Madec)  remove vertical time-splitting option
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_adv       : compute ocean tracer advection trend
16   !!   trc_adv_ini   : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce_trc        ! ocean dynamics and active tracers
19   USE trc            ! ocean passive tracers variables
20   USE sbcwave        ! wave module
21   USE sbc_oce        ! surface boundary condition: ocean
22   USE traadv_cen     ! centered scheme           (tra_adv_cen  routine)
23   USE traadv_fct     ! FCT      scheme           (tra_adv_fct  routine)
24   USE traadv_fct_lf  ! FCT      scheme           (tra_adv_fct  routine - loop fusion version)
25   USE traadv_mus     ! MUSCL    scheme           (tra_adv_mus  routine)
26   USE traadv_mus_lf  ! MUSCL    scheme           (tra_adv_mus  routine - loop fusion version)
27   USE traadv_ubs     ! UBS      scheme           (tra_adv_ubs  routine)
28   USE traadv_qck     ! QUICKEST scheme           (tra_adv_qck  routine)
29   USE tramle         ! ML eddy induced transport (tra_adv_mle  routine)
30   USE ldftra         ! lateral diffusion: eddy diffusivity & EIV coeff.
31   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
32   !
33   USE prtctl         ! control print
34   USE timing         ! Timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   trc_adv       ! called by trctrp.F90
40   PUBLIC   trc_adv_ini   ! called by trcini.F90
41
42   !                            !!* Namelist namtrc_adv *
43   LOGICAL ::   ln_trcadv_OFF    ! no advection on passive tracers
44   LOGICAL ::   ln_trcadv_cen    ! centered scheme flag
45   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
46   LOGICAL ::   ln_trcadv_fct    ! FCT scheme flag
47   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
48   LOGICAL ::   ln_trcadv_mus    ! MUSCL scheme flag
49   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
50   LOGICAL ::   ln_trcadv_ubs    ! UBS scheme flag
51   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
52   LOGICAL ::   ln_trcadv_qck    ! QUICKEST scheme flag
53
54   INTEGER ::   nadv             ! choice of the type of advection scheme
55   !                             ! associated indices:
56   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
57   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
58   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
59   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
60   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
61   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
62   
63#  include "domzgr_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
66   !! $Id$
67   !! Software governed by the CeCILL license (see ./LICENSE)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE trc_adv( kt, Kbb, Kmm, ptr, Krhs  )
72      !!----------------------------------------------------------------------
73      !!                  ***  ROUTINE trc_adv  ***
74      !!
75      !! ** Purpose :   compute the ocean tracer advection trend.
76      !!
77      !! ** Method  : - Update after tracers (tr(Krhs)) with the advection term following nadv
78      !!----------------------------------------------------------------------
79      INTEGER                                   , INTENT(in)    :: kt   ! ocean time-step index
80      INTEGER                                   , INTENT(in)    :: Kbb, Kmm, Krhs ! time level indices
81      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr            ! passive tracers and RHS of tracer equation
82      !
83      INTEGER ::   jk   ! dummy loop index
84      CHARACTER (len=22) ::   charout
85      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zuu, zvv, zww  ! effective velocity
86      !!----------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('trc_adv')
89      !
90      !                                         !==  effective transport  ==!
91      IF( l_offline ) THEN
92         zuu(:,:,:) = uu(:,:,:,Kmm)                ! already in (uu(Kmm),vv(Kmm),ww)
93         zvv(:,:,:) = vv(:,:,:,Kmm)
94         zww(:,:,:) = ww(:,:,:)
95      ELSE                                         ! build the effective transport
96         zuu(:,:,jpk) = 0._wp
97         zvv(:,:,jpk) = 0._wp
98         zww(:,:,jpk) = 0._wp
99         IF( ln_wave .AND. ln_sdw )  THEN
100            DO jk = 1, jpkm1                                                       ! eulerian transport + Stokes Drift
101               zuu(:,:,jk) = e2u  (:,:) * e3u(:,:,jk,Kmm) * ( uu(:,:,jk,Kmm) + usd(:,:,jk) )
102               zvv(:,:,jk) = e1v  (:,:) * e3v(:,:,jk,Kmm) * ( vv(:,:,jk,Kmm) + vsd(:,:,jk) )
103               zww(:,:,jk) = e1e2t(:,:)                   * ( ww(:,:,jk) + wsd(:,:,jk) )
104            END DO
105         ELSE
106            DO jk = 1, jpkm1
107               zuu(:,:,jk) = e2u  (:,:) * e3u(:,:,jk,Kmm) * uu(:,:,jk,Kmm)                   ! eulerian transport
108               zvv(:,:,jk) = e1v  (:,:) * e3v(:,:,jk,Kmm) * vv(:,:,jk,Kmm)
109               zww(:,:,jk) = e1e2t(:,:)                   * ww(:,:,jk)
110            END DO
111         ENDIF
112         !
113         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                 ! add z-tilde and/or vvl corrections
114            zuu(:,:,:) = zuu(:,:,:) + un_td(:,:,:)
115            zvv(:,:,:) = zvv(:,:,:) + vn_td(:,:,:)
116         ENDIF
117         !
118         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   & 
119            &              CALL ldf_eiv_trp( kt, nittrc000, zuu, zvv, zww, 'TRC', Kmm, Krhs )  ! add the eiv transport
120         !
121         IF( ln_mle    )   CALL tra_mle_trp( kt, nittrc000, zuu, zvv, zww, 'TRC', Kmm       )  ! add the mle transport
122         !
123      ENDIF
124      !
125      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
126      !
127      CASE ( np_CEN )                                 ! Centered : 2nd / 4th order
128#if defined key_mpi3
129         IF (nn_hls.EQ.2) CALL lbc_lnk_nc_multi( 'trcadv', ptr(:,:,:,:,Kmm), 'T', 1.)
130#else
131         IF (nn_hls.EQ.2) CALL lbc_lnk( 'trcadv', ptr(:,:,:,:,Kmm), 'T', 1.)
132#endif
133         CALL tra_adv_cen( kt, nittrc000,'TRC',          zuu, zvv, zww,      Kmm, ptr, jptra, Krhs, nn_cen_h, nn_cen_v )
134      CASE ( np_FCT )                                 ! FCT      : 2nd / 4th order
135         IF (nn_hls.EQ.2) THEN
136#if defined key_mpi3
137            CALL lbc_lnk_nc_multi( 'trcadv', ptr(:,:,:,:,Kbb), 'T', 1., ptr(:,:,:,:,Kmm), 'T', 1.)
138            CALL lbc_lnk_nc_multi( 'traadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1., zww(:,:,:), 'W', 1.)
139#else
140            CALL lbc_lnk_multi( 'trcadv', ptr(:,:,:,:,Kbb), 'T', 1., ptr(:,:,:,:,Kmm), 'T', 1.)
141            CALL lbc_lnk_multi( 'traadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1., zww(:,:,:), 'W', 1.)
142#endif
143#if defined key_loop_fusion
144            CALL tra_adv_fct_lf( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, nn_fct_h, nn_fct_v )
145#else
146            CALL tra_adv_fct( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, nn_fct_h, nn_fct_v )
147#endif
148         ELSE
149            CALL tra_adv_fct( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, nn_fct_h, nn_fct_v )
150         END IF
151      CASE ( np_MUS )                                 ! MUSCL
152         IF (nn_hls.EQ.2) THEN
153#if defined key_mpi3
154            IF (nn_hls.EQ.2) CALL lbc_lnk_nc_multi( 'trcadv', ptr(:,:,:,:,Kbb), 'T', 1.)
155#else
156            IF (nn_hls.EQ.2) CALL lbc_lnk( 'trcadv', ptr(:,:,:,:,Kbb), 'T', 1.)
157#endif
158#if defined key_loop_fusion
159            CALL tra_adv_mus_lf( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, ln_mus_ups ) 
160#else
161            CALL tra_adv_mus( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, ln_mus_ups ) 
162#endif
163         ELSE
164            CALL tra_adv_mus( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, ln_mus_ups ) 
165         END IF
166      CASE ( np_UBS )                                 ! UBS
167#if defined key_mpi3
168         IF (nn_hls.EQ.2) CALL lbc_lnk_nc_multi( 'trcadv', ptr(:,:,:,:,Kbb), 'T', 1.)
169#else
170         IF (nn_hls.EQ.2) CALL lbc_lnk( 'trcadv', ptr(:,:,:,:,Kbb), 'T', 1.)
171#endif
172         CALL tra_adv_ubs( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, nn_ubs_v           )
173      CASE ( np_QCK )                                 ! QUICKEST
174         IF (nn_hls.EQ.2) THEN
175#if defined key_mpi3
176            CALL lbc_lnk_nc_multi( 'trcadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1.)
177            CALL lbc_lnk_nc_multi( 'traadv', ptr(:,:,:,:,Kbb), 'T', 1.)
178#else
179            CALL lbc_lnk_multi( 'trcadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1.)
180            CALL lbc_lnk( 'traadv', ptr(:,:,:,:,Kbb), 'T', 1.)
181#endif
182         END IF
183         CALL tra_adv_qck( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs                     )
184      !
185      END SELECT
186      !                 
187      IF( sn_cfctl%l_prttrc ) THEN        !== print mean trends (used for debugging)
188         WRITE(charout, FMT="('adv ')")
189         CALL prt_ctl_info( charout, cdcomp = 'top' )
190         CALL prt_ctl( tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm, clinfo3='trd' )
191      END IF
192      !
193      IF( ln_timing )   CALL timing_stop('trc_adv')
194      !
195   END SUBROUTINE trc_adv
196
197
198   SUBROUTINE trc_adv_ini
199      !!---------------------------------------------------------------------
200      !!                  ***  ROUTINE trc_adv_ini  ***
201      !!               
202      !! ** Purpose :   Control the consistency between namelist options for
203      !!              passive tracer advection schemes and set nadv
204      !!----------------------------------------------------------------------
205      INTEGER ::   ioptio, ios   ! Local integer
206      !!
207      NAMELIST/namtrc_adv/ ln_trcadv_OFF,                        &   ! No advection
208         &                 ln_trcadv_cen, nn_cen_h, nn_cen_v,    &   ! CEN
209         &                 ln_trcadv_fct, nn_fct_h, nn_fct_v,    &   ! FCT
210         &                 ln_trcadv_mus, ln_mus_ups,            &   ! MUSCL
211         &                 ln_trcadv_ubs,           nn_ubs_v,    &   ! UBS
212         &                 ln_trcadv_qck                             ! QCK
213      !!----------------------------------------------------------------------
214      !
215      !                                !==  Namelist  ==!
216      READ  ( numnat_ref, namtrc_adv, IOSTAT = ios, ERR = 901)
217901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_adv in reference namelist' )
218      READ  ( numnat_cfg, namtrc_adv, IOSTAT = ios, ERR = 902 )
219902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_adv in configuration namelist' )
220      IF(lwm) WRITE ( numont, namtrc_adv )
221      !
222      IF(lwp) THEN                           ! Namelist print
223         WRITE(numout,*)
224         WRITE(numout,*) 'trc_adv_ini : choice/control of the tracer advection scheme'
225         WRITE(numout,*) '~~~~~~~~~~~'
226         WRITE(numout,*) '   Namelist namtrc_adv : chose a advection scheme for tracers'
227         WRITE(numout,*) '      No advection on passive tracers           ln_trcadv_OFF = ', ln_trcadv_OFF
228         WRITE(numout,*) '      centered scheme                           ln_trcadv_cen = ', ln_trcadv_cen
229         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
230         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
231         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_trcadv_fct = ', ln_trcadv_fct
232         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
233         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
234         WRITE(numout,*) '      MUSCL scheme                              ln_trcadv_mus = ', ln_trcadv_mus
235         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
236         WRITE(numout,*) '      UBS scheme                                ln_trcadv_ubs = ', ln_trcadv_ubs
237         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
238         WRITE(numout,*) '      QUICKEST scheme                           ln_trcadv_qck = ', ln_trcadv_qck
239      ENDIF
240      !
241      !                                !==  Parameter control & set nadv ==!
242      ioptio = 0
243      IF( ln_trcadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
244      IF( ln_trcadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
245      IF( ln_trcadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
246      IF( ln_trcadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
247      IF( ln_trcadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
248      IF( ln_trcadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
249      !
250      IF( ioptio /= 1 )   CALL ctl_stop( 'trc_adv_ini: Choose ONE advection option in namelist namtrc_adv' )
251      !
252      IF( ln_trcadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &
253                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
254        CALL ctl_stop( 'trc_adv_ini: CEN scheme, choose 2nd or 4th order' )
255      ENDIF
256      IF( ln_trcadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &
257                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
258        CALL ctl_stop( 'trc_adv_ini: FCT scheme, choose 2nd or 4th order' )
259      ENDIF
260      IF( ln_trcadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN
261        CALL ctl_stop( 'trc_adv_ini: UBS scheme, choose 2nd or 4th order' )
262      ENDIF
263      IF( ln_trcadv_ubs .AND. nn_ubs_v == 4 ) THEN
264         CALL ctl_warn( 'trc_adv_ini: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
265      ENDIF
266      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
267         IF(  ln_trcadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
268            & ln_trcadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_ini: 4th order COMPACT scheme not allowed with ISF' )
269      ENDIF
270      !
271      !                                !==  Print the choice  ==! 
272      IF(lwp) THEN
273         WRITE(numout,*)
274         SELECT CASE ( nadv )
275         CASE( np_NO_adv  )   ;   WRITE(numout,*) '      ===>>   NO passive tracer advection'
276         CASE( np_CEN     )   ;   WRITE(numout,*) '      ===>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
277            &                                                                     ' Vertical   order: ', nn_cen_v
278         CASE( np_FCT     )   ;   WRITE(numout,*) '      ===>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
279            &                                                                      ' Vertical   order: ', nn_fct_v
280         CASE( np_MUS     )   ;   WRITE(numout,*) '      ===>>   MUSCL    scheme is used'
281         CASE( np_UBS     )   ;   WRITE(numout,*) '      ===>>   UBS      scheme is used'
282         CASE( np_QCK     )   ;   WRITE(numout,*) '      ===>>   QUICKEST scheme is used'
283         END SELECT
284      ENDIF
285      !
286   END SUBROUTINE trc_adv_ini
287   
288#endif
289
290  !!======================================================================
291END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.