New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iceupdate.F90 in NEMO/branches/2020/r4.0-HEAD_r12713_clem_dan_fixcpl/src/ICE – NEMO

source: NEMO/branches/2020/r4.0-HEAD_r12713_clem_dan_fixcpl/src/ICE/iceupdate.F90 @ 13249

Last change on this file since 13249 was 13249, checked in by clem, 3 years ago

merge with Jerome's branch NEMO_4.03_IODRAG

  • Property svn:keywords set to Id
File size: 27.4 KB
Line 
1MODULE iceupdate
2   !!======================================================================
3   !!                       ***  MODULE iceupdate   ***
4   !!  Sea-ice :   computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :  4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_update_alloc : allocate the iceupdate arrays
13   !!   ice_update_init  : initialisation
14   !!   ice_update_flx   : updates mass, heat and salt fluxes at the ocean surface
15   !!   ice_update_tau   : update i- and j-stresses, and its modulus at the ocean surface
16   !!----------------------------------------------------------------------
17   USE oce     , ONLY : sshn, sshb
18   USE phycst         ! physical constants
19   USE dom_oce        ! ocean domain
20   USE ice            ! sea-ice: variables
21   USE sbc_ice        ! Surface boundary condition: ice   fields
22   USE sbc_oce        ! Surface boundary condition: ocean fields
23   USE sbccpl         ! Surface boundary condition: coupled interface
24   USE icealb         ! sea-ice: albedo parameters
25   USE traqsr         ! add penetration of solar flux in the calculation of heat budget
26   USE icectl         ! sea-ice: control prints
27   USE bdy_oce , ONLY : ln_bdy
28   USE zdfdrg  , ONLY : ln_drgice_imp
29   !
30   USE in_out_manager ! I/O manager
31   USE iom            ! I/O manager library
32   USE lib_mpp        ! MPP library
33   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
34   USE lbclnk         ! lateral boundary conditions (or mpp links)
35   USE timing         ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   ice_update_init   ! called by ice_init
41   PUBLIC   ice_update_flx    ! called by ice_stp
42   PUBLIC   ice_update_tau    ! called by ice_stp
43
44   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
45   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   INTEGER FUNCTION ice_update_alloc()
57      !!-------------------------------------------------------------------
58      !!             ***  ROUTINE ice_update_alloc ***
59      !!-------------------------------------------------------------------
60      ALLOCATE( utau_oce(jpi,jpj), vtau_oce(jpi,jpj), tmod_io(jpi,jpj), STAT=ice_update_alloc )
61      !
62      CALL mpp_sum( 'iceupdate', ice_update_alloc )
63      IF( ice_update_alloc /= 0 )   CALL ctl_stop( 'STOP', 'ice_update_alloc: failed to allocate arrays' )
64      !
65   END FUNCTION ice_update_alloc
66
67
68   SUBROUTINE ice_update_flx( kt )
69      !!-------------------------------------------------------------------
70      !!                ***  ROUTINE ice_update_flx ***
71      !! 
72      !! ** Purpose :   Update the surface ocean boundary condition for heat
73      !!                salt and mass over areas where sea-ice is non-zero
74      !!         
75      !! ** Action  : - computes the heat and freshwater/salt fluxes
76      !!                at the ice-ocean interface.
77      !!              - Update the ocean sbc
78      !!     
79      !! ** Outputs : - qsr     : sea heat flux:     solar
80      !!              - qns     : sea heat flux: non solar
81      !!              - emp     : freshwater budget: volume flux
82      !!              - sfx     : salt flux
83      !!              - fr_i    : ice fraction
84      !!              - tn_ice  : sea-ice surface temperature
85      !!              - alb_ice : sea-ice albedo (recomputed only for coupled mode)
86      !!
87      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
88      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
89      !!              These refs are now obsolete since everything has been revised
90      !!              The ref should be Rousset et al., 2015
91      !!---------------------------------------------------------------------
92      INTEGER, INTENT(in) ::   kt   ! number of iteration
93      !
94      INTEGER  ::   ji, jj, jl, jk   ! dummy loop indices
95      REAL(wp) ::   zqmass           ! Heat flux associated with mass exchange ice->ocean (W.m-2)
96      REAL(wp) ::   zqsr             ! New solar flux received by the ocean
97      REAL(wp), DIMENSION(jpi,jpj) ::   z2d                  ! 2D workspace
98      !!---------------------------------------------------------------------
99      IF( ln_timing )   CALL timing_start('ice_update')
100
101      IF( kt == nit000 .AND. lwp ) THEN
102         WRITE(numout,*)
103         WRITE(numout,*)'ice_update_flx: update fluxes (mass, salt and heat) at the ice-ocean interface'
104         WRITE(numout,*)'~~~~~~~~~~~~~~'
105      ENDIF
106
107      ! --- case we bypass ice thermodynamics --- !
108      IF( .NOT. ln_icethd ) THEN   ! we suppose ice is impermeable => ocean is isolated from atmosphere
109         qt_atm_oi  (:,:)   = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
110         qt_oce_ai  (:,:)   = ( 1._wp - at_i_b(:,:) ) *   qns_oce(:,:)                  + qemp_oce(:,:)
111         emp_ice    (:,:)   = 0._wp
112         qemp_ice   (:,:)   = 0._wp
113         qevap_ice  (:,:,:) = 0._wp
114      ENDIF
115     
116      DO jj = 1, jpj
117         DO ji = 1, jpi
118
119            ! Solar heat flux reaching the ocean = zqsr (W.m-2)
120            !---------------------------------------------------
121            zqsr = qsr_tot(ji,jj) - SUM( a_i_b(ji,jj,:) * ( qsr_ice(ji,jj,:) - qtr_ice_bot(ji,jj,:) ) )
122
123            ! Total heat flux reaching the ocean = qt_oce_ai (W.m-2)
124            !---------------------------------------------------
125            zqmass           = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC)
126            qt_oce_ai(ji,jj) = qt_oce_ai(ji,jj) + zqmass + zqsr
127
128            ! Add the residual from heat diffusion equation and sublimation (W.m-2)
129            !----------------------------------------------------------------------
130            qt_oce_ai(ji,jj) = qt_oce_ai(ji,jj) + hfx_err_dif(ji,jj) +   &
131               &             ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) )
132
133            ! New qsr and qns used to compute the oceanic heat flux at the next time step
134            !----------------------------------------------------------------------------
135            qsr(ji,jj) = zqsr                                     
136            qns(ji,jj) = qt_oce_ai(ji,jj) - zqsr             
137
138            ! Mass flux at the atm. surface       
139            !-----------------------------------
140            wfx_sub(ji,jj) = wfx_snw_sub(ji,jj) + wfx_ice_sub(ji,jj)
141
142            ! Mass flux at the ocean surface     
143            !------------------------------------
144            !  case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
145            !  -------------------------------------------------------------------------------------
146            !  The idea of this approach is that the system that we consider is the ICE-OCEAN system
147            !  Thus  FW  flux  =  External ( E-P+snow melt)
148            !       Salt flux  =  Exchanges in the ice-ocean system then converted into FW
149            !                     Associated to Ice formation AND Ice melting
150            !                     Even if i see Ice melting as a FW and SALT flux
151            !       
152            ! mass flux from ice/ocean
153            wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj)   &
154               &           + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) + wfx_pnd(ji,jj)
155
156            ! add the snow melt water to snow mass flux to the ocean
157            wfx_snw(ji,jj) = wfx_snw_sni(ji,jj) + wfx_snw_dyn(ji,jj) + wfx_snw_sum(ji,jj)
158
159            ! mass flux at the ocean/ice interface
160            fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) )              ! F/M mass flux save at least for biogeochemical model
161            emp(ji,jj)    = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj)   ! mass flux + F/M mass flux (always ice/ocean mass exchange)
162
163
164            ! Salt flux at the ocean surface     
165            !------------------------------------------
166            sfx(ji,jj) = sfx_bog(ji,jj) + sfx_bom(ji,jj) + sfx_sum(ji,jj) + sfx_sni(ji,jj) + sfx_opw(ji,jj)   &
167               &       + sfx_res(ji,jj) + sfx_dyn(ji,jj) + sfx_bri(ji,jj) + sfx_sub(ji,jj) + sfx_lam(ji,jj)
168           
169            ! Mass of snow and ice per unit area   
170            !----------------------------------------
171            snwice_mass_b(ji,jj) = snwice_mass(ji,jj)       ! save mass from the previous ice time step
172            !                                               ! new mass per unit area
173            snwice_mass  (ji,jj) = tmask(ji,jj,1) * ( rhos * vt_s(ji,jj) + rhoi * vt_i(ji,jj)  ) 
174            !                                               ! time evolution of snow+ice mass
175            snwice_fmass (ji,jj) = ( snwice_mass(ji,jj) - snwice_mass_b(ji,jj) ) * r1_rdtice
176           
177         END DO
178      END DO
179
180      ! Storing the transmitted variables
181      !----------------------------------
182      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
183      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
184
185      ! Snow/ice albedo (only if sent to coupler, useless in forced mode)
186      !------------------------------------------------------------------
187      CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_eff, h_ip, cloud_fra, alb_ice ) ! ice albedo
188
189      !
190      IF( lrst_ice ) THEN                       !* write snwice_mass fields in the restart file
191         CALL update_rst( 'WRITE', kt )
192      ENDIF
193      !
194      ! output all fluxes
195      !------------------
196      !
197      ! --- salt fluxes [kg/m2/s] --- !
198      !                           ! sfxice =  sfxbog + sfxbom + sfxsum + sfxsni + sfxopw + sfxres + sfxdyn + sfxbri + sfxsub + sfxlam
199      IF( iom_use('sfxice'  ) )   CALL iom_put( 'sfxice', sfx     * 1.e-03 )   ! salt flux from total ice growth/melt
200      IF( iom_use('sfxbog'  ) )   CALL iom_put( 'sfxbog', sfx_bog * 1.e-03 )   ! salt flux from bottom growth
201      IF( iom_use('sfxbom'  ) )   CALL iom_put( 'sfxbom', sfx_bom * 1.e-03 )   ! salt flux from bottom melting
202      IF( iom_use('sfxsum'  ) )   CALL iom_put( 'sfxsum', sfx_sum * 1.e-03 )   ! salt flux from surface melting
203      IF( iom_use('sfxlam'  ) )   CALL iom_put( 'sfxlam', sfx_lam * 1.e-03 )   ! salt flux from lateral melting
204      IF( iom_use('sfxsni'  ) )   CALL iom_put( 'sfxsni', sfx_sni * 1.e-03 )   ! salt flux from snow ice formation
205      IF( iom_use('sfxopw'  ) )   CALL iom_put( 'sfxopw', sfx_opw * 1.e-03 )   ! salt flux from open water formation
206      IF( iom_use('sfxdyn'  ) )   CALL iom_put( 'sfxdyn', sfx_dyn * 1.e-03 )   ! salt flux from ridging rafting
207      IF( iom_use('sfxbri'  ) )   CALL iom_put( 'sfxbri', sfx_bri * 1.e-03 )   ! salt flux from brines
208      IF( iom_use('sfxres'  ) )   CALL iom_put( 'sfxres', sfx_res * 1.e-03 )   ! salt flux from undiagnosed processes
209      IF( iom_use('sfxsub'  ) )   CALL iom_put( 'sfxsub', sfx_sub * 1.e-03 )   ! salt flux from sublimation
210
211      ! --- mass fluxes [kg/m2/s] --- !
212      CALL iom_put( 'emp_oce', emp_oce )   ! emp over ocean (taking into account the snow blown away from the ice)
213      CALL iom_put( 'emp_ice', emp_ice )   ! emp over ice   (taking into account the snow blown away from the ice)
214
215      !                           ! vfxice = vfxbog + vfxbom + vfxsum + vfxsni + vfxopw + vfxdyn + vfxres + vfxlam + vfxpnd
216      CALL iom_put( 'vfxice'    , wfx_ice     )   ! mass flux from total ice growth/melt
217      CALL iom_put( 'vfxbog'    , wfx_bog     )   ! mass flux from bottom growth
218      CALL iom_put( 'vfxbom'    , wfx_bom     )   ! mass flux from bottom melt
219      CALL iom_put( 'vfxsum'    , wfx_sum     )   ! mass flux from surface melt
220      CALL iom_put( 'vfxlam'    , wfx_lam     )   ! mass flux from lateral melt
221      CALL iom_put( 'vfxsni'    , wfx_sni     )   ! mass flux from snow-ice formation
222      CALL iom_put( 'vfxopw'    , wfx_opw     )   ! mass flux from growth in open water
223      CALL iom_put( 'vfxdyn'    , wfx_dyn     )   ! mass flux from dynamics (ridging)
224      CALL iom_put( 'vfxres'    , wfx_res     )   ! mass flux from undiagnosed processes
225      CALL iom_put( 'vfxpnd'    , wfx_pnd     )   ! mass flux from melt ponds
226      CALL iom_put( 'vfxsub'    , wfx_ice_sub )   ! mass flux from ice sublimation (ice-atm.)
227      CALL iom_put( 'vfxsub_err', wfx_err_sub )   ! "excess" of sublimation sent to ocean     
228
229      IF ( iom_use( 'vfxthin' ) ) THEN   ! mass flux from ice growth in open water + thin ice (<20cm) => comparable to observations 
230         WHERE( hm_i(:,:) < 0.2 .AND. hm_i(:,:) > 0. ) ; z2d = wfx_bog
231         ELSEWHERE                                     ; z2d = 0._wp
232         END WHERE
233         CALL iom_put( 'vfxthin', wfx_opw + z2d )
234      ENDIF
235
236      !                            ! vfxsnw = vfxsnw_sni + vfxsnw_dyn + vfxsnw_sum
237      CALL iom_put( 'vfxsnw'     , wfx_snw     )   ! mass flux from total snow growth/melt
238      CALL iom_put( 'vfxsnw_sum' , wfx_snw_sum )   ! mass flux from snow melt at the surface
239      CALL iom_put( 'vfxsnw_sni' , wfx_snw_sni )   ! mass flux from snow melt during snow-ice formation
240      CALL iom_put( 'vfxsnw_dyn' , wfx_snw_dyn )   ! mass flux from dynamics (ridging)
241      CALL iom_put( 'vfxsnw_sub' , wfx_snw_sub )   ! mass flux from snow sublimation (ice-atm.)
242      CALL iom_put( 'vfxsnw_pre' , wfx_spr     )   ! snow precip
243
244      ! --- heat fluxes [W/m2] --- !
245      !                              ! qt_atm_oi - qt_oce_ai = hfxdhc - ( dihctrp + dshctrp )
246      IF( iom_use('qsr_oce'    ) )   CALL iom_put( 'qsr_oce'    , qsr_oce * ( 1._wp - at_i_b )                               )   !     solar flux at ocean surface
247      IF( iom_use('qns_oce'    ) )   CALL iom_put( 'qns_oce'    , qns_oce * ( 1._wp - at_i_b ) + qemp_oce                    )   ! non-solar flux at ocean surface
248      IF( iom_use('qsr_ice'    ) )   CALL iom_put( 'qsr_ice'    , SUM( qsr_ice * a_i_b, dim=3 )                              )   !     solar flux at ice surface
249      IF( iom_use('qns_ice'    ) )   CALL iom_put( 'qns_ice'    , SUM( qns_ice * a_i_b, dim=3 ) + qemp_ice                   )   ! non-solar flux at ice surface
250      IF( iom_use('qtr_ice_bot') )   CALL iom_put( 'qtr_ice_bot', SUM( qtr_ice_bot * a_i_b, dim=3 )                          )   !     solar flux transmitted thru ice
251      IF( iom_use('qtr_ice_top') )   CALL iom_put( 'qtr_ice_top', SUM( qtr_ice_top * a_i_b, dim=3 )                          )   !     solar flux transmitted thru ice surface
252      IF( iom_use('qt_oce'     ) )   CALL iom_put( 'qt_oce'     ,      ( qsr_oce + qns_oce ) * ( 1._wp - at_i_b ) + qemp_oce )
253      IF( iom_use('qt_ice'     ) )   CALL iom_put( 'qt_ice'     , SUM( ( qns_ice + qsr_ice ) * a_i_b, dim=3 )     + qemp_ice )
254      IF( iom_use('qt_oce_ai'  ) )   CALL iom_put( 'qt_oce_ai'  , qt_oce_ai * tmask(:,:,1)                                   )   ! total heat flux at the ocean   surface: interface oce-(ice+atm)
255      IF( iom_use('qt_atm_oi'  ) )   CALL iom_put( 'qt_atm_oi'  , qt_atm_oi * tmask(:,:,1)                                   )   ! total heat flux at the oce-ice surface: interface atm-(ice+oce)
256      IF( iom_use('qemp_oce'   ) )   CALL iom_put( 'qemp_oce'   , qemp_oce                                                   )   ! Downward Heat Flux from E-P over ocean
257      IF( iom_use('qemp_ice'   ) )   CALL iom_put( 'qemp_ice'   , qemp_ice                                                   )   ! Downward Heat Flux from E-P over ice
258
259      ! heat fluxes from ice transformations
260      !                            ! hfxdhc = hfxbog + hfxbom + hfxsum + hfxopw + hfxdif + hfxsnw - ( hfxthd + hfxdyn + hfxres + hfxsub + hfxspr )
261      CALL iom_put ('hfxbog'     , hfx_bog     )   ! heat flux used for ice bottom growth
262      CALL iom_put ('hfxbom'     , hfx_bom     )   ! heat flux used for ice bottom melt
263      CALL iom_put ('hfxsum'     , hfx_sum     )   ! heat flux used for ice surface melt
264      CALL iom_put ('hfxopw'     , hfx_opw     )   ! heat flux used for ice formation in open water
265      CALL iom_put ('hfxdif'     , hfx_dif     )   ! heat flux used for ice temperature change
266      CALL iom_put ('hfxsnw'     , hfx_snw     )   ! heat flux used for snow melt
267      CALL iom_put ('hfxerr'     , hfx_err_dif )   ! heat flux error after heat diffusion (included in qt_oce_ai)
268
269      ! heat fluxes associated with mass exchange (freeze/melt/precip...)
270      CALL iom_put ('hfxthd'     , hfx_thd     )   
271      CALL iom_put ('hfxdyn'     , hfx_dyn     )   
272      CALL iom_put ('hfxres'     , hfx_res     )   
273      CALL iom_put ('hfxsub'     , hfx_sub     )   
274      CALL iom_put ('hfxspr'     , hfx_spr     )   ! Heat flux from snow precip heat content
275
276      ! other heat fluxes
277      IF( iom_use('hfxsensib'  ) )   CALL iom_put( 'hfxsensib'  ,     -qsb_ice_bot * at_i_b         )   ! Sensible oceanic heat flux
278      IF( iom_use('hfxcndbot'  ) )   CALL iom_put( 'hfxcndbot'  , SUM( qcn_ice_bot * a_i_b, dim=3 ) )   ! Bottom conduction flux
279      IF( iom_use('hfxcndtop'  ) )   CALL iom_put( 'hfxcndtop'  , SUM( qcn_ice_top * a_i_b, dim=3 ) )   ! Surface conduction flux
280
281      ! controls
282      !---------
283#if ! defined key_agrif
284      IF( ln_icediachk .AND. .NOT. ln_bdy)   CALL ice_cons_final('iceupdate')                                       ! conservation
285#endif
286      IF( ln_icectl                      )   CALL ice_prt       (kt, iiceprt, jiceprt, 3, 'Final state ice_update') ! prints
287      IF( ln_ctl                         )   CALL ice_prt3D     ('iceupdate')                                       ! prints
288      IF( ln_timing                      )   CALL timing_stop   ('ice_update')                                      ! timing
289      !
290   END SUBROUTINE ice_update_flx
291
292
293   SUBROUTINE ice_update_tau( kt, pu_oce, pv_oce )
294      !!-------------------------------------------------------------------
295      !!                ***  ROUTINE ice_update_tau ***
296      !! 
297      !! ** Purpose : Update the ocean surface stresses due to the ice
298      !!         
299      !! ** Action  : * at each ice time step (every nn_fsbc time step):
300      !!                - compute the modulus of ice-ocean relative velocity
301      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
302      !!                      tmod_io = rhoco * | U_ice-U_oce |
303      !!                - update the modulus of stress at ocean surface
304      !!                      taum = (1-a) * taum + a * tmod_io * | U_ice-U_oce |
305      !!              * at each ocean time step (every kt):
306      !!                  compute linearized ice-ocean stresses as
307      !!                      Utau = tmod_io * | U_ice - pU_oce |
308      !!                using instantaneous current ocean velocity (usually before)
309      !!
310      !!    NB: - ice-ocean rotation angle no more allowed
311      !!        - here we make an approximation: taum is only computed every ice time step
312      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
313      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
314      !!
315      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
316      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
317      !!---------------------------------------------------------------------
318      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
319      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
320      !
321      INTEGER  ::   ji, jj   ! dummy loop indices
322      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
323      REAL(wp) ::   zat_v, zvtau_ice, zv_t, zrhoco  !   -      -
324      REAL(wp) ::   zflagi                          !   -      -
325      !!---------------------------------------------------------------------
326      IF( ln_timing )   CALL timing_start('ice_update_tau')
327
328      IF( kt == nit000 .AND. lwp ) THEN
329         WRITE(numout,*)
330         WRITE(numout,*)'ice_update_tau: update stress at the ice-ocean interface'
331         WRITE(numout,*)'~~~~~~~~~~~~~~'
332      ENDIF
333
334      zrhoco = rau0 * rn_cio
335      !
336      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
337         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
338            DO ji = fs_2, fs_jpim1
339               !                                               ! 2*(U_ice-U_oce) at T-point
340               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
341               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
342               !                                              ! |U_ice-U_oce|^2
343               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
344               !                                               ! update the ocean stress modulus
345               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt
346               tmod_io(ji,jj) = zrhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
347            END DO
348         END DO
349         CALL lbc_lnk_multi( 'iceupdate', taum, 'T', 1., tmod_io, 'T', 1. )
350         !
351         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
352         vtau_oce(:,:) = vtau(:,:)
353         !
354      ENDIF
355      !
356      !                                      !==  every ocean time-step  ==!
357      IF ( ln_drgice_imp ) THEN
358         ! Save drag with right sign to update top drag in the ocean implicit friction
359         rCdU_ice(:,:) = -r1_rau0 * tmod_io(:,:) * at_i(:,:) * tmask(:,:,1) 
360         zflagi = 0._wp
361      ELSE
362         zflagi = 1._wp
363      ENDIF
364      !
365      DO jj = 2, jpjm1                                !* update the stress WITHOUT an ice-ocean rotation angle
366         DO ji = fs_2, fs_jpim1   ! Vect. Opt.   
367            ! ice area at u and v-points
368            zat_u  = ( at_i(ji,jj) * tmask(ji,jj,1) + at_i (ji+1,jj    ) * tmask(ji+1,jj  ,1) )  &
369               &     / MAX( 1.0_wp , tmask(ji,jj,1) + tmask(ji+1,jj  ,1) )
370            zat_v  = ( at_i(ji,jj) * tmask(ji,jj,1) + at_i (ji  ,jj+1  ) * tmask(ji  ,jj+1,1) )  &
371               &     / MAX( 1.0_wp , tmask(ji,jj,1) + tmask(ji  ,jj+1,1) )
372            !                                                   ! linearized quadratic drag formulation
373            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - zflagi * pu_oce(ji,jj) )
374            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - zflagi * pv_oce(ji,jj) )
375            !                                                   ! stresses at the ocean surface
376            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
377            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
378         END DO
379      END DO
380      CALL lbc_lnk_multi( 'iceupdate', utau, 'U', -1., vtau, 'V', -1. )   ! lateral boundary condition
381      !
382      IF( ln_timing )   CALL timing_stop('ice_update_tau')
383     
384   END SUBROUTINE ice_update_tau
385
386
387   SUBROUTINE ice_update_init
388      !!-------------------------------------------------------------------
389      !!                  ***  ROUTINE ice_update_init  ***
390      !!             
391      !! ** Purpose :   allocate ice-ocean stress fields and read restarts
392      !!                containing the snow & ice mass
393      !!
394      !!-------------------------------------------------------------------
395      INTEGER  ::   ji, jj, jk               ! dummy loop indices
396      REAL(wp) ::   zcoefu, zcoefv, zcoeff   ! local scalar
397      !!-------------------------------------------------------------------
398      !
399      IF(lwp) WRITE(numout,*)
400      IF(lwp) WRITE(numout,*) 'ice_update_init: ice-ocean stress init'
401      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
402      !
403      !                                      ! allocate ice_update array
404      IF( ice_update_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'ice_update_init : unable to allocate standard arrays' )
405      !
406      CALL update_rst( 'READ' )  !* read or initialize all required files
407      !
408   END SUBROUTINE ice_update_init
409
410
411   SUBROUTINE update_rst( cdrw, kt )
412      !!---------------------------------------------------------------------
413      !!                   ***  ROUTINE rhg_evp_rst  ***
414      !!                     
415      !! ** Purpose :   Read or write RHG file in restart file
416      !!
417      !! ** Method  :   use of IOM library
418      !!----------------------------------------------------------------------
419      CHARACTER(len=*) , INTENT(in) ::   cdrw   ! 'READ'/'WRITE' flag
420      INTEGER, OPTIONAL, INTENT(in) ::   kt     ! ice time-step
421      !
422      INTEGER  ::   iter   ! local integer
423      INTEGER  ::   id1    ! local integer
424      !!----------------------------------------------------------------------
425      !
426      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialize
427         !                                   ! ---------------
428         IF( ln_rstart ) THEN                   !* Read the restart file
429            !
430            id1 = iom_varid( numrir, 'snwice_mass' , ldstop = .FALSE. )
431            !
432            IF( id1 > 0 ) THEN                       ! fields exist
433               CALL iom_get( numrir, jpdom_autoglo, 'snwice_mass'  , snwice_mass   )
434               CALL iom_get( numrir, jpdom_autoglo, 'snwice_mass_b', snwice_mass_b )
435            ELSE                                     ! start from rest
436               IF(lwp) WRITE(numout,*) '   ==>>   previous run without snow-ice mass output then set it'
437               snwice_mass  (:,:) = tmask(:,:,1) * ( rhos * vt_s(:,:) + rhoi * vt_i(:,:) )
438               snwice_mass_b(:,:) = snwice_mass(:,:)
439            ENDIF
440         ELSE                                   !* Start from rest
441            IF(lwp) WRITE(numout,*) '   ==>>   start from rest: set the snow-ice mass'
442            snwice_mass  (:,:) = tmask(:,:,1) * ( rhos * vt_s(:,:) + rhoi * vt_i(:,:) )
443            snwice_mass_b(:,:) = snwice_mass(:,:)
444         ENDIF
445         !
446      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
447         !                                   ! -------------------
448         IF(lwp) WRITE(numout,*) '---- update-rst ----'
449         iter = kt + nn_fsbc - 1             ! ice restarts are written at kt == nitrst - nn_fsbc + 1
450         !
451         CALL iom_rstput( iter, nitrst, numriw, 'snwice_mass'  , snwice_mass   )
452         CALL iom_rstput( iter, nitrst, numriw, 'snwice_mass_b', snwice_mass_b )
453         !
454      ENDIF
455      !
456   END SUBROUTINE update_rst
457
458#else
459   !!----------------------------------------------------------------------
460   !!   Default option         Dummy module           NO SI3 sea-ice model
461   !!----------------------------------------------------------------------
462#endif 
463
464   !!======================================================================
465END MODULE iceupdate
Note: See TracBrowser for help on using the repository browser.