source: NEMO/branches/2020/ticket2377/src/OCE/SBC/sbcfwb.F90 @ 13082

Last change on this file since 13082 was 13082, checked in by smueller, 11 months ago

Removal of variable fwfold from module sbcfwb (ticket #2377)

  • Property svn:keywords set to Id
File size: 12.6 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE isf_oce , ONLY : fwfisf_cav, fwfisf_par                    ! ice shelf melting contribution
20   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
21   USE phycst         ! physical constants
22   USE sbcrnf         ! ocean runoffs
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! IOM
27   USE lib_mpp        ! distribued memory computing library
28   USE timing         ! Timing
29   USE lbclnk         ! ocean lateral boundary conditions
30   USE lib_fortran    !
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_fwb    ! routine called by step
36
37   REAL(wp) ::   a_fwb     ! annual domain averaged freshwater budget from the
38                           ! previous year
39   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
40
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc, Kmm )
49      !!---------------------------------------------------------------------
50      !!                  ***  ROUTINE sbc_fwb  ***
51      !!
52      !! ** Purpose :   Control the mean sea surface drift
53      !!
54      !! ** Method  :   several ways  depending on kn_fwb
55      !!                =0 no control
56      !!                =1 global mean of emp set to zero at each nn_fsbc time step
57      !!                =2 annual global mean corrected from previous year
58      !!                =3 global mean of emp set to zero at each nn_fsbc time step
59      !!                   & spread out over erp area depending its sign
60      !! Note: if sea ice is embedded it is taken into account when computing the budget
61      !!----------------------------------------------------------------------
62      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
63      INTEGER, INTENT( in ) ::   kn_fsbc  !
64      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
65      INTEGER, INTENT( in ) ::   Kmm      ! ocean time level index
66      !
67      INTEGER  ::   inum, ikty, iyear     ! local integers
68      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
69      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
70      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
71      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
72      REAL(wp)   ,DIMENSION(1) ::   z_fwfprv 
73      COMPLEX(wp),DIMENSION(1) ::   y_fwfnow 
74      !!----------------------------------------------------------------------
75      !
76      IF( kt == nit000 ) THEN
77         IF(lwp) THEN
78            WRITE(numout,*)
79            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
80            WRITE(numout,*) '~~~~~~~'
81            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
82            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
83            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
84         ENDIF
85         !
86         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
87         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
88         !
89         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
90         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
91         ! and in case of no melt, it can generate HSSW.
92         !
93#if ! defined key_si3 && ! defined key_cice
94         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
95         snwice_mass  (:,:) = 0.e0
96#endif
97         !
98      ENDIF
99
100      SELECT CASE ( kn_fwb )
101      !
102      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
103         !
104         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
105            y_fwfnow(1) = local_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) )
106            CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 )
107            z_fwfprv(1) = z_fwfprv(1) / area
108            zcoef = z_fwfprv(1) * rcp
109            emp(:,:) = emp(:,:) - z_fwfprv(1)        * tmask(:,:,1)
110            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
111         ENDIF
112         !
113      CASE ( 2 )                             !==  fw adjustment based on fw budget at the end of the previous year  ==!
114         !
115         IF( kt == nit000 ) THEN                      ! initialisation
116            !                                         ! read the fw adjustment (a_fwb)
117            IF ( ln_rstart .AND. iom_varid( numror, 'a_fwb',   ldstop = .FALSE. ) > 0 ) THEN
118               IF(lwp) WRITE(numout,*) 'sbc_fwb : reading FW-budget adjustment from restart file'
119               CALL iom_get( numror, 'a_fwb',   a_fwb,   ldxios = lrxios )
120            ELSE
121               CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
122               READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb
123               CLOSE( inum )
124            END IF
125            !
126            IF(lwp)WRITE(numout,*)
127            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', a_fwb
128            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
129            !
130            IF( lwxios ) THEN                         ! Activate output of restart variables
131               CALL iom_set_rstw_var_active( 'a_fwb'   )
132            END IF
133         ENDIF   
134         !                                         ! Update a_fwb if new year start
135         ikty = 365 * 86400 / rn_Dt                  !!bug  use of 365 days leap year or 360d year !!!!!!!
136         IF( MOD( kt, ikty ) == 0 ) THEN
137                                                      ! mean sea level taking into account the ice+snow
138                                                      ! sum over the global domain
139            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( ssh(:,:,Kmm) + snwice_mass(:,:) * r1_rho0 ) )
140            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
141!!gm        !                                                      !!bug 365d year
142         ENDIF
143         !
144         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
145            zcoef = a_fwb * rcp
146            emp(:,:) = emp(:,:) + a_fwb              * tmask(:,:,1)
147            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
148         ENDIF
149         ! Output restart information
150         IF( lrst_oce ) THEN
151            IF(lwp) WRITE(numout,*)
152            IF(lwp) WRITE(numout,*) 'sbc_fwb : writing FW-budget adjustment to ocean restart file at it = ', kt
153            IF(lwp) WRITE(numout,*) '~~~~'
154            IF( lwxios ) CALL iom_swap( cwxios_context )
155            CALL iom_rstput( kt, nitrst, numrow, 'a_fwb',   a_fwb,   ldxios = lwxios )
156            IF( lwxios ) CALL iom_swap( cxios_context  )
157         END IF
158         !
159         IF( kt == nitend .AND. lwm ) THEN            ! save a_fwb value in a file (only one required)
160            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
161            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb
162            CLOSE( inum )
163         ENDIF
164         !
165      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
166         !
167         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
168         !
169         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
170            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
171            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
172            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
173            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
174            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) ) / area
175            !           
176            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
177               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
178               zsurf_tospread      = zsurf_pos
179               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
180            ELSE                             ! spread out over <0 erp area to increase precipitation
181               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
182               zsurf_tospread      = zsurf_neg
183               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
184            ENDIF
185            !
186            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
187!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
188            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
189            !                                                  ! weight to respect erp field 2D structure
190            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
191            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
192            !                                                  ! final correction term to apply
193            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
194            !
195!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
196            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1. )
197            !
198            emp(:,:) = emp(:,:) + zerp_cor(:,:)
199            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
200            erp(:,:) = erp(:,:) + zerp_cor(:,:)
201            !
202            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
203               IF( z_fwf < 0._wp ) THEN
204                  WRITE(numout,*)'   z_fwf < 0'
205                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
206               ELSE
207                  WRITE(numout,*)'   z_fwf >= 0'
208                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
209               ENDIF
210               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
211               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
212               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
213               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
214               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
215            ENDIF
216         ENDIF
217         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
218         !
219      CASE DEFAULT                           !==  you should never be there  ==!
220         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
221         !
222      END SELECT
223      !
224   END SUBROUTINE sbc_fwb
225
226   !!======================================================================
227END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.