New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
eosbn2.F90 in NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14116_HPC-10_mcastril_Mixed_Precision_implementation/src/OCE/TRA/eosbn2.F90 @ 15520

Last change on this file since 15520 was 15520, checked in by sparonuz, 8 months ago

fix name of variables mispelled in subprogram declaration. Removed file added for error.

  • Property svn:keywords set to Id
File size: 80.7 KB
Line 
1MODULE eosbn2
2   !!==============================================================================
3   !!                       ***  MODULE  eosbn2  ***
4   !! Equation Of Seawater : in situ density - Brunt-Vaisala frequency
5   !!==============================================================================
6   !! History :  OPA  ! 1989-03  (O. Marti)  Original code
7   !!            6.0  ! 1994-07  (G. Madec, M. Imbard)  add bn2
8   !!            6.0  ! 1994-08  (G. Madec)  Add Jackett & McDougall eos
9   !!            7.0  ! 1996-01  (G. Madec)  statement function for e3
10   !!            8.1  ! 1997-07  (G. Madec)  density instead of volumic mass
11   !!             -   ! 1999-02  (G. Madec, N. Grima) semi-implicit pressure gradient
12   !!            8.2  ! 2001-09  (M. Ben Jelloul)  bugfix on linear eos
13   !!   NEMO     1.0  ! 2002-10  (G. Madec)  add eos_init
14   !!             -   ! 2002-11  (G. Madec, A. Bozec)  partial step, eos_insitu_2d
15   !!             -   ! 2003-08  (G. Madec)  F90, free form
16   !!            3.0  ! 2006-08  (G. Madec)  add tfreez function (now eos_fzp function)
17   !!            3.3  ! 2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
18   !!             -   ! 2010-10  (G. Nurser, G. Madec)  add alpha/beta used in ldfslp
19   !!            3.7  ! 2012-03  (F. Roquet, G. Madec)  add primitive of alpha and beta used in PE computation
20   !!             -   ! 2012-05  (F. Roquet)  add Vallis and original JM95 equation of state
21   !!             -   ! 2013-04  (F. Roquet, G. Madec)  add eos_rab, change bn2 computation and reorganize the module
22   !!             -   ! 2014-09  (F. Roquet)  add TEOS-10, S-EOS, and modify EOS-80
23   !!             -   ! 2015-06  (P.A. Bouttier) eos_fzp functions changed to subroutines for AGRIF
24   !!----------------------------------------------------------------------
25
26   !!----------------------------------------------------------------------
27   !!   eos           : generic interface of the equation of state
28   !!   eos_insitu    : Compute the in situ density
29   !!   eos_insitu_pot: Compute the insitu and surface referenced potential volumic mass
30   !!   eos_insitu_2d : Compute the in situ density for 2d fields
31   !!   bn2           : compute the Brunt-Vaisala frequency
32   !!   eos_pt_from_ct: compute the potential temperature from the Conservative Temperature
33   !!   eos_rab       : generic interface of in situ thermal/haline expansion ratio
34   !!   eos_rab_3d    : compute in situ thermal/haline expansion ratio
35   !!   eos_rab_2d    : compute in situ thermal/haline expansion ratio for 2d fields
36   !!   eos_fzp_2d    : freezing temperature for 2d fields
37   !!   eos_fzp_0d    : freezing temperature for scalar
38   !!   eos_init      : set eos parameters (namelist)
39   !!----------------------------------------------------------------------
40   USE dom_oce        ! ocean space and time domain
41   USE domutl, ONLY : is_tile
42   USE phycst         ! physical constants
43   USE stopar         ! Stochastic T/S fluctuations
44   USE stopts         ! Stochastic T/S fluctuations
45   !
46   USE in_out_manager ! I/O manager
47   USE lib_mpp        ! MPP library
48   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
49   USE prtctl         ! Print control
50   USE lbclnk         ! ocean lateral boundary conditions
51   USE timing         ! Timing
52
53   IMPLICIT NONE
54   PRIVATE
55
56   !                  !! * Interface
57   INTERFACE eos
58      MODULE PROCEDURE eos_insitu, eos_insitu_pot, eos_insitu_2d, eos_insitu_pot_2d
59   END INTERFACE
60   !
61   INTERFACE eos_rab
62      MODULE PROCEDURE rab_3d, rab_2d, rab_0d
63   END INTERFACE
64   !
65   INTERFACE eos_fzp
66      MODULE PROCEDURE eos_fzp_2d, eos_fzp_0d
67   END INTERFACE
68   !
69   PUBLIC   eos            ! called by step, istate, tranpc and zpsgrd modules
70   PUBLIC   bn2            ! called by step module
71   PUBLIC   eos_rab        ! called by ldfslp, zdfddm, trabbl
72   PUBLIC   eos_pt_from_ct ! called by sbcssm
73   PUBLIC   eos_fzp        ! called by traadv_cen2 and sbcice_... modules
74   PUBLIC   eos_pen        ! used for pe diagnostics in trdpen module
75   PUBLIC   eos_init       ! called by istate module
76
77   !                               !!** Namelist nameos **
78   LOGICAL , PUBLIC ::   ln_TEOS10
79   LOGICAL , PUBLIC ::   ln_EOS80
80   LOGICAL , PUBLIC ::   ln_SEOS
81
82   ! Parameters
83   LOGICAL , PUBLIC    ::   l_useCT         ! =T in ln_TEOS10=T (i.e. use eos_pt_from_ct to compute sst_m), =F otherwise
84   INTEGER , PUBLIC    ::   neos            ! Identifier for equation of state used
85
86   INTEGER , PARAMETER ::   np_teos10 = -1  ! parameter for using TEOS10
87   INTEGER , PARAMETER ::   np_eos80  =  0  ! parameter for using EOS80
88   INTEGER , PARAMETER ::   np_seos   = 1   ! parameter for using Simplified Equation of state
89
90   !                               !!!  simplified eos coefficients (default value: Vallis 2006)
91   REAL(wp), PUBLIC ::   rn_a0      = 1.6550e-1_wp     ! thermal expansion coeff.
92   REAL(wp), PUBLIC ::   rn_b0      = 7.6554e-1_wp     ! saline  expansion coeff.
93   REAL(wp) ::   rn_lambda1 = 5.9520e-2_wp     ! cabbeling coeff. in T^2
94   REAL(wp) ::   rn_lambda2 = 5.4914e-4_wp     ! cabbeling coeff. in S^2
95   REAL(wp) ::   rn_mu1     = 1.4970e-4_wp     ! thermobaric coeff. in T
96   REAL(wp) ::   rn_mu2     = 1.1090e-5_wp     ! thermobaric coeff. in S
97   REAL(wp) ::   rn_nu      = 2.4341e-3_wp     ! cabbeling coeff. in theta*salt
98
99   ! TEOS10/EOS80 parameters
100   REAL(wp) ::   r1_S0, r1_T0, r1_Z0, rdeltaS
101
102   ! EOS parameters
103   REAL(wp) ::   EOS000 , EOS100 , EOS200 , EOS300 , EOS400 , EOS500 , EOS600
104   REAL(wp) ::   EOS010 , EOS110 , EOS210 , EOS310 , EOS410 , EOS510
105   REAL(wp) ::   EOS020 , EOS120 , EOS220 , EOS320 , EOS420
106   REAL(wp) ::   EOS030 , EOS130 , EOS230 , EOS330
107   REAL(wp) ::   EOS040 , EOS140 , EOS240
108   REAL(wp) ::   EOS050 , EOS150
109   REAL(wp) ::   EOS060
110   REAL(wp) ::   EOS001 , EOS101 , EOS201 , EOS301 , EOS401
111   REAL(wp) ::   EOS011 , EOS111 , EOS211 , EOS311
112   REAL(wp) ::   EOS021 , EOS121 , EOS221
113   REAL(wp) ::   EOS031 , EOS131
114   REAL(wp) ::   EOS041
115   REAL(wp) ::   EOS002 , EOS102 , EOS202
116   REAL(wp) ::   EOS012 , EOS112
117   REAL(wp) ::   EOS022
118   REAL(wp) ::   EOS003 , EOS103
119   REAL(wp) ::   EOS013
120
121   ! ALPHA parameters
122   REAL(wp) ::   ALP000 , ALP100 , ALP200 , ALP300 , ALP400 , ALP500
123   REAL(wp) ::   ALP010 , ALP110 , ALP210 , ALP310 , ALP410
124   REAL(wp) ::   ALP020 , ALP120 , ALP220 , ALP320
125   REAL(wp) ::   ALP030 , ALP130 , ALP230
126   REAL(wp) ::   ALP040 , ALP140
127   REAL(wp) ::   ALP050
128   REAL(wp) ::   ALP001 , ALP101 , ALP201 , ALP301
129   REAL(wp) ::   ALP011 , ALP111 , ALP211
130   REAL(wp) ::   ALP021 , ALP121
131   REAL(wp) ::   ALP031
132   REAL(wp) ::   ALP002 , ALP102
133   REAL(wp) ::   ALP012
134   REAL(wp) ::   ALP003
135
136   ! BETA parameters
137   REAL(wp) ::   BET000 , BET100 , BET200 , BET300 , BET400 , BET500
138   REAL(wp) ::   BET010 , BET110 , BET210 , BET310 , BET410
139   REAL(wp) ::   BET020 , BET120 , BET220 , BET320
140   REAL(wp) ::   BET030 , BET130 , BET230
141   REAL(wp) ::   BET040 , BET140
142   REAL(wp) ::   BET050
143   REAL(wp) ::   BET001 , BET101 , BET201 , BET301
144   REAL(wp) ::   BET011 , BET111 , BET211
145   REAL(wp) ::   BET021 , BET121
146   REAL(wp) ::   BET031
147   REAL(wp) ::   BET002 , BET102
148   REAL(wp) ::   BET012
149   REAL(wp) ::   BET003
150
151   ! PEN parameters
152   REAL(wp) ::   PEN000 , PEN100 , PEN200 , PEN300 , PEN400
153   REAL(wp) ::   PEN010 , PEN110 , PEN210 , PEN310
154   REAL(wp) ::   PEN020 , PEN120 , PEN220
155   REAL(wp) ::   PEN030 , PEN130
156   REAL(wp) ::   PEN040
157   REAL(wp) ::   PEN001 , PEN101 , PEN201
158   REAL(wp) ::   PEN011 , PEN111
159   REAL(wp) ::   PEN021
160   REAL(wp) ::   PEN002 , PEN102
161   REAL(wp) ::   PEN012
162
163   ! ALPHA_PEN parameters
164   REAL(wp) ::   APE000 , APE100 , APE200 , APE300
165   REAL(wp) ::   APE010 , APE110 , APE210
166   REAL(wp) ::   APE020 , APE120
167   REAL(wp) ::   APE030
168   REAL(wp) ::   APE001 , APE101
169   REAL(wp) ::   APE011
170   REAL(wp) ::   APE002
171
172   ! BETA_PEN parameters
173   REAL(wp) ::   BPE000 , BPE100 , BPE200 , BPE300
174   REAL(wp) ::   BPE010 , BPE110 , BPE210
175   REAL(wp) ::   BPE020 , BPE120
176   REAL(wp) ::   BPE030
177   REAL(wp) ::   BPE001 , BPE101
178   REAL(wp) ::   BPE011
179   REAL(wp) ::   BPE002
180
181   !! * Substitutions
182#  include "do_loop_substitute.h90"
183#  include "domzgr_substitute.h90"
184#  include "single_precision_substitute.h90"
185   !!----------------------------------------------------------------------
186   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
187   !! $Id$
188   !! Software governed by the CeCILL license (see ./LICENSE)
189   !!----------------------------------------------------------------------
190CONTAINS
191
192   SUBROUTINE eos_insitu( pts, prd, pdep )
193      !!
194      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celsius]
195      !                                                      ! 2 : salinity               [psu]
196      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out) ::   prd   ! in situ density            [-]
197      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pdep  ! depth                      [m]
198      !!
199      CALL eos_insitu_t( pts, is_tile(pts), prd, is_tile(prd), pdep, is_tile(pdep) )
200   END SUBROUTINE eos_insitu
201
202
203   SUBROUTINE eos_insitu_t( pts, ktts, prd, ktrd, pdep, ktdep )
204      !!----------------------------------------------------------------------
205      !!                   ***  ROUTINE
206      !!
207      !! ** Purpose :   Compute the in situ density (ratio rho/rho0) from
208      !!       potential temperature and salinity using an equation of state
209      !!       selected in the nameos namelist
210      !!
211      !! ** Method  :   prd(t,s,z) = ( rho(t,s,z) - rho0 ) / rho0
212      !!         with   prd    in situ density anomaly      no units
213      !!                t      TEOS10: CT or EOS80: PT      Celsius
214      !!                s      TEOS10: SA or EOS80: SP      TEOS10: g/kg or EOS80: psu
215      !!                z      depth                        meters
216      !!                rho    in situ density              kg/m^3
217      !!                rho0   reference density            kg/m^3
218      !!
219      !!     ln_teos10 : polynomial TEOS-10 equation of state is used for rho(t,s,z).
220      !!         Check value: rho = 1028.21993233072 kg/m^3 for z=3000 dbar, ct=3 Celsius, sa=35.5 g/kg
221      !!
222      !!     ln_eos80 : polynomial EOS-80 equation of state is used for rho(t,s,z).
223      !!         Check value: rho = 1028.35011066567 kg/m^3 for z=3000 dbar, pt=3 Celsius, sp=35.5 psu
224      !!
225      !!     ln_seos : simplified equation of state
226      !!              prd(t,s,z) = ( -a0*(1+lambda/2*(T-T0)+mu*z+nu*(S-S0))*(T-T0) + b0*(S-S0) ) / rho0
227      !!              linear case function of T only: rn_alpha<>0, other coefficients = 0
228      !!              linear eos function of T and S: rn_alpha and rn_beta<>0, other coefficients=0
229      !!              Vallis like equation: use default values of coefficients
230      !!
231      !! ** Action  :   compute prd , the in situ density (no units)
232      !!
233      !! References :   Roquet et al, Ocean Modelling, in preparation (2014)
234      !!                Vallis, Atmospheric and Oceanic Fluid Dynamics, 2006
235      !!                TEOS-10 Manual, 2010
236      !!----------------------------------------------------------------------
237      INTEGER                                 , INTENT(in   ) ::   ktts, ktrd, ktdep
238      REAL(wp), DIMENSION(A2D_T(ktts) ,JPK,JPTS), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celsius]
239      !                                                                  ! 2 : salinity               [psu]
240      REAL(wp), DIMENSION(A2D_T(ktrd) ,JPK     ), INTENT(  out) ::   prd   ! in situ density            [-]
241      REAL(wp), DIMENSION(A2D_T(ktdep),JPK     ), INTENT(in   ) ::   pdep  ! depth                      [m]
242      !
243      INTEGER  ::   ji, jj, jk                ! dummy loop indices
244      REAL(wp) ::   zt , zh , zs , ztm        ! local scalars
245      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
246      !!----------------------------------------------------------------------
247      !
248      IF( ln_timing )   CALL timing_start('eos-insitu')
249      !
250      SELECT CASE( neos )
251      !
252      CASE( np_teos10, np_eos80 )                !==  polynomial TEOS-10 / EOS-80 ==!
253         !
254         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
255            !
256            zh  = pdep(ji,jj,jk) * r1_Z0                                  ! depth
257            zt  = pts (ji,jj,jk,jp_tem) * r1_T0                           ! temperature
258            zs  = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
259            ztm = tmask(ji,jj,jk)                                         ! tmask
260            !
261            zn3 = EOS013*zt   &
262               &   + EOS103*zs+EOS003
263               !
264            zn2 = (EOS022*zt   &
265               &   + EOS112*zs+EOS012)*zt   &
266               &   + (EOS202*zs+EOS102)*zs+EOS002
267               !
268            zn1 = (((EOS041*zt   &
269               &   + EOS131*zs+EOS031)*zt   &
270               &   + (EOS221*zs+EOS121)*zs+EOS021)*zt   &
271               &   + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt   &
272               &   + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001
273               !
274            zn0 = (((((EOS060*zt   &
275               &   + EOS150*zs+EOS050)*zt   &
276               &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
277               &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
278               &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
279               &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
280               &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
281               !
282            zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
283            !
284            prd(ji,jj,jk) = (  zn * r1_rho0 - 1._wp  ) * ztm  ! density anomaly (masked)
285            !
286         END_3D
287         !
288      CASE( np_seos )                !==  simplified EOS  ==!
289         !
290         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
291            zt  = pts  (ji,jj,jk,jp_tem) - 10._wp
292            zs  = pts  (ji,jj,jk,jp_sal) - 35._wp
293            zh  = pdep (ji,jj,jk)
294            ztm = tmask(ji,jj,jk)
295            !
296            zn =  - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt + rn_mu1*zh ) * zt   &
297               &  + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs - rn_mu2*zh ) * zs   &
298               &  - rn_nu * zt * zs
299               !
300            prd(ji,jj,jk) = zn * r1_rho0 * ztm                ! density anomaly (masked)
301         END_3D
302         !
303      END SELECT
304      !
305      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos-insitu  : ', kdim=jpk )
306      !
307      IF( ln_timing )   CALL timing_stop('eos-insitu')
308      !
309   END SUBROUTINE eos_insitu_t
310 
311   SUBROUTINE eos_insitu_pot( pts, prd, prhop, pdep )
312      !!
313      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pts    ! 1 : potential temperature  [Celsius]
314      !                                                       ! 2 : salinity               [psu]
315      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out) ::   prd    ! in situ density            [-]
316      REAL(dp), DIMENSION(:,:,:)  , INTENT(  out) ::   prhop  ! potential density (surface referenced)
317      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pdep   ! depth                      [m]
318      !!
319      CALL eos_insitu_pot_t( pts, is_tile(pts), prd, is_tile(prd), prhop, is_tile(prhop), pdep, is_tile(pdep) )
320   END SUBROUTINE eos_insitu_pot
321
322   SUBROUTINE eos_insitu_pot_t( pts, ktts, prd, ktrd, prhop, ktrhop, pdep, ktdep )
323      !!----------------------------------------------------------------------
324      !!                  ***  ROUTINE eos_insitu_pot  ***
325      !!
326      !! ** Purpose :   Compute the in situ density (ratio rho/rho0) and the
327      !!      potential volumic mass (Kg/m3) from potential temperature and
328      !!      salinity fields using an equation of state selected in the
329      !!     namelist.
330      !!
331      !! ** Action  : - prd  , the in situ density (no units)
332      !!              - prhop, the potential volumic mass (Kg/m3)
333      !!
334      !!----------------------------------------------------------------------
335      INTEGER                                  , INTENT(in   ) ::   ktts, ktrd, ktrhop, ktdep
336      REAL(wp), DIMENSION(A2D_T(ktts)  ,JPK,JPTS), INTENT(in   ) ::   pts    ! 1 : potential temperature  [Celsius]
337      !                                                                    ! 2 : salinity               [psu]
338      REAL(wp), DIMENSION(A2D_T(ktrd)  ,JPK     ), INTENT(  out) ::   prd    ! in situ density            [-]
339      REAL(dp), DIMENSION(A2D_T(ktrhop),JPK     ), INTENT(  out) ::   prhop  ! potential density (surface referenced)
340      REAL(wp), DIMENSION(A2D_T(ktdep) ,JPK     ), INTENT(in   ) ::   pdep   ! depth                      [m]
341      !
342      INTEGER  ::   ji, jj, jk, jsmp             ! dummy loop indices
343      INTEGER  ::   jdof
344      REAL(wp) ::   zt , zh , zstemp, zs , ztm   ! local scalars
345      REAL(wp) ::   zn , zn0, zn1, zn2, zn3      !   -      -
346      REAL(wp), DIMENSION(:), ALLOCATABLE :: zn0_sto, zn_sto, zsign    ! local vectors
347      !!----------------------------------------------------------------------
348      !
349      IF( ln_timing )   CALL timing_start('eos-pot')
350      !
351      SELECT CASE ( neos )
352      !
353      CASE( np_teos10, np_eos80 )                !==  polynomial TEOS-10 / EOS-80 ==!
354         !
355         ! Stochastic equation of state
356         IF ( ln_sto_eos ) THEN
357            ALLOCATE(zn0_sto(1:2*nn_sto_eos))
358            ALLOCATE(zn_sto(1:2*nn_sto_eos))
359            ALLOCATE(zsign(1:2*nn_sto_eos))
360            DO jsmp = 1, 2*nn_sto_eos, 2
361              zsign(jsmp)   = 1._wp
362              zsign(jsmp+1) = -1._wp
363            END DO
364            !
365            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
366               !
367               ! compute density (2*nn_sto_eos) times:
368               ! (1) for t+dt, s+ds (with the random TS fluctutation computed in sto_pts)
369               ! (2) for t-dt, s-ds (with the opposite fluctuation)
370               DO jsmp = 1, nn_sto_eos*2
371                  jdof   = (jsmp + 1) / 2
372                  zh     = pdep(ji,jj,jk) * r1_Z0                                  ! depth
373                  zt     = (pts (ji,jj,jk,jp_tem) + pts_ran(ji,jj,jk,jp_tem,jdof) * zsign(jsmp)) * r1_T0    ! temperature
374                  zstemp = pts  (ji,jj,jk,jp_sal) + pts_ran(ji,jj,jk,jp_sal,jdof) * zsign(jsmp)
375                  zs     = SQRT( ABS( zstemp + rdeltaS ) * r1_S0 )   ! square root salinity
376                  ztm    = tmask(ji,jj,jk)                                         ! tmask
377                  !
378                  zn3 = EOS013*zt   &
379                     &   + EOS103*zs+EOS003
380                     !
381                  zn2 = (EOS022*zt   &
382                     &   + EOS112*zs+EOS012)*zt   &
383                     &   + (EOS202*zs+EOS102)*zs+EOS002
384                     !
385                  zn1 = (((EOS041*zt   &
386                     &   + EOS131*zs+EOS031)*zt   &
387                     &   + (EOS221*zs+EOS121)*zs+EOS021)*zt   &
388                     &   + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt   &
389                     &   + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001
390                     !
391                  zn0_sto(jsmp) = (((((EOS060*zt   &
392                     &   + EOS150*zs+EOS050)*zt   &
393                     &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
394                     &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
395                     &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
396                     &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
397                     &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
398                     !
399                  zn_sto(jsmp)  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0_sto(jsmp)
400               END DO
401               !
402               ! compute stochastic density as the mean of the (2*nn_sto_eos) densities
403               prhop(ji,jj,jk) = 0._wp ; prd(ji,jj,jk) = 0._wp
404               DO jsmp = 1, nn_sto_eos*2
405                  prhop(ji,jj,jk) = prhop(ji,jj,jk) + zn0_sto(jsmp)                      ! potential density referenced at the surface
406                  !
407                  prd(ji,jj,jk) = prd(ji,jj,jk) + (  zn_sto(jsmp) * r1_rho0 - 1._wp  )   ! density anomaly (masked)
408               END DO
409               prhop(ji,jj,jk) = 0.5_wp * prhop(ji,jj,jk) * ztm / nn_sto_eos
410               prd  (ji,jj,jk) = 0.5_wp * prd  (ji,jj,jk) * ztm / nn_sto_eos
411            END_3D
412            DEALLOCATE(zn0_sto,zn_sto,zsign)
413         ! Non-stochastic equation of state
414         ELSE
415            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
416               !
417               zh  = pdep(ji,jj,jk) * r1_Z0                                  ! depth
418               zt  = pts (ji,jj,jk,jp_tem) * r1_T0                           ! temperature
419               zs  = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
420               ztm = tmask(ji,jj,jk)                                         ! tmask
421               !
422               zn3 = EOS013*zt   &
423                  &   + EOS103*zs+EOS003
424                  !
425               zn2 = (EOS022*zt   &
426                  &   + EOS112*zs+EOS012)*zt   &
427                  &   + (EOS202*zs+EOS102)*zs+EOS002
428                  !
429               zn1 = (((EOS041*zt   &
430                  &   + EOS131*zs+EOS031)*zt   &
431                  &   + (EOS221*zs+EOS121)*zs+EOS021)*zt   &
432                  &   + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt   &
433                  &   + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001
434                  !
435               zn0 = (((((EOS060*zt   &
436                  &   + EOS150*zs+EOS050)*zt   &
437                  &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
438                  &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
439                  &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
440                  &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
441                  &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
442                  !
443               zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
444               !
445               prhop(ji,jj,jk) = zn0 * ztm                           ! potential density referenced at the surface
446               !
447               prd(ji,jj,jk) = (  zn * r1_rho0 - 1._wp  ) * ztm      ! density anomaly (masked)
448            END_3D
449         ENDIF
450
451      CASE( np_seos )                !==  simplified EOS  ==!
452         !
453         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
454            zt  = pts  (ji,jj,jk,jp_tem) - 10._wp
455            zs  = pts  (ji,jj,jk,jp_sal) - 35._wp
456            zh  = pdep (ji,jj,jk)
457            ztm = tmask(ji,jj,jk)
458            !                                                     ! potential density referenced at the surface
459            zn =  - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt ) * zt   &
460               &  + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs ) * zs   &
461               &  - rn_nu * zt * zs
462            prhop(ji,jj,jk) = ( rho0 + zn ) * ztm
463            !                                                     ! density anomaly (masked)
464            zn = zn - ( rn_a0 * rn_mu1 * zt + rn_b0 * rn_mu2 * zs ) * zh
465            prd(ji,jj,jk) = zn * r1_rho0 * ztm
466            !
467         END_3D
468         !
469      END SELECT
470      !
471      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos-pot: ', &
472         &                                  tab3d_2=CASTWP(prhop), clinfo2=' pot : ', kdim=jpk )
473      !
474      IF( ln_timing )   CALL timing_stop('eos-pot')
475      !
476   END SUBROUTINE eos_insitu_pot_t
477
478 
479   SUBROUTINE eos_insitu_2d( pts, pdep, prd )
480      !!
481      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celsius]
482      !                                                    ! 2 : salinity               [psu]
483      REAL(wp), DIMENSION(:,:)  , INTENT(in   ) ::   pdep  ! depth                      [m]
484      REAL(wp), DIMENSION(:,:)  , INTENT(  out) ::   prd   ! in situ density
485      !!
486      CALL eos_insitu_2d_t( pts, is_tile(pts), pdep, is_tile(pdep), prd, is_tile(prd) )
487   END SUBROUTINE eos_insitu_2d
488
489
490   SUBROUTINE eos_insitu_2d_t( pts, ktts, pdep, ktdep, prd, ktrd )
491      !!----------------------------------------------------------------------
492      !!                  ***  ROUTINE eos_insitu_2d  ***
493      !!
494      !! ** Purpose :   Compute the in situ density (ratio rho/rho0) from
495      !!      potential temperature and salinity using an equation of state
496      !!      selected in the nameos namelist. * 2D field case
497      !!
498      !! ** Action  : - prd , the in situ density (no units) (unmasked)
499      !!
500      !!----------------------------------------------------------------------
501      INTEGER                            , INTENT(in   ) ::   ktts, ktdep, ktrd
502      REAL(wp), DIMENSION(A2D_T(ktts),JPTS), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celsius]
503      !                                                             ! 2 : salinity               [psu]
504      REAL(wp), DIMENSION(A2D_T(ktdep)    ), INTENT(in   ) ::   pdep  ! depth                      [m]
505      REAL(wp), DIMENSION(A2D_T(ktrd)     ), INTENT(  out) ::   prd   ! in situ density
506      !
507      INTEGER  ::   ji, jj, jk                ! dummy loop indices
508      REAL(wp) ::   zt , zh , zs              ! local scalars
509      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
510      !!----------------------------------------------------------------------
511      !
512      IF( ln_timing )   CALL timing_start('eos2d')
513      !
514      prd(:,:) = 0._wp
515      !
516      SELECT CASE( neos )
517      !
518      CASE( np_teos10, np_eos80 )                !==  polynomial TEOS-10 / EOS-80 ==!
519         !
520         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
521            !
522            zh  = pdep(ji,jj) * r1_Z0                                  ! depth
523            zt  = pts (ji,jj,jp_tem) * r1_T0                           ! temperature
524            zs  = SQRT( ABS( pts(ji,jj,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
525            !
526            zn3 = EOS013*zt   &
527               &   + EOS103*zs+EOS003
528               !
529            zn2 = (EOS022*zt   &
530               &   + EOS112*zs+EOS012)*zt   &
531               &   + (EOS202*zs+EOS102)*zs+EOS002
532               !
533            zn1 = (((EOS041*zt   &
534               &   + EOS131*zs+EOS031)*zt   &
535               &   + (EOS221*zs+EOS121)*zs+EOS021)*zt   &
536               &   + ((EOS311*zs+EOS211)*zs+EOS111)*zs+EOS011)*zt   &
537               &   + (((EOS401*zs+EOS301)*zs+EOS201)*zs+EOS101)*zs+EOS001
538               !
539            zn0 = (((((EOS060*zt   &
540               &   + EOS150*zs+EOS050)*zt   &
541               &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
542               &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
543               &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
544               &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
545               &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
546               !
547            zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
548            !
549            prd(ji,jj) = zn * r1_rho0 - 1._wp               ! unmasked in situ density anomaly
550            !
551         END_2D
552         !
553      CASE( np_seos )                !==  simplified EOS  ==!
554         !
555         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
556            !
557            zt    = pts  (ji,jj,jp_tem)  - 10._wp
558            zs    = pts  (ji,jj,jp_sal)  - 35._wp
559            zh    = pdep (ji,jj)                         ! depth at the partial step level
560            !
561            zn =  - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt + rn_mu1*zh ) * zt   &
562               &  + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs - rn_mu2*zh ) * zs   &
563               &  - rn_nu * zt * zs
564               !
565            prd(ji,jj) = zn * r1_rho0               ! unmasked in situ density anomaly
566            !
567         END_2D
568         !
569      END SELECT
570      !
571      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab2d_1=prd, clinfo1=' eos2d: ' )
572      !
573      IF( ln_timing )   CALL timing_stop('eos2d')
574      !
575   END SUBROUTINE eos_insitu_2d_t
576
577
578   SUBROUTINE eos_insitu_pot_2d( pts, prhop )
579      !!
580      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pts    ! 1 : potential temperature  [Celsius]
581      !                                                     ! 2 : salinity               [psu]
582      REAL(dp), DIMENSION(:,:)  , INTENT(  out) ::   prhop  ! potential density (surface referenced)
583      !!
584      CALL eos_insitu_pot_2d_t( pts, is_tile(pts), prhop, is_tile(prhop) )
585   END SUBROUTINE eos_insitu_pot_2d
586
587
588   SUBROUTINE eos_insitu_pot_2d_t( pts, ktts, prhop, ktrhop )
589      !!----------------------------------------------------------------------
590      !!                  ***  ROUTINE eos_insitu_pot  ***
591      !!
592      !! ** Purpose :   Compute the in situ density (ratio rho/rho0) and the
593      !!      potential volumic mass (Kg/m3) from potential temperature and
594      !!      salinity fields using an equation of state selected in the
595      !!     namelist.
596      !!
597      !! ** Action  :
598      !!              - prhop, the potential volumic mass (Kg/m3)
599      !!
600      !!----------------------------------------------------------------------
601      INTEGER                              , INTENT(in   ) ::   ktts, ktrhop
602      REAL(wp), DIMENSION(A2D_T(ktts),JPTS), INTENT(in   ) ::   pts    ! 1 : potential temperature  [Celsius]
603      !                                                                ! 2 : salinity               [psu]
604      REAL(dp), DIMENSION(A2D_T(ktrhop)   ), INTENT(  out) ::   prhop  ! potential density (surface referenced)
605      !
606      INTEGER  ::   ji, jj, jk, jsmp             ! dummy loop indices
607      INTEGER  ::   jdof
608      REAL(wp) ::   zt , zh , zstemp, zs , ztm   ! local scalars
609      REAL(wp) ::   zn , zn0, zn1, zn2, zn3      !   -      -
610      REAL(wp), DIMENSION(:), ALLOCATABLE :: zn0_sto, zn_sto, zsign    ! local vectors
611      !!----------------------------------------------------------------------
612      !
613      IF( ln_timing )   CALL timing_start('eos-pot')
614      !
615      SELECT CASE ( neos )
616      !
617      CASE( np_teos10, np_eos80 )                !==  polynomial TEOS-10 / EOS-80 ==!
618         !
619         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
620            !
621            zt  = pts (ji,jj,jp_tem) * r1_T0                           ! temperature
622            zs  = SQRT( ABS( pts(ji,jj,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
623            ztm = tmask(ji,jj,1)                                         ! tmask
624            !
625            zn0 = (((((EOS060*zt   &
626               &   + EOS150*zs+EOS050)*zt   &
627               &   + (EOS240*zs+EOS140)*zs+EOS040)*zt   &
628               &   + ((EOS330*zs+EOS230)*zs+EOS130)*zs+EOS030)*zt   &
629               &   + (((EOS420*zs+EOS320)*zs+EOS220)*zs+EOS120)*zs+EOS020)*zt   &
630               &   + ((((EOS510*zs+EOS410)*zs+EOS310)*zs+EOS210)*zs+EOS110)*zs+EOS010)*zt   &
631               &   + (((((EOS600*zs+EOS500)*zs+EOS400)*zs+EOS300)*zs+EOS200)*zs+EOS100)*zs+EOS000
632               !
633            !
634            prhop(ji,jj) = zn0 * ztm                           ! potential density referenced at the surface
635            !
636         END_2D
637
638      CASE( np_seos )                !==  simplified EOS  ==!
639         !
640         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
641            zt  = pts  (ji,jj,jp_tem) - 10._wp
642            zs  = pts  (ji,jj,jp_sal) - 35._wp
643            ztm = tmask(ji,jj,1)
644            !                                                     ! potential density referenced at the surface
645            zn =  - rn_a0 * ( 1._wp + 0.5_wp*rn_lambda1*zt ) * zt   &
646               &  + rn_b0 * ( 1._wp - 0.5_wp*rn_lambda2*zs ) * zs   &
647               &  - rn_nu * zt * zs
648            prhop(ji,jj) = ( rho0 + zn ) * ztm
649            !
650         END_2D
651         !
652      END SELECT
653      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab2d_1=CASTWP(prhop), clinfo1=' pot: ', kdim=1 )
654      !
655      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab2d_1=CASTWP(prhop), clinfo1=' eos-pot: ' )
656      !
657      IF( ln_timing )   CALL timing_stop('eos-pot')
658      !
659   END SUBROUTINE eos_insitu_pot_2d_t
660
661
662   SUBROUTINE rab_3d( pts, pab, Kmm )
663      !!
664      INTEGER                     , INTENT(in   ) ::   Kmm   ! time level index
665      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pts   ! pot. temperature & salinity
666      REAL(wp), DIMENSION(:,:,:,:), INTENT(  out) ::   pab   ! thermal/haline expansion ratio
667      !!
668      CALL rab_3d_t( pts, is_tile(pts), pab, is_tile(pab), Kmm )
669   END SUBROUTINE rab_3d
670
671   SUBROUTINE rab_3d_t( pts, ktts, pab, ktab, Kmm )
672      !!----------------------------------------------------------------------
673      !!                 ***  ROUTINE rab_3d  ***
674      !!
675      !! ** Purpose :   Calculates thermal/haline expansion ratio at T-points
676      !!
677      !! ** Method  :   calculates alpha / beta at T-points
678      !!
679      !! ** Action  : - pab     : thermal/haline expansion ratio at T-points
680      !!----------------------------------------------------------------------
681      INTEGER                                , INTENT(in   ) ::   Kmm   ! time level index
682      INTEGER                                , INTENT(in   ) ::   ktts, ktab
683      REAL(wp), DIMENSION(A2D_T(ktts),JPK,JPTS), INTENT(in   ) ::   pts   ! pot. temperature & salinity
684      REAL(wp), DIMENSION(A2D_T(ktab),JPK,JPTS), INTENT(  out) ::   pab   ! thermal/haline expansion ratio
685      !
686      INTEGER  ::   ji, jj, jk                ! dummy loop indices
687      REAL(wp) ::   zt , zh , zs , ztm        ! local scalars
688      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
689      !!----------------------------------------------------------------------
690      !
691      IF( ln_timing )   CALL timing_start('rab_3d')
692      !
693      SELECT CASE ( neos )
694      !
695      CASE( np_teos10, np_eos80 )                !==  polynomial TEOS-10 / EOS-80 ==!
696         !
697         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
698            !
699            zh  = gdept(ji,jj,jk,Kmm) * r1_Z0                                ! depth
700            zt  = pts (ji,jj,jk,jp_tem) * r1_T0                           ! temperature
701            zs  = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
702            ztm = tmask(ji,jj,jk)                                         ! tmask
703            !
704            ! alpha
705            zn3 = ALP003
706            !
707            zn2 = ALP012*zt + ALP102*zs+ALP002
708            !
709            zn1 = ((ALP031*zt   &
710               &   + ALP121*zs+ALP021)*zt   &
711               &   + (ALP211*zs+ALP111)*zs+ALP011)*zt   &
712               &   + ((ALP301*zs+ALP201)*zs+ALP101)*zs+ALP001
713               !
714            zn0 = ((((ALP050*zt   &
715               &   + ALP140*zs+ALP040)*zt   &
716               &   + (ALP230*zs+ALP130)*zs+ALP030)*zt   &
717               &   + ((ALP320*zs+ALP220)*zs+ALP120)*zs+ALP020)*zt   &
718               &   + (((ALP410*zs+ALP310)*zs+ALP210)*zs+ALP110)*zs+ALP010)*zt   &
719               &   + ((((ALP500*zs+ALP400)*zs+ALP300)*zs+ALP200)*zs+ALP100)*zs+ALP000
720               !
721            zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
722            !
723            pab(ji,jj,jk,jp_tem) = zn * r1_rho0 * ztm
724            !
725            ! beta
726            zn3 = BET003
727            !
728            zn2 = BET012*zt + BET102*zs+BET002
729            !
730            zn1 = ((BET031*zt   &
731               &   + BET121*zs+BET021)*zt   &
732               &   + (BET211*zs+BET111)*zs+BET011)*zt   &
733               &   + ((BET301*zs+BET201)*zs+BET101)*zs+BET001
734               !
735            zn0 = ((((BET050*zt   &
736               &   + BET140*zs+BET040)*zt   &
737               &   + (BET230*zs+BET130)*zs+BET030)*zt   &
738               &   + ((BET320*zs+BET220)*zs+BET120)*zs+BET020)*zt   &
739               &   + (((BET410*zs+BET310)*zs+BET210)*zs+BET110)*zs+BET010)*zt   &
740               &   + ((((BET500*zs+BET400)*zs+BET300)*zs+BET200)*zs+BET100)*zs+BET000
741               !
742            zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
743            !
744            pab(ji,jj,jk,jp_sal) = zn / zs * r1_rho0 * ztm
745            !
746         END_3D
747         !
748      CASE( np_seos )                  !==  simplified EOS  ==!
749         !
750         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
751            zt  = pts (ji,jj,jk,jp_tem) - 10._wp   ! pot. temperature anomaly (t-T0)
752            zs  = pts (ji,jj,jk,jp_sal) - 35._wp   ! abs. salinity anomaly (s-S0)
753            zh  = gdept(ji,jj,jk,Kmm)                ! depth in meters at t-point
754            ztm = tmask(ji,jj,jk)                  ! land/sea bottom mask = surf. mask
755            !
756            zn  = rn_a0 * ( 1._wp + rn_lambda1*zt + rn_mu1*zh ) + rn_nu*zs
757            pab(ji,jj,jk,jp_tem) = zn * r1_rho0 * ztm   ! alpha
758            !
759            zn  = rn_b0 * ( 1._wp - rn_lambda2*zs - rn_mu2*zh ) - rn_nu*zt
760            pab(ji,jj,jk,jp_sal) = zn * r1_rho0 * ztm   ! beta
761            !
762         END_3D
763         !
764      CASE DEFAULT
765         WRITE(ctmp1,*) '          bad flag value for neos = ', neos
766         CALL ctl_stop( 'rab_3d:', ctmp1 )
767         !
768      END SELECT
769      !
770      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pab(:,:,:,jp_tem), clinfo1=' rab_3d_t: ', &
771         &                                  tab3d_2=pab(:,:,:,jp_sal), clinfo2=' rab_3d_s : ', kdim=jpk )
772      !
773      IF( ln_timing )   CALL timing_stop('rab_3d')
774      !
775   END SUBROUTINE rab_3d_t
776
777   SUBROUTINE rab_2d( pts, pdep, pab, Kmm )
778      !!
779      INTEGER                   , INTENT(in   ) ::   Kmm   ! time level index
780      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pts    ! pot. temperature & salinity
781      REAL(wp), DIMENSION(:,:)  , INTENT(in   ) ::   pdep   ! depth                  [m]
782      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   pab    ! thermal/haline expansion ratio
783      !!
784      CALL rab_2d_t(pts, is_tile(pts), pdep, is_tile(pdep), pab, is_tile(pab), Kmm)
785   END SUBROUTINE rab_2d
786
787
788   SUBROUTINE rab_2d_t( pts, ktts, pdep, ktdep, pab, ktab, Kmm )
789      !!----------------------------------------------------------------------
790      !!                 ***  ROUTINE rab_2d  ***
791      !!
792      !! ** Purpose :   Calculates thermal/haline expansion ratio for a 2d field (unmasked)
793      !!
794      !! ** Action  : - pab     : thermal/haline expansion ratio at T-points
795      !!----------------------------------------------------------------------
796      INTEGER                            , INTENT(in   ) ::   Kmm   ! time level index
797      INTEGER                            , INTENT(in   ) ::   ktts, ktdep, ktab
798      REAL(wp), DIMENSION(A2D_T(ktts),JPTS), INTENT(in   ) ::   pts    ! pot. temperature & salinity
799      REAL(wp), DIMENSION(A2D_T(ktdep)    ), INTENT(in   ) ::   pdep   ! depth                  [m]
800      REAL(wp), DIMENSION(A2D_T(ktab),JPTS), INTENT(  out) ::   pab    ! thermal/haline expansion ratio
801      !
802      INTEGER  ::   ji, jj, jk                ! dummy loop indices
803      REAL(wp) ::   zt , zh , zs              ! local scalars
804      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
805      !!----------------------------------------------------------------------
806      !
807      IF( ln_timing )   CALL timing_start('rab_2d')
808      !
809      pab(:,:,:) = 0._wp
810      !
811      SELECT CASE ( neos )
812      !
813      CASE( np_teos10, np_eos80 )                !==  polynomial TEOS-10 / EOS-80 ==!
814         !
815         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
816            !
817            zh  = pdep(ji,jj) * r1_Z0                                  ! depth
818            zt  = pts (ji,jj,jp_tem) * r1_T0                           ! temperature
819            zs  = SQRT( ABS( pts(ji,jj,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
820            !
821            ! alpha
822            zn3 = ALP003
823            !
824            zn2 = ALP012*zt + ALP102*zs+ALP002
825            !
826            zn1 = ((ALP031*zt   &
827               &   + ALP121*zs+ALP021)*zt   &
828               &   + (ALP211*zs+ALP111)*zs+ALP011)*zt   &
829               &   + ((ALP301*zs+ALP201)*zs+ALP101)*zs+ALP001
830               !
831            zn0 = ((((ALP050*zt   &
832               &   + ALP140*zs+ALP040)*zt   &
833               &   + (ALP230*zs+ALP130)*zs+ALP030)*zt   &
834               &   + ((ALP320*zs+ALP220)*zs+ALP120)*zs+ALP020)*zt   &
835               &   + (((ALP410*zs+ALP310)*zs+ALP210)*zs+ALP110)*zs+ALP010)*zt   &
836               &   + ((((ALP500*zs+ALP400)*zs+ALP300)*zs+ALP200)*zs+ALP100)*zs+ALP000
837               !
838            zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
839            !
840            pab(ji,jj,jp_tem) = zn * r1_rho0
841            !
842            ! beta
843            zn3 = BET003
844            !
845            zn2 = BET012*zt + BET102*zs+BET002
846            !
847            zn1 = ((BET031*zt   &
848               &   + BET121*zs+BET021)*zt   &
849               &   + (BET211*zs+BET111)*zs+BET011)*zt   &
850               &   + ((BET301*zs+BET201)*zs+BET101)*zs+BET001
851               !
852            zn0 = ((((BET050*zt   &
853               &   + BET140*zs+BET040)*zt   &
854               &   + (BET230*zs+BET130)*zs+BET030)*zt   &
855               &   + ((BET320*zs+BET220)*zs+BET120)*zs+BET020)*zt   &
856               &   + (((BET410*zs+BET310)*zs+BET210)*zs+BET110)*zs+BET010)*zt   &
857               &   + ((((BET500*zs+BET400)*zs+BET300)*zs+BET200)*zs+BET100)*zs+BET000
858               !
859            zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
860            !
861            pab(ji,jj,jp_sal) = zn / zs * r1_rho0
862            !
863            !
864         END_2D
865         !
866      CASE( np_seos )                  !==  simplified EOS  ==!
867         !
868         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
869            !
870            zt    = pts  (ji,jj,jp_tem) - 10._wp   ! pot. temperature anomaly (t-T0)
871            zs    = pts  (ji,jj,jp_sal) - 35._wp   ! abs. salinity anomaly (s-S0)
872            zh    = pdep (ji,jj)                   ! depth at the partial step level
873            !
874            zn  = rn_a0 * ( 1._wp + rn_lambda1*zt + rn_mu1*zh ) + rn_nu*zs
875            pab(ji,jj,jp_tem) = zn * r1_rho0   ! alpha
876            !
877            zn  = rn_b0 * ( 1._wp - rn_lambda2*zs - rn_mu2*zh ) - rn_nu*zt
878            pab(ji,jj,jp_sal) = zn * r1_rho0   ! beta
879            !
880         END_2D
881         !
882      CASE DEFAULT
883         WRITE(ctmp1,*) '          bad flag value for neos = ', neos
884         CALL ctl_stop( 'rab_2d:', ctmp1 )
885         !
886      END SELECT
887      !
888      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab2d_1=pab(:,:,jp_tem), clinfo1=' rab_2d_t: ', &
889         &                                  tab2d_2=pab(:,:,jp_sal), clinfo2=' rab_2d_s : ' )
890      !
891      IF( ln_timing )   CALL timing_stop('rab_2d')
892      !
893   END SUBROUTINE rab_2d_t
894
895
896   SUBROUTINE rab_0d( pts, pdep, pab, Kmm )
897      !!----------------------------------------------------------------------
898      !!                 ***  ROUTINE rab_0d  ***
899      !!
900      !! ** Purpose :   Calculates thermal/haline expansion ratio for a 2d field (unmasked)
901      !!
902      !! ** Action  : - pab     : thermal/haline expansion ratio at T-points
903      !!----------------------------------------------------------------------
904      INTEGER                              , INTENT(in   ) ::   Kmm   ! time level index
905      REAL(wp), DIMENSION(jpts)    , INTENT(in   ) ::   pts    ! pot. temperature & salinity
906      REAL(wp),                      INTENT(in   ) ::   pdep   ! depth                  [m]
907      REAL(wp), DIMENSION(jpts)    , INTENT(  out) ::   pab    ! thermal/haline expansion ratio
908      !
909      REAL(wp) ::   zt , zh , zs              ! local scalars
910      REAL(wp) ::   zn , zn0, zn1, zn2, zn3   !   -      -
911      !!----------------------------------------------------------------------
912      !
913      IF( ln_timing )   CALL timing_start('rab_0d')
914      !
915      pab(:) = 0._wp
916      !
917      SELECT CASE ( neos )
918      !
919      CASE( np_teos10, np_eos80 )      !==  polynomial TEOS-10 / EOS-80 ==!
920         !
921         !
922         zh  = pdep * r1_Z0                                  ! depth
923         zt  = pts (jp_tem) * r1_T0                           ! temperature
924         zs  = SQRT( ABS( pts(jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
925         !
926         ! alpha
927         zn3 = ALP003
928         !
929         zn2 = ALP012*zt + ALP102*zs+ALP002
930         !
931         zn1 = ((ALP031*zt   &
932            &   + ALP121*zs+ALP021)*zt   &
933            &   + (ALP211*zs+ALP111)*zs+ALP011)*zt   &
934            &   + ((ALP301*zs+ALP201)*zs+ALP101)*zs+ALP001
935            !
936         zn0 = ((((ALP050*zt   &
937            &   + ALP140*zs+ALP040)*zt   &
938            &   + (ALP230*zs+ALP130)*zs+ALP030)*zt   &
939            &   + ((ALP320*zs+ALP220)*zs+ALP120)*zs+ALP020)*zt   &
940            &   + (((ALP410*zs+ALP310)*zs+ALP210)*zs+ALP110)*zs+ALP010)*zt   &
941            &   + ((((ALP500*zs+ALP400)*zs+ALP300)*zs+ALP200)*zs+ALP100)*zs+ALP000
942            !
943         zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
944         !
945         pab(jp_tem) = zn * r1_rho0
946         !
947         ! beta
948         zn3 = BET003
949         !
950         zn2 = BET012*zt + BET102*zs+BET002
951         !
952         zn1 = ((BET031*zt   &
953            &   + BET121*zs+BET021)*zt   &
954            &   + (BET211*zs+BET111)*zs+BET011)*zt   &
955            &   + ((BET301*zs+BET201)*zs+BET101)*zs+BET001
956            !
957         zn0 = ((((BET050*zt   &
958            &   + BET140*zs+BET040)*zt   &
959            &   + (BET230*zs+BET130)*zs+BET030)*zt   &
960            &   + ((BET320*zs+BET220)*zs+BET120)*zs+BET020)*zt   &
961            &   + (((BET410*zs+BET310)*zs+BET210)*zs+BET110)*zs+BET010)*zt   &
962            &   + ((((BET500*zs+BET400)*zs+BET300)*zs+BET200)*zs+BET100)*zs+BET000
963            !
964         zn  = ( ( zn3 * zh + zn2 ) * zh + zn1 ) * zh + zn0
965         !
966         pab(jp_sal) = zn / zs * r1_rho0
967         !
968         !
969         !
970      CASE( np_seos )                  !==  simplified EOS  ==!
971         !
972         zt    = pts(jp_tem) - 10._wp   ! pot. temperature anomaly (t-T0)
973         zs    = pts(jp_sal) - 35._wp   ! abs. salinity anomaly (s-S0)
974         zh    = pdep                   ! depth at the partial step level
975         !
976         zn  = rn_a0 * ( 1._wp + rn_lambda1*zt + rn_mu1*zh ) + rn_nu*zs
977         pab(jp_tem) = zn * r1_rho0   ! alpha
978         !
979         zn  = rn_b0 * ( 1._wp - rn_lambda2*zs - rn_mu2*zh ) - rn_nu*zt
980         pab(jp_sal) = zn * r1_rho0   ! beta
981         !
982      CASE DEFAULT
983         WRITE(ctmp1,*) '          bad flag value for neos = ', neos
984         CALL ctl_stop( 'rab_0d:', ctmp1 )
985         !
986      END SELECT
987      !
988      IF( ln_timing )   CALL timing_stop('rab_0d')
989      !
990   END SUBROUTINE rab_0d
991
992
993   SUBROUTINE bn2( pts, pab, pn2, Kmm )
994      !!
995      INTEGER                              , INTENT(in   ) ::  Kmm   ! time level index
996      REAL(dp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::  pts   ! pot. temperature and salinity   [Celsius,psu]
997      REAL(wp), DIMENSION(:,:,:,:)         , INTENT(in   ) ::  pab   ! thermal/haline expansion coef.  [Celsius-1,psu-1]
998      REAL(wp), DIMENSION(:,:,:)           , INTENT(  out) ::  pn2   ! Brunt-Vaisala frequency squared [1/s^2]
999      !!
1000      CALL bn2_t( pts, pab, is_tile(pab), pn2, is_tile(pn2), Kmm )
1001   END SUBROUTINE bn2
1002
1003
1004   SUBROUTINE bn2_t( pts, pab, ktab, pn2, ktn2, Kmm )
1005      !!----------------------------------------------------------------------
1006      !!                  ***  ROUTINE bn2  ***
1007      !!
1008      !! ** Purpose :   Compute the local Brunt-Vaisala frequency at the
1009      !!                time-step of the input arguments
1010      !!
1011      !! ** Method  :   pn2 = grav * (alpha dk[T] + beta dk[S] ) / e3w
1012      !!      where alpha and beta are given in pab, and computed on T-points.
1013      !!      N.B. N^2 is set one for all to zero at jk=1 in istate module.
1014      !!
1015      !! ** Action  :   pn2 : square of the brunt-vaisala frequency at w-point
1016      !!
1017      !!----------------------------------------------------------------------
1018      INTEGER                                , INTENT(in   ) ::  Kmm   ! time level index
1019      INTEGER                                , INTENT(in   ) ::  ktab, ktn2
1020      REAL(dp), DIMENSION(jpi,jpj,  jpk,jpts), INTENT(in   ) ::  pts   ! pot. temperature and salinity   [Celsius,psu]
1021      REAL(wp), DIMENSION(A2D_T(ktab),JPK,JPTS), INTENT(in   ) ::  pab   ! thermal/haline expansion coef.  [Celsius-1,psu-1]
1022      REAL(wp), DIMENSION(A2D_T(ktn2),JPK     ), INTENT(  out) ::  pn2   ! Brunt-Vaisala frequency squared [1/s^2]
1023      !
1024      INTEGER  ::   ji, jj, jk      ! dummy loop indices
1025      REAL(wp) ::   zaw, zbw, zrw   ! local scalars
1026      !!----------------------------------------------------------------------
1027      !
1028      IF( ln_timing )   CALL timing_start('bn2')
1029      !
1030      DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 2, jpkm1 )      ! interior points only (2=< jk =< jpkm1 ); surface and bottom value set to zero one for all in istate.F90
1031         zrw =   ( gdepw(ji,jj,jk  ,Kmm) - gdept(ji,jj,jk,Kmm) )   &
1032            &  / ( gdept(ji,jj,jk-1,Kmm) - gdept(ji,jj,jk,Kmm) )
1033            !
1034         zaw = pab(ji,jj,jk,jp_tem) * (1. - zrw) + pab(ji,jj,jk-1,jp_tem) * zrw
1035         zbw = pab(ji,jj,jk,jp_sal) * (1. - zrw) + pab(ji,jj,jk-1,jp_sal) * zrw
1036         !
1037         pn2(ji,jj,jk) = grav * (  zaw * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) )     &
1038            &                    - zbw * ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) )  )  &
1039            &            / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)
1040      END_3D
1041      !
1042      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pn2, clinfo1=' bn2  : ', kdim=jpk )
1043      !
1044      IF( ln_timing )   CALL timing_stop('bn2')
1045      !
1046   END SUBROUTINE bn2_t
1047
1048
1049   FUNCTION eos_pt_from_ct( ctmp, psal ) RESULT( ptmp )
1050      !!----------------------------------------------------------------------
1051      !!                 ***  ROUTINE eos_pt_from_ct  ***
1052      !!
1053      !! ** Purpose :   Compute pot.temp. from cons. temp. [Celsius]
1054      !!
1055      !! ** Method  :   rational approximation (5/3th order) of TEOS-10 algorithm
1056      !!       checkvalue: pt=20.02391895 Celsius for sa=35.7g/kg, ct=20degC
1057      !!
1058      !! Reference  :   TEOS-10, UNESCO
1059      !!                Rational approximation to TEOS10 algorithm (rms error on WOA13 values: 4.0e-5 degC)
1060      !!----------------------------------------------------------------------
1061      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   ctmp   ! Cons. Temp   [Celsius]
1062      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   psal   ! salinity     [psu]
1063      ! Leave result array automatic rather than making explicitly allocated
1064      REAL(wp), DIMENSION(jpi,jpj) ::   ptmp   ! potential temperature [Celsius]
1065      !
1066      INTEGER  ::   ji, jj               ! dummy loop indices
1067      REAL(wp) ::   zt , zs , ztm        ! local scalars
1068      REAL(wp) ::   zn , zd              ! local scalars
1069      REAL(wp) ::   zdeltaS , z1_S0 , z1_T0
1070      !!----------------------------------------------------------------------
1071      !
1072      IF( ln_timing )   CALL timing_start('eos_pt_from_ct')
1073      !
1074      zdeltaS = 5._wp
1075      z1_S0   = 0.875_wp/35.16504_wp
1076      z1_T0   = 1._wp/40._wp
1077      !
1078      DO_2D( 1, 1, 1, 1 )
1079         !
1080         zt  = ctmp   (ji,jj) * z1_T0
1081         zs  = SQRT( ABS( psal(ji,jj) + zdeltaS ) * r1_S0 )
1082         ztm = tmask(ji,jj,1)
1083         !
1084         zn = ((((-2.1385727895e-01_wp*zt   &
1085            &   - 2.7674419971e-01_wp*zs+1.0728094330_wp)*zt   &
1086            &   + (2.6366564313_wp*zs+3.3546960647_wp)*zs-7.8012209473_wp)*zt   &
1087            &   + ((1.8835586562_wp*zs+7.3949191679_wp)*zs-3.3937395875_wp)*zs-5.6414948432_wp)*zt   &
1088            &   + (((3.5737370589_wp*zs-1.5512427389e+01_wp)*zs+2.4625741105e+01_wp)*zs   &
1089            &      +1.9912291000e+01_wp)*zs-3.2191146312e+01_wp)*zt   &
1090            &   + ((((5.7153204649e-01_wp*zs-3.0943149543_wp)*zs+9.3052495181_wp)*zs   &
1091            &      -9.4528934807_wp)*zs+3.1066408996_wp)*zs-4.3504021262e-01_wp
1092            !
1093         zd = (2.0035003456_wp*zt   &
1094            &   -3.4570358592e-01_wp*zs+5.6471810638_wp)*zt   &
1095            &   + (1.5393993508_wp*zs-6.9394762624_wp)*zs+1.2750522650e+01_wp
1096            !
1097         ptmp(ji,jj) = ( zt / z1_T0 + zn / zd ) * ztm
1098            !
1099      END_2D
1100      !
1101      IF( ln_timing )   CALL timing_stop('eos_pt_from_ct')
1102      !
1103   END FUNCTION eos_pt_from_ct
1104
1105
1106   SUBROUTINE eos_fzp_2d( psal, ptf, pdep )
1107      !!
1108      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   )           ::   psal   ! salinity   [psu]
1109      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ), OPTIONAL ::   pdep   ! depth      [m]
1110      REAL(wp), DIMENSION(:,:)    , INTENT(out  )           ::   ptf    ! freezing temperature [Celsius]
1111      !!
1112      CALL eos_fzp_2d_t( psal, ptf, is_tile(ptf), pdep )
1113   END SUBROUTINE eos_fzp_2d
1114
1115
1116   SUBROUTINE  eos_fzp_2d_t( psal, ptf, kttf, pdep )
1117      !!----------------------------------------------------------------------
1118      !!                 ***  ROUTINE eos_fzp  ***
1119      !!
1120      !! ** Purpose :   Compute the freezing point temperature [Celsius]
1121      !!
1122      !! ** Method  :   UNESCO freezing point (ptf) in Celsius is given by
1123      !!       ptf(t,z) = (-.0575+1.710523e-3*sqrt(abs(s))-2.154996e-4*s)*s - 7.53e-4*z
1124      !!       checkvalue: tf=-2.588567 Celsius for s=40psu, z=500m
1125      !!
1126      !! Reference  :   UNESCO tech. papers in the marine science no. 28. 1978
1127      !!----------------------------------------------------------------------
1128      INTEGER                       , INTENT(in   )           ::   kttf
1129      REAL(wp), DIMENSION(jpi,jpj)  , INTENT(in   )           ::   psal   ! salinity   [psu]
1130      REAL(wp), DIMENSION(jpi,jpj)  , INTENT(in   ), OPTIONAL ::   pdep   ! depth      [m]
1131      REAL(wp), DIMENSION(A2D_T(kttf)), INTENT(out  )           ::   ptf    ! freezing temperature [Celsius]
1132      !
1133      INTEGER  ::   ji, jj          ! dummy loop indices
1134      REAL(wp) ::   zt, zs, z1_S0   ! local scalars
1135      !!----------------------------------------------------------------------
1136      !
1137      SELECT CASE ( neos )
1138      !
1139      CASE ( np_teos10, np_seos )      !==  CT,SA (TEOS-10 and S-EOS formulations) ==!
1140         !
1141         z1_S0 = 1._wp / 35.16504_wp
1142         DO_2D( 1, 1, 1, 1 )
1143            zs= SQRT( ABS( psal(ji,jj) ) * z1_S0 )           ! square root salinity
1144            ptf(ji,jj) = ((((1.46873e-03_wp*zs-9.64972e-03_wp)*zs+2.28348e-02_wp)*zs &
1145               &          - 3.12775e-02_wp)*zs+2.07679e-02_wp)*zs-5.87701e-02_wp
1146         END_2D
1147         ptf(:,:) = ptf(:,:) * psal(:,:)
1148         !
1149         IF( PRESENT( pdep ) )   ptf(:,:) = ptf(:,:) - 7.53e-4 * pdep(:,:)
1150         !
1151      CASE ( np_eos80 )                !==  PT,SP (UNESCO formulation)  ==!
1152         !
1153         ptf(:,:) = ( - 0.0575_wp + 1.710523e-3_wp * SQRT( psal(:,:) )   &
1154            &                     - 2.154996e-4_wp *       psal(:,:)   ) * psal(:,:)
1155            !
1156         IF( PRESENT( pdep ) )   ptf(:,:) = ptf(:,:) - 7.53e-4 * pdep(:,:)
1157         !
1158      CASE DEFAULT
1159         WRITE(ctmp1,*) '          bad flag value for neos = ', neos
1160         CALL ctl_stop( 'eos_fzp_2d:', ctmp1 )
1161         !
1162      END SELECT
1163      !
1164  END SUBROUTINE eos_fzp_2d_t
1165
1166
1167  SUBROUTINE eos_fzp_0d( psal, ptf, pdep )
1168      !!----------------------------------------------------------------------
1169      !!                 ***  ROUTINE eos_fzp  ***
1170      !!
1171      !! ** Purpose :   Compute the freezing point temperature [Celsius]
1172      !!
1173      !! ** Method  :   UNESCO freezing point (ptf) in Celsius is given by
1174      !!       ptf(t,z) = (-.0575+1.710523e-3*sqrt(abs(s))-2.154996e-4*s)*s - 7.53e-4*z
1175      !!       checkvalue: tf=-2.588567 Celsius for s=40psu, z=500m
1176      !!
1177      !! Reference  :   UNESCO tech. papers in the marine science no. 28. 1978
1178      !!----------------------------------------------------------------------
1179      REAL(wp), INTENT(in )           ::   psal         ! salinity   [psu]
1180      REAL(wp), INTENT(in ), OPTIONAL ::   pdep         ! depth      [m]
1181      REAL(wp), INTENT(out)           ::   ptf          ! freezing temperature [Celsius]
1182      !
1183      REAL(wp) :: zs   ! local scalars
1184      !!----------------------------------------------------------------------
1185      !
1186      SELECT CASE ( neos )
1187      !
1188      CASE ( np_teos10, np_seos )      !==  CT,SA (TEOS-10 and S-EOS formulations) ==!
1189         !
1190         zs  = SQRT( ABS( psal ) / 35.16504_wp )           ! square root salinity
1191         ptf = ((((1.46873e-03_wp*zs-9.64972e-03_wp)*zs+2.28348e-02_wp)*zs &
1192                  &          - 3.12775e-02_wp)*zs+2.07679e-02_wp)*zs-5.87701e-02_wp
1193         ptf = ptf * psal
1194         !
1195         IF( PRESENT( pdep ) )   ptf = ptf - 7.53e-4 * pdep
1196         !
1197      CASE ( np_eos80 )                !==  PT,SP (UNESCO formulation)  ==!
1198         !
1199         ptf = ( - 0.0575_wp + 1.710523e-3_wp * SQRT( psal )   &
1200            &                - 2.154996e-4_wp *       psal   ) * psal
1201            !
1202         IF( PRESENT( pdep ) )   ptf = ptf - 7.53e-4 * pdep
1203         !
1204      CASE DEFAULT
1205         WRITE(ctmp1,*) '          bad flag value for neos = ', neos
1206         CALL ctl_stop( 'eos_fzp_0d:', ctmp1 )
1207         !
1208      END SELECT
1209      !
1210   END SUBROUTINE eos_fzp_0d
1211
1212
1213   SUBROUTINE eos_pen( pts, pab_pe, ppen, Kmm )
1214      !!----------------------------------------------------------------------
1215      !!                 ***  ROUTINE eos_pen  ***
1216      !!
1217      !! ** Purpose :   Calculates nonlinear anomalies of alpha_PE, beta_PE and PE at T-points
1218      !!
1219      !! ** Method  :   PE is defined analytically as the vertical
1220      !!                   primitive of EOS times -g integrated between 0 and z>0.
1221      !!                pen is the nonlinear bsq-PE anomaly: pen = ( PE - rho0 gz ) / rho0 gz - rd
1222      !!                                                      = 1/z * /int_0^z rd dz - rd
1223      !!                                where rd is the density anomaly (see eos_rhd function)
1224      !!                ab_pe are partial derivatives of PE anomaly with respect to T and S:
1225      !!                    ab_pe(1) = - 1/(rho0 gz) * dPE/dT + drd/dT = - d(pen)/dT
1226      !!                    ab_pe(2) =   1/(rho0 gz) * dPE/dS + drd/dS =   d(pen)/dS
1227      !!
1228      !! ** Action  : - pen         : PE anomaly given at T-points
1229      !!            : - pab_pe  : given at T-points
1230      !!                    pab_pe(:,:,:,jp_tem) is alpha_pe
1231      !!                    pab_pe(:,:,:,jp_sal) is beta_pe
1232      !!----------------------------------------------------------------------
1233      INTEGER                              , INTENT(in   ) ::   Kmm   ! time level index
1234      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts     ! pot. temperature & salinity
1235      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   pab_pe  ! alpha_pe and beta_pe
1236      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   ppen     ! potential energy anomaly
1237      !
1238      INTEGER  ::   ji, jj, jk                ! dummy loop indices
1239      REAL(wp) ::   zt , zh , zs , ztm        ! local scalars
1240      REAL(wp) ::   zn , zn0, zn1, zn2        !   -      -
1241      !!----------------------------------------------------------------------
1242      !
1243      IF( ln_timing )   CALL timing_start('eos_pen')
1244      !
1245      SELECT CASE ( neos )
1246      !
1247      CASE( np_teos10, np_eos80 )                !==  polynomial TEOS-10 / EOS-80 ==!
1248         !
1249         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
1250            !
1251            zh  = gdept(ji,jj,jk,Kmm) * r1_Z0                                ! depth
1252            zt  = pts (ji,jj,jk,jp_tem) * r1_T0                           ! temperature
1253            zs  = SQRT( ABS( pts(ji,jj,jk,jp_sal) + rdeltaS ) * r1_S0 )   ! square root salinity
1254            ztm = tmask(ji,jj,jk)                                         ! tmask
1255            !
1256            ! potential energy non-linear anomaly
1257            zn2 = (PEN012)*zt   &
1258               &   + PEN102*zs+PEN002
1259               !
1260            zn1 = ((PEN021)*zt   &
1261               &   + PEN111*zs+PEN011)*zt   &
1262               &   + (PEN201*zs+PEN101)*zs+PEN001
1263               !
1264            zn0 = ((((PEN040)*zt   &
1265               &   + PEN130*zs+PEN030)*zt   &
1266               &   + (PEN220*zs+PEN120)*zs+PEN020)*zt   &
1267               &   + ((PEN310*zs+PEN210)*zs+PEN110)*zs+PEN010)*zt   &
1268               &   + (((PEN400*zs+PEN300)*zs+PEN200)*zs+PEN100)*zs+PEN000
1269               !
1270            zn  = ( zn2 * zh + zn1 ) * zh + zn0
1271            !
1272            ppen(ji,jj,jk)  = zn * zh * r1_rho0 * ztm
1273            !
1274            ! alphaPE non-linear anomaly
1275            zn2 = APE002
1276            !
1277            zn1 = (APE011)*zt   &
1278               &   + APE101*zs+APE001
1279               !
1280            zn0 = (((APE030)*zt   &
1281               &   + APE120*zs+APE020)*zt   &
1282               &   + (APE210*zs+APE110)*zs+APE010)*zt   &
1283               &   + ((APE300*zs+APE200)*zs+APE100)*zs+APE000
1284               !
1285            zn  = ( zn2 * zh + zn1 ) * zh + zn0
1286            !
1287            pab_pe(ji,jj,jk,jp_tem) = zn * zh * r1_rho0 * ztm
1288            !
1289            ! betaPE non-linear anomaly
1290            zn2 = BPE002
1291            !
1292            zn1 = (BPE011)*zt   &
1293               &   + BPE101*zs+BPE001
1294               !
1295            zn0 = (((BPE030)*zt   &
1296               &   + BPE120*zs+BPE020)*zt   &
1297               &   + (BPE210*zs+BPE110)*zs+BPE010)*zt   &
1298               &   + ((BPE300*zs+BPE200)*zs+BPE100)*zs+BPE000
1299               !
1300            zn  = ( zn2 * zh + zn1 ) * zh + zn0
1301            !
1302            pab_pe(ji,jj,jk,jp_sal) = zn / zs * zh * r1_rho0 * ztm
1303            !
1304         END_3D
1305         !
1306      CASE( np_seos )                !==  Vallis (2006) simplified EOS  ==!
1307         !
1308         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
1309            zt  = pts(ji,jj,jk,jp_tem) - 10._wp  ! temperature anomaly (t-T0)
1310            zs = pts (ji,jj,jk,jp_sal) - 35._wp  ! abs. salinity anomaly (s-S0)
1311            zh  = gdept(ji,jj,jk,Kmm)              ! depth in meters  at t-point
1312            ztm = tmask(ji,jj,jk)                ! tmask
1313            zn  = 0.5_wp * zh * r1_rho0 * ztm
1314            !                                    ! Potential Energy
1315            ppen(ji,jj,jk) = ( rn_a0 * rn_mu1 * zt + rn_b0 * rn_mu2 * zs ) * zn
1316            !                                    ! alphaPE
1317            pab_pe(ji,jj,jk,jp_tem) = - rn_a0 * rn_mu1 * zn
1318            pab_pe(ji,jj,jk,jp_sal) =   rn_b0 * rn_mu2 * zn
1319            !
1320         END_3D
1321         !
1322      CASE DEFAULT
1323         WRITE(ctmp1,*) '          bad flag value for neos = ', neos
1324         CALL ctl_stop( 'eos_pen:', ctmp1 )
1325         !
1326      END SELECT
1327      !
1328      IF( ln_timing )   CALL timing_stop('eos_pen')
1329      !
1330   END SUBROUTINE eos_pen
1331
1332
1333   SUBROUTINE eos_init
1334      !!----------------------------------------------------------------------
1335      !!                 ***  ROUTINE eos_init  ***
1336      !!
1337      !! ** Purpose :   initializations for the equation of state
1338      !!
1339      !! ** Method  :   Read the namelist nameos and control the parameters
1340      !!----------------------------------------------------------------------
1341      INTEGER  ::   ios   ! local integer
1342      INTEGER  ::   ioptio   ! local integer
1343      !!
1344      NAMELIST/nameos/ ln_TEOS10, ln_EOS80, ln_SEOS, rn_a0, rn_b0, rn_lambda1, rn_mu1,   &
1345         &                                             rn_lambda2, rn_mu2, rn_nu
1346      !!----------------------------------------------------------------------
1347      !
1348      READ  ( numnam_ref, nameos, IOSTAT = ios, ERR = 901 )
1349901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nameos in reference namelist' )
1350      !
1351      READ  ( numnam_cfg, nameos, IOSTAT = ios, ERR = 902 )
1352902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nameos in configuration namelist' )
1353      IF(lwm) WRITE( numond, nameos )
1354      !
1355      rho0        = 1026._wp                 !: volumic mass of reference     [kg/m3]
1356      rcp         = 3991.86795711963_wp      !: heat capacity     [J/K]
1357      !
1358      IF(lwp) THEN                ! Control print
1359         WRITE(numout,*)
1360         WRITE(numout,*) 'eos_init : equation of state'
1361         WRITE(numout,*) '~~~~~~~~'
1362         WRITE(numout,*) '   Namelist nameos : Chosen the Equation Of Seawater (EOS)'
1363         WRITE(numout,*) '      TEOS-10 : rho=F(Conservative Temperature, Absolute  Salinity, depth)   ln_TEOS10 = ', ln_TEOS10
1364         WRITE(numout,*) '      EOS-80  : rho=F(Potential    Temperature, Practical Salinity, depth)   ln_EOS80  = ', ln_EOS80
1365         WRITE(numout,*) '      S-EOS   : rho=F(Conservative Temperature, Absolute  Salinity, depth)   ln_SEOS   = ', ln_SEOS
1366      ENDIF
1367
1368      ! Check options for equation of state & set neos based on logical flags
1369      ioptio = 0
1370      IF( ln_TEOS10 ) THEN   ;   ioptio = ioptio+1   ;   neos = np_teos10   ;   ENDIF
1371      IF( ln_EOS80  ) THEN   ;   ioptio = ioptio+1   ;   neos = np_eos80    ;   ENDIF
1372      IF( ln_SEOS   ) THEN   ;   ioptio = ioptio+1   ;   neos = np_seos     ;   ENDIF
1373      IF( ioptio /= 1 )   CALL ctl_stop("Exactly one equation of state option must be selected")
1374      !
1375      SELECT CASE( neos )         ! check option
1376      !
1377      CASE( np_teos10 )                       !==  polynomial TEOS-10  ==!
1378         IF(lwp) WRITE(numout,*)
1379         IF(lwp) WRITE(numout,*) '   ==>>>   use of TEOS-10 equation of state (cons. temp. and abs. salinity)'
1380         !
1381         l_useCT = .TRUE.                          ! model temperature is Conservative temperature
1382         !
1383         rdeltaS = 32._wp
1384         r1_S0  = 0.875_wp/35.16504_wp
1385         r1_T0  = 1._wp/40._wp
1386         r1_Z0  = 1.e-4_wp
1387         !
1388         EOS000 = 8.0189615746e+02_wp
1389         EOS100 = 8.6672408165e+02_wp
1390         EOS200 = -1.7864682637e+03_wp
1391         EOS300 = 2.0375295546e+03_wp
1392         EOS400 = -1.2849161071e+03_wp
1393         EOS500 = 4.3227585684e+02_wp
1394         EOS600 = -6.0579916612e+01_wp
1395         EOS010 = 2.6010145068e+01_wp
1396         EOS110 = -6.5281885265e+01_wp
1397         EOS210 = 8.1770425108e+01_wp
1398         EOS310 = -5.6888046321e+01_wp
1399         EOS410 = 1.7681814114e+01_wp
1400         EOS510 = -1.9193502195_wp
1401         EOS020 = -3.7074170417e+01_wp
1402         EOS120 = 6.1548258127e+01_wp
1403         EOS220 = -6.0362551501e+01_wp
1404         EOS320 = 2.9130021253e+01_wp
1405         EOS420 = -5.4723692739_wp
1406         EOS030 = 2.1661789529e+01_wp
1407         EOS130 = -3.3449108469e+01_wp
1408         EOS230 = 1.9717078466e+01_wp
1409         EOS330 = -3.1742946532_wp
1410         EOS040 = -8.3627885467_wp
1411         EOS140 = 1.1311538584e+01_wp
1412         EOS240 = -5.3563304045_wp
1413         EOS050 = 5.4048723791e-01_wp
1414         EOS150 = 4.8169980163e-01_wp
1415         EOS060 = -1.9083568888e-01_wp
1416         EOS001 = 1.9681925209e+01_wp
1417         EOS101 = -4.2549998214e+01_wp
1418         EOS201 = 5.0774768218e+01_wp
1419         EOS301 = -3.0938076334e+01_wp
1420         EOS401 = 6.6051753097_wp
1421         EOS011 = -1.3336301113e+01_wp
1422         EOS111 = -4.4870114575_wp
1423         EOS211 = 5.0042598061_wp
1424         EOS311 = -6.5399043664e-01_wp
1425         EOS021 = 6.7080479603_wp
1426         EOS121 = 3.5063081279_wp
1427         EOS221 = -1.8795372996_wp
1428         EOS031 = -2.4649669534_wp
1429         EOS131 = -5.5077101279e-01_wp
1430         EOS041 = 5.5927935970e-01_wp
1431         EOS002 = 2.0660924175_wp
1432         EOS102 = -4.9527603989_wp
1433         EOS202 = 2.5019633244_wp
1434         EOS012 = 2.0564311499_wp
1435         EOS112 = -2.1311365518e-01_wp
1436         EOS022 = -1.2419983026_wp
1437         EOS003 = -2.3342758797e-02_wp
1438         EOS103 = -1.8507636718e-02_wp
1439         EOS013 = 3.7969820455e-01_wp
1440         !
1441         ALP000 = -6.5025362670e-01_wp
1442         ALP100 = 1.6320471316_wp
1443         ALP200 = -2.0442606277_wp
1444         ALP300 = 1.4222011580_wp
1445         ALP400 = -4.4204535284e-01_wp
1446         ALP500 = 4.7983755487e-02_wp
1447         ALP010 = 1.8537085209_wp
1448         ALP110 = -3.0774129064_wp
1449         ALP210 = 3.0181275751_wp
1450         ALP310 = -1.4565010626_wp
1451         ALP410 = 2.7361846370e-01_wp
1452         ALP020 = -1.6246342147_wp
1453         ALP120 = 2.5086831352_wp
1454         ALP220 = -1.4787808849_wp
1455         ALP320 = 2.3807209899e-01_wp
1456         ALP030 = 8.3627885467e-01_wp
1457         ALP130 = -1.1311538584_wp
1458         ALP230 = 5.3563304045e-01_wp
1459         ALP040 = -6.7560904739e-02_wp
1460         ALP140 = -6.0212475204e-02_wp
1461         ALP050 = 2.8625353333e-02_wp
1462         ALP001 = 3.3340752782e-01_wp
1463         ALP101 = 1.1217528644e-01_wp
1464         ALP201 = -1.2510649515e-01_wp
1465         ALP301 = 1.6349760916e-02_wp
1466         ALP011 = -3.3540239802e-01_wp
1467         ALP111 = -1.7531540640e-01_wp
1468         ALP211 = 9.3976864981e-02_wp
1469         ALP021 = 1.8487252150e-01_wp
1470         ALP121 = 4.1307825959e-02_wp
1471         ALP031 = -5.5927935970e-02_wp
1472         ALP002 = -5.1410778748e-02_wp
1473         ALP102 = 5.3278413794e-03_wp
1474         ALP012 = 6.2099915132e-02_wp
1475         ALP003 = -9.4924551138e-03_wp
1476         !
1477         BET000 = 1.0783203594e+01_wp
1478         BET100 = -4.4452095908e+01_wp
1479         BET200 = 7.6048755820e+01_wp
1480         BET300 = -6.3944280668e+01_wp
1481         BET400 = 2.6890441098e+01_wp
1482         BET500 = -4.5221697773_wp
1483         BET010 = -8.1219372432e-01_wp
1484         BET110 = 2.0346663041_wp
1485         BET210 = -2.1232895170_wp
1486         BET310 = 8.7994140485e-01_wp
1487         BET410 = -1.1939638360e-01_wp
1488         BET020 = 7.6574242289e-01_wp
1489         BET120 = -1.5019813020_wp
1490         BET220 = 1.0872489522_wp
1491         BET320 = -2.7233429080e-01_wp
1492         BET030 = -4.1615152308e-01_wp
1493         BET130 = 4.9061350869e-01_wp
1494         BET230 = -1.1847737788e-01_wp
1495         BET040 = 1.4073062708e-01_wp
1496         BET140 = -1.3327978879e-01_wp
1497         BET050 = 5.9929880134e-03_wp
1498         BET001 = -5.2937873009e-01_wp
1499         BET101 = 1.2634116779_wp
1500         BET201 = -1.1547328025_wp
1501         BET301 = 3.2870876279e-01_wp
1502         BET011 = -5.5824407214e-02_wp
1503         BET111 = 1.2451933313e-01_wp
1504         BET211 = -2.4409539932e-02_wp
1505         BET021 = 4.3623149752e-02_wp
1506         BET121 = -4.6767901790e-02_wp
1507         BET031 = -6.8523260060e-03_wp
1508         BET002 = -6.1618945251e-02_wp
1509         BET102 = 6.2255521644e-02_wp
1510         BET012 = -2.6514181169e-03_wp
1511         BET003 = -2.3025968587e-04_wp
1512         !
1513         PEN000 = -9.8409626043_wp
1514         PEN100 = 2.1274999107e+01_wp
1515         PEN200 = -2.5387384109e+01_wp
1516         PEN300 = 1.5469038167e+01_wp
1517         PEN400 = -3.3025876549_wp
1518         PEN010 = 6.6681505563_wp
1519         PEN110 = 2.2435057288_wp
1520         PEN210 = -2.5021299030_wp
1521         PEN310 = 3.2699521832e-01_wp
1522         PEN020 = -3.3540239802_wp
1523         PEN120 = -1.7531540640_wp
1524         PEN220 = 9.3976864981e-01_wp
1525         PEN030 = 1.2324834767_wp
1526         PEN130 = 2.7538550639e-01_wp
1527         PEN040 = -2.7963967985e-01_wp
1528         PEN001 = -1.3773949450_wp
1529         PEN101 = 3.3018402659_wp
1530         PEN201 = -1.6679755496_wp
1531         PEN011 = -1.3709540999_wp
1532         PEN111 = 1.4207577012e-01_wp
1533         PEN021 = 8.2799886843e-01_wp
1534         PEN002 = 1.7507069098e-02_wp
1535         PEN102 = 1.3880727538e-02_wp
1536         PEN012 = -2.8477365341e-01_wp
1537         !
1538         APE000 = -1.6670376391e-01_wp
1539         APE100 = -5.6087643219e-02_wp
1540         APE200 = 6.2553247576e-02_wp
1541         APE300 = -8.1748804580e-03_wp
1542         APE010 = 1.6770119901e-01_wp
1543         APE110 = 8.7657703198e-02_wp
1544         APE210 = -4.6988432490e-02_wp
1545         APE020 = -9.2436260751e-02_wp
1546         APE120 = -2.0653912979e-02_wp
1547         APE030 = 2.7963967985e-02_wp
1548         APE001 = 3.4273852498e-02_wp
1549         APE101 = -3.5518942529e-03_wp
1550         APE011 = -4.1399943421e-02_wp
1551         APE002 = 7.1193413354e-03_wp
1552         !
1553         BPE000 = 2.6468936504e-01_wp
1554         BPE100 = -6.3170583896e-01_wp
1555         BPE200 = 5.7736640125e-01_wp
1556         BPE300 = -1.6435438140e-01_wp
1557         BPE010 = 2.7912203607e-02_wp
1558         BPE110 = -6.2259666565e-02_wp
1559         BPE210 = 1.2204769966e-02_wp
1560         BPE020 = -2.1811574876e-02_wp
1561         BPE120 = 2.3383950895e-02_wp
1562         BPE030 = 3.4261630030e-03_wp
1563         BPE001 = 4.1079296834e-02_wp
1564         BPE101 = -4.1503681096e-02_wp
1565         BPE011 = 1.7676120780e-03_wp
1566         BPE002 = 1.7269476440e-04_wp
1567         !
1568      CASE( np_eos80 )                        !==  polynomial EOS-80 formulation  ==!
1569         !
1570         IF(lwp) WRITE(numout,*)
1571         IF(lwp) WRITE(numout,*) '   ==>>>   use of EOS-80 equation of state (pot. temp. and pract. salinity)'
1572         !
1573         l_useCT = .FALSE.                         ! model temperature is Potential temperature
1574         rdeltaS = 20._wp
1575         r1_S0  = 1._wp/40._wp
1576         r1_T0  = 1._wp/40._wp
1577         r1_Z0  = 1.e-4_wp
1578         !
1579         EOS000 = 9.5356891948e+02_wp
1580         EOS100 = 1.7136499189e+02_wp
1581         EOS200 = -3.7501039454e+02_wp
1582         EOS300 = 5.1856810420e+02_wp
1583         EOS400 = -3.7264470465e+02_wp
1584         EOS500 = 1.4302533998e+02_wp
1585         EOS600 = -2.2856621162e+01_wp
1586         EOS010 = 1.0087518651e+01_wp
1587         EOS110 = -1.3647741861e+01_wp
1588         EOS210 = 8.8478359933_wp
1589         EOS310 = -7.2329388377_wp
1590         EOS410 = 1.4774410611_wp
1591         EOS510 = 2.0036720553e-01_wp
1592         EOS020 = -2.5579830599e+01_wp
1593         EOS120 = 2.4043512327e+01_wp
1594         EOS220 = -1.6807503990e+01_wp
1595         EOS320 = 8.3811577084_wp
1596         EOS420 = -1.9771060192_wp
1597         EOS030 = 1.6846451198e+01_wp
1598         EOS130 = -2.1482926901e+01_wp
1599         EOS230 = 1.0108954054e+01_wp
1600         EOS330 = -6.2675951440e-01_wp
1601         EOS040 = -8.0812310102_wp
1602         EOS140 = 1.0102374985e+01_wp
1603         EOS240 = -4.8340368631_wp
1604         EOS050 = 1.2079167803_wp
1605         EOS150 = 1.1515380987e-01_wp
1606         EOS060 = -2.4520288837e-01_wp
1607         EOS001 = 1.0748601068e+01_wp
1608         EOS101 = -1.7817043500e+01_wp
1609         EOS201 = 2.2181366768e+01_wp
1610         EOS301 = -1.6750916338e+01_wp
1611         EOS401 = 4.1202230403_wp
1612         EOS011 = -1.5852644587e+01_wp
1613         EOS111 = -7.6639383522e-01_wp
1614         EOS211 = 4.1144627302_wp
1615         EOS311 = -6.6955877448e-01_wp
1616         EOS021 = 9.9994861860_wp
1617         EOS121 = -1.9467067787e-01_wp
1618         EOS221 = -1.2177554330_wp
1619         EOS031 = -3.4866102017_wp
1620         EOS131 = 2.2229155620e-01_wp
1621         EOS041 = 5.9503008642e-01_wp
1622         EOS002 = 1.0375676547_wp
1623         EOS102 = -3.4249470629_wp
1624         EOS202 = 2.0542026429_wp
1625         EOS012 = 2.1836324814_wp
1626         EOS112 = -3.4453674320e-01_wp
1627         EOS022 = -1.2548163097_wp
1628         EOS003 = 1.8729078427e-02_wp
1629         EOS103 = -5.7238495240e-02_wp
1630         EOS013 = 3.8306136687e-01_wp
1631         !
1632         ALP000 = -2.5218796628e-01_wp
1633         ALP100 = 3.4119354654e-01_wp
1634         ALP200 = -2.2119589983e-01_wp
1635         ALP300 = 1.8082347094e-01_wp
1636         ALP400 = -3.6936026529e-02_wp
1637         ALP500 = -5.0091801383e-03_wp
1638         ALP010 = 1.2789915300_wp
1639         ALP110 = -1.2021756164_wp
1640         ALP210 = 8.4037519952e-01_wp
1641         ALP310 = -4.1905788542e-01_wp
1642         ALP410 = 9.8855300959e-02_wp
1643         ALP020 = -1.2634838399_wp
1644         ALP120 = 1.6112195176_wp
1645         ALP220 = -7.5817155402e-01_wp
1646         ALP320 = 4.7006963580e-02_wp
1647         ALP030 = 8.0812310102e-01_wp
1648         ALP130 = -1.0102374985_wp
1649         ALP230 = 4.8340368631e-01_wp
1650         ALP040 = -1.5098959754e-01_wp
1651         ALP140 = -1.4394226233e-02_wp
1652         ALP050 = 3.6780433255e-02_wp
1653         ALP001 = 3.9631611467e-01_wp
1654         ALP101 = 1.9159845880e-02_wp
1655         ALP201 = -1.0286156825e-01_wp
1656         ALP301 = 1.6738969362e-02_wp
1657         ALP011 = -4.9997430930e-01_wp
1658         ALP111 = 9.7335338937e-03_wp
1659         ALP211 = 6.0887771651e-02_wp
1660         ALP021 = 2.6149576513e-01_wp
1661         ALP121 = -1.6671866715e-02_wp
1662         ALP031 = -5.9503008642e-02_wp
1663         ALP002 = -5.4590812035e-02_wp
1664         ALP102 = 8.6134185799e-03_wp
1665         ALP012 = 6.2740815484e-02_wp
1666         ALP003 = -9.5765341718e-03_wp
1667         !
1668         BET000 = 2.1420623987_wp
1669         BET100 = -9.3752598635_wp
1670         BET200 = 1.9446303907e+01_wp
1671         BET300 = -1.8632235232e+01_wp
1672         BET400 = 8.9390837485_wp
1673         BET500 = -1.7142465871_wp
1674         BET010 = -1.7059677327e-01_wp
1675         BET110 = 2.2119589983e-01_wp
1676         BET210 = -2.7123520642e-01_wp
1677         BET310 = 7.3872053057e-02_wp
1678         BET410 = 1.2522950346e-02_wp
1679         BET020 = 3.0054390409e-01_wp
1680         BET120 = -4.2018759976e-01_wp
1681         BET220 = 3.1429341406e-01_wp
1682         BET320 = -9.8855300959e-02_wp
1683         BET030 = -2.6853658626e-01_wp
1684         BET130 = 2.5272385134e-01_wp
1685         BET230 = -2.3503481790e-02_wp
1686         BET040 = 1.2627968731e-01_wp
1687         BET140 = -1.2085092158e-01_wp
1688         BET050 = 1.4394226233e-03_wp
1689         BET001 = -2.2271304375e-01_wp
1690         BET101 = 5.5453416919e-01_wp
1691         BET201 = -6.2815936268e-01_wp
1692         BET301 = 2.0601115202e-01_wp
1693         BET011 = -9.5799229402e-03_wp
1694         BET111 = 1.0286156825e-01_wp
1695         BET211 = -2.5108454043e-02_wp
1696         BET021 = -2.4333834734e-03_wp
1697         BET121 = -3.0443885826e-02_wp
1698         BET031 = 2.7786444526e-03_wp
1699         BET002 = -4.2811838287e-02_wp
1700         BET102 = 5.1355066072e-02_wp
1701         BET012 = -4.3067092900e-03_wp
1702         BET003 = -7.1548119050e-04_wp
1703         !
1704         PEN000 = -5.3743005340_wp
1705         PEN100 = 8.9085217499_wp
1706         PEN200 = -1.1090683384e+01_wp
1707         PEN300 = 8.3754581690_wp
1708         PEN400 = -2.0601115202_wp
1709         PEN010 = 7.9263222935_wp
1710         PEN110 = 3.8319691761e-01_wp
1711         PEN210 = -2.0572313651_wp
1712         PEN310 = 3.3477938724e-01_wp
1713         PEN020 = -4.9997430930_wp
1714         PEN120 = 9.7335338937e-02_wp
1715         PEN220 = 6.0887771651e-01_wp
1716         PEN030 = 1.7433051009_wp
1717         PEN130 = -1.1114577810e-01_wp
1718         PEN040 = -2.9751504321e-01_wp
1719         PEN001 = -6.9171176978e-01_wp
1720         PEN101 = 2.2832980419_wp
1721         PEN201 = -1.3694684286_wp
1722         PEN011 = -1.4557549876_wp
1723         PEN111 = 2.2969116213e-01_wp
1724         PEN021 = 8.3654420645e-01_wp
1725         PEN002 = -1.4046808820e-02_wp
1726         PEN102 = 4.2928871430e-02_wp
1727         PEN012 = -2.8729602515e-01_wp
1728         !
1729         APE000 = -1.9815805734e-01_wp
1730         APE100 = -9.5799229402e-03_wp
1731         APE200 = 5.1430784127e-02_wp
1732         APE300 = -8.3694846809e-03_wp
1733         APE010 = 2.4998715465e-01_wp
1734         APE110 = -4.8667669469e-03_wp
1735         APE210 = -3.0443885826e-02_wp
1736         APE020 = -1.3074788257e-01_wp
1737         APE120 = 8.3359333577e-03_wp
1738         APE030 = 2.9751504321e-02_wp
1739         APE001 = 3.6393874690e-02_wp
1740         APE101 = -5.7422790533e-03_wp
1741         APE011 = -4.1827210323e-02_wp
1742         APE002 = 7.1824006288e-03_wp
1743         !
1744         BPE000 = 1.1135652187e-01_wp
1745         BPE100 = -2.7726708459e-01_wp
1746         BPE200 = 3.1407968134e-01_wp
1747         BPE300 = -1.0300557601e-01_wp
1748         BPE010 = 4.7899614701e-03_wp
1749         BPE110 = -5.1430784127e-02_wp
1750         BPE210 = 1.2554227021e-02_wp
1751         BPE020 = 1.2166917367e-03_wp
1752         BPE120 = 1.5221942913e-02_wp
1753         BPE030 = -1.3893222263e-03_wp
1754         BPE001 = 2.8541225524e-02_wp
1755         BPE101 = -3.4236710714e-02_wp
1756         BPE011 = 2.8711395266e-03_wp
1757         BPE002 = 5.3661089288e-04_wp
1758         !
1759      CASE( np_seos )                        !==  Simplified EOS     ==!
1760
1761         r1_S0  = 0.875_wp/35.16504_wp   ! Used to convert CT in potential temperature when using bulk formulae (eos_pt_from_ct)
1762
1763         IF(lwp) THEN
1764            WRITE(numout,*)
1765            WRITE(numout,*) '   ==>>>   use of simplified eos:    '
1766            WRITE(numout,*) '              rhd(dT=T-10,dS=S-35,Z) = [-a0*(1+lambda1/2*dT+mu1*Z)*dT '
1767            WRITE(numout,*) '                                       + b0*(1+lambda2/2*dT+mu2*Z)*dS - nu*dT*dS] / rho0'
1768            WRITE(numout,*) '              with the following coefficients :'
1769            WRITE(numout,*) '                 thermal exp. coef.    rn_a0      = ', rn_a0
1770            WRITE(numout,*) '                 saline  cont. coef.   rn_b0      = ', rn_b0
1771            WRITE(numout,*) '                 cabbeling coef.       rn_lambda1 = ', rn_lambda1
1772            WRITE(numout,*) '                 cabbeling coef.       rn_lambda2 = ', rn_lambda2
1773            WRITE(numout,*) '                 thermobar. coef.      rn_mu1     = ', rn_mu1
1774            WRITE(numout,*) '                 thermobar. coef.      rn_mu2     = ', rn_mu2
1775            WRITE(numout,*) '                 2nd cabbel. coef.     rn_nu      = ', rn_nu
1776            WRITE(numout,*) '              Caution: rn_beta0=0 incompatible with ddm parameterization '
1777         ENDIF
1778         l_useCT = .TRUE.          ! Use conservative temperature
1779         !
1780      CASE DEFAULT                     !==  ERROR in neos  ==!
1781         WRITE(ctmp1,*) '          bad flag value for neos = ', neos, '. You should never see this error'
1782         CALL ctl_stop( ctmp1 )
1783         !
1784      END SELECT
1785      !
1786      rho0_rcp    = rho0 * rcp
1787      r1_rho0     = 1._wp / rho0
1788      r1_rcp      = 1._wp / rcp
1789      r1_rho0_rcp = 1._wp / rho0_rcp
1790      !
1791      IF(lwp) THEN
1792         IF( l_useCT )   THEN
1793            WRITE(numout,*)
1794            WRITE(numout,*) '   ==>>>   model uses Conservative Temperature'
1795            WRITE(numout,*) '           Important: model must be initialized with CT and SA fields'
1796         ELSE
1797            WRITE(numout,*)
1798            WRITE(numout,*) '   ==>>>   model does not use Conservative Temperature'
1799         ENDIF
1800      ENDIF
1801      !
1802      IF(lwp) WRITE(numout,*)
1803      IF(lwp) WRITE(numout,*) '   Associated physical constant'
1804      IF(lwp) WRITE(numout,*) '      volumic mass of reference           rho0  = ', rho0   , ' kg/m^3'
1805      IF(lwp) WRITE(numout,*) '      1. / rho0                        r1_rho0  = ', r1_rho0, ' m^3/kg'
1806      IF(lwp) WRITE(numout,*) '      ocean specific heat                 rcp   = ', rcp    , ' J/Kelvin'
1807      IF(lwp) WRITE(numout,*) '      rho0 * rcp                       rho0_rcp = ', rho0_rcp
1808      IF(lwp) WRITE(numout,*) '      1. / ( rho0 * rcp )           r1_rho0_rcp = ', r1_rho0_rcp
1809      !
1810   END SUBROUTINE eos_init
1811
1812   !!======================================================================
1813END MODULE eosbn2
Note: See TracBrowser for help on using the repository browser.