source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/DYN/dynadv_cen2.F90 @ 14381

Last change on this file since 14381 was 14381, checked in by techene, 8 months ago

#2605 : add advection velocity as input in advective flux form routines

  • Property svn:keywords set to Id
File size: 8.0 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
27
28   !! * Substitutions
29#  include "do_loop_substitute.h90"
30#  include "domzgr_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
33   !! $Id$
34   !! Software governed by the CeCILL license (see ./LICENSE)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE dyn_adv_cen2( kt, Kmm, puu, pvv, Krhs, pau, pav, paw )
39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE dyn_adv_cen2  ***
41      !!
42      !! ** Purpose :   Compute the now momentum advection trend in flux form
43      !!              and the general trend of the momentum equation.
44      !!
45      !! ** Method  :   Trend evaluated using now fields (centered in time)
46      !!
47      !! ** Action  :   (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) updated with the now vorticity term trend
48      !!----------------------------------------------------------------------
49      INTEGER                                               , INTENT(in   ) ::   kt              ! ocean time-step index
50      INTEGER                                               , INTENT(in   ) ::   Kmm, Krhs       ! ocean time level indices
51      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt)          , TARGET, INTENT(inout) ::   puu, pvv        ! ocean velocities and RHS of momentum equation
52      REAL(wp), DIMENSION(:,:,:)          , OPTIONAL, TARGET, INTENT(in   ) ::   pau, pav, paw   ! advective velocity
53      !
54      INTEGER  ::   ji, jj, jk   ! dummy loop indices
55      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zfu_t, zfu_f, zfu_uw, zfu
56      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zfv_t, zfv_f, zfv_vw, zfv, zfw
57      REAL(wp), DIMENSION(:,:,:), POINTER ::   zptu, zptv, zptw
58      !!----------------------------------------------------------------------
59      !
60      IF( kt == nit000 .AND. lwp ) THEN
61         WRITE(numout,*)
62         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
63         WRITE(numout,*) '~~~~~~~~~~~~'
64      ENDIF
65      !
66      IF( l_trddyn ) THEN           ! trends: store the input trends
67         zfu_uw(:,:,:) = puu(:,:,:,Krhs)
68         zfv_vw(:,:,:) = pvv(:,:,:,Krhs)
69      ENDIF
70      !
71      IF( PRESENT( pau ) ) THEN     ! RK3: advective velocity (pau,pav,paw) /= advected velocity (puu,pvv,ww)
72         zptu => pau(:,:,:)
73         zptv => pav(:,:,:)
74         zptw => paw(:,:,:)
75      ELSE                          ! MLF: advective velocity = (puu,pvv,ww)
76         zptu => puu(:,:,:,Kmm)
77         zptv => pvv(:,:,:,Kmm)
78         zptw => ww (:,:,:    )
79      ENDIF
80      !
81      !                             !==  Horizontal advection  ==!
82      !
83      DO jk = 1, jpkm1                    ! horizontal transport
84         zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u(:,:,jk,Kmm) * zptu(:,:,jk)
85         zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v(:,:,jk,Kmm) * zptv(:,:,jk)
86         DO_2D( 1, 0, 1, 0 )              ! horizontal momentum fluxes (at T- and F-point)
87            zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji+1,jj  ,jk,Kmm) )
88            zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji  ,jj+1,jk,Kmm) )
89            zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji+1,jj  ,jk,Kmm) )
90            zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji  ,jj+1,jk,Kmm) )
91         END_2D
92         DO_2D( 0, 0, 0, 0 )              ! divergence of horizontal momentum fluxes
93            puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
94               &                           + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj)   &
95               &                           / e3u(ji,jj,jk,Kmm)
96            pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
97               &                           + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj)   &
98               &                           / e3v(ji,jj,jk,Kmm)
99         END_2D
100      END DO
101      !
102      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
103         zfu_uw(:,:,:) = puu(:,:,:,Krhs) - zfu_uw(:,:,:)
104         zfv_vw(:,:,:) = pvv(:,:,:,Krhs) - zfv_vw(:,:,:)
105         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt, Kmm )
106         zfu_t(:,:,:) = puu(:,:,:,Krhs)
107         zfv_t(:,:,:) = pvv(:,:,:,Krhs)
108      ENDIF
109      !
110      !                             !==  Vertical advection  ==!
111      !
112      DO_2D( 0, 0, 0, 0 )                 ! surface/bottom advective fluxes set to zero
113         zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(ji,jj,jpk) = 0._wp
114         zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(ji,jj, 1 ) = 0._wp
115      END_2D
116      IF( ln_linssh ) THEN                ! linear free surface: advection through the surface
117         DO_2D( 0, 0, 0, 0 )
118            zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * zptw(ji,jj,1) + e1e2t(ji+1,jj) * zptw(ji+1,jj,1) ) * puu(ji,jj,1,Kmm)
119            zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * zptw(ji,jj,1) + e1e2t(ji,jj+1) * zptw(ji,jj+1,1) ) * pvv(ji,jj,1,Kmm)
120         END_2D
121      ENDIF
122      DO jk = 2, jpkm1                    ! interior advective fluxes
123         DO_2D( 0, 1, 0, 1 )                  ! 1/4 * Vertical transport
124            zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * zptw(ji,jj,jk)
125         END_2D
126         DO_2D( 0, 0, 0, 0 )
127            zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji,jj,jk-1,Kmm) )
128            zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk-1,Kmm) )
129         END_2D
130      END DO
131      DO_3D( 0, 0, 0, 0, 1, jpkm1 )       ! divergence of vertical momentum flux divergence
132         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj)   &
133            &                                      / e3u(ji,jj,jk,Kmm)
134         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj)   &
135            &                                      / e3v(ji,jj,jk,Kmm)
136      END_3D
137      !
138      IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
139         zfu_t(:,:,:) = puu(:,:,:,Krhs) - zfu_t(:,:,:)
140         zfv_t(:,:,:) = pvv(:,:,:,Krhs) - zfv_t(:,:,:)
141         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt, Kmm )
142      ENDIF
143      !                                   ! Control print
144      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
145         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
146      !
147   END SUBROUTINE dyn_adv_cen2
148
149   !!==============================================================================
150END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.