source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/DYN/dynhpg.F90 @ 15036

Last change on this file since 15036 was 15036, checked in by techene, 6 months ago

#2695 isf + qco OK in ISOMIP not in WED025

  • Property svn:keywords set to Id
File size: 75.4 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!            4.2  !  2020-12  (M. Bell, A. Young) hpg_djc: revised djc scheme
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   dyn_hpg      : update the momentum trend with the now horizontal
24   !!                  gradient of the hydrostatic pressure
25   !!   dyn_hpg_init : initialisation and control of options
26   !!       hpg_zco  : z-coordinate scheme
27   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
28   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
29   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
30   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
31   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
32   !!----------------------------------------------------------------------
33   USE oce             ! ocean dynamics and tracers
34   USE isf_oce , ONLY : risfload  ! ice shelf  (risfload variable)
35   USE isfload , ONLY : isf_load  ! ice shelf  (isf_load routine )
36   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
37   USE dom_oce         ! ocean space and time domain
38   USE wet_dry         ! wetting and drying
39   USE phycst          ! physical constants
40   USE trd_oce         ! trends: ocean variables
41   USE trddyn          ! trend manager: dynamics
42   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
43   !
44   USE in_out_manager  ! I/O manager
45   USE prtctl          ! Print control
46   USE lbclnk          ! lateral boundary condition
47   USE lib_mpp         ! MPP library
48   USE eosbn2          ! compute density
49   USE timing          ! Timing
50   USE iom
51
52   IMPLICIT NONE
53   PRIVATE
54
55   PUBLIC   dyn_hpg        ! routine called by step module
56   PUBLIC   dyn_hpg_init   ! routine called by opa module
57
58   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
59   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
60   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
61   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
62   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
63   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
64   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
65
66   !                                !! Flag to control the type of hydrostatic pressure gradient
67   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
68   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
69   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
70   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
71   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
72   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
73   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
74   !
75   INTEGER, PUBLIC  ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
76   !
77   LOGICAL          ::   ln_hpg_djc_vnh, ln_hpg_djc_vnv                 ! flag to specify hpg_djc boundary condition type
78   REAL(wp), PUBLIC ::   aco_bc_hor, bco_bc_hor, aco_bc_vrt, bco_bc_vrt !: coefficients for hpg_djc hor and vert boundary conditions
79
80   !! * Substitutions
81#  include "do_loop_substitute.h90"
82#  include "domzgr_substitute.h90"
83
84   !!----------------------------------------------------------------------
85   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
86   !! $Id$
87   !! Software governed by the CeCILL license (see ./LICENSE)
88   !!----------------------------------------------------------------------
89CONTAINS
90
91   SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
92      !!---------------------------------------------------------------------
93      !!                  ***  ROUTINE dyn_hpg  ***
94      !!
95      !! ** Method  :   Call the hydrostatic pressure gradient routine
96      !!              using the scheme defined in the namelist
97      !!
98      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
99      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
100      !!----------------------------------------------------------------------
101      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
102      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
103      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
104      !
105      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
106      !!----------------------------------------------------------------------
107      !
108      IF( ln_timing )   CALL timing_start('dyn_hpg')
109      !
110      IF( l_trddyn ) THEN                    ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
111         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
112         ztrdu(:,:,:) = puu(:,:,:,Krhs)
113         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
114      ENDIF
115      !
116      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
117      CASE ( np_zco )   ;   CALL hpg_zco    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate
118      CASE ( np_zps )   ;   CALL hpg_zps    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate plus partial steps (interpolation)
119      CASE ( np_sco )   ;   CALL hpg_sco    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (standard jacobian formulation)
120      CASE ( np_djc )   ;   CALL hpg_djc    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Density Jacobian with Cubic polynomial)
121      CASE ( np_prj )   ;   CALL hpg_prj    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Pressure Jacobian scheme)
122      CASE ( np_isf )   ;   CALL hpg_isf    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate similar to sco modify for ice shelf
123      END SELECT
124      !
125      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
126         ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
127         ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
128         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
129         DEALLOCATE( ztrdu , ztrdv )
130      ENDIF
131      !
132      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg  - Ua: ', mask1=umask,   &
133         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
134      !
135      IF( ln_timing )   CALL timing_stop('dyn_hpg')
136      !
137   END SUBROUTINE dyn_hpg
138
139
140   SUBROUTINE dyn_hpg_init( Kmm )
141      !!----------------------------------------------------------------------
142      !!                 ***  ROUTINE dyn_hpg_init  ***
143      !!
144      !! ** Purpose :   initializations for the hydrostatic pressure gradient
145      !!              computation and consistency control
146      !!
147      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
148      !!      with the type of vertical coordinate used (zco, zps, sco)
149      !!----------------------------------------------------------------------
150      INTEGER, INTENT( in ) :: Kmm   ! ocean time level index
151      !
152      INTEGER ::   ioptio = 0      ! temporary integer
153      INTEGER ::   ios             ! Local integer output status for namelist read
154      !!
155      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
156      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
157      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
158      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
159      !!
160      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
161         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf,     &
162         &                 ln_hpg_djc_vnh, ln_hpg_djc_vnv
163      !!----------------------------------------------------------------------
164      !
165      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
166901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
167      !
168      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
169902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
170      IF(lwm) WRITE ( numond, namdyn_hpg )
171      !
172      IF(lwp) THEN                   ! Control print
173         WRITE(numout,*)
174         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
175         WRITE(numout,*) '~~~~~~~~~~~~'
176         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
177         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
178         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
179         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
180         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
181         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
182         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
183      ENDIF
184      !
185      IF( .NOT.ln_linssh .AND. (ln_hpg_zco.OR.ln_hpg_zps) )   &
186         &   CALL ctl_stop( 'dyn_hpg_init : non-linear free surface incompatible with hpg_zco or hpg_zps' )
187      !
188      IF( (.NOT.ln_hpg_isf .AND. ln_isfcav) .OR. (ln_hpg_isf .AND. .NOT.ln_isfcav) )                  &
189         &   CALL ctl_stop( 'dyn_hpg_init : ln_hpg_isf=T requires ln_isfcav=T and vice versa' ) 
190      !
191      !                               ! Set nhpg from ln_hpg_... flags & consistency check
192      nhpg   = np_ERROR
193      ioptio = 0
194      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
195      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
196      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
197      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
198      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
199      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
200      !
201      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
202      !
203      IF(lwp) THEN
204         WRITE(numout,*)
205         SELECT CASE( nhpg )
206         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
207         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
208         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
209         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
210         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
211         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
212         END SELECT
213         WRITE(numout,*)
214      ENDIF
215      !                         
216      IF ( ln_hpg_djc ) THEN
217         IF (ln_hpg_djc_vnh) THEN ! Von Neumann boundary condition
218           IF(lwp) WRITE(numout,*) '           horizontal bc: von Neumann '
219           aco_bc_hor = 6.0_wp/5.0_wp
220           bco_bc_hor = 7.0_wp/15.0_wp
221         ELSE ! Linear extrapolation
222           IF(lwp) WRITE(numout,*) '           horizontal bc: linear extrapolation'
223           aco_bc_hor = 3.0_wp/2.0_wp
224           bco_bc_hor = 1.0_wp/2.0_wp
225         END IF
226         IF (ln_hpg_djc_vnv) THEN ! Von Neumann boundary condition
227           IF(lwp) WRITE(numout,*) '           vertical bc: von Neumann '
228           aco_bc_vrt = 6.0_wp/5.0_wp
229           bco_bc_vrt = 7.0_wp/15.0_wp
230         ELSE ! Linear extrapolation
231           IF(lwp) WRITE(numout,*) '           vertical bc: linear extrapolation'
232           aco_bc_vrt = 3.0_wp/2.0_wp
233           bco_bc_vrt = 1.0_wp/2.0_wp
234         END IF
235      END IF
236      !
237   END SUBROUTINE dyn_hpg_init
238
239
240   SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
241      !!---------------------------------------------------------------------
242      !!                  ***  ROUTINE hpg_zco  ***
243      !!
244      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
245      !!      The now hydrostatic pressure gradient at a given level, jk,
246      !!      is computed by taking the vertical integral of the in-situ
247      !!      density gradient along the model level from the suface to that
248      !!      level:    zhpi = grav .....
249      !!                zhpj = grav .....
250      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
251      !!            puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
252      !!            pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
253      !!
254      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
255      !!----------------------------------------------------------------------
256      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
257      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
258      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
259      !
260      INTEGER  ::   ji, jj, jk       ! dummy loop indices
261      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
262      REAL(wp), DIMENSION(jpi,jpj) ::  zhpi, zhpj
263      !!----------------------------------------------------------------------
264      !
265      IF( kt == nit000 ) THEN
266         IF(lwp) WRITE(numout,*)
267         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
268         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
269      ENDIF
270      !
271      zcoef0 = - grav * 0.5_wp            ! Local constant initialization
272      !
273      DO_2D( 0, 0, 0, 0 )                 ! Surface value
274         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
275         !                                   ! hydrostatic pressure gradient
276         zhpi(ji,jj) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
277         zhpj(ji,jj) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
278         !                                   ! add to the general momentum trend
279         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj)
280         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj)
281      END_2D
282      !
283      DO_3D( 0, 0, 0, 0, 2, jpkm1 )        ! interior value (2=<jk=<jpkm1)
284         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
285         !                                   ! hydrostatic pressure gradient
286         zhpi(ji,jj) = zhpi(ji,jj) + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )  &
287            &                                  - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
288
289         zhpj(ji,jj) = zhpj(ji,jj) + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )  &
290            &                                  - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
291         !                                   ! add to the general momentum trend
292         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj)
293         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj)
294      END_3D
295      !
296   END SUBROUTINE hpg_zco
297
298
299   SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
300      !!---------------------------------------------------------------------
301      !!                 ***  ROUTINE hpg_zps  ***
302      !!
303      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
304      !!
305      !! ** Action  : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
306      !!----------------------------------------------------------------------
307      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
308      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
309      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
310      !!
311      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
312      INTEGER  ::   iku, ikv                         ! temporary integers
313      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
314      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
315      REAL(wp), DIMENSION(jpi,jpj,jpts)   :: zgtsu, zgtsv
316      REAL(wp), DIMENSION(jpi,jpj)     :: zgru, zgrv
317      !!----------------------------------------------------------------------
318      !
319      IF( kt == nit000 ) THEN
320         IF(lwp) WRITE(numout,*)
321         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
322         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
323      ENDIF
324
325      ! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
326      CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
327
328      ! Local constant initialization
329      zcoef0 = - grav * 0.5_wp
330
331      !  Surface value (also valid in partial step case)
332      DO_2D( 0, 0, 0, 0 )
333         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
334         ! hydrostatic pressure gradient
335         zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
336         zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
337         ! add to the general momentum trend
338         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
339         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
340      END_2D
341
342      ! interior value (2=<jk=<jpkm1)
343      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
344         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
345         ! hydrostatic pressure gradient
346         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
347            &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
348            &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
349
350         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
351            &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
352            &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
353         ! add to the general momentum trend
354         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
355         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
356      END_3D
357
358      ! partial steps correction at the last level  (use zgru & zgrv computed in zpshde.F90)
359      DO_2D( 0, 0, 0, 0 )
360         iku = mbku(ji,jj)
361         ikv = mbkv(ji,jj)
362         zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj  ,iku,Kmm) )
363         zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji  ,jj+1,ikv,Kmm) )
364         IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
365            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku)         ! subtract old value
366            zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
367               &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
368            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
369         ENDIF
370         IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
371            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv)         ! subtract old value
372            zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
373               &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
374            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
375         ENDIF
376      END_2D
377      !
378   END SUBROUTINE hpg_zps
379
380
381   SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
382      !!---------------------------------------------------------------------
383      !!                  ***  ROUTINE hpg_sco  ***
384      !!
385      !! ** Method  :   s-coordinate case. Jacobian scheme.
386      !!      The now hydrostatic pressure gradient at a given level, jk,
387      !!      is computed by taking the vertical integral of the in-situ
388      !!      density gradient along the model level from the suface to that
389      !!      level. s-coordinates (ln_sco): a corrective term is added
390      !!      to the horizontal pressure gradient :
391      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
392      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
393      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
394      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
395      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
396      !!
397      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
398      !!----------------------------------------------------------------------
399      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
400      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
401      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
402      !!
403      INTEGER  ::   ji, jj, jk, jii, jjj           ! dummy loop indices
404      REAL(wp) ::   zcoef0, zuap, zvap, ztmp       ! local scalars
405      LOGICAL  ::   ll_tmp1, ll_tmp2               ! local logical variables
406      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
407      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
408      !!----------------------------------------------------------------------
409      !
410      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
411      !
412      IF( kt == nit000 ) THEN
413         IF(lwp) WRITE(numout,*)
414         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
415         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OCE original scheme used'
416      ENDIF
417      !
418      zcoef0 = - grav * 0.5_wp
419      !
420      IF( ln_wd_il ) THEN
421        DO_2D( 0, 0, 0, 0 )
422          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)               ,  ssh(ji+1,jj,Kmm) ) >                &
423               &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
424               &    MAX(  ssh(ji,jj,Kmm) +  ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
425               &                                                       > rn_wdmin1 + rn_wdmin2
426          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)              -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (       &
427               &    MAX(   ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
428               &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
429
430          IF(ll_tmp1) THEN
431            zcpx(ji,jj) = 1.0_wp
432          ELSE IF(ll_tmp2) THEN
433            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
434            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
435                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
436          ELSE
437            zcpx(ji,jj) = 0._wp
438          END IF
439   
440          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
441               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
442               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
443               &                                                      > rn_wdmin1 + rn_wdmin2
444          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
445               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
446               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
447
448          IF(ll_tmp1) THEN
449            zcpy(ji,jj) = 1.0_wp
450          ELSE IF(ll_tmp2) THEN
451            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
452            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
453                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
454          ELSE
455            zcpy(ji,jj) = 0._wp
456          END IF
457        END_2D
458        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
459      END IF
460      !
461      DO_2D( 0, 0, 0, 0 )              ! Surface value
462         !                                   ! hydrostatic pressure gradient along s-surfaces
463         zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj)                      &
464            &          * (  e3w(ji+1,jj  ,1,Kmm) * rhd(ji+1,jj  ,1)  &
465            &             - e3w(ji  ,jj  ,1,Kmm) * rhd(ji  ,jj  ,1)  )
466         zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj)                      &
467            &          * (  e3w(ji  ,jj+1,1,Kmm) * rhd(ji  ,jj+1,1)  &
468            &             - e3w(ji  ,jj  ,1,Kmm) * rhd(ji  ,jj  ,1)  )
469         !                                   ! s-coordinate pressure gradient correction
470         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) )   &
471            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
472         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) )   &
473            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
474         !
475         IF( ln_wd_il ) THEN
476            zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
477            zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
478            zuap = zuap * zcpx(ji,jj)
479            zvap = zvap * zcpy(ji,jj)
480         ENDIF
481         !                                   ! add to the general momentum trend
482         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
483         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
484      END_2D
485      !
486      DO_3D( 0, 0, 0, 0, 2, jpkm1 )    ! interior value (2=<jk=<jpkm1)
487         !                                   ! hydrostatic pressure gradient along s-surfaces
488         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)                         &
489            &           * (  e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )  &
490            &              - e3w(ji  ,jj,jk,Kmm) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  )
491         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)                         &
492            &           * (  e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )  &
493            &              - e3w(ji,jj  ,jk,Kmm) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  )
494         !                                   ! s-coordinate pressure gradient correction
495         zuap = -zcoef0 * ( rhd  (ji+1,jj  ,jk) + rhd  (ji,jj,jk) ) &
496            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
497         zvap = -zcoef0 * ( rhd  (ji  ,jj+1,jk) + rhd  (ji,jj,jk) ) &
498            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
499         !
500         IF( ln_wd_il ) THEN
501            zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
502            zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
503            zuap = zuap * zcpx(ji,jj)
504            zvap = zvap * zcpy(ji,jj)
505         ENDIF
506         !
507         ! add to the general momentum trend
508         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
509         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
510      END_3D
511      !
512      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
513      !
514   END SUBROUTINE hpg_sco
515
516
517   SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
518      !!---------------------------------------------------------------------
519      !!                  ***  ROUTINE hpg_isf  ***
520      !!
521      !! ** Method  :   s-coordinate case. Jacobian scheme.
522      !!      The now hydrostatic pressure gradient at a given level, jk,
523      !!      is computed by taking the vertical integral of the in-situ
524      !!      density gradient along the model level from the suface to that
525      !!      level. s-coordinates (ln_sco): a corrective term is added
526      !!      to the horizontal pressure gradient :
527      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
528      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
529      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
530      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
531      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
532      !!      iceload is added
533      !!     
534      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
535      !!----------------------------------------------------------------------
536      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
537      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
538      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
539      !!
540      INTEGER  ::   ji, jj, jk             ! dummy loop indices
541      INTEGER  ::   ikt ,  ikti1,  iktj1   ! local integer
542      REAL(wp) ::   ze3w, ze3wi1, ze3wj1   ! local scalars
543      REAL(wp) ::   zcoef0, zuap, zvap     !   -      -
544      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
545      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
546      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhd_top, zdep_top
547      !!----------------------------------------------------------------------
548      !
549      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
550      !
551      !                          ! iniitialised to 0. zhpi zhpi
552      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
553
554      ! compute rhd at the ice/oce interface (ocean side)
555      ! usefull to reduce residual current in the test case ISOMIP with no melting
556      DO ji = 1, jpi
557         DO jj = 1, jpj
558            ikt = mikt(ji,jj)
559            zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
560            zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
561            zdep_top(ji,jj)  = MAX( risfdep(ji,jj) , gdept(ji,jj,1,Kmm) )
562         END DO
563      END DO
564!!st      CALL eos( zts_top, zdep_top, zrhd_top )
565      CALL eos( zts_top, risfdep, zrhd_top )
566
567      !                     !===========================!
568      !                     !=====  surface value  =====!
569      !                     !===========================!
570      DO_2D( 0, 0, 0, 0 )
571         ikt   = mikt(ji  ,jj  )   ;   ze3w   = e3w(ji  ,jj  ,ikt  ,Kmm)
572         ikti1 = mikt(ji+1,jj  )   ;   ze3wi1 = e3w(ji+1,jj  ,ikti1,Kmm)
573         iktj1 = mikt(ji  ,jj+1)   ;   ze3wj1 = e3w(ji  ,jj+1,iktj1,Kmm)
574         !                          ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
575         !                          ! we assume ISF is in isostatic equilibrium
576         zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) * (   risfload(ji+1,jj) - risfload(ji,jj)  &
577            &                                       + 0.5_wp * ( ze3wi1 * ( rhd(ji+1,jj,ikti1) + zrhd_top(ji+1,jj) )     &
578            &                                                  - ze3w   * ( rhd(ji  ,jj,ikt  ) + zrhd_top(ji  ,jj) ) )   )
579         zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) * (   risfload(ji,jj+1) - risfload(ji,jj)  &
580            &                                       + 0.5_wp * ( ze3wj1 * ( rhd(ji,jj+1,iktj1) + zrhd_top(ji,jj+1) )      &
581            &                                                  - ze3w   * ( rhd(ji,jj  ,ikt  ) + zrhd_top(ji,jj  ) ) )   ) 
582         !                          ! s-coordinate pressure gradient correction (=0 if z coordinate)
583         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) )   &
584            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
585         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) )   &
586            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
587         !                          ! add to the general momentum trend
588         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
589         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
590      END_2D
591      !   
592      !                     !=============================!
593      !                     !=====  interior values  =====!
594      !                     !=============================!
595      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
596         ze3w   = e3w(ji  ,jj  ,jk,Kmm)
597         ze3wi1 = e3w(ji+1,jj  ,jk,Kmm)
598         ze3wj1 = e3w(ji  ,jj+1,jk,Kmm)
599         !                          ! hydrostatic pressure gradient along s-surfaces
600         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
601            &           * (  ze3wi1 * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) * wmask(ji+1,jj,jk)   &
602            &              - ze3w   * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) ) * wmask(ji  ,jj,jk)   )
603         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
604            &           * (  ze3wj1 * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) * wmask(ji,jj+1,jk)   &
605            &              - ze3w   * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) ) * wmask(ji,jj  ,jk)   )
606         !                          ! s-coordinate pressure gradient correction
607         zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
608            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
609         zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
610            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
611         !                          ! add to the general momentum trend
612         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
613         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
614      END_3D
615      !
616   END SUBROUTINE hpg_isf
617
618
619   SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
620      !!---------------------------------------------------------------------
621      !!                  ***  ROUTINE hpg_djc  ***
622      !!
623      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
624      !!
625      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
626      !!----------------------------------------------------------------------
627      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
628      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
629      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
630      !!
631      INTEGER  ::   ji, jj, jk          ! dummy loop indices
632      INTEGER  ::   iktb, iktt          ! jk indices at tracer points for top and bottom points
633      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
634      REAL(wp) ::   z_grav_10, z1_12
635      REAL(wp) ::   cffu, cffx          !    "         "
636      REAL(wp) ::   cffv, cffy          !    "         "
637      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
638      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
639 
640      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdzx, zdzy, zdzz                          ! Primitive grid differences ('delta_xyz')
641      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdz_i, zdz_j, zdz_k                       ! Harmonic average of primitive grid differences ('d_xyz')
642      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdrhox, zdrhoy, zdrhoz                    ! Primitive rho differences ('delta_rho')
643      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdrho_i, zdrho_j, zdrho_k                 ! Harmonic average of primitive rho differences ('d_rho')
644      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   z_rho_i, z_rho_j, z_rho_k                 ! Face intergrals
645      REAL(wp), DIMENSION(jpi,jpj)     ::   zz_dz_i, zz_dz_j, zz_drho_i, zz_drho_j    ! temporary arrays
646      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
647      !!----------------------------------------------------------------------
648      !
649      IF( ln_wd_il ) THEN
650         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
651        DO_2D( 0, 0, 0, 0 )
652          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
653               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
654               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
655               &                                                      > rn_wdmin1 + rn_wdmin2
656          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (        &
657               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
658               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
659          IF(ll_tmp1) THEN
660            zcpx(ji,jj) = 1.0_wp
661          ELSE IF(ll_tmp2) THEN
662            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
663            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
664                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
665          ELSE
666            zcpx(ji,jj) = 0._wp
667          END IF
668   
669          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
670               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
671               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
672               &                                                      > rn_wdmin1 + rn_wdmin2
673          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
674               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
675               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
676
677          IF(ll_tmp1) THEN
678            zcpy(ji,jj) = 1.0_wp
679          ELSE IF(ll_tmp2) THEN
680            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
681            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
682                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
683          ELSE
684            zcpy(ji,jj) = 0._wp
685          END IF
686        END_2D
687        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
688      END IF
689
690      IF( kt == nit000 ) THEN
691         IF(lwp) WRITE(numout,*)
692         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
693         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
694      ENDIF
695
696      ! Local constant initialization
697      zcoef0 = - grav * 0.5_wp
698      z_grav_10  = grav / 10._wp
699      z1_12  = 1.0_wp / 12._wp
700
701      !----------------------------------------------------------------------------------------
702      !  1. compute and store elementary vertical differences in provisional arrays
703      !----------------------------------------------------------------------------------------
704
705!!bug gm   Not a true bug, but... zdzz=e3w  for zdzx, zdzy verify what it is really
706
707      DO_3D( 1, 1, 1, 1, 2, jpkm1 ) 
708         zdrhoz(ji,jj,jk) =   rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
709         zdzz  (ji,jj,jk) = - gde3w(ji  ,jj  ,jk) + gde3w(ji,jj,jk-1)
710      END_3D
711
712      !-------------------------------------------------------------------------
713      ! 2. compute harmonic averages for vertical differences using eq. 5.18
714      !-------------------------------------------------------------------------
715      zep = 1.e-15
716
717!! mb zdrho_k, zdz_k, zdrho_i, zdz_i, zdrho_j, zdz_j re-centred about the point (ji,jj,jk)
718      zdrho_k(:,:,:) = 0._wp
719      zdz_k  (:,:,:) = 0._wp
720
721      DO_3D( 1, 1, 1, 1, 2, jpk-2 ) 
722         cffw = 2._wp * zdrhoz(ji  ,jj  ,jk) * zdrhoz(ji,jj,jk+1)
723         IF( cffw > zep) THEN
724            zdrho_k(ji,jj,jk) = cffw / ( zdrhoz(ji,jj,jk) + zdrhoz(ji,jj,jk+1) )
725         ENDIF
726         zdz_k(ji,jj,jk) = 2._wp *   zdzz(ji,jj,jk) * zdzz(ji,jj,jk+1)   &
727            &                  / ( zdzz(ji,jj,jk) + zdzz(ji,jj,jk+1) )
728      END_3D
729
730      !----------------------------------------------------------------------------------
731      ! 3. apply boundary conditions at top and bottom using 5.36-5.37
732      !----------------------------------------------------------------------------------
733
734! mb for sea-ice shelves we will need to re-write this upper boundary condition in the same form as the lower boundary condition
735      zdrho_k(:,:,1) = aco_bc_vrt * ( rhd    (:,:,2) - rhd    (:,:,1) ) - bco_bc_vrt * zdrho_k(:,:,2)
736      zdz_k  (:,:,1) = aco_bc_vrt * (-gde3w(:,:,2) + gde3w(:,:,1) ) - bco_bc_vrt * zdz_k  (:,:,2)
737
738      DO_2D( 1, 1, 1, 1 )
739         IF ( mbkt(ji,jj)>1 ) THEN
740            iktb = mbkt(ji,jj)
741            zdrho_k(ji,jj,iktb) = aco_bc_vrt * (     rhd(ji,jj,iktb) -     rhd(ji,jj,iktb-1) ) - bco_bc_vrt * zdrho_k(ji,jj,iktb-1)
742            zdz_k  (ji,jj,iktb) = aco_bc_vrt * (-gde3w(ji,jj,iktb) + gde3w(ji,jj,iktb-1) ) - bco_bc_vrt * zdz_k  (ji,jj,iktb-1) 
743         END IF
744      END_2D
745
746      !--------------------------------------------------------------
747      ! 4. Compute side face integrals
748      !-------------------------------------------------------------
749
750!! ssh replaces e3w_n ; gde3w is a depth; the formulae involve heights 
751!! rho_k stores grav * FX / rho_0 
752
753      !--------------------------------------------------------------
754      ! 4. a) Upper half of top-most grid box, compute and store
755      !-------------------------------------------------------------
756! *** AY note: ssh(ji,jj,Kmm) + gde3w(ji,jj,1) = e3w(ji,jj,1,Kmm)
757      DO_2D( 0, 1, 0, 1)
758         z_rho_k(ji,jj,1) =  grav * ( ssh(ji,jj,Kmm) + gde3w(ji,jj,1) )                        & 
759            &                     * (  rhd(ji,jj,1)                                        &
760            &                     + 0.5_wp * (   rhd    (ji,jj,2) - rhd    (ji,jj,1) ) &
761            &                              * (   ssh   (ji,jj,Kmm) + gde3w(ji,jj,1) )          &
762            &                              / ( - gde3w(ji,jj,2) + gde3w(ji,jj,1) )  )
763      END_2D
764
765      !--------------------------------------------------------------
766      ! 4. b) Interior faces, compute and store
767      !-------------------------------------------------------------
768
769      DO_3D( 0, 1, 0, 1, 2, jpkm1 )
770         z_rho_k(ji,jj,jk) = zcoef0 * (   rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
771            &                       * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) )                                               &
772            &                       + z_grav_10 * (                                                                           &
773            &     (   zdrho_k  (ji,jj,jk) - zdrho_k  (ji,jj,jk-1) )                                                           &
774            &   * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) - z1_12 * ( zdz_k  (ji,jj,jk) + zdz_k  (ji,jj,jk-1) ) )             &
775            &   - ( zdz_k    (ji,jj,jk) - zdz_k    (ji,jj,jk-1) )                                                             &
776            &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( zdrho_k(ji,jj,jk) + zdrho_k(ji,jj,jk-1) ) )   &
777            &                             )
778      END_3D
779
780      !----------------------------------------------------------------------------------------
781      !  5. compute and store elementary horizontal differences in provisional arrays
782      !----------------------------------------------------------------------------------------
783
784      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
785         zdrhox(ji,jj,jk) =   rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
786         zdzx  (ji,jj,jk) = - gde3w(ji+1,jj  ,jk) + gde3w(ji,jj,jk  )
787         zdrhoy(ji,jj,jk) =   rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
788         zdzy  (ji,jj,jk) = - gde3w(ji  ,jj+1,jk) + gde3w(ji,jj,jk  )
789      END_3D
790
791      CALL lbc_lnk_multi( 'dynhpg', zdrhox, 'U', 1., zdzx, 'U', 1., zdrhoy, 'V', 1., zdzy, 'V', 1. ) 
792
793      !-------------------------------------------------------------------------
794      ! 6. compute harmonic averages using eq. 5.18
795      !-------------------------------------------------------------------------
796
797      DO_3D( 0, 1, 0, 1, 1, jpkm1 )
798         cffu = 2._wp * zdrhox(ji-1,jj  ,jk) * zdrhox(ji,jj,jk  )
799         IF( cffu > zep ) THEN
800            zdrho_i(ji,jj,jk) = cffu / ( zdrhox(ji-1,jj,jk) + zdrhox(ji,jj,jk) )
801         ELSE
802            zdrho_i(ji,jj,jk ) = 0._wp
803         ENDIF
804
805         cffx = 2._wp * zdzx  (ji-1,jj  ,jk) * zdzx  (ji,jj,jk  )
806         IF( cffx > zep ) THEN
807            zdz_i(ji,jj,jk) = cffx / ( zdzx(ji-1,jj,jk) + zdzx(ji,jj,jk) )
808         ELSE
809            zdz_i(ji,jj,jk) = 0._wp
810         ENDIF
811
812         cffv = 2._wp * zdrhoy(ji  ,jj-1,jk) * zdrhoy(ji,jj,jk  )
813         IF( cffv > zep ) THEN
814            zdrho_j(ji,jj,jk) = cffv / ( zdrhoy(ji,jj-1,jk) + zdrhoy(ji,jj,jk) )
815         ELSE
816            zdrho_j(ji,jj,jk) = 0._wp
817         ENDIF
818
819         cffy = 2._wp * zdzy  (ji  ,jj-1,jk) * zdzy  (ji,jj,jk  )
820         IF( cffy > zep ) THEN
821            zdz_j(ji,jj,jk) = cffy / ( zdzy(ji,jj-1,jk) + zdzy(ji,jj,jk) )
822         ELSE
823            zdz_j(ji,jj,jk) = 0._wp
824         ENDIF
825      END_3D
826     
827!!! Note that zdzx, zdzy, zdzz, zdrhox, zdrhoy and zdrhoz should NOT be used beyond this point     
828
829      !----------------------------------------------------------------------------------
830      ! 6B. apply boundary conditions at side boundaries using 5.36-5.37
831      !----------------------------------------------------------------------------------
832
833      DO jk = 1, jpkm1
834         zz_drho_i(:,:) = zdrho_i(:,:,jk)
835         zz_dz_i  (:,:) = zdz_i  (:,:,jk)
836         zz_drho_j(:,:) = zdrho_j(:,:,jk)
837         zz_dz_j  (:,:) = zdz_j  (:,:,jk)
838         DO_2D( 0, 1, 0, 1)
839            ! Walls coming from left: should check from 2 to jpi-1 (and jpj=2-jpj)
840            IF (ji < jpi) THEN
841               IF ( umask(ji,jj,jk) > 0.5_wp .AND. umask(ji-1,jj,jk) < 0.5_wp .AND. umask(ji+1,jj,jk) > 0.5_wp)  THEN 
842                  zz_drho_i(ji,jj) = aco_bc_hor * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) ) - bco_bc_hor * zdrho_i(ji+1,jj,jk) 
843                  zz_dz_i  (ji,jj) = aco_bc_hor * (-gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_i  (ji+1,jj,jk)
844               END IF
845            END IF
846            ! Walls coming from right: should check from 3 to jpi (and jpj=2-jpj)
847            IF (ji > 2) THEN
848               IF ( umask(ji,jj,jk) < 0.5_wp .AND. umask(ji-1,jj,jk) > 0.5_wp .AND. umask(ji-2,jj,jk) > 0.5_wp) THEN
849                  zz_drho_i(ji,jj) = aco_bc_hor * ( rhd    (ji,jj,jk) - rhd    (ji-1,jj,jk) ) - bco_bc_hor * zdrho_i(ji-1,jj,jk) 
850                  zz_dz_i  (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji-1,jj,jk) ) - bco_bc_hor * zdz_i  (ji-1,jj,jk)
851               END IF
852            END IF
853            ! Walls coming from left: should check from 2 to jpj-1 (and jpi=2-jpi)
854            IF (jj < jpj) THEN
855               IF ( vmask(ji,jj,jk) > 0.5_wp .AND. vmask(ji,jj-1,jk) < 0.5_wp .AND. vmask(ji,jj+1,jk) > 0.5_wp)  THEN
856                  zz_drho_j(ji,jj) = aco_bc_hor * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) ) - bco_bc_hor * zdrho_j(ji,jj+1,jk)
857                  zz_dz_j  (ji,jj) = aco_bc_hor * (-gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_j  (ji,jj+1,jk)
858               END IF
859            END IF 
860            ! Walls coming from right: should check from 3 to jpj (and jpi=2-jpi)
861            IF (jj > 2) THEN
862               IF ( vmask(ji,jj,jk) < 0.5_wp .AND. vmask(ji,jj-1,jk) > 0.5_wp .AND. vmask(ji,jj-2,jk) > 0.5_wp) THEN
863                  zz_drho_j(ji,jj) = aco_bc_hor * ( rhd    (ji,jj,jk) - rhd    (ji,jj-1,jk) ) - bco_bc_hor * zdrho_j(ji,jj-1,jk) 
864                  zz_dz_j  (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji,jj-1,jk) ) - bco_bc_hor * zdz_j  (ji,jj-1,jk)
865               END IF
866            END IF
867         END_2D
868         zdrho_i(:,:,jk) = zz_drho_i(:,:)
869         zdz_i  (:,:,jk) = zz_dz_i  (:,:)
870         zdrho_j(:,:,jk) = zz_drho_j(:,:)
871         zdz_j  (:,:,jk) = zz_dz_j  (:,:)
872      END DO
873
874      !--------------------------------------------------------------
875      ! 7. Calculate integrals on side faces 
876      !-------------------------------------------------------------
877
878      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
879! two -ve signs cancel in next two lines (within zcoef0 and because gde3w is a depth not a height)
880         z_rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                       &
881             &                    * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )                                   
882         IF ( umask(ji-1, jj, jk) > 0.5 .OR. umask(ji+1, jj, jk) > 0.5 ) THEN
883            z_rho_i(ji,jj,jk) = z_rho_i(ji,jj,jk) - z_grav_10 * (                                                               &
884             &     (   zdrho_i  (ji+1,jj,jk) - zdrho_i  (ji,jj,jk) )                                                            &
885             &   * ( - gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_i  (ji+1,jj,jk) + zdz_i  (ji,jj,jk) ) )              &
886             &   - (   zdz_i    (ji+1,jj,jk) - zdz_i    (ji,jj,jk) )                                                            &
887             &   * (   rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( zdrho_i(ji+1,jj,jk) + zdrho_i(ji,jj,jk) ) )  &
888             &                                               )
889         END IF
890 
891         z_rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                       &
892             &                    * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )                                 
893         IF ( vmask(ji, jj-1, jk) > 0.5 .OR. vmask(ji, jj+1, jk) > 0.5 ) THEN
894            z_rho_j(ji,jj,jk) = z_rho_j(ji,jj,jk) - z_grav_10 * (                                                               &
895             &     (   zdrho_j  (ji,jj+1,jk) - zdrho_j  (ji,jj,jk) )                                                            &
896             &   * ( - gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_j  (ji,jj+1,jk) + zdz_j  (ji,jj,jk) ) )              &
897             &   - (   zdz_j    (ji,jj+1,jk) - zdz_j    (ji,jj,jk) )                                                            &
898             &   * (   rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( zdrho_j(ji,jj+1,jk) + zdrho_j(ji,jj,jk) ) )  &
899             &                                                 )
900         END IF
901      END_3D
902
903      !--------------------------------------------------------------
904      ! 8. Integrate in the vertical   
905      !-------------------------------------------------------------
906      !
907      ! ---------------
908      !  Surface value
909      ! ---------------
910      DO_2D( 0, 0, 0, 0 )
911         zhpi(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji+1,jj  ,1) - z_rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
912         zhpj(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji  ,jj+1,1) - z_rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
913         IF( ln_wd_il ) THEN
914           zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
915           zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
916         ENDIF
917         ! add to the general momentum trend
918         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
919         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
920      END_2D
921
922      ! ----------------
923      !  interior value   (2=<jk=<jpkm1)
924      ! ----------------
925      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
926         ! hydrostatic pressure gradient along s-surfaces
927         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                                     &
928            &           + (  ( z_rho_k(ji,jj,jk) - z_rho_k(ji+1,jj,jk  ) )                     &
929            &              - ( z_rho_i(ji,jj,jk) - z_rho_i(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
930         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                                     &
931            &           + (  ( z_rho_k(ji,jj,jk) - z_rho_k(ji,jj+1,jk  ) )                     &
932            &               -( z_rho_j(ji,jj,jk) - z_rho_j(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
933         IF( ln_wd_il ) THEN
934           zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
935           zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
936         ENDIF
937         ! add to the general momentum trend
938         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
939         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
940      END_3D
941      !
942      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
943      !
944   END SUBROUTINE hpg_djc
945
946
947   SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
948      !!---------------------------------------------------------------------
949      !!                  ***  ROUTINE hpg_prj  ***
950      !!
951      !! ** Method  :   s-coordinate case.
952      !!      A Pressure-Jacobian horizontal pressure gradient method
953      !!      based on the constrained cubic-spline interpolation for
954      !!      all vertical coordinate systems
955      !!
956      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
957      !!----------------------------------------------------------------------
958      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
959      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
960      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
961      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
962      !!
963      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
964      REAL(wp) ::   zcoef0, znad                    ! local scalars
965      !
966      !! The local variables for the correction term
967      INTEGER  :: jk1, jis, jid, jjs, jjd
968      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
969      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
970      REAL(wp) :: zrhdt1
971      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
972      REAL(wp), DIMENSION(jpi,jpj)     ::   zpgu, zpgv   ! 2D workspace
973      REAL(wp), DIMENSION(jpi,jpj)     ::   zsshu_n, zsshv_n
974      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
975      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
976      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
977      !!----------------------------------------------------------------------
978      !
979      IF( kt == nit000 ) THEN
980         IF(lwp) WRITE(numout,*)
981         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
982         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
983      ENDIF
984
985      ! Local constant initialization
986      zcoef0 = - grav
987      znad = 1._wp
988      IF( ln_linssh )   znad = 1._wp
989      !
990      ! ---------------
991      !  Surface pressure gradient to be removed
992      ! ---------------
993      DO_2D( 0, 0, 0, 0 )
994         zpgu(ji,jj) = - grav * ( ssh(ji+1,jj,Kmm) - ssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
995         zpgv(ji,jj) = - grav * ( ssh(ji,jj+1,Kmm) - ssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
996      END_2D
997      !
998      IF( ln_wd_il ) THEN
999         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
1000         DO_2D( 0, 0, 0, 0 )
1001          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
1002               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
1003               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
1004               &                                                      > rn_wdmin1 + rn_wdmin2
1005          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (         &
1006               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
1007               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
1008
1009          IF(ll_tmp1) THEN
1010            zcpx(ji,jj) = 1.0_wp
1011          ELSE IF(ll_tmp2) THEN
1012            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
1013            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1014                        &    / (ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm)) )
1015           
1016             zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
1017          ELSE
1018            zcpx(ji,jj) = 0._wp
1019          END IF
1020   
1021          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
1022               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
1023               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
1024               &                                                      > rn_wdmin1 + rn_wdmin2
1025          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (      &
1026               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
1027               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1028
1029          IF(ll_tmp1) THEN
1030            zcpy(ji,jj) = 1.0_wp
1031          ELSE IF(ll_tmp2) THEN
1032            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
1033            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1034                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
1035             zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1036
1037            ELSE
1038               zcpy(ji,jj) = 0._wp
1039            ENDIF
1040         END_2D
1041         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
1042      ENDIF
1043
1044      ! Clean 3-D work arrays
1045      zhpi(:,:,:) = 0._wp
1046      zrhh(:,:,:) = rhd(:,:,:)
1047
1048      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1049      DO_2D( 1, 1, 1, 1 )
1050       jk = mbkt(ji,jj)
1051       IF(     jk <=  1   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1052       ELSEIF( jk ==  2   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1053       ELSEIF( jk < jpkm1 ) THEN
1054          DO jkk = jk+1, jpk
1055             zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk  ), gde3w(ji,jj,jkk-1),   &
1056                &                      gde3w(ji,jj,jkk-2), zrhh (ji,jj,jkk-1), zrhh(ji,jj,jkk-2))
1057          END DO
1058       ENDIF
1059      END_2D
1060
1061      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1062      DO_2D( 1, 1, 1, 1 )
1063         zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm)
1064      END_2D
1065
1066      DO_3D( 1, 1, 1, 1, 2, jpk )
1067         zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
1068      END_3D
1069
1070      fsp(:,:,:) = zrhh (:,:,:)
1071      xsp(:,:,:) = zdept(:,:,:)
1072
1073      ! Construct the vertical density profile with the
1074      ! constrained cubic spline interpolation
1075      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1076      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1077
1078      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1079      DO_2D( 0, 1, 0, 1 )
1080       zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1081          &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
1082
1083       ! assuming linear profile across the top half surface layer
1084       zhpi(ji,jj,1) =  0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
1085      END_2D
1086
1087      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1088      DO_3D( 0, 1, 0, 1, 2, jpkm1 )
1089      zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1090         &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1091         &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1092         &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1093      END_3D
1094
1095      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1096
1097      ! Prepare zsshu_n and zsshv_n
1098      DO_2D( 0, 0, 0, 0 )
1099!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1100!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1101!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1102!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1103!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1104!!gm not this:
1105       zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1106                      & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1107       zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1108                      & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1109      END_2D
1110
1111      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1.0_wp, zsshv_n, 'V', 1.0_wp )
1112
1113      DO_2D( 0, 0, 0, 0 )
1114       zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) ) 
1115       zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) )
1116      END_2D
1117
1118      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
1119      zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1120      zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1121      END_3D
1122
1123      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1124      zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1125      zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1126      END_3D
1127
1128      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1129      zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1130      zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1131      zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1132      zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1133      END_3D
1134
1135
1136      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1137      zpwes = 0._wp; zpwed = 0._wp
1138      zpnss = 0._wp; zpnsd = 0._wp
1139      zuijk = zu(ji,jj,jk)
1140      zvijk = zv(ji,jj,jk)
1141
1142      !!!!!     for u equation
1143      IF( jk <= mbku(ji,jj) ) THEN
1144         IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1145           jis = ji + 1; jid = ji
1146         ELSE
1147           jis = ji;     jid = ji +1
1148         ENDIF
1149
1150         ! integrate the pressure on the shallow side
1151         jk1 = jk
1152         DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1153           IF( jk1 == mbku(ji,jj) ) THEN
1154             zuijk = -zdept(jis,jj,jk1)
1155             EXIT
1156           ENDIF
1157           zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1158           zpwes = zpwes +                                    &
1159                integ_spline(zdept(jis,jj,jk1), zdeps,            &
1160                       asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1161                       csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1162           jk1 = jk1 + 1
1163         END DO
1164
1165         ! integrate the pressure on the deep side
1166         jk1 = jk
1167         DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1168           IF( jk1 == 1 ) THEN
1169             zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1170             zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1171                                               bsp(jid,jj,1),   csp(jid,jj,1), &
1172                                               dsp(jid,jj,1)) * zdeps
1173             zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1174             EXIT
1175           ENDIF
1176           zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1177           zpwed = zpwed +                                        &
1178                  integ_spline(zdeps,              zdept(jid,jj,jk1), &
1179                         asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1180                         csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1181           jk1 = jk1 - 1
1182         END DO
1183
1184         ! update the momentum trends in u direction
1185
1186         zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1187         IF( .NOT.ln_linssh ) THEN
1188           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1189              &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1190          ELSE
1191           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1192         ENDIF
1193         IF( ln_wd_il ) THEN
1194            zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1195            zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1196         ENDIF
1197         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2 - zpgu(ji,jj)) * umask(ji,jj,jk) 
1198      ENDIF
1199
1200      !!!!!     for v equation
1201      IF( jk <= mbkv(ji,jj) ) THEN
1202         IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1203           jjs = jj + 1; jjd = jj
1204         ELSE
1205           jjs = jj    ; jjd = jj + 1
1206         ENDIF
1207
1208         ! integrate the pressure on the shallow side
1209         jk1 = jk
1210         DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1211           IF( jk1 == mbkv(ji,jj) ) THEN
1212             zvijk = -zdept(ji,jjs,jk1)
1213             EXIT
1214           ENDIF
1215           zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1216           zpnss = zpnss +                                      &
1217                  integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1218                         asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1219                         csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1220           jk1 = jk1 + 1
1221         END DO
1222
1223         ! integrate the pressure on the deep side
1224         jk1 = jk
1225         DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1226           IF( jk1 == 1 ) THEN
1227             zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1228             zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1229                                               bsp(ji,jjd,1),   csp(ji,jjd,1), &
1230                                               dsp(ji,jjd,1) ) * zdeps
1231             zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1232             EXIT
1233           ENDIF
1234           zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1235           zpnsd = zpnsd +                                        &
1236                  integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1237                         asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1238                         csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1239           jk1 = jk1 - 1
1240         END DO
1241
1242
1243         ! update the momentum trends in v direction
1244
1245         zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1246         IF( .NOT.ln_linssh ) THEN
1247            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1248                    ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1249         ELSE
1250            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1251         ENDIF
1252         IF( ln_wd_il ) THEN
1253            zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1254            zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1255         ENDIF
1256
1257         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2 - zpgv(ji,jj)) * vmask(ji,jj,jk)
1258      ENDIF
1259         !
1260      END_3D
1261      !
1262      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1263      !
1264   END SUBROUTINE hpg_prj
1265
1266
1267   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1268      !!----------------------------------------------------------------------
1269      !!                 ***  ROUTINE cspline  ***
1270      !!
1271      !! ** Purpose :   constrained cubic spline interpolation
1272      !!
1273      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1274      !!
1275      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1276      !!----------------------------------------------------------------------
1277      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1278      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1279      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1280      !
1281      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1282      INTEGER  ::   jpi, jpj, jpkm1
1283      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1284      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1285      REAL(wp) ::   zdf(size(fsp,3))
1286      !!----------------------------------------------------------------------
1287      !
1288!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1289      jpi   = size(fsp,1)
1290      jpj   = size(fsp,2)
1291      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1292      !
1293      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1294         DO ji = 1, jpi
1295            DO jj = 1, jpj
1296           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1297           !    DO jk = 2, jpkm1-1
1298           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1299           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1300           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1301           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1302           !
1303           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1304           !
1305           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1306           !           zdf(jk) = 0._wp
1307           !       ELSE
1308           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1309           !       ENDIF
1310           !    END DO
1311
1312           !!Simply geometric average
1313               DO jk = 2, jpkm1-1
1314                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1315                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1316
1317                  IF(zdf1 * zdf2 <= 0._wp) THEN
1318                     zdf(jk) = 0._wp
1319                  ELSE
1320                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1321                  ENDIF
1322               END DO
1323
1324               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1325                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1326               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1327                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1328
1329               DO jk = 1, jpkm1 - 1
1330                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1331                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1332                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1333                 zddf1  = -2._wp * ztmp1 + ztmp2
1334                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1335                 zddf2  =  2._wp * ztmp1 - ztmp2
1336
1337                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1338                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1339                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1340                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1341                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1342                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1343                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1344                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1345                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1346               END DO
1347            END DO
1348         END DO
1349
1350      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1351         DO ji = 1, jpi
1352            DO jj = 1, jpj
1353               DO jk = 1, jpkm1-1
1354                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1355                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1356
1357                  dsp(ji,jj,jk) = 0._wp
1358                  csp(ji,jj,jk) = 0._wp
1359                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1360                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1361               END DO
1362            END DO
1363         END DO
1364         !
1365      ELSE
1366         CALL ctl_stop( 'invalid polynomial type in cspline' )
1367      ENDIF
1368      !
1369   END SUBROUTINE cspline
1370
1371
1372   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1373      !!----------------------------------------------------------------------
1374      !!                 ***  ROUTINE interp1  ***
1375      !!
1376      !! ** Purpose :   1-d linear interpolation
1377      !!
1378      !! ** Method  :   interpolation is straight forward
1379      !!                extrapolation is also permitted (no value limit)
1380      !!----------------------------------------------------------------------
1381      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1382      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1383      REAL(wp)             ::  zdeltx
1384      !!----------------------------------------------------------------------
1385      !
1386      zdeltx = xr - xl
1387      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1388         f = 0.5_wp * (fl + fr)
1389      ELSE
1390         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1391      ENDIF
1392      !
1393   END FUNCTION interp1
1394
1395
1396   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1397      !!----------------------------------------------------------------------
1398      !!                 ***  ROUTINE interp1  ***
1399      !!
1400      !! ** Purpose :   1-d constrained cubic spline interpolation
1401      !!
1402      !! ** Method  :  cubic spline interpolation
1403      !!
1404      !!----------------------------------------------------------------------
1405      REAL(wp), INTENT(in) ::  x, a, b, c, d
1406      REAL(wp)             ::  f ! value from the interpolation
1407      !!----------------------------------------------------------------------
1408      !
1409      f = a + x* ( b + x * ( c + d * x ) )
1410      !
1411   END FUNCTION interp2
1412
1413
1414   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1415      !!----------------------------------------------------------------------
1416      !!                 ***  ROUTINE interp1  ***
1417      !!
1418      !! ** Purpose :   Calculate the first order of derivative of
1419      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1420      !!
1421      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1422      !!
1423      !!----------------------------------------------------------------------
1424      REAL(wp), INTENT(in) ::  x, a, b, c, d
1425      REAL(wp)             ::  f ! value from the interpolation
1426      !!----------------------------------------------------------------------
1427      !
1428      f = b + x * ( 2._wp * c + 3._wp * d * x)
1429      !
1430   END FUNCTION interp3
1431
1432
1433   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1434      !!----------------------------------------------------------------------
1435      !!                 ***  ROUTINE interp1  ***
1436      !!
1437      !! ** Purpose :   1-d constrained cubic spline integration
1438      !!
1439      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1440      !!
1441      !!----------------------------------------------------------------------
1442      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1443      REAL(wp)             ::  za1, za2, za3
1444      REAL(wp)             ::  f                   ! integration result
1445      !!----------------------------------------------------------------------
1446      !
1447      za1 = 0.5_wp * b
1448      za2 = c / 3.0_wp
1449      za3 = 0.25_wp * d
1450      !
1451      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1452         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1453      !
1454   END FUNCTION integ_spline
1455
1456   !!======================================================================
1457END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.