New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/TRA/traadv.F90 @ 14381

Last change on this file since 14381 was 14381, checked in by techene, 3 years ago

#2605 : add advection velocity as input in advective flux form routines

  • Property svn:keywords set to Id
File size: 20.0 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_init  : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   ! TEMP: [tiling] This change not necessary after extended haloes development
21   USE domtile
22   USE domvvl         ! variable vertical scale factors
23   USE sbcwave        ! wave module
24   USE sbc_oce        ! surface boundary condition: ocean
25   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
26   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
27   USE traadv_fct_lf  ! FCT      scheme            (tra_adv_fct  routine - loop fusion version)
28   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
29   USE traadv_mus_lf  ! MUSCL    scheme            (tra_adv_mus  routine - loop fusion version)
30   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
31   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
32   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
33   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
34   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
35   USE trd_oce        ! trends: ocean variables
36   USE trdtra         ! trends manager: tracers
37   USE diaptr         ! Poleward heat transport
38   !
39   USE in_out_manager ! I/O manager
40   USE iom            ! I/O module
41   USE prtctl         ! Print control
42   USE lib_mpp        ! MPP library
43   USE timing         ! Timing
44
45   IMPLICIT NONE
46   PRIVATE
47
48   PUBLIC   tra_adv        ! called by step.F90
49   PUBLIC   tra_adv_init   ! called by nemogcm.F90
50
51   !                            !!* Namelist namtra_adv *
52   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
53   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
54   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
55   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
56   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
57   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
58   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
59   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
60   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
61   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
62
63   INTEGER ::   nadv             ! choice of the type of advection scheme
64   !                             ! associated indices:
65   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
66   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
67   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
68   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
69   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
70   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
71
72   !! * Substitutions
73#  include "do_loop_substitute.h90"
74#  include "domzgr_substitute.h90"
75   !!----------------------------------------------------------------------
76   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
77   !! $Id$
78   !! Software governed by the CeCILL license (see ./LICENSE)
79   !!----------------------------------------------------------------------
80CONTAINS
81
82   SUBROUTINE tra_adv( kt, Kbb, Kmm, pts, Krhs, pau, pav, paw )
83      !!----------------------------------------------------------------------
84      !!                  ***  ROUTINE tra_adv  ***
85      !!
86      !! ** Purpose :   compute the ocean tracer advection trend.
87      !!
88      !! ** Method  : - Update (uu(:,:,:,Krhs),vv(:,:,:,Krhs)) with the advection term following nadv
89      !!----------------------------------------------------------------------
90      INTEGER                                     , INTENT(in   ) ::   kt             ! ocean time-step index
91      INTEGER                                     , INTENT(in   ) ::   Kbb, Kmm, Krhs ! time level indices
92      REAL(wp), DIMENSION(:,:,:), OPTIONAL, TARGET, INTENT(in   ) ::   pau, pav, paw  ! advective velocity
93      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt)   , INTENT(inout) ::   pts            ! active tracers and RHS of tracer equation
94      !
95      INTEGER ::   ji, jj, jk   ! dummy loop index
96      REAL(wp), DIMENSION(:,:,:), POINTER ::   zptu, zptv, zptw
97      ! TEMP: [tiling] This change not necessary and can be A2D(nn_hls) if using XIOS (subdomain support)
98      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zuu, zvv, zww   ! 3D workspace
99      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE       ::   ztrdt, ztrds
100      ! TEMP: [tiling] This change not necessary after extra haloes development
101      LOGICAL ::   lskip
102      !!----------------------------------------------------------------------
103      !
104      IF( ln_timing )   CALL timing_start('tra_adv')
105      !
106      lskip = .FALSE.
107
108      ! TEMP: [tiling] These changes not necessary if using XIOS (subdomain support)
109      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
110         ALLOCATE( zuu(jpi,jpj,jpk), zvv(jpi,jpj,jpk), zww(jpi,jpj,jpk) )
111      ENDIF
112
113      ! TEMP: [tiling] These changes not necessary after extra haloes development (lbc_lnk removed from tra_adv_*) and if XIOS has subdomain support (ldf_eiv_dia)
114      IF( nadv /= np_CEN .OR. (nadv == np_CEN .AND. nn_cen_h == 4) .OR. ln_ldfeiv_dia )  THEN
115         IF( ln_tile ) THEN
116            IF( ntile == 1 ) THEN
117               CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
118            ELSE
119               lskip = .TRUE.
120            ENDIF
121         ENDIF
122      ENDIF
123      !
124      IF( .NOT. lskip ) THEN
125         !                                         !==  effective advective transport  ==!
126         !
127         IF( PRESENT( pau ) ) THEN     ! RK3: advective velocity (pau,pav,paw) /= advected velocity (uu,vv,ww)
128            zptu => pau(:,:,:)
129            zptv => pav(:,:,:)
130            zptw => paw(:,:,:)
131         ELSE                          ! MLF: advective velocity = (uu,vv,ww)
132            zptu => uu(:,:,:,Kmm)
133            zptv => vv(:,:,:,Kmm)
134            zptw => ww(:,:,:    )
135         ENDIF
136         !
137         IF( ln_wave .AND. ln_sdw )  THEN
138            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
139               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * ( zptu(ji,jj,jk) + usd(ji,jj,jk) )
140               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * ( zptv(ji,jj,jk) + vsd(ji,jj,jk) )
141               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ( zptw(ji,jj,jk) + wsd(ji,jj,jk) )
142            END_3D
143         ELSE
144            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
145               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * zptu(ji,jj,jk)               ! eulerian transport only
146               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * zptv(ji,jj,jk)
147               zww(ji,jj,jk) = e1e2t(ji,jj)                     * zptw(ji,jj,jk)
148            END_3D
149         ENDIF
150         !
151         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
152            DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
153               zuu(ji,jj,jk) = zuu(ji,jj,jk) + un_td(ji,jj,jk)
154               zvv(ji,jj,jk) = zvv(ji,jj,jk) + vn_td(ji,jj,jk)
155            END_3D
156         ENDIF
157         !
158         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
159            zuu(ji,jj,jpk) = 0._wp                                                      ! no transport trough the bottom
160            zvv(ji,jj,jpk) = 0._wp
161            zww(ji,jj,jpk) = 0._wp
162         END_2D
163         !
164         ! TEMP: [tiling] These changes not necessary if using XIOS (subdomain support)
165         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
166            &              CALL ldf_eiv_trp( kt, nit000, zuu(A2D(nn_hls),:), zvv(A2D(nn_hls),:), zww(A2D(nn_hls),:), &
167            &                                'TRA', Kmm, Krhs )   ! add the eiv transport (if necessary)
168         !
169         IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zuu(A2D(nn_hls),:), zvv(A2D(nn_hls),:), zww(A2D(nn_hls),:), &
170            &                                'TRA', Kmm       )   ! add the mle transport (if necessary)
171         !
172         ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
173         IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
174            CALL iom_put( "uocetr_eff", zuu )                                        ! output effective transport
175            CALL iom_put( "vocetr_eff", zvv )
176            CALL iom_put( "wocetr_eff", zww )
177         ENDIF
178         !
179   !!gm ???
180         ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
181         CALL dia_ptr( kt, Kmm, zvv(A2D(nn_hls),:) )                                    ! diagnose the effective MSF
182   !!gm ???
183         !
184
185         IF( l_trdtra )   THEN                    !* Save ta and sa trends
186            ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
187            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
188            ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
189         ENDIF
190         !
191         SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
192         !
193         CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
194            IF (nn_hls.EQ.2) CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kmm), 'T', 1. )
195            CALL tra_adv_cen    ( kt, nit000, 'TRA',         zuu, zvv, zww, Kmm, pts, jpts, Krhs, nn_cen_h, nn_cen_v )
196         CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
197            IF (nn_hls.EQ.2) THEN
198               CALL lbc_lnk_multi( 'traadv', pts(:,:,:,:,Kbb), 'T', 1., pts(:,:,:,:,Kmm), 'T', 1.)
199               CALL lbc_lnk_multi( 'traadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1., zww(:,:,:), 'W', 1.)
200#if defined key_loop_fusion
201               CALL tra_adv_fct_lf ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
202#else
203               CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
204#endif
205            ELSE
206               CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
207            END IF
208         CASE ( np_MUS )                                 ! MUSCL
209            IF (nn_hls.EQ.2) THEN
210                CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1.)
211#if defined key_loop_fusion
212                CALL tra_adv_mus_lf ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
213#else
214                CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
215#endif
216            ELSE
217                CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
218            END IF
219         CASE ( np_UBS )                                 ! UBS
220            IF (nn_hls.EQ.2) CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1.)
221            CALL tra_adv_ubs    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_ubs_v   )
222         CASE ( np_QCK )                                 ! QUICKEST
223            IF (nn_hls.EQ.2) THEN
224               CALL lbc_lnk_multi( 'traadv', zuu(:,:,:), 'U', -1., zvv(:,:,:), 'V', -1.)
225               CALL lbc_lnk( 'traadv', pts(:,:,:,:,Kbb), 'T', 1.)
226            END IF
227            CALL tra_adv_qck    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs )
228         !
229         END SELECT
230         !
231         IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
232            DO jk = 1, jpkm1
233               ztrdt(:,:,jk) = pts(:,:,jk,jp_tem,Krhs) - ztrdt(:,:,jk)
234               ztrds(:,:,jk) = pts(:,:,jk,jp_sal,Krhs) - ztrds(:,:,jk)
235            END DO
236            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_totad, ztrdt )
237            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_totad, ztrds )
238            DEALLOCATE( ztrdt, ztrds )
239         ENDIF
240
241         ! TEMP: [tiling] This change not necessary after extra haloes development (lbc_lnk removed from tra_adv_*) and if XIOS has subdomain support (ldf_eiv_dia)
242         IF( ln_tile .AND. ntile == 0 ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 1 )
243
244      ENDIF
245      !                                              ! print mean trends (used for debugging)
246      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' adv  - Ta: ', mask1=tmask, &
247         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
248
249      ! TEMP: [tiling] This change not necessary if using XIOS (subdomain support)
250      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
251         DEALLOCATE( zuu, zvv, zww )
252      ENDIF
253      !
254      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
255      !
256   END SUBROUTINE tra_adv
257
258
259   SUBROUTINE tra_adv_init
260      !!---------------------------------------------------------------------
261      !!                  ***  ROUTINE tra_adv_init  ***
262      !!
263      !! ** Purpose :   Control the consistency between namelist options for
264      !!              tracer advection schemes and set nadv
265      !!----------------------------------------------------------------------
266      INTEGER ::   ioptio, ios   ! Local integers
267      !
268      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
269         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
270         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
271         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
272         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
273         &                 ln_traadv_qck                             ! QCK
274      !!----------------------------------------------------------------------
275      !
276      !                                !==  Namelist  ==!
277      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
278901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist' )
279      !
280      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
281902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist' )
282      IF(lwm) WRITE( numond, namtra_adv )
283      !
284      IF(lwp) THEN                           ! Namelist print
285         WRITE(numout,*)
286         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
287         WRITE(numout,*) '~~~~~~~~~~~~'
288         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
289         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
290         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
291         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_cen_h
292         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_cen_v
293         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
294         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
295         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
296         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
297         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
298         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
299         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
300         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
301      ENDIF
302      !
303      !                                !==  Parameter control & set nadv ==!
304      ioptio = 0
305      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
306      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
307      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
308      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
309      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
310      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
311      !
312      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
313      !
314      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
315                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
316        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
317      ENDIF
318      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
319                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
320        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
321      ENDIF
322      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
323        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
324      ENDIF
325      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
326         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
327      ENDIF
328      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
329         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
330            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
331      ENDIF
332      !
333      !                                !==  Print the choice  ==!
334      IF(lwp) THEN
335         WRITE(numout,*)
336         SELECT CASE ( nadv )
337         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
338         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
339            &                                                                        ' Vertical   order: ', nn_cen_v
340         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
341            &                                                                        ' Vertical   order: ', nn_fct_v
342         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
343         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
344         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
345         END SELECT
346      ENDIF
347      !
348      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
349      !
350   END SUBROUTINE tra_adv_init
351
352  !!======================================================================
353END MODULE traadv
Note: See TracBrowser for help on using the repository browser.