New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zflx.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/TOP/PISCES/P4Z/p4zflx.F90 @ 15532

Last change on this file since 15532 was 15532, checked in by techene, 7 months ago

#2605 #2715 : version in dev (still buggy)

  • Property svn:keywords set to Id
File size: 17.8 KB
Line 
1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :   -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!             -   !  1998     (O. Aumont) additions
8   !!             -   !  1999     (C. Le Quere) modifications
9   !!            1.0  !  2004     (O. Aumont) modifications
10   !!            2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                 !  2011-02  (J. Simeon, J. Orr) Include total atm P correction
12   !!             4.2  !  2020     (J. ORR )  rhop is replaced by "in situ density" rhd
13   !!----------------------------------------------------------------------
14   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
15   !!   p4z_flx_init  :   Read the namelist
16   !!   p4z_patm      :   Read sfc atm pressure [atm] for each grid cell
17   !!----------------------------------------------------------------------
18   USE oce_trc        !  shared variables between ocean and passive tracers
19   USE trc            !  passive tracers common variables
20   USE sms_pisces     !  PISCES Source Minus Sink variables
21   USE p4zche         !  Chemical model
22   USE prtctl         !  print control for debugging
23   USE iom            !  I/O manager
24   USE fldread        !  read input fields
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_flx 
30   PUBLIC   p4z_flx_init 
31   PUBLIC   p4z_flx_alloc 
32
33   !                                 !!** Namelist  nampisext  **
34   REAL(wp)          ::   atcco2      !: pre-industrial atmospheric [co2] (ppm) 
35   LOGICAL           ::   ln_co2int   !: flag to read in a file and interpolate atmospheric pco2 or not
36   CHARACTER(len=34) ::   clname      !: filename of pco2 values
37   INTEGER           ::   nn_offset   !: Offset model-data start year (default = 0)
38
39   !!  Variables related to reading atmospheric CO2 time history   
40   INTEGER                                   ::   nmaxrec, numco2   !
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   atcco2h, years    !
42
43   !                                  !!* nampisatm namelist (Atmospheric PRessure) *
44   LOGICAL, PUBLIC ::   ln_presatm     !: ref. pressure: global mean Patm (F) or a constant (F)
45   LOGICAL, PUBLIC ::   ln_presatmco2  !: accounting for spatial atm CO2 in the compuation of carbon flux (T) or not (F)
46
47   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) ::   patm      ! atmospheric pressure at kt                 [N/m2]
48   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::   sf_patm   ! structure of input fields (file informations, fields read)
49   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::   sf_atmco2 ! structure of input fields (file informations, fields read)
50
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::  satmco2   !: atmospheric pco2
52
53   REAL(wp) ::   xconv  = 0.01_wp / 3600._wp   !: coefficients for conversion
54
55   !! * Substitutions
56#  include "do_loop_substitute.h90"
57#  include "domzgr_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
60   !! $Id$
61   !! Software governed by the CeCILL license (see ./LICENSE)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE p4z_flx ( kt, knt, Kbb, Kmm, Krhs )
66      !!---------------------------------------------------------------------
67      !!                     ***  ROUTINE p4z_flx  ***
68      !!
69      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
70      !!
71      !! ** Method  :
72      !!              - Include total atm P correction via Esbensen & Kushnir (1981)
73      !!              - Remove Wanninkhof chemical enhancement;
74      !!              - Add option for time-interpolation of atcco2.txt 
75      !!---------------------------------------------------------------------
76      INTEGER, INTENT(in) ::   kt, knt   !
77      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs      ! time level indices
78      !
79      INTEGER  ::   ji, jj, jm, iind, iindm1
80      REAL(wp) ::   ztc, ztc2, ztc3, ztc4, zws, zkgwan
81      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zrhd
82      REAL(wp) ::   zvapsw, zsal, zfco2, zxc2, xCO2approx, ztkel, zfugcoeff
83      REAL(wp) ::   zph, zdic, zsch_o2, zsch_co2
84      REAL(wp) ::   zyr_dec, zdco2dt
85      CHARACTER (len=25) ::   charout
86      REAL(wp), DIMENSION(jpi,jpj) ::   zkgco2, zkgo2, zh2co3, zoflx,  zpco2atm 
87      !!---------------------------------------------------------------------
88      !
89      IF( ln_timing )   CALL timing_start('p4z_flx')
90      !
91      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
92      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
93      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
94
95      IF( kt /= nit000 .AND. .NOT.l_co2cpl .AND. knt == 1 )   CALL p4z_patm( kt )   ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs
96
97      IF( ln_co2int .AND. .NOT.ln_presatmco2 .AND. .NOT.l_co2cpl ) THEN 
98         ! Linear temporal interpolation  of atmospheric pco2.  atcco2.txt has annual values.
99         ! Caveats: First column of .txt must be in years, decimal  years preferably.
100         ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy)
101         ! then the first atmospheric CO2 record read is at years(1)
102         zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp )
103         jm = 1
104         DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ;  jm = jm + 1 ;  END DO
105         iind = jm  ;   iindm1 = jm - 1
106         zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn )
107         atcco2  = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1)
108         satmco2(:,:) = atcco2 
109      ENDIF
110
111      IF( l_co2cpl )   satmco2(:,:) = atm_co2(:,:)
112
113      DO_2D( 1, 1, 1, 1 )
114         ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
115         zrhd = rhd(ji,jj,1) + 1._wp
116         zdic  = tr(ji,jj,1,jpdic,Kbb)
117         zph   = MAX( hi(ji,jj,1), 1.e-10 ) / ( zrhd + rtrn )
118         ! CALCULATE [H2CO3]
119         zh2co3(ji,jj) = zdic/(1. + ak13(ji,jj,1)/zph + ak13(ji,jj,1)*ak23(ji,jj,1)/zph**2)
120      END_2D
121
122      ! --------------
123      ! COMPUTE FLUXES
124      ! --------------
125
126      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
127      ! -------------------------------------------
128
129      DO_2D( 1, 1, 1, 1 )
130         ztc  = MIN( 35., ts(ji,jj,1,jp_tem,Kmm) )
131         ztc2 = ztc * ztc
132         ztc3 = ztc * ztc2 
133         ztc4 = ztc2 * ztc2 
134         ! Compute the schmidt Number both O2 and CO2
135         zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4
136         zsch_o2  = 1920.4 - 135.6  * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4
137         !  wind speed
138         zws  = wndm(ji,jj) * wndm(ji,jj)
139         ! Compute the piston velocity for O2 and CO2
140         zkgwan = 0.251 * zws
141         zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
142         ! compute gas exchange for CO2 and O2
143         zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
144         zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
145      END_2D
146
147
148      DO_2D( 1, 1, 1, 1 )
149         ztkel = tempis(ji,jj,1) + 273.15
150         zsal  = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35.
151         zvapsw    = EXP(24.4543 - 67.4509*(100.0/ztkel) - 4.8489*LOG(ztkel/100) - 0.000544*zsal)
152         zpco2atm(ji,jj) = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw )
153         zxc2      = ( 1.0 - zpco2atm(ji,jj) * 1E-6 )**2
154         zfugcoeff = EXP( patm(ji,jj) * (chemc(ji,jj,2) + 2.0 * zxc2 * chemc(ji,jj,3) )   &
155         &           / ( 82.05736 * ztkel ))
156         zfco2 = zpco2atm(ji,jj) * zfugcoeff
157
158         ! Compute CO2 flux for the sea and air
159         zfld = zfco2 * chemc(ji,jj,1) * zkgco2(ji,jj)  ! (mol/L) * (m/s)
160         zflu = zh2co3(ji,jj) * zkgco2(ji,jj)                                   ! (mol/L) (m/s) ?
161         oce_co2(ji,jj) = ( zfld - zflu ) * tmask(ji,jj,1) 
162         ! compute the trend
163         tr(ji,jj,1,jpdic,Krhs) = tr(ji,jj,1,jpdic,Krhs) + oce_co2(ji,jj) * rfact2 / e3t(ji,jj,1,Kmm)
164
165         ! Compute O2 flux
166         zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * zkgo2(ji,jj)          ! (mol/L) * (m/s)
167         zflu16 = tr(ji,jj,1,jpoxy,Kbb) * zkgo2(ji,jj)
168         zoflx(ji,jj) = ( zfld16 - zflu16 ) * tmask(ji,jj,1)
169         tr(ji,jj,1,jpoxy,Krhs) = tr(ji,jj,1,jpoxy,Krhs) + zoflx(ji,jj) * rfact2 / e3t(ji,jj,1,Kmm)
170      END_2D
171
172      IF( iom_use("tcflx") .OR. iom_use("tcflxcum") .OR. kt == nitrst   &
173         &                 .OR. (ln_check_mass .AND. kt == nitend) )    &
174         t_oce_co2_flx  = glob_sum( 'p4zflx', oce_co2(:,:) * e1e2t(:,:) * 1000. )                    !  Total Flux of Carbon
175      t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx       !  Cumulative Total Flux of Carbon
176!      t_atm_co2_flx     = glob_sum( 'p4zflx', satmco2(:,:) * e1e2t(:,:) )       ! Total atmospheric pCO2
177      t_atm_co2_flx     =  atcco2      ! Total atmospheric pCO2
178 
179      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
180         WRITE(charout, FMT="('flx ')")
181         CALL prt_ctl_info( charout, cdcomp = 'top' )
182         CALL prt_ctl(tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm)
183      ENDIF
184
185      IF( lk_iomput .AND. knt == nrdttrc ) THEN
186         CALL iom_put( "AtmCo2"  , satmco2(:,:) * tmask(:,:,1) )   ! Atmospheric CO2 concentration
187         CALL iom_put( "Cflx"    , oce_co2(:,:) * 1000. ) 
188         CALL iom_put( "Oflx"    , zoflx(:,:) * 1000.  )
189         CALL iom_put( "Kg"      , zkgco2(:,:) * tmask(:,:,1)  )
190         CALL iom_put( "Dpco2"   , ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) )
191         CALL iom_put( "pCO2sea" , ( zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) )
192         CALL iom_put( "Dpo2"    , ( atcox * patm(:,:) - atcox * tr(:,:,1,jpoxy,Kbb) / ( chemo2(:,:,1) + rtrn ) ) * tmask(:,:,1) )
193         CALL iom_put( "tcflx"   , t_oce_co2_flx     )   ! molC/s
194         CALL iom_put( "tcflxcum", t_oce_co2_flx_cum )   ! molC
195      ENDIF
196      !
197      IF( ln_timing )   CALL timing_stop('p4z_flx')
198      !
199   END SUBROUTINE p4z_flx
200
201
202   SUBROUTINE p4z_flx_init
203      !!----------------------------------------------------------------------
204      !!                  ***  ROUTINE p4z_flx_init  ***
205      !!
206      !! ** Purpose :   Initialization of atmospheric conditions
207      !!
208      !! ** Method  :   Read the nampisext namelist and check the parameters
209      !!      called at the first timestep (nittrc000)
210      !!
211      !! ** input   :   Namelist nampisext
212      !!----------------------------------------------------------------------
213      INTEGER ::   jm, ios   ! Local integer
214      !!
215      NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset
216      !!----------------------------------------------------------------------
217      IF(lwp) THEN
218         WRITE(numout,*)
219         WRITE(numout,*) ' p4z_flx_init : atmospheric conditions for air-sea flux calculation'
220         WRITE(numout,*) ' ~~~~~~~~~~~~'
221      ENDIF
222      !
223      READ  ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901)
224901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisext in reference namelist' )
225      READ  ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 )
226902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisext in configuration namelist' )
227      IF(lwm) WRITE ( numonp, nampisext )
228      !
229      IF(lwp) THEN                         ! control print
230         WRITE(numout,*) '   Namelist : nampisext --- parameters for air-sea exchange'
231         WRITE(numout,*) '      reading in the atm pCO2 file or constant value   ln_co2int =', ln_co2int
232      ENDIF
233      !
234      CALL p4z_patm( nit000 )
235      !
236      IF( .NOT.ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
237         IF(lwp) THEN                         ! control print
238            WRITE(numout,*) '         Constant Atmospheric pCO2 value               atcco2    =', atcco2
239         ENDIF
240         satmco2(:,:)  = atcco2      ! Initialisation of atmospheric pco2
241      ELSEIF( ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
242         IF(lwp)  THEN
243            WRITE(numout,*) '         Constant Atmospheric pCO2 value               atcco2    =', atcco2
244            WRITE(numout,*) '         Atmospheric pCO2 value  from file             clname    =', TRIM( clname )
245            WRITE(numout,*) '         Offset model-data start year                  nn_offset =', nn_offset
246         ENDIF
247         CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp )
248         jm = 0                      ! Count the number of record in co2 file
249         DO
250           READ(numco2,*,END=100) 
251           jm = jm + 1
252         END DO
253 100     nmaxrec = jm - 1 
254         ALLOCATE( years  (nmaxrec) )   ;   years  (:) = 0._wp
255         ALLOCATE( atcco2h(nmaxrec) )   ;   atcco2h(:) = 0._wp
256         !
257         REWIND(numco2)
258         DO jm = 1, nmaxrec          ! get  xCO2 data
259            READ(numco2, *)  years(jm), atcco2h(jm)
260            IF(lwp) WRITE(numout, '(f6.0,f7.2)')  years(jm), atcco2h(jm)
261         END DO
262         CLOSE(numco2)
263      ELSEIF( .NOT.ln_co2int .AND. ln_presatmco2 ) THEN
264         IF(lwp) WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
265      ELSE
266         IF(lwp) WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
267      ENDIF
268      !
269      oce_co2(:,:)  = 0._wp                ! Initialization of Flux of Carbon
270      t_oce_co2_flx = 0._wp
271      t_atm_co2_flx = 0._wp
272      !
273   END SUBROUTINE p4z_flx_init
274
275
276   SUBROUTINE p4z_patm( kt )
277      !!----------------------------------------------------------------------
278      !!                  ***  ROUTINE p4z_atm  ***
279      !!
280      !! ** Purpose :   Read and interpolate the external atmospheric sea-level pressure
281      !! ** Method  :   Read the files and interpolate the appropriate variables
282      !!
283      !!----------------------------------------------------------------------
284      INTEGER, INTENT(in) ::   kt   ! ocean time step
285      !
286      INTEGER            ::   ierr, ios   ! Local integer
287      CHARACTER(len=100) ::   cn_dir      ! Root directory for location of ssr files
288      TYPE(FLD_N)        ::   sn_patm     ! informations about the fields to be read
289      TYPE(FLD_N)        ::   sn_atmco2   ! informations about the fields to be read
290      !!
291      NAMELIST/nampisatm/ ln_presatm, ln_presatmco2, sn_patm, sn_atmco2, cn_dir
292      !!----------------------------------------------------------------------
293      !
294      IF( kt == nit000 ) THEN    !==  First call kt=nittrc000  ==!
295         !
296         IF(lwp) THEN
297            WRITE(numout,*)
298            WRITE(numout,*) ' p4z_patm : sea-level atmospheric pressure'
299            WRITE(numout,*) ' ~~~~~~~~'
300         ENDIF
301         !
302         READ  ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901)
303901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist' )
304         READ  ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 )
305902      IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisatm in configuration namelist' )
306         IF(lwm) WRITE ( numonp, nampisatm )
307         !
308         !
309         IF(lwp) THEN                                 !* control print
310            WRITE(numout,*) '   Namelist : nampisatm --- Atmospheric Pressure as external forcing'
311            WRITE(numout,*) '      constant atmopsheric pressure (F) or from a file (T)  ln_presatm    = ', ln_presatm
312            WRITE(numout,*) '      spatial atmopsheric CO2 for flux calcs                ln_presatmco2 = ', ln_presatmco2
313         ENDIF
314         !
315         IF( ln_presatm ) THEN
316            ALLOCATE( sf_patm(1), STAT=ierr )           !* allocate and fill sf_patm (forcing structure) with sn_patm
317            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' )
318            !
319            CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' )
320                                   ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1)   )
321            IF( sn_patm%ln_tint )  ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) )
322         ENDIF
323         !                                         
324         IF( ln_presatmco2 ) THEN
325            ALLOCATE( sf_atmco2(1), STAT=ierr )           !* allocate and fill sf_atmco2 (forcing structure) with sn_atmco2
326            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_atmco2 structure' )
327            !
328            CALL fld_fill( sf_atmco2, (/ sn_atmco2 /), cn_dir, 'p4z_flx', 'Atmospheric co2 partial pressure ', 'nampisatm' )
329                                   ALLOCATE( sf_atmco2(1)%fnow(jpi,jpj,1)   )
330            IF( sn_atmco2%ln_tint )  ALLOCATE( sf_atmco2(1)%fdta(jpi,jpj,1,2) )
331         ENDIF
332         !
333         IF( .NOT.ln_presatm )   patm(:,:) = 1._wp    ! Initialize patm if no reading from a file
334         !
335      ENDIF
336      !
337      IF( ln_presatm ) THEN
338         CALL fld_read( kt, 1, sf_patm )               !* input Patm provided at kt + 1/2
339         patm(:,:) = sf_patm(1)%fnow(:,:,1)                        ! atmospheric pressure
340      ENDIF
341      !
342      IF( ln_presatmco2 ) THEN
343         CALL fld_read( kt, 1, sf_atmco2 )               !* input atmco2 provided at kt + 1/2
344         satmco2(:,:) = sf_atmco2(1)%fnow(:,:,1)                        ! atmospheric pressure
345      ELSE
346         satmco2(:,:) = atcco2    ! Initialize atmco2 if no reading from a file
347      ENDIF
348      !
349   END SUBROUTINE p4z_patm
350
351
352   INTEGER FUNCTION p4z_flx_alloc()
353      !!----------------------------------------------------------------------
354      !!                     ***  ROUTINE p4z_flx_alloc  ***
355      !!----------------------------------------------------------------------
356      ALLOCATE( satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc )
357      !
358      IF( p4z_flx_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_flx_alloc : failed to allocate arrays' )
359      !
360   END FUNCTION p4z_flx_alloc
361
362   !!======================================================================
363END MODULE p4zflx
Note: See TracBrowser for help on using the repository browser.