New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcsbc.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/TOP/TRP – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/TOP/TRP/trcsbc.F90 @ 15373

Last change on this file since 15373 was 15373, checked in by techene, 12 months ago

#2715 RK3: adapt trc surface boundary management

  • Property svn:keywords set to Id
File size: 18.6 KB
Line 
1MODULE trcsbc
2   !!==============================================================================
3   !!                       ***  MODULE  trcsbc  ***
4   !! Ocean passive tracers:  surface boundary condition
5   !!======================================================================
6   !! History :  8.2  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            9.0  !  2004-03  (C. Ethe)  adapted for passive tracers
10   !!                 !  2006-08  (C. Deltel) Diagnose ML trends for passive tracers
11   !!==============================================================================
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_sbc      : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE par_trc        ! need jptra, number of passive tracers
19   USE oce_trc        ! ocean dynamics and active tracers variables
20   USE trc            ! ocean  passive tracers variables
21   USE prtctl         ! Print control for debbuging
22   USE iom
23   USE trd_oce
24   USE trdtra
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   trc_sbc       ! routine called by trctrp.F90
30   PUBLIC   trc_sbc_RK3   ! routine called by stprk3_stg.F90
31
32   !! * Substitutions
33#  include "do_loop_substitute.h90"
34#  include "domzgr_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE trc_sbc ( kt, Kmm, ptr, Krhs )
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE trc_sbc  ***
45      !!                   
46      !! ** Purpose :   Compute the tracer surface boundary condition trend of
47      !!      (concentration/dilution effect) and add it to the general
48      !!       trend of tracer equations.
49      !!
50      !! ** Method :
51      !!      * concentration/dilution effect:
52      !!            The surface freshwater flux modify the ocean volume
53      !!         and thus the concentration of a tracer as :
54      !!            tr(Krhs) = tr(Krhs) + emp * tr(Kmm) / e3t_   for k=1
55      !!         where emp, the surface freshwater budget (evaporation minus
56      !!         precipitation ) given in kg/m2/s is divided
57      !!         by 1035 kg/m3 (density of ocean water) to obtain m/s.
58      !!
59      !! ** Action  : - Update the 1st level of tr(:,:,:,:,Krhs) with the trend associated
60      !!                with the tracer surface boundary condition
61      !!
62      !!----------------------------------------------------------------------
63      INTEGER,                                    INTENT(in   ) :: kt        ! ocean time-step index
64      INTEGER,                                    INTENT(in   ) :: Kmm, Krhs ! time level indices
65      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr       ! passive tracers and RHS of tracer equation
66      !
67      INTEGER  ::   ji, jj, jn                      ! dummy loop indices
68      REAL(wp) ::   zse3t, zrtrn, zfact     ! local scalars
69      REAL(wp) ::   zftra, zdtra, ztfx, ztra   !   -      -
70      CHARACTER (len=22) :: charout
71      REAL(wp), DIMENSION(jpi,jpj)   ::   zsfx
72      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrtrd
73      !!---------------------------------------------------------------------
74      !
75      IF( ln_timing )   CALL timing_start('trc_sbc')
76      !
77      ! Allocate temporary workspace
78      IF( l_trdtrc )  ALLOCATE( ztrtrd(jpi,jpj,jpk) )
79      !
80      zrtrn = 1.e-15_wp
81
82      IF( kt == nittrc000 ) THEN
83         IF(lwp) WRITE(numout,*)
84         IF(lwp) WRITE(numout,*) 'trc_sbc : Passive tracers surface boundary condition'
85         IF(lwp) WRITE(numout,*) '~~~~~~~ '
86         !
87#if ! defined key_RK3
88         IF( ln_rsttr .AND. .NOT.ln_top_euler .AND.   &                     ! Restart: read in restart  file
89            iom_varid( numrtr, 'sbc_'//TRIM(ctrcnm(1))//'_b', ldstop = .FALSE. ) > 0 ) THEN
90            IF(lwp) WRITE(numout,*) '          nittrc000-1 surface tracer content forcing fields read in the restart file'
91            zfact = 0.5_wp
92            DO jn = 1, jptra
93               CALL iom_get( numrtr, jpdom_auto, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc_b(:,:,jn) )   ! before tracer content sbc
94            END DO
95         ELSE                                         ! No restart or restart not found: Euler forward time stepping
96           zfact = 1._wp
97           sbc_trc_b(:,:,:) = 0._wp
98         ENDIF
99      ELSE                                         ! Swap of forcing fields
100         IF( ln_top_euler ) THEN
101            zfact = 1._wp
102            sbc_trc_b(:,:,:) = 0._wp
103         ELSE
104            zfact = 0.5_wp
105            sbc_trc_b(:,:,:) = sbc_trc(:,:,:)
106         ENDIF
107         !
108#endif
109      ENDIF
110
111      ! Coupling online : river runoff is added to the horizontal divergence (hdiv) in the subroutine sbc_rnf_div
112      ! one only consider the concentration/dilution effect due to evaporation minus precipitation + freezing/melting of sea-ice
113      ! Coupling offline : runoff are in emp which contains E-P-R
114      !
115      IF( .NOT.ln_linssh ) THEN  ! online coupling with vvl
116         zsfx(:,:) = 0._wp
117      ELSE                                      ! online coupling free surface or offline with free surface
118         zsfx(:,:) = emp(:,:)
119      ENDIF
120
121      ! 0. initialization
122      SELECT CASE ( nn_ice_tr )
123
124      CASE ( -1 ) ! No tracers in sea ice (null concentration in sea ice)
125         !
126         DO jn = 1, jptra
127            DO_2D( 0, 0, 0, 1 )
128               sbc_trc(ji,jj,jn) = zsfx(ji,jj) * r1_rho0 * ptr(ji,jj,1,jn,Kmm)
129            END_2D
130         END DO
131         !
132      CASE ( 0 )  ! Same concentration in sea ice and in the ocean
133         !
134         DO jn = 1, jptra
135            DO_2D( 0, 0, 0, 1 )
136               sbc_trc(ji,jj,jn) = ( zsfx(ji,jj) + fmmflx(ji,jj) ) * r1_rho0 * ptr(ji,jj,1,jn,Kmm)
137            END_2D
138         END DO
139         !
140      CASE ( 1 )  ! Specific treatment of sea ice fluxes with an imposed concentration in sea ice
141         !
142         DO jn = 1, jptra
143            DO_2D( 0, 0, 0, 1 )
144               ! tracer flux at the ice/ocean interface (tracer/m2/s)
145               zftra = - trc_i(ji,jj,jn) * fmmflx(ji,jj) ! uptake of tracer in the sea ice
146               !                                         ! only used in the levitating sea ice case
147               ! tracer flux only       : add concentration dilution term in net tracer flux, no F-M in volume flux
148               ! tracer and mass fluxes : no concentration dilution term in net tracer flux, F-M term in volume flux
149               ztfx  = zftra                        ! net tracer flux
150               !
151               zdtra = r1_rho0 * ( ztfx + ( zsfx(ji,jj) + fmmflx(ji,jj) ) * ptr(ji,jj,1,jn,Kmm) ) 
152               IF ( zdtra < 0. ) THEN
153                  zdtra  = MAX(zdtra, -ptr(ji,jj,1,jn,Kmm) * e3t(ji,jj,1,Kmm) / rDt_trc )   ! avoid negative concentrations to arise
154               ENDIF
155               sbc_trc(ji,jj,jn) =  zdtra 
156            END_2D
157         END DO
158      END SELECT
159      !
160      CALL lbc_lnk( 'trcsbc', sbc_trc(:,:,:), 'T', 1.0_wp )
161      !                                       Concentration dilution effect on tracers due to evaporation & precipitation
162      DO jn = 1, jptra
163         !
164         IF( l_trdtrc )   ztrtrd(:,:,:) = ptr(:,:,:,jn,Krhs)  ! save trends
165         !
166         DO_2D( 0, 0, 0, 1 )
167#if defined key_RK3
168            zse3t = 1._wp / e3t(ji,jj,1,Kmm)
169            ptr(ji,jj,1,jn,Krhs) = ptr(ji,jj,1,jn,Krhs) + sbc_trc(ji,jj,jn) * zse3t
170#else
171            zse3t = zfact / e3t(ji,jj,1,Kmm)
172            ptr(ji,jj,1,jn,Krhs) = ptr(ji,jj,1,jn,Krhs) + ( sbc_trc_b(ji,jj,jn) + sbc_trc(ji,jj,jn) ) * zse3t
173#endif
174         END_2D
175         !
176         IF( l_trdtrc ) THEN
177            ztrtrd(:,:,:) = ptr(:,:,:,jn,Krhs) - ztrtrd(:,:,:)
178            CALL trd_tra( kt, Kmm, Krhs, 'TRC', jn, jptra_nsr, ztrtrd )
179         END IF
180         !                                                       ! ===========
181      END DO                                                     ! tracer loop
182      !                                                          ! ===========
183      !
184#if ! defined key_RK3
185      !                                           Write in the tracer restar  file
186      !                                          *******************************
187      IF( lrst_trc .AND. .NOT.ln_top_euler ) THEN
188         IF(lwp) WRITE(numout,*)
189         IF(lwp) WRITE(numout,*) 'sbc : ocean surface tracer content forcing fields written in tracer restart file ',   &
190            &                    'at it= ', kt,' date= ', ndastp
191         IF(lwp) WRITE(numout,*) '~~~~'
192         DO jn = 1, jptra
193            CALL iom_rstput( kt, nitrst, numrtw, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc(:,:,jn) )
194         END DO
195      ENDIF
196#endif
197      !
198      IF( sn_cfctl%l_prttrc )   THEN
199         WRITE(charout, FMT="('sbc ')") ;  CALL prt_ctl_info( charout, cdcomp = 'top' )
200                                           CALL prt_ctl( tab4d_1=ptr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm, clinfo3='trd' )
201      ENDIF
202      IF( l_trdtrc )  DEALLOCATE( ztrtrd )
203      !
204      IF( ln_timing )   CALL timing_stop('trc_sbc')
205      !
206   END SUBROUTINE trc_sbc
207
208!!st
209   SUBROUTINE trc_sbc_RK3 ( kt, Kmm, ptr, Krhs, kstg )
210      !!----------------------------------------------------------------------
211      !!                  ***  ROUTINE trc_sbc_RK3  ***
212      !!                   
213      !! ** Purpose :   Compute the tracer surface boundary condition trend of
214      !!      (concentration/dilution effect) and add it to the general
215      !!       trend of tracer equations.
216      !!
217      !! ** Method :
218      !!      * concentration/dilution effect:
219      !!            The surface freshwater flux modify the ocean volume
220      !!         and thus the concentration of a tracer as :
221      !!            tr(Krhs) = tr(Krhs) + emp * tr(Kmm) / e3t_   for k=1
222      !!         where emp, the surface freshwater budget (evaporation minus
223      !!         precipitation ) given in kg/m2/s is divided
224      !!         by 1035 kg/m3 (density of ocean water) to obtain m/s.
225      !!
226      !! ** Action  : - Update the 1st level of tr(:,:,:,:,Krhs) with the trend associated
227      !!                with the tracer surface boundary condition
228      !!
229      !!----------------------------------------------------------------------
230      INTEGER                                   , INTENT(in   ) ::   kt, Kmm, Krhs   ! ocean time-step and time-level indices
231      INTEGER                                   , INTENT(in   ) ::   kstg            ! RK3 stage index
232      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) ::   ptr       ! passive tracers and RHS of tracer equation
233      !
234      INTEGER  ::   ji, jj, jn                      ! dummy loop indices
235      REAL(wp) ::   zse3t, zrtrn, zfact     ! local scalars
236      REAL(wp) ::   zftra, zdtra, ztfx, ztra   !   -      -
237      CHARACTER (len=22) :: charout
238      REAL(wp), DIMENSION(jpi,jpj)   ::   zmfx
239      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrtrd
240      !!---------------------------------------------------------------------
241      !
242      IF( ln_timing )   CALL timing_start('trc_sbc_RK3')
243      !
244      ! Allocate temporary workspace
245      IF( l_trdtrc )  ALLOCATE( ztrtrd(jpi,jpj,jpk) )
246      !
247      IF( kt == nittrc000 ) THEN
248         IF(lwp) WRITE(numout,*)
249         IF(lwp) WRITE(numout,*) 'trc_sbc_RK3 : Passive tracers surface boundary condition'
250         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
251      ENDIF
252!!st: not sure of the way to deal about this
253      SELECT CASE( kstg )
254      !
255      CASE( 1 , 2 )                       !=  stage 1 and 2  =!   only in non linear ssh
256         !
257         IF( .NOT.ln_linssh ) THEN           !* only passive tracer fluxes associated with mass fluxes
258            !
259            SELECT CASE ( nn_ice_tr )
260               !
261            CASE ( -1 , 0 , 1 )                      ! no passive tracer concentration modification due to ssh variation
262               !
263!!st emp includes fmm see iceupdate.F90
264               DO jn = 1, jptra
265                  DO_2D( 0, 0, 0, 1 )
266                     sbc_trc(ji,jj,jn) =  - emp(ji,jj) * ptr(ji,jj,1,jn,Kmm) * r1_rho0
267                  END_2D
268               END DO
269               !
270            END SELECT
271            !
272         ENDIF
273         !
274      CASE( 3 )
275!!st copy of existing code
276         !
277         IF( .NOT.ln_linssh ) THEN    !!st concentration/dilution effect due to volume variation
278            SELECT CASE ( nn_ice_tr )
279            !
280            CASE ( 0 )  ! Same concentration in sea ice and in the ocean
281               !
282               DO jn = 1, jptra
283                  DO_2D( 0, 0, 0, 1 )
284                     sbc_trc(ji,jj,jn) =  - fmmflx(ji,jj) * r1_rho0 * ptr(ji,jj,1,jn,Kmm)
285                  END_2D
286               END DO
287               !
288            CASE ( 1 )  ! Specific treatment of sea ice fluxes with an imposed concentration in sea ice
289               !
290               DO jn = 1, jptra
291                  DO_2D( 0, 0, 0, 1 )
292                  ! tracer flux at the ice/ocean interface (tracer/m2/s)
293                  zftra = - trc_i(ji,jj,jn) * fmmflx(ji,jj) ! uptake of tracer in the sea ice
294                  !                                         ! only used in the levitating sea ice case
295                  ! tracer flux only       : add concentration dilution term in net tracer flux, no F-M in volume flux
296                  ! tracer and mass fluxes : no concentration dilution term in net tracer flux, F-M term in volume flux
297                  ztfx  = zftra                        ! net tracer flux
298                  !
299                  zdtra = r1_rho0 * ( ztfx -  fmmflx(ji,jj) * ptr(ji,jj,1,jn,Kmm) ) 
300                  IF ( zdtra < 0. ) THEN
301                     zdtra  = MAX(zdtra, -ptr(ji,jj,1,jn,Kmm) * e3t(ji,jj,1,Kmm) / rDt_trc )   ! avoid negative concentrations to arise
302                  ENDIF
303                  sbc_trc(ji,jj,jn) =  zdtra 
304                  END_2D
305               END DO
306               !
307            END SELECT
308         ELSE                         !linear ssh !!st need to mimic concentration/dilution effect since no volume variation
309            SELECT CASE ( nn_ice_tr )
310            !
311            CASE ( -1 ) ! No tracers in sea ice (null concentration in sea ice)
312               !
313               DO jn = 1, jptra
314                  DO_2D( 0, 0, 0, 1 )
315                  sbc_trc(ji,jj,jn) = emp(ji,jj) * r1_rho0 * ptr(ji,jj,1,jn,Kmm)
316                  END_2D
317               END DO
318               !
319            CASE ( 0 )  ! Same concentration in sea ice and in the ocean
320               !
321               DO jn = 1, jptra
322                  DO_2D( 0, 0, 0, 1 )
323                     sbc_trc(ji,jj,jn) = ( emp(ji,jj) - fmmflx(ji,jj) ) * r1_rho0 * ptr(ji,jj,1,jn,Kmm)
324                  END_2D
325               END DO
326               !
327            CASE ( 1 )  ! Specific treatment of sea ice fluxes with an imposed concentration in sea ice
328               !
329               DO jn = 1, jptra
330                  DO_2D( 0, 0, 0, 1 )
331                  ! tracer flux at the ice/ocean interface (tracer/m2/s)
332                  zftra = - trc_i(ji,jj,jn) * fmmflx(ji,jj) ! uptake of tracer in the sea ice
333                  !                                         ! only used in the levitating sea ice case
334                  ! tracer flux only       : add concentration dilution term in net tracer flux, no F-M in volume flux
335                  ! tracer and mass fluxes : no concentration dilution term in net tracer flux, F-M term in volume flux
336                  ztfx  = zftra                        ! net tracer flux
337                  !
338                  zdtra = r1_rho0 * ( ztfx +  ( emp(ji,jj) - fmmflx(ji,jj) ) * ptr(ji,jj,1,jn,Kmm) ) 
339                  IF ( zdtra < 0. ) THEN
340                     zdtra  = MAX(zdtra, -ptr(ji,jj,1,jn,Kmm) * e3t(ji,jj,1,Kmm) / rDt_trc )   ! avoid negative concentrations to arise
341                  ENDIF
342                  sbc_trc(ji,jj,jn) =  zdtra 
343                  END_2D
344               END DO
345               !
346            END SELECT
347            !
348         ENDIF
349         !
350         !
351         !
352      END SELECT
353      !
354      CALL lbc_lnk( 'trcsbc', sbc_trc(:,:,:), 'T', 1.0_wp )
355      !                                       Concentration dilution effect on tracers due to evaporation & precipitation
356      DO jn = 1, jptra
357         !
358         IF( l_trdtrc )   ztrtrd(:,:,:) = ptr(:,:,:,jn,Krhs)  ! save trends
359         !
360         IF(lwp) WRITE(numout,*)
361         IF(lwp) WRITE(numout,*) 'trc_sbc_RK3 : Runge Kutta 3rd order at stage ', kstg, jn
362         IF(lwp) WRITE(numout,*) 'emp', MAXVAL(emp(:,:))
363         IF(lwp) WRITE(numout,*) 'sbc_trc', MAXVAL(sbc_trc(:,:,jn))
364         IF(lwp) WRITE(numout,*)
365         DO_2D( 0, 0, 0, 1 )
366            zse3t = 1._wp / e3t(ji,jj,1,Kmm)
367            ptr(ji,jj,1,jn,Krhs) = ptr(ji,jj,1,jn,Krhs) +  sbc_trc(ji,jj,jn) * zse3t
368         END_2D
369         !
370         IF( l_trdtrc ) THEN
371            ztrtrd(:,:,:) = ptr(:,:,:,jn,Krhs) - ztrtrd(:,:,:)
372            CALL trd_tra( kt, Kmm, Krhs, 'TRC', jn, jptra_nsr, ztrtrd )
373         END IF
374         !
375      END DO
376      !
377      IF( sn_cfctl%l_prttrc )   THEN
378         WRITE(charout, FMT="('sbc ')") ;  CALL prt_ctl_info( charout, cdcomp = 'top' )
379                                           CALL prt_ctl( tab4d_1=ptr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm, clinfo3='trd' )
380      ENDIF
381      !
382      IF( l_trdtrc )  DEALLOCATE( ztrtrd )
383      !
384      IF( ln_timing )   CALL timing_stop('trc_sbc_RK3')
385      !
386   END SUBROUTINE trc_sbc_RK3
387!!st
388
389#else
390   !!----------------------------------------------------------------------
391   !!   Dummy module :                      NO passive tracer
392   !!----------------------------------------------------------------------
393   USE par_oce
394   USE par_trc
395CONTAINS
396   SUBROUTINE trc_sbc ( kt, Kmm, ptr, Krhs )      ! Empty routine
397      INTEGER,                                    INTENT(in   ) :: kt        ! ocean time-step index
398      INTEGER,                                    INTENT(in   ) :: Kmm, Krhs ! time level indices
399      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr       ! passive tracers and RHS of tracer equation
400      WRITE(*,*) 'trc_sbc: You should not have seen this print! error?', kt
401   END SUBROUTINE trc_sbc
402#endif
403   
404   !!======================================================================
405END MODULE trcsbc
Note: See TracBrowser for help on using the repository browser.