New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zfechem.F90 in NEMO/branches/2021/dev_r14383_PISCES_NEWDEV_PISCO/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2021/dev_r14383_PISCES_NEWDEV_PISCO/src/TOP/PISCES/P4Z/p4zfechem.F90 @ 14385

Last change on this file since 14385 was 14385, checked in by cetlod, 4 years ago

dev_r11708_aumont_PISCES_QUOTA : merge with the trunk
  • Property svn:keywords set to Id
File size: 13.9 KB
Line 
1MODULE p4zfechem
2   !!======================================================================
3   !!                         ***  MODULE p4zfechem  ***
4   !! TOP :   PISCES Compute iron chemistry and scavenging
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, A. Tagliabue, C. Ethe) Original code
7   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
8   !!----------------------------------------------------------------------
9   !!   p4z_fechem       : Compute remineralization/scavenging of iron
10   !!   p4z_fechem_init  : Initialisation of parameters for remineralisation
11   !!   p4z_fechem_alloc : Allocate remineralisation variables
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zche          ! chemical model
17   USE p4zbc           ! Boundary conditions from sediments
18   USE prtctl          ! print control for debugging
19   USE iom             ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_fechem        ! called in p4zbio.F90
25   PUBLIC   p4z_fechem_init   ! called in trcsms_pisces.F90
26
27   LOGICAL          ::   ln_ligvar    !: boolean for variable ligand concentration following Tagliabue and voelker
28   REAL(wp), PUBLIC ::   xlam1        !: scavenging rate of Iron
29   REAL(wp), PUBLIC ::   xlamdust     !: scavenging rate of Iron by dust
30   REAL(wp), PUBLIC ::   ligand       !: ligand concentration in the ocean
31   REAL(wp), PUBLIC ::   kfep         !: rate constant for nanoparticle formation
32   REAL(wp), PUBLIC ::   scaveff      !: Fraction of scavenged iron that is considered as being subject to solubilization
33
34   !! * Substitutions
35#  include "do_loop_substitute.h90"
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE p4z_fechem( kt, knt, Kbb, Kmm, Krhs )
45      !!---------------------------------------------------------------------
46      !!                     ***  ROUTINE p4z_fechem  ***
47      !!
48      !! ** Purpose :   Compute remineralization/scavenging of iron
49      !!
50      !! ** Method  :   A simple chemistry model of iron from Aumont and Bopp (2006)
51      !!                based on one ligand and one inorganic form
52      !!---------------------------------------------------------------------
53      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step
54      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
55      !
56      INTEGER  ::   ji, jj, jk, jic, jn
57      REAL(wp) ::   zlam1a, zlam1b
58      REAL(wp) ::   zkeq, zfesatur, zfecoll, fe3sol, zligco
59      REAL(wp) ::   zscave, zaggdfea, zaggdfeb, ztrc, zdust, zklight
60      REAL(wp) ::   ztfe, zhplus, zxlam, zaggliga, zaggligb
61      REAL(wp) ::   zrfact2
62      CHARACTER (len=25) :: charout
63      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zTL1, zFe3, ztotlig, precip, precipno3, zFeL1
64      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zcoll3d, zscav3d, zlcoll3d, zprecip3d
65      !!---------------------------------------------------------------------
66      !
67      IF( ln_timing )   CALL timing_start('p4z_fechem')
68      !
69      zFe3 (:,:,:) = 0.
70      zFeL1(:,:,:) = 0.
71      zTL1 (:,:,:) = 0.
72
73      ! Total ligand concentration : Ligands can be chosen to be constant or variable
74      ! Parameterization from Pham and Ito (2018)
75      ! -------------------------------------------------
76      IF( ln_ligvar ) THEN
77         ztotlig(:,:,:) =  0.09 * 0.667 * tr(:,:,:,jpdoc,Kbb) * 1E6 + ligand * 1E9 + MAX(0., chemo2(:,:,:) - tr(:,:,:,jpoxy,Kbb) ) / 400.E-6
78         ztotlig(:,:,:) =  MIN( ztotlig(:,:,:), 10. )
79      ELSE
80        IF( ln_ligand ) THEN  ;   ztotlig(:,:,:) = tr(:,:,:,jplgw,Kbb) * 1E9
81        ELSE                  ;   ztotlig(:,:,:) = ligand * 1E9 
82        ENDIF
83      ENDIF
84
85      ! ------------------------------------------------------------
86      !  from Aumont and Bopp (2006)
87      ! This model is based on one ligand, Fe2+ and Fe3+
88      ! Chemistry is supposed to be fast enough to be at equilibrium
89      ! ------------------------------------------------------------
90      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
91          zTL1(ji,jj,jk)  = ztotlig(ji,jj,jk)
92          zkeq            = fekeq(ji,jj,jk)
93          zklight         = 4.77E-7 * etot(ji,jj,jk) * 0.5 / 10**-6.3
94          zfesatur        = zTL1(ji,jj,jk) * 1E-9
95          ztfe            = (1.0 + zklight) * tr(ji,jj,jk,jpfer,Kbb) 
96          ! Fe' is the root of a 2nd order polynom
97          zFe3 (ji,jj,jk) = ( -( 1. + zfesatur * zkeq + zklight + consfe3(ji,jj,jk)/10**-6.3 - zkeq * tr(ji,jj,jk,jpfer,Kbb) )               &
98             &              + SQRT( ( 1. + zfesatur * zkeq + zklight + consfe3(ji,jj,jk)/10**-6.3 - zkeq * tr(ji,jj,jk,jpfer,Kbb) )**2       &
99             &              + 4. * ztfe * zkeq) ) / ( 2. * zkeq )
100          zFeL1(ji,jj,jk) = MAX( 0., tr(ji,jj,jk,jpfer,Kbb) - zFe3(ji,jj,jk) )
101      END_3D
102      !
103      plig(:,:,:) =  MAX( 0., ( zFeL1(:,:,:) / ( tr(:,:,:,jpfer,Kbb) + rtrn ) ) )
104      !
105      zdust = 0.         ! if no dust available
106      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
107         ! Scavenging rate of iron. This scavenging rate depends on the load of particles of sea water.
108         ! This parameterization assumes a simple second order kinetics (k[Particles][Fe]).
109         ! Scavenging onto dust is also included as evidenced from the DUNE experiments.
110         ! --------------------------------------------------------------------------------------
111         zhplus  = max( rtrn, hi(ji,jj,jk) )
112         fe3sol  = fesol(ji,jj,jk,1) * ( zhplus**3 + fesol(ji,jj,jk,2) * zhplus**2  &
113         &         + fesol(ji,jj,jk,3) * zhplus + fesol(ji,jj,jk,4)     &
114         &         + fesol(ji,jj,jk,5) / zhplus )
115         !
116         zfecoll = 0.5 * zFeL1(ji,jj,jk) * 1E-9
117         ! precipitation of Fe3+, creation of nanoparticles
118         precip(ji,jj,jk) = MAX( 0., ( zFe3(ji,jj,jk) - fe3sol ) ) * kfep * xstep * ( 1.0 - nitrfac(ji,jj,jk) ) 
119         ! Precipitation of Fe2+ due to oxidation by NO3 (Croot et al., 2019)
120         ! This occurs in anoxic waters only
121         precipno3(ji,jj,jk) = 2.0 * 130.0 * tr(ji,jj,jk,jpno3,Kbb) * nitrfac(ji,jj,jk) * xstep * zFe3(ji,jj,jk)
122         !
123         ztrc   = ( tr(ji,jj,jk,jppoc,Kbb) + tr(ji,jj,jk,jpgoc,Kbb) + tr(ji,jj,jk,jpcal,Kbb) + tr(ji,jj,jk,jpgsi,Kbb) ) * 1.e6 
124         ztrc = MAX( rtrn, ztrc )
125         IF( ll_dust )  zdust  = dust(ji,jj) / ( wdust / rday ) * tmask(ji,jj,jk)
126         zxlam  = MAX( 1.E-3, (1. - EXP(-2 * tr(ji,jj,jk,jpoxy,Kbb) / 100.E-6 ) ))
127         zlam1b = 3.e-5 + ( xlamdust * zdust + xlam1 * ztrc ) * zxlam
128         zscave = zFe3(ji,jj,jk) * zlam1b * xstep
129
130         !  Compute the coagulation of colloidal iron. This parameterization
131         !  could be thought as an equivalent of colloidal pumping.
132         !  It requires certainly some more work as it is very poorly constrained.
133         !  ----------------------------------------------------------------
134         zlam1a   = ( 12.0  * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 9.05  * tr(ji,jj,jk,jppoc,Kbb) ) * xdiss(ji,jj,jk)    &
135             &    + ( 2.49  * tr(ji,jj,jk,jppoc,Kbb) )     &
136             &    + ( 127.8 * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 725.7 * tr(ji,jj,jk,jppoc,Kbb) )
137         zaggdfea = zlam1a * xstep * zfecoll
138               !
139         zlam1b   = ( 1.94 * xdiss(ji,jj,jk) + 1.37 ) * tr(ji,jj,jk,jpgoc,Kbb)
140         zaggdfeb = zlam1b * xstep * zfecoll
141
142         !
143         tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zscave - zaggdfea - zaggdfeb &
144         &                       - precip(ji,jj,jk) - precipno3(ji,jj,jk)
145
146         tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zscave * scaveff * tr(ji,jj,jk,jppoc,Kbb) / ztrc
147         tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + zscave * scaveff * tr(ji,jj,jk,jppoc,Kbb) / ztrc
148
149
150          ! Precipitated iron is supposed to be permanently lost.
151          ! Scavenged iron is supposed to be released back to seawater
152          ! when POM is solubilized. This is highly uncertain as probably
153          ! a significant part of it may be rescavenged back onto
154          ! the particles. An efficiency factor is applied that is read
155          ! in the namelist.
156          ! See for instance Tagliabue et al. (2019).
157          ! Aggregated FeL is considered as biogenic Fe as it
158          ! probably remains  complexed when the particle is solubilized.
159          ! -------------------------------------------------------------
160          tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zaggdfea
161          tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + zaggdfeb
162          !
163          zscav3d(ji,jj,jk)   = zscave 
164          zcoll3d(ji,jj,jk)   = zaggdfea + zaggdfeb
165          zprecip3d(ji,jj,jk) = precip(ji,jj,jk) + precipno3(ji,jj,jk)
166         !
167      END_3D
168      !
169      !  Define the bioavailable fraction of iron
170      !  ----------------------------------------
171      biron(:,:,:) = tr(:,:,:,jpfer,Kbb) 
172      !
173      IF( ln_ligand ) THEN
174         !
175         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
176             ! Coagulation of ligands due to various processes (Brownian, shear, diff. sedimentation
177             ! Coefficients are taken from p4zagg
178             ! -------------------------------------------------------------------------------------
179             zlam1a   = ( 12.0  * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 9.05  * tr(ji,jj,jk,jppoc,Kbb) ) * xdiss(ji,jj,jk)    &
180                 &    + ( 2.49  * tr(ji,jj,jk,jppoc,Kbb) )     &
181                 &    + ( 127.8 * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 725.7 * tr(ji,jj,jk,jppoc,Kbb) )
182             !
183             zlam1b   = ( 1.94 * xdiss(ji,jj,jk) + 1.37 ) * tr(ji,jj,jk,jpgoc,Kbb)
184             ! 50% of the ligands are supposed to be in the colloidal size fraction
185             ! as for FeL
186             zligco   = 0.5 * tr(ji,jj,jk,jplgw,Kbb)
187             zaggliga = zlam1a * xstep * zligco 
188             zaggligb = zlam1b * xstep * zligco
189             !
190             tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs)  - zaggliga - zaggligb
191             zlcoll3d(ji,jj,jk)  = zaggliga + zaggligb
192         END_3D
193         plig(:,:,:) =  MAX( 0., ( ( zFeL1(:,:,:) * 1E-9 ) / ( tr(:,:,:,jpfer,Kbb) +rtrn ) ) )
194         !
195      ENDIF
196      !  Output of some diagnostics variables
197      !     ---------------------------------
198      IF( lk_iomput .AND. knt == nrdttrc ) THEN
199         zrfact2 = 1.e3 * rfact2r  ! conversion from mol/L/timestep into mol/m3/s
200         IF( iom_use("Fe3")    )  CALL iom_put("Fe3"    , zFe3   (:,:,:)       * tmask(:,:,:) )   ! Fe3+
201         IF( iom_use("FeL1")   )  CALL iom_put("FeL1"   , zFeL1  (:,:,:)       * tmask(:,:,:) )   ! FeL1
202         IF( iom_use("TL1")    )  CALL iom_put("TL1"    , zTL1   (:,:,:)       * tmask(:,:,:) )   ! TL1
203         IF( iom_use("Totlig") )  CALL iom_put("Totlig" , ztotlig(:,:,:)       * tmask(:,:,:) )   ! TL
204         IF( iom_use("Biron")  )  CALL iom_put("Biron"  , biron  (:,:,:)  * 1e9 * tmask(:,:,:) )   ! biron
205         IF( iom_use("FESCAV") )  CALL iom_put("FESCAV" , zscav3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
206         IF( iom_use("FECOLL") )  CALL iom_put("FECOLL" , zcoll3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
207         IF( iom_use("FEPREC") )  CALL iom_put("FEPREC" , zprecip3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
208         IF( iom_use("LGWCOLL"))  CALL iom_put("LGWCOLL", zlcoll3d(:,:,:) * 1e9 * tmask(:,:,:) * zrfact2 )
209      ENDIF
210
211      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
212         WRITE(charout, FMT="('fechem')")
213         CALL prt_ctl_info( charout, cdcomp = 'top' )
214         CALL prt_ctl(tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm)
215      ENDIF
216      !
217      IF( ln_timing )   CALL timing_stop('p4z_fechem')
218      !
219   END SUBROUTINE p4z_fechem
220
221
222   SUBROUTINE p4z_fechem_init
223      !!----------------------------------------------------------------------
224      !!                  ***  ROUTINE p4z_fechem_init  ***
225      !!
226      !! ** Purpose :   Initialization of iron chemistry parameters
227      !!
228      !! ** Method  :   Read the nampisfer namelist and check the parameters
229      !!      called at the first timestep
230      !!
231      !! ** input   :   Namelist nampisfer
232      !!
233      !!----------------------------------------------------------------------
234      INTEGER ::   ios   ! Local integer
235      !!
236      NAMELIST/nampisfer/ ln_ligvar, xlam1, xlamdust, ligand, kfep, scaveff 
237      !!----------------------------------------------------------------------
238      !
239      IF(lwp) THEN
240         WRITE(numout,*)
241         WRITE(numout,*) 'p4z_rem_init : Initialization of iron chemistry parameters'
242         WRITE(numout,*) '~~~~~~~~~~~~'
243      ENDIF
244      !
245      READ  ( numnatp_ref, nampisfer, IOSTAT = ios, ERR = 901)
246901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisfer in reference namelist' )
247      READ  ( numnatp_cfg, nampisfer, IOSTAT = ios, ERR = 902 )
248902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisfer in configuration namelist' )
249      IF(lwm) WRITE( numonp, nampisfer )
250
251      IF(lwp) THEN                     ! control print
252         WRITE(numout,*) '   Namelist : nampisfer'
253         WRITE(numout,*) '      variable concentration of ligand          ln_ligvar    =', ln_ligvar
254         WRITE(numout,*) '      scavenging rate of Iron                   xlam1        =', xlam1
255         WRITE(numout,*) '      scavenging rate of Iron by dust           xlamdust     =', xlamdust
256         WRITE(numout,*) '      ligand concentration in the ocean         ligand       =', ligand
257         WRITE(numout,*) '      rate constant for nanoparticle formation  kfep         =', kfep
258         WRITE(numout,*) '      Scavenged iron that is added to POFe      scaveff      =', scaveff
259      ENDIF
260      !
261   END SUBROUTINE p4z_fechem_init
262   
263   !!======================================================================
264END MODULE p4zfechem
Note: See TracBrowser for help on using the repository browser.