New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zprod.F90 in NEMO/branches/2021/dev_r14383_PISCES_NEWDEV_PISCO/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2021/dev_r14383_PISCES_NEWDEV_PISCO/src/TOP/PISCES/P4Z/p5zprod.F90 @ 14385

Last change on this file since 14385 was 14385, checked in by cetlod, 4 years ago

dev_r11708_aumont_PISCES_QUOTA : merge with the trunk
  • Property svn:keywords set to Id
File size: 37.3 KB
Line 
1MODULE p5zprod
2   !!======================================================================
3   !!                         ***  MODULE p5zprod  ***
4   !! TOP :  Growth Rate of the three phytoplanktons groups
5   !!        PISCES-QUOTA version of the module
6   !!======================================================================
7   !! History :   1.0  !  2004     (O. Aumont) Original code
8   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
9   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
10   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
11   !!----------------------------------------------------------------------
12   !!   p5z_prod       :   Compute the growth Rate of the two phytoplanktons groups
13   !!   p5z_prod_init  :   Initialization of the parameters for growth
14   !!   p5z_prod_alloc :   Allocate variables for growth
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE p4zlim
20   USE p5zlim          !  Co-limitations of differents nutrients
21   USE prtctl          !  print control for debugging
22   USE iom             !  I/O manager
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p5z_prod         ! called in p5zbio.F90
28   PUBLIC   p5z_prod_init    ! called in trcsms_pisces.F90
29   PUBLIC   p5z_prod_alloc
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::  pislopen        !: P-I slope of nanophytoplankton
33   REAL(wp), PUBLIC ::  pislopep        !: P-I slope of picophytoplankton
34   REAL(wp), PUBLIC ::  pisloped        !: P-I slope of diatoms
35   REAL(wp), PUBLIC ::  xadap           !: Adaptation factor to low light
36   REAL(wp), PUBLIC ::  excretn         !: Excretion ratio of nanophyto
37   REAL(wp), PUBLIC ::  excretp         !: Excretion ratio of picophyto
38   REAL(wp), PUBLIC ::  excretd         !: Excretion ratio of diatoms
39   REAL(wp), PUBLIC ::  bresp           !: Basal respiration rate
40   REAL(wp), PUBLIC ::  thetanpm        !: Maximum Chl/N ratio of picophyto
41   REAL(wp), PUBLIC ::  thetannm        !: Maximum Chl/N ratio of nanophyto
42   REAL(wp), PUBLIC ::  thetandm        !: Maximum Chl/N ratio of diatoms
43   REAL(wp), PUBLIC ::  chlcmin         !: Minimum Chl/C ratio of phytoplankton
44   REAL(wp), PUBLIC ::  grosip          !: Mean Si/C ratio of diatoms
45
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   zdaylen ! day length
47   
48   REAL(wp) :: r1_rday                !: 1 / rday
49   REAL(wp) :: texcretn               !: 1 - excretn
50   REAL(wp) :: texcretp               !: 1 - excretp
51   REAL(wp) :: texcretd               !: 1 - excretd       
52
53   !! * Substitutions
54#  include "do_loop_substitute.h90"
55#  include "domzgr_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
58   !! $Id$
59   !! Software governed by the CeCILL license (see ./LICENSE)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE p5z_prod( kt , knt, Kbb, Kmm, Krhs )
64      !!---------------------------------------------------------------------
65      !!                     ***  ROUTINE p5z_prod  ***
66      !!
67      !! ** Purpose :   Compute the phytoplankton production depending on
68      !!              light, temperature and nutrient availability
69      !!              Computes also the uptake of nutrients. PISCES-quota
70      !!              relies on a full quota formalism
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in) :: kt, knt
74      INTEGER, INTENT(in) :: Kbb, Kmm, Krhs      ! time level indices
75      !
76      INTEGER  ::   ji, jj, jk
77      REAL(wp) ::   zsilfac, znanotot, zpicotot, zdiattot, zconctemp, zconctemp2
78      REAL(wp) ::   zration, zratiop, zratiof, zmax, ztn, zadap
79      REAL(wp) ::   zpronmax, zpropmax, zprofmax, zratio
80      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zprontot, zproptot, zprodtot
81      REAL(wp) ::   zproddoc, zproddon, zproddop, zprodsil, zprodfer, zprodlig, zresptot     
82      REAL(wp) ::   zprnutmax, zprochln, zprochld, zprochlp
83      REAL(wp) ::   zpislopen, zpislopep, zpisloped
84      REAL(wp) ::   zval, zpptot, zpnewtot, zpregtot
85      REAL(wp) ::   zqfpmax, zqfnmax, zqfdmax
86      REAL(wp) ::   zfact, zrfact2, zmaxsi, zratiosi, zsizetmp, zlimfac, zsilim
87      CHARACTER (len=25) :: charout
88      REAL(wp), DIMENSION(jpi,jpj    ) :: zmixnano, zmixpico, zmixdiat
89      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadp, zpislopeadd
90      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprnut, zprmaxp, zprmaxn, zprmaxd
91      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprbio, zprpic, zprdia, zysopt
92      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprchln, zprchlp, zprchld
93      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcap, zprorcad 
94      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprofed, zprofep, zprofen
95      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewp, zpronewd
96      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zproregn, zproregp, zproregd
97      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpropo4n, zpropo4p, zpropo4d
98      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprodopn, zprodopp, zprodopd
99      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zrespn, zrespp, zrespd
100      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
101      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zpligprod
102      !!---------------------------------------------------------------------
103      !
104      IF( ln_timing )   CALL timing_start('p5z_prod')
105
106      ! Initialize the local arrays
107      zprorcan(:,:,:) = 0._wp ; zprorcap(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp
108      zprofed (:,:,:) = 0._wp ; zprofep (:,:,:) = 0._wp ; zprofen (:,:,:) = 0._wp
109      zpronewn(:,:,:) = 0._wp ; zpronewp(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp
110      zproregn(:,:,:) = 0._wp ; zproregp(:,:,:) = 0._wp ; zproregd(:,:,:) = 0._wp 
111      zpropo4n(:,:,:) = 0._wp ; zpropo4p(:,:,:) = 0._wp ; zpropo4d(:,:,:) = 0._wp
112      zprdia  (:,:,:) = 0._wp ; zprpic  (:,:,:) = 0._wp ; zprbio  (:,:,:) = 0._wp
113      zprodopn(:,:,:) = 0._wp ; zprodopp(:,:,:) = 0._wp ; zprodopd(:,:,:) = 0._wp
114      zysopt  (:,:,:) = 0._wp 
115      zrespn  (:,:,:) = 0._wp ; zrespp  (:,:,:) = 0._wp ; zrespd  (:,:,:) = 0._wp 
116      zmxl_fac(:,:,:) = 0._wp ; zmxl_chl(:,:,:) = 0._wp
117      consfe3 (:,:,:) = 0._wp
118
119      ! Computation of the optimal production rates and nutrient uptake
120      ! rates. Based on a Q10 description of the thermal dependency.
121      zprnut (:,:,:) =  0.8_wp * r1_rday * tgfunc(:,:,:)
122      zprmaxn(:,:,:) =  0.8_wp * (1. + zpsino3 * qnnmax ) * r1_rday * tgfunc(:,:,:)
123      zprmaxd(:,:,:) =  0.8_wp * (1. + zpsino3 * qndmax ) * r1_rday * tgfunc(:,:,:)
124      zprmaxp(:,:,:) =  0.6_wp * (1. + zpsino3 * qnpmax ) * r1_rday * tgfunc(:,:,:)
125
126      ! Impact of the day duration and light intermittency on phytoplankton growth
127      ! Intermittency is supposed to have a similar effect on production as
128      ! day length (Shatwell et al., 2012). The correcting factor is zmxl_fac.
129      ! zmxl_chl is the fractional day length and is used to compute the mean
130      ! PAR during daytime. The effect of mixing is computed using the
131      ! absolute light level definition of the euphotic zone
132      ! -------------------------------------------------------------------------
133      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
134         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
135            zval = MAX( 1., strn(ji,jj) )
136            IF( gdepw(ji,jj,jk+1,Kmm) <= hmld(ji,jj) ) THEN
137               zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
138            ENDIF
139            zmxl_chl(ji,jj,jk) = zval / 24.
140            zmxl_fac(ji,jj,jk) = 1.0 - exp( -0.26 * zval )
141         ENDIF
142      END_3D
143
144      zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:)
145      zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:)
146      zprpic(:,:,:) = zprmaxp(:,:,:) * zmxl_fac(:,:,:)
147
148      ! Maximum light intensity
149      zdaylen(:,:) = MAX(1., strn(:,:)) / 24.
150
151      ! Computation of the P-I slope for nanos, picos and diatoms
152      ! The formulation proposed by Geider et al. (1997) has been used.
153      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
154         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
155            ! Computation of the P-I slope for nanos and diatoms
156            ztn         = MAX( 0., ts(ji,jj,jk,jp_tem,Kmm) - 15. )
157            zadap       = xadap * ztn / ( 2.+ ztn )
158            !
159            ! Nanophytoplankton
160            zpislopeadn(ji,jj,jk) = pislopen * tr(ji,jj,jk,jpnch,Kbb)    &
161            &                       /( tr(ji,jj,jk,jpphy,Kbb) * 12. + rtrn)
162
163            ! Picophytoplankton
164            zpislopeadp(ji,jj,jk) = pislopep * ( 1. + zadap * EXP( -0.25 * epico(ji,jj,jk) ) )   &
165            &                       * tr(ji,jj,jk,jppch,Kbb) /( tr(ji,jj,jk,jppic,Kbb) * 12. + rtrn)
166
167            ! Diatoms
168            zpislopeadd(ji,jj,jk) = pisloped * tr(ji,jj,jk,jpdch,Kbb)    &
169               &                    /( tr(ji,jj,jk,jpdia,Kbb) * 12. + rtrn)
170            !
171            zpislopen = zpislopeadn(ji,jj,jk) / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
172            zpislopep = zpislopeadp(ji,jj,jk) / ( zprpic(ji,jj,jk) * rday * xlimpic(ji,jj,jk) + rtrn )
173            zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
174
175            ! Computation of production function for Carbon
176            ! Actual light levels are used here
177            !  ---------------------------------------------
178            zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) / zmxl_fac(ji,jj,jk) )  )
179            zprpic(ji,jj,jk) = zprpic(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) / zmxl_fac(ji,jj,jk) )  )
180            zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) / zmxl_fac(ji,jj,jk) )  )
181
182            !  Computation of production function for Chlorophyll
183            !  Mean light level in the mixed layer (when appropriate)
184            !  is used here (acclimation is in general slower than
185            !  the characteristic time scales of vertical mixing)
186            !  ------------------------------------------------------
187            zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
188            zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
189            zpislopep = zpislopep * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
190            zprchln(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) )  )
191            zprchlp(ji,jj,jk) = zprmaxp(ji,jj,jk) * ( 1.- EXP( -zpislopep * epicom(ji,jj,jk) )  )
192            zprchld(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) )  )
193         ENDIF
194      END_3D
195
196      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
197          IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
198            ! Si/C of diatoms
199            ! ------------------------
200            ! Si/C increases with iron stress and silicate availability (zsilfac)
201            ! Si/C is arbitrariliy increased for very high Si concentrations
202            ! to mimic the very high ratios observed in the Southern Ocean (zsilfac2)
203            ! A parameterization derived from Flynn (2003) is used for the control
204            ! when Si is not limiting which is similar to the parameterisation
205            ! proposed by Gurney and Davidson (1999).
206            ! -----------------------------------------------------------------------
207            zlim  = tr(ji,jj,jk,jpsil,Kbb) / ( tr(ji,jj,jk,jpsil,Kbb) + xksi1 )
208            zsilim = xlimdia(ji,jj,jk) * zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn )
209            zsiborn = tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb)
210            IF (gphit(ji,jj) < -30 ) THEN
211              zsilfac2 = 1. + 1. * zsiborn / ( zsiborn + xksi2**3 )
212            ELSE
213              zsilfac2 = 1.
214            ENDIF
215            zratiosi = 1.0 - tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn ) / ( zsilfac2 * grosip * 3.0 + rtrn )
216            zratiosi = MAX(0., MIN(1.0, zratiosi) )
217            zmaxsi  = (1.0 + 0.1**4) * zratiosi**4 / ( zratiosi**4 + 0.1**4 )
218            IF ( xlimsi(ji,jj,jk) /= xlimdia(ji,jj,jk) ) THEN
219               zysopt(ji,jj,jk) = zlim * zsilfac2 * grosip * 1.0 * zmaxsi
220            ELSE
221               zysopt(ji,jj,jk) = zlim * zsilfac2 * grosip * 1.0 * zsilim**0.7 * zmaxsi
222            ENDIF
223         ENDIF
224      END_3D
225
226      !  Sea-ice effect on production
227      ! No production is assumed below sea ice
228      ! --------------------------------------
229      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
230         zprbio(ji,jj,jk)  = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
231         zprpic(ji,jj,jk)  = zprpic(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
232         zprdia(ji,jj,jk)  = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
233         zprnut(ji,jj,jk)  = zprnut(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
234      END_3D
235
236      ! Computation of the various production and uptake terms of nanophytoplankton
237      ! Interactions between N and P are modeled according to the Chain Model
238      ! of Pahlow et al. (2009). Iron uptake is modeled following traditional
239      ! Droop kinetics. When the quota is approaching the maximum achievable
240      ! quota, uptake is downregulated according to a sigmoidal function
241      ! (power 2), as proposed by Flynn (2003)
242      ! ---------------------------------------------------------------------------
243      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
244         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
245            !  production terms for nanophyto.
246            zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * tr(ji,jj,jk,jpphy,Kbb) * rfact2
247
248            ! Size computation
249            ! Size is made a function of the limitation of of phytoplankton growth
250            ! Strongly limited cells are supposed to be smaller. sizena is the
251            ! size at time step t+1 and is thus updated at the end of the
252            ! current time step
253            ! --------------------------------------------------------------------
254            zlimfac = xlimphys(ji,jj,jk) * zprchln(ji,jj,jk) / ( zprmaxn(ji,jj,jk) + rtrn )
255            zsizetmp = 1.0 + 1.3 * ( xsizern - 1.0 ) * zlimfac**3/(0.3 + zlimfac**3)
256            sizena(ji,jj,jk) = MIN(xsizern, MAX( sizena(ji,jj,jk), zsizetmp ) )
257            ! Maximum potential uptake rate
258            zration = tr(ji,jj,jk,jpnph,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
259            zratiop = tr(ji,jj,jk,jppph,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
260            zratiof = tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
261            zprnutmax = zprnut(ji,jj,jk) * fvnuptk(ji,jj,jk) / rno3 * tr(ji,jj,jk,jpphy,Kbb) * rfact2
262            ! Uptake of nitrogen
263            zratio = 1.0 - MIN( 1., zration / (xqnnmax(ji,jj,jk) + rtrn) )
264            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
265            zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpnmin(ji,jj,jk) )   &
266            &          / ( xqpnmax(ji,jj,jk) - xqpnmin(ji,jj,jk) + rtrn ), xlimnfe(ji,jj,jk) ) )
267            zpronmax = zpronmax * xqnnmin(ji,jj,jk) / qnnmin
268            zpronewn(ji,jj,jk) = zpronmax * xnanono3(ji,jj,jk)
269            zproregn(ji,jj,jk) = zpronmax * xnanonh4(ji,jj,jk)
270            ! Uptake of phosphorus and DOP
271            zratio = 1.0 - MIN( 1., zratiop / (xqpnmax(ji,jj,jk) + rtrn) )
272            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
273            zpropmax = zprnutmax * zmax * xlimnfe(ji,jj,jk)
274            zpropo4n(ji,jj,jk) = zpropmax * xnanopo4(ji,jj,jk)
275            zprodopn(ji,jj,jk) = zpropmax * xnanodop(ji,jj,jk)
276            ! Uptake of iron
277            zqfnmax = xqfuncfecn(ji,jj,jk) + ( qfnmax - xqfuncfecn(ji,jj,jk) ) * xlimnpn(ji,jj,jk)
278            zratio = 1.0 - MIN( 1., zratiof / zqfnmax )
279            zmax = MAX(0., MIN(1., zratio**2/ (0.05**2 + zratio**2) ) )
280            zprofmax = zprnutmax * zqfnmax * zmax 
281            zprofen(ji,jj,jk) = zprofmax * xnanofer(ji,jj,jk)    &
282            &          * (1. + 0.8 * xnanono3(ji,jj,jk) / ( rtrn  &
283            &          + xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) ) * (1. - xnanofer(ji,jj,jk) ) )
284         ENDIF
285      END_3D
286
287      ! Computation of the various production and uptake terms of picophytoplankton
288      ! Interactions between N and P are modeled according to the Chain Model
289      ! of Pahlow et al. (2009). Iron uptake is modeled following traditional
290      ! Droop kinetics. When the quota is approaching the maximum achievable
291      ! quota, uptake is downregulated according to a sigmoidal function
292      ! (power 2), as proposed by Flynn (2003)
293      ! ---------------------------------------------------------------------------
294      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
295         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
296            !  production terms for picophyto.
297            zprorcap(ji,jj,jk) = zprpic(ji,jj,jk)  * xlimpic(ji,jj,jk) * tr(ji,jj,jk,jppic,Kbb) * rfact2
298            ! Size computation
299            ! Size is made a function of the limitation of of phytoplankton growth
300            ! Strongly limited cells are supposed to be smaller. sizepa is
301            ! size at time step t+1 and is thus updated at the end of the
302            ! current time step
303            ! --------------------------------------------------------------------
304            zlimfac = zprchlp(ji,jj,jk)  * xlimpics(ji,jj,jk) / ( zprmaxp(ji,jj,jk) + rtrn )
305            zsizetmp = 1.0 + 1.3 * ( xsizerp - 1.0 ) * zlimfac**3/(0.3 + zlimfac**3)
306            sizepa(ji,jj,jk) = min(xsizerp, max( sizepa(ji,jj,jk), zsizetmp ) )
307            ! Maximum potential uptake rate of nutrients
308            zration = tr(ji,jj,jk,jpnpi,Kbb) / ( tr(ji,jj,jk,jppic,Kbb) + rtrn )
309            zratiop = tr(ji,jj,jk,jpppi,Kbb) / ( tr(ji,jj,jk,jppic,Kbb) + rtrn )
310            zratiof = tr(ji,jj,jk,jppfe,Kbb) / ( tr(ji,jj,jk,jppic,Kbb) + rtrn )
311            zprnutmax = zprnut(ji,jj,jk) * fvpuptk(ji,jj,jk) / rno3 * tr(ji,jj,jk,jppic,Kbb) * rfact2
312            ! Uptake of nitrogen
313            zratio = 1.0 - MIN( 1., zration / (xqnpmax(ji,jj,jk) + rtrn) )
314            zmax = MAX(0., MIN(1., zratio**2/ (0.05**2 + zratio**2) ) )
315            zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqppmin(ji,jj,jk) )   &
316            &          / ( xqppmax(ji,jj,jk) - xqppmin(ji,jj,jk) + rtrn ), xlimpfe(ji,jj,jk) ) )
317            zpronmax = zpronmax * xqnpmin(ji,jj,jk) / qnnmin
318            zpronewp(ji,jj,jk) = zpronmax * xpicono3(ji,jj,jk) 
319            zproregp(ji,jj,jk) = zpronmax * xpiconh4(ji,jj,jk)
320            ! Uptake of phosphorus
321            zratio = 1.0 - MIN( 1., zratiop / (xqppmax(ji,jj,jk) + rtrn) )
322            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
323            zpropmax = zprnutmax * zmax * xlimpfe(ji,jj,jk) 
324            zpropo4p(ji,jj,jk) = zpropmax * xpicopo4(ji,jj,jk)
325            zprodopp(ji,jj,jk) = zpropmax * xpicodop(ji,jj,jk)
326            ! Uptake of iron
327            zqfpmax = xqfuncfecp(ji,jj,jk) + ( qfpmax - xqfuncfecp(ji,jj,jk) ) * xlimnpp(ji,jj,jk)
328            zratio = 1.0 - MIN( 1., zratiof / zqfpmax )
329            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
330            zprofmax = zprnutmax * zqfpmax * zmax
331            zprofep(ji,jj,jk) = zprofmax * xpicofer(ji,jj,jk)  &
332            &          * (1. + 0.8 * xpicono3(ji,jj,jk) / ( rtrn   &
333            &          + xpicono3(ji,jj,jk) + xpiconh4(ji,jj,jk) ) * (1. - xpicofer(ji,jj,jk) ) )
334         ENDIF
335      END_3D
336
337      ! Computation of the various production and uptake terms of diatoms
338      ! Interactions between N and P are modeled according to the Chain Model
339      ! of Pahlow et al. (2009). Iron uptake is modeled following traditional
340      ! Droop kinetics. When the quota is approaching the maximum achievable
341      ! quota, uptake is downregulated according to a sigmoidal function
342      ! (power 2), as proposed by Flynn (2003)
343      ! ---------------------------------------------------------------------------
344      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
345         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
346            !  production terms for diatomees
347            zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * tr(ji,jj,jk,jpdia,Kbb) * rfact2
348            ! Size computation
349            ! Size is made a function of the limitation of of phytoplankton growth
350            ! Strongly limited cells are supposed to be smaller. sizeda is
351            ! size at time step t+1 and is thus updated at the end of the
352            ! current time step.
353            ! --------------------------------------------------------------------
354            zlimfac = zprchld(ji,jj,jk) * xlimdias(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn )
355            zsizetmp = 1.0 + 1.3 * ( xsizerd - 1.0 ) * zlimfac**3/(0.3 + zlimfac**3)
356            sizeda(ji,jj,jk) = min(xsizerd, max( sizeda(ji,jj,jk), zsizetmp ) )
357            ! Maximum potential uptake rate of nutrients
358            zration = tr(ji,jj,jk,jpndi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
359            zratiop = tr(ji,jj,jk,jppdi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
360            zratiof = tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
361            zprnutmax = zprnut(ji,jj,jk) * fvduptk(ji,jj,jk) / rno3 * tr(ji,jj,jk,jpdia,Kbb) * rfact2
362            ! Uptake of nitrogen
363            zratio = 1.0 - MIN( 1., zration / (xqndmax(ji,jj,jk) + rtrn) )
364            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
365            zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpdmin(ji,jj,jk) )   &
366            &          / ( xqpdmax(ji,jj,jk) - xqpdmin(ji,jj,jk) + rtrn ), xlimdfe(ji,jj,jk) ) )
367            zpronmax = zpronmax * xqndmin(ji,jj,jk) / qnnmin
368            zpronewd(ji,jj,jk) = zpronmax * xdiatno3(ji,jj,jk)
369            zproregd(ji,jj,jk) = zpronmax * xdiatnh4(ji,jj,jk)
370            ! Uptake of phosphorus
371            zratio = 1.0 - MIN( 1., zratiop / (xqpdmax(ji,jj,jk) + rtrn) )
372            zmax = MAX(0., MIN(1., zratio**2/ (0.05**2 + zratio**2) ) )
373            zpropmax = zprnutmax * zmax * xlimdfe(ji,jj,jk)
374            zpropo4d(ji,jj,jk) = zpropmax * xdiatpo4(ji,jj,jk)
375            zprodopd(ji,jj,jk) = zpropmax * xdiatdop(ji,jj,jk)
376            ! Uptake of iron
377            zqfdmax = xqfuncfecd(ji,jj,jk) + ( qfdmax - xqfuncfecd(ji,jj,jk) ) * xlimnpd(ji,jj,jk)
378            zratio = 1.0 - MIN( 1., zratiof / zqfdmax )
379            zmax = MAX(0., MIN(1., zratio**2 / (0.05**2 + zratio**2) ) )
380            zprofmax = zprnutmax * zqfdmax * zmax
381            zprofed(ji,jj,jk) = zprofmax * xdiatfer(ji,jj,jk)    &
382            &          * (1. + 0.8 * xdiatno3(ji,jj,jk) / ( rtrn   &
383            &          + xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) ) * (1. - xdiatfer(ji,jj,jk) ) )
384         ENDIF
385      END_3D
386
387      ! Production of Chlorophyll. The formulation proposed by Geider et al.
388      ! is adopted here.
389      ! --------------------------------------------------------------------
390      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
391         IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
392               !  production terms for nanophyto. ( chlorophyll )
393            znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
394            zprod = rday * (zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)) * zprchln(ji,jj,jk) * xlimphy(ji,jj,jk)
395            zprochln = thetannm * zprod / ( zpislopeadn(ji,jj,jk) * znanotot + rtrn )
396            zprochln = MAX(zprochln, chlcmin * 12. * zprorcan (ji,jj,jk) )
397               !  production terms for picophyto. ( chlorophyll )
398            zpicotot = epicom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
399            zprod = rday * (zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)) * zprchlp(ji,jj,jk) * xlimpic(ji,jj,jk)
400            zprochlp = thetanpm * zprod / ( zpislopeadp(ji,jj,jk) * zpicotot + rtrn )
401            zprochlp = MAX(zprochlp, chlcmin * 12. * zprorcap(ji,jj,jk) )
402            !  production terms for diatoms ( chlorophyll )
403            zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
404            zprod = rday * (zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)) * zprchld(ji,jj,jk) * xlimdia(ji,jj,jk)
405            zprochld = thetandm * zprod / ( zpislopeadd(ji,jj,jk) * zdiattot + rtrn )
406            zprochld = MAX(zprochld, chlcmin * 12. * zprorcad(ji,jj,jk) )
407            !   Update the arrays TRA which contain the Chla sources and sinks
408            tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) + zprochln * texcretn
409            tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) + zprochld * texcretd
410            tr(ji,jj,jk,jppch,Krhs) = tr(ji,jj,jk,jppch,Krhs) + zprochlp * texcretp
411         ENDIF
412      END_3D
413
414      !   Update the arrays TRA which contain the biological sources and sinks
415      DO_3D( 1, 1, 1, 1, 1, jpkm1 )
416        zpptot   = zpropo4n(ji,jj,jk) + zpropo4d(ji,jj,jk) + zpropo4p(ji,jj,jk)
417        zpnewtot = zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) + zpronewp(ji,jj,jk)
418        zpregtot = zproregn(ji,jj,jk) + zproregd(ji,jj,jk) + zproregp(ji,jj,jk)
419
420        zprontot = zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)
421        zproptot = zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)
422        zprodtot = zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)
423        !
424        zproddoc = excretd * zprorcad(ji,jj,jk) &
425        &        + excretn * zprorcan(ji,jj,jk) &
426        &        + excretp * zprorcap(ji,jj,jk)
427        !
428        zproddop = excretd * zpropo4d(ji,jj,jk) - texcretd * zprodopd(ji,jj,jk) &
429        &        + excretn * zpropo4n(ji,jj,jk) - texcretn * zprodopn(ji,jj,jk) &
430        &        + excretp * zpropo4p(ji,jj,jk) - texcretp * zprodopp(ji,jj,jk)
431
432        zproddon =  excretd * zprodtot + excretn * zprontot + excretp * zproptot
433
434        zprodfer = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
435        zresptot = zrespn(ji,jj,jk) + zrespp(ji,jj,jk) + zrespd(ji,jj,jk) 
436 
437        !
438        tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zpptot
439        tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - zpnewtot
440        tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zpregtot 
441        !
442        tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs)         &
443           &                     + zprorcan(ji,jj,jk) * texcretn  &
444           &                     - zpsino3 * zpronewn(ji,jj,jk)   &
445           &                     - zpsinh4 * zproregn(ji,jj,jk)   &
446           &                     - zrespn(ji,jj,jk) 
447
448        tr(ji,jj,jk,jpnph,Krhs) = tr(ji,jj,jk,jpnph,Krhs) + zprontot * texcretn
449        tr(ji,jj,jk,jppph,Krhs) = tr(ji,jj,jk,jppph,Krhs) + ( zpropo4n(ji,jj,jk) + zprodopn(ji,jj,jk) ) * texcretn
450        tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) + zprofen(ji,jj,jk) * texcretn
451
452        !
453        tr(ji,jj,jk,jppic,Krhs) = tr(ji,jj,jk,jppic,Krhs)         &
454           &                     + zprorcap(ji,jj,jk) * texcretp  &
455           &                     - zpsino3 * zpronewp(ji,jj,jk)   &
456           &                     - zpsinh4 * zproregp(ji,jj,jk)   &
457           &                     - zrespp(ji,jj,jk) 
458
459        tr(ji,jj,jk,jpnpi,Krhs) = tr(ji,jj,jk,jpnpi,Krhs) + zproptot * texcretp
460        tr(ji,jj,jk,jpppi,Krhs) = tr(ji,jj,jk,jpppi,Krhs) + ( zpropo4p(ji,jj,jk) + zprodopp(ji,jj,jk) ) * texcretp
461        tr(ji,jj,jk,jppfe,Krhs) = tr(ji,jj,jk,jppfe,Krhs) + zprofep(ji,jj,jk) * texcretp
462
463        !
464        tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs)         &
465           &                    + zprorcad(ji,jj,jk) * texcretd   &
466           &                    - zpsino3 * zpronewd(ji,jj,jk)    &
467           &                    - zpsinh4 * zproregd(ji,jj,jk)    &
468           &                    - zrespd(ji,jj,jk) 
469
470        tr(ji,jj,jk,jpndi,Krhs) = tr(ji,jj,jk,jpndi,Krhs) + zprodtot * texcretd
471        tr(ji,jj,jk,jppdi,Krhs) = tr(ji,jj,jk,jppdi,Krhs) + ( zpropo4d(ji,jj,jk) + zprodopd(ji,jj,jk) ) * texcretd
472        tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) + zprofed(ji,jj,jk) * texcretd
473        tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
474
475        tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zproddoc
476        tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + zproddon                                       
477        tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + zproddop
478 
479        tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) &
480           &                     + o2ut * zpregtot + ( o2ut + o2nit ) * zpnewtot - o2ut * zresptot 
481
482        tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zprodfer
483        consfe3(ji,jj,jk)       = zprodfer * 75.0 / ( rtrn + ( plig(ji,jj,jk) + 75.0 * (1.0 - plig(ji,jj,jk) ) )   &
484           &                   * tr(ji,jj,jk,jpfer,Kbb) ) / rfact2
485       
486        tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) 
487
488        tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zpptot  &
489           &                     + zpsino3 * zpronewn(ji,jj,jk) + zpsinh4 * zproregn(ji,jj,jk)   &
490           &                     + zpsino3 * zpronewp(ji,jj,jk) + zpsinh4 * zproregp(ji,jj,jk)   &
491           &                     + zpsino3 * zpronewd(ji,jj,jk) + zpsinh4 * zproregd(ji,jj,jk) 
492
493        tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zpnewtot - zpregtot )
494        !
495      END_3D
496     
497     ! Production and uptake of ligands by phytoplankton. This part is activated
498     ! when ln_ligand is set to .true. in the namelist. Ligand uptake is small
499     ! and based on the FeL model by Morel et al. (2008) and on the study of
500     ! Shaked and Lis (2012)
501     ! -------------------------------------------------------------------------
502     IF( ln_ligand ) THEN
503         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
504           zproddoc = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk) + excretp * zprorcap(ji,jj,jk)
505           zprodfer = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
506           zprodlig = plig(ji,jj,jk) / ( rtrn + plig(ji,jj,jk) + 75.0 * (1.0 - plig(ji,jj,jk) ) ) * lthet 
507           !
508           tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + zproddoc * ldocp - zprodfer * zprodlig
509        END_3D
510     ENDIF
511
512    ! Total primary production per year
513    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
514      & tpp = glob_sum( 'p5zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) + zprorcap(:,:,:) ) * cvol(:,:,:) )
515
516    IF( lk_iomput .AND.  knt == nrdttrc ) THEN
517       zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
518       !
519       CALL iom_put( "PPPHYP"  , zprorcap(:,:,:) * zfact * tmask(:,:,:)   ) ! primary production by picophyto
520       CALL iom_put( "PPPHYN"  , zprorcan(:,:,:) * zfact * tmask(:,:,:) )  ! primary production by nanophyto
521       CALL iom_put( "PPPHYD"  , zprorcad(:,:,:) * zfact * tmask(:,:,:)   ) ! primary production by diatomes
522       CALL iom_put( "PPNEWN"  , zpronewp(:,:,:) * zfact * tmask(:,:,:)    ) ! new primary production by picophyto
523       CALL iom_put( "PPNEWN"  , zpronewn(:,:,:) * zfact * tmask(:,:,:)    ) ! new primary production by nanophyto
524       CALL iom_put( "PPNEWD"  , zpronewd(:,:,:) * zfact * tmask(:,:,:)   ) ! new primary production by diatomes
525       CALL iom_put( "PBSi"    , zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)  ) ! biogenic silica production
526       CALL iom_put( "PFeP"    , zprofep(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by picophyto
527       CALL iom_put( "PFeN"    , zprofen(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by nanophyto
528       CALL iom_put( "PFeD"    , zprofed(:,:,:) * zfact * tmask(:,:,:)  ) ! biogenic iron production by  diatomes
529       IF( ln_ligand .AND. ( iom_use( "LPRODP" ) .OR. iom_use( "LDETP" ) ) ) THEN
530           ALLOCATE(  zpligprod(jpi,jpj,jpk) )
531           zpligprod(:,:,:) = excretd * zprorcad(:,:,:) + excretn * zprorcan(:,:,:) + excretp * zprorcap(:,:,:)
532           CALL iom_put( "LPRODP"  , zpligprod(:,:,:) * ldocp * 1e9 * zfact * tmask(:,:,:) )
533           !
534           zpligprod(:,:,:) = ( texcretn * zprofen(:,:,:) + texcretd * zprofed(:,:,:) + texcretp * zprofep(:,:,:) ) & 
535             &                  * plig(:,:,:) / ( rtrn + plig(:,:,:) + 75.0 * (1.0 - plig(:,:,:) ) )
536           CALL iom_put( "LDETP"   , zpligprod(:,:,:)  * lthet * 1e9 * zfact * tmask(:,:,:) )
537           DEALLOCATE(  zpligprod )
538       ENDIF
539       CALL iom_put( "Mumax"   , zprmaxn(:,:,:) * tmask(:,:,:)  ) ! Maximum growth rate
540       CALL iom_put( "MuP"     , zprpic(:,:,:) * xlimpic(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for picophyto
541       CALL iom_put( "MuN"     , zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for nanophyto
542       CALL iom_put( "MuD"     , zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) ) ! Realized growth rate for diatoms
543       CALL iom_put( "LPlight" , zprpic(:,:,:) / (zprmaxp(:,:,:) + rtrn) * tmask(:,:,:)  )  ! light limitation term
544       CALL iom_put( "LNlight" , zprbio(:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:)  )  ! light limitation term
545       CALL iom_put( "LDlight" , zprdia(:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:)   )
546       CALL iom_put( "MunetP"  , ( tr(:,:,:,jppic,Krhs)/rfact2/(tr(:,:,:,jppic,Kbb)+ rtrn ) * tmask(:,:,:)) ) ! Realized growth rate for picophyto
547       CALL iom_put( "MunetN"  , ( tr(:,:,:,jpphy,Krhs)/rfact2/(tr(:,:,:,jpphy,Kbb)+ rtrn ) * tmask(:,:,:)) ) ! Realized growth rate for picophyto
548       CALL iom_put( "MunetD"  , ( tr(:,:,:,jpdia,Krhs)/rfact2/(tr(:,:,:,jpdia,Kbb)+ rtrn ) * tmask(:,:,:)) ) ! Realized growth rate for picophyto
549       CALL iom_put( "TPP"     , ( zprorcap(:,:,:) + zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  )  ! total primary production
550       CALL iom_put( "TPNEW"   , ( zpronewp(:,:,:) + zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ) ! total new production
551       CALL iom_put( "TPBFE"   , ( zprofep (:,:,:) + zprofen (:,:,:) + zprofed (:,:,:) ) * zfact * tmask(:,:,:)  )  ! total biogenic iron production
552       CALL iom_put( "tintpp"  , tpp * zfact )  !  global total integrated primary production molC/s
553     ENDIF
554
555      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
556         WRITE(charout, FMT="('prod')")
557         CALL prt_ctl_info( charout, cdcomp = 'top' )
558         CALL prt_ctl(tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm)
559      ENDIF
560      !
561      IF( ln_timing )   CALL timing_stop('p5z_prod')
562      !
563   END SUBROUTINE p5z_prod
564
565
566   SUBROUTINE p5z_prod_init
567      !!----------------------------------------------------------------------
568      !!                  ***  ROUTINE p5z_prod_init  ***
569      !!
570      !! ** Purpose :   Initialization of phytoplankton production parameters
571      !!
572      !! ** Method  :   Read the namp5zprod namelist and check the parameters
573      !!      called at the first timestep (nittrc000)
574      !!
575      !! ** input   :   Namelist namp5zprod
576      !!----------------------------------------------------------------------
577      INTEGER :: ios    ! Local integer output status for namelist read
578      !!
579      NAMELIST/namp5zprod/ pislopen, pislopep, pisloped, excretn, excretp, excretd,     &
580         &                 thetannm, thetanpm, thetandm, chlcmin, grosip, bresp, xadap
581      !!----------------------------------------------------------------------
582
583      READ  ( numnatp_ref, namp5zprod, IOSTAT = ios, ERR = 901)
584901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in reference namelist' )
585
586      READ  ( numnatp_cfg, namp5zprod, IOSTAT = ios, ERR = 902 )
587902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zprod in configuration namelist' )
588      IF(lwm) WRITE ( numonp, namp5zprod )
589
590      IF(lwp) THEN                         ! control print
591         WRITE(numout,*) ' '
592         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp5zprod'
593         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
594         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
595         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
596         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
597         WRITE(numout,*) '    P-I slope  for picophytoplankton          pislopep     =', pislopep
598         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
599         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
600         WRITE(numout,*) '    excretion ratio of picophytoplankton      excretp      =', excretp
601         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
602         WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
603         WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
604         WRITE(numout,*) '    Minimum Chl/N in nanophytoplankton        thetannm     =', thetannm
605         WRITE(numout,*) '    Minimum Chl/N in picophytoplankton        thetanpm     =', thetanpm
606         WRITE(numout,*) '    Minimum Chl/N in diatoms                  thetandm     =', thetandm
607      ENDIF
608      !
609      r1_rday   = 1._wp / rday 
610      texcretn  = 1._wp - excretn
611      texcretp  = 1._wp - excretp
612      texcretd  = 1._wp - excretd
613      tpp       = 0._wp
614      !
615   END SUBROUTINE p5z_prod_init
616
617
618   INTEGER FUNCTION p5z_prod_alloc()
619      !!----------------------------------------------------------------------
620      !!                     ***  ROUTINE p5z_prod_alloc  ***
621      !!----------------------------------------------------------------------
622      ALLOCATE( zdaylen(jpi,jpj), STAT = p5z_prod_alloc )
623      !
624      IF( p5z_prod_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p5z_prod_alloc : failed to allocate arrays.' )
625      !
626   END FUNCTION p5z_prod_alloc
627   !!======================================================================
628END MODULE p5zprod
Note: See TracBrowser for help on using the repository browser.