New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2021/dev_r14393_HPC-03_Mele_Comm_Cleanup/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14393_HPC-03_Mele_Comm_Cleanup/src/OCE/TRA/traadv_fct.F90 @ 14776

Last change on this file since 14776 was 14776, checked in by mocavero, 3 years ago

Bug fixing on neighbours collectives exchanges and set communication calls to 5-point on TRA where data dependencies are satisfied

  • Property svn:keywords set to Id
File size: 36.3 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36   PUBLIC   tridia_solver      ! called by traadv_fct_lf.F90
37   PUBLIC   nonosc             ! called by traadv_fct_lf.F90 - key_agrif
38
39   LOGICAL  ::   l_trd   ! flag to compute trends
40   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
41   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
42   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
43
44   !                                        ! tridiag solver associated indices:
45   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
46   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50#  include "domzgr_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
53   !! $Id$
54   !! Software governed by the CeCILL license (see ./LICENSE)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
59      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE tra_adv_fct  ***
62      !!
63      !! **  Purpose :   Compute the now trend due to total advection of tracers
64      !!               and add it to the general trend of tracer equations
65      !!
66      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
67      !!               (choice through the value of kn_fct)
68      !!               - on the vertical the 4th order is a compact scheme
69      !!               - corrected flux (monotonic correction)
70      !!
71      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
72      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
73      !!             - poleward advective heat and salt transport (ln_diaptr=T)
74      !!----------------------------------------------------------------------
75      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
77      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
78      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
79      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
80      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
81      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
82      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
83      ! TEMP: [tiling] This can be A2D(nn_hls) if using XIOS (subdomain support)
84      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
85      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
86      !
87      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices
88      REAL(wp) ::   ztra                                     ! local scalar
89      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
90      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
91      REAL(wp), DIMENSION(A2D(nn_hls),jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
92      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
93      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
94      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
95      !!----------------------------------------------------------------------
96      !
97      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
98         IF( kt == kit000 )  THEN
99            IF(lwp) WRITE(numout,*)
100            IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
101            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
102         ENDIF
103         !
104         l_trd = .FALSE.            ! set local switches
105         l_hst = .FALSE.
106         l_ptr = .FALSE.
107         ll_zAimp = .FALSE.
108         IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
109         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE.
110         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
111            &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
112         !
113      ENDIF
114
115      !! -- init to 0
116      zwi(:,:,:) = 0._wp
117      zwx(:,:,:) = 0._wp
118      zwy(:,:,:) = 0._wp
119      zwz(:,:,:) = 0._wp
120      ztu(:,:,:) = 0._wp
121      ztv(:,:,:) = 0._wp
122      zltu(:,:,:) = 0._wp
123      zltv(:,:,:) = 0._wp
124      ztw(:,:,:) = 0._wp
125      !
126      IF( l_trd .OR. l_hst )  THEN
127         ALLOCATE( ztrdx(A2D(nn_hls),jpk), ztrdy(A2D(nn_hls),jpk), ztrdz(A2D(nn_hls),jpk) )
128         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
129      ENDIF
130      !
131      IF( l_ptr ) THEN
132         ALLOCATE( zptry(A2D(nn_hls),jpk) )
133         zptry(:,:,:) = 0._wp
134      ENDIF
135      !
136      ! If adaptive vertical advection, check if it is needed on this PE at this time
137      IF( ln_zad_Aimp ) THEN
138         IF( MAXVAL( ABS( wi(A2D(nn_hls),:) ) ) > 0._wp ) ll_zAimp = .TRUE.
139      END IF
140      ! If active adaptive vertical advection, build tridiagonal matrix
141      IF( ll_zAimp ) THEN
142         ALLOCATE(zwdia(A2D(nn_hls),jpk), zwinf(A2D(nn_hls),jpk), zwsup(A2D(nn_hls),jpk))
143         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
144            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
145            &                               / e3t(ji,jj,jk,Krhs)
146            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
147            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
148         END_3D
149      END IF
150      !
151      DO jn = 1, kjpt            !==  loop over the tracers  ==!
152         !
153         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
154         !                    !* upstream tracer flux in the i and j direction
155         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
156            ! upstream scheme
157            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
158            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
159            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
160            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
161            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
162            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
163         END_3D
164         !                               !* upstream tracer flux in the k direction *!
165         DO_3D( 1, 1, 1, 1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
166            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
167            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
168            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
169         END_3D
170         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
171            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
172               DO_2D( 1, 1, 1, 1 )
173                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
174               END_2D
175            ELSE                                        ! no cavities: only at the ocean surface
176               DO_2D( 1, 1, 1, 1 )
177                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
178               END_2D
179            ENDIF
180         ENDIF
181         !
182         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )   !* trend and after field with monotonic scheme
183            !                               ! total intermediate advective trends
184            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
185               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
186               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
187            !                               ! update and guess with monotonic sheme
188            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
189               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
190            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
191               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
192         END_3D
193
194         IF ( ll_zAimp ) THEN
195            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
196            !
197            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
198            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
199               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
200               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
201               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
202               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
203            END_3D
204            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
205               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
206                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
207            END_3D
208            !
209         END IF
210         !
211         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
212            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
213         END IF
214         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
215         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:)
216         !
217         !        !==  anti-diffusive flux : high order minus low order  ==!
218         !
219         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
220         !
221         CASE(  2  )                   !- 2nd order centered
222            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
223               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
224               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
225            END_3D
226            !
227         CASE(  4  )                   !- 4th order centered
228            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
229            zltv(:,:,jpk) = 0._wp
230            DO jk = 1, jpkm1                 ! Laplacian
231               DO_2D( 1, 0, 1, 0 )                 ! 1st derivative (gradient)
232                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
233                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
234               END_2D
235               DO_2D( 0, 0, 0, 0 )                 ! 2nd derivative * 1/ 6
236                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
237                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
238               END_2D
239            END DO
240            ! NOTE [ comm_cleanup ] : need to change sign to ensure halo 1 - halo 2 compatibility
241            CALL lbc_lnk( 'traadv_fct', zltu, 'T', -1.0_wp , zltv, 'T', -1.0_wp, ld4only= .TRUE. )   ! Lateral boundary cond. (unchanged sgn)
242            !
243            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
244               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
245               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
246               !                                                        ! C4 minus upstream advective fluxes
247               ! round brackets added to fix the order of floating point operations
248               ! needed to ensure halo 1 - halo 2 compatibility
249               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + ( zltu(ji,jj,jk) - zltu(ji+1,jj,jk)   &
250                             &                                     )                                     & ! bracket for halo 1 - halo 2 compatibility
251                             &                          ) - zwx(ji,jj,jk)
252               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + ( zltv(ji,jj,jk) - zltv(ji,jj+1,jk)   &
253                             &                                     )                                     & ! bracket for halo 1 - halo 2 compatibility
254                             &                          ) - zwy(ji,jj,jk)
255            END_3D
256            !
257         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
258            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
259            ztv(:,:,jpk) = 0._wp
260            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    ! 1st derivative (gradient)
261               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
262               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
263            END_3D
264            IF (nn_hls==1) CALL lbc_lnk( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp, ld4only= .TRUE. )   ! Lateral boundary cond. (unchanged sgn)
265            !
266            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
267               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
268               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
269               !                                                  ! C4 interpolation of T at u- & v-points (x2)
270               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
271               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
272               !                                                  ! C4 minus upstream advective fluxes
273               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
274               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
275            END_3D
276            IF (nn_hls==2) CALL lbc_lnk( 'traadv_fct', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
277            !
278         END SELECT
279         !
280         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
281         !
282         CASE(  2  )                   !- 2nd order centered
283            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
284               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
285                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
286            END_3D
287            !
288         CASE(  4  )                   !- 4th order COMPACT
289            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
290            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
291               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
292            END_3D
293            !
294         END SELECT
295         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
296            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
297         ENDIF
298         !
299         IF (nn_hls==1) THEN
300            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
301         ELSE
302            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
303         END IF
304         !
305         IF ( ll_zAimp ) THEN
306            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !* trend and after field with monotonic scheme
307               !                                                ! total intermediate advective trends
308               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
309                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
310                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
311               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
312            END_3D
313            !
314            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
315            !
316            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
317               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
318               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
319               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
320            END_3D
321         END IF
322         !
323         !        !==  monotonicity algorithm  ==!
324         !
325         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
326         !
327         !        !==  final trend with corrected fluxes  ==!
328         !
329         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
330            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
331               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
332               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
333            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
334            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
335         END_3D
336         !
337         IF ( ll_zAimp ) THEN
338            !
339            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
340            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
341               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
342               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
343               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
344               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
345            END_3D
346            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
347               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
348                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
349            END_3D
350         END IF
351         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
352            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
353            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
354            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
355            !
356            IF( l_trd ) THEN              ! trend diagnostics
357               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
358               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
359               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
360            ENDIF
361            !                             ! heat/salt transport
362            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
363            !
364         ENDIF
365         IF( l_ptr ) THEN              ! "Poleward" transports
366            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
367            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
368         ENDIF
369         !
370      END DO                     ! end of tracer loop
371      !
372      IF ( ll_zAimp ) THEN
373         DEALLOCATE( zwdia, zwinf, zwsup )
374      ENDIF
375      IF( l_trd .OR. l_hst ) THEN
376         DEALLOCATE( ztrdx, ztrdy, ztrdz )
377      ENDIF
378      IF( l_ptr ) THEN
379         DEALLOCATE( zptry )
380      ENDIF
381      !
382   END SUBROUTINE tra_adv_fct
383
384
385   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
386      !!---------------------------------------------------------------------
387      !!                    ***  ROUTINE nonosc  ***
388      !!
389      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
390      !!       scheme and the before field by a nonoscillatory algorithm
391      !!
392      !! **  Method  :   ... ???
393      !!       warning : pbef and paft must be masked, but the boundaries
394      !!       conditions on the fluxes are not necessary zalezak (1979)
395      !!       drange (1995) multi-dimensional forward-in-time and upstream-
396      !!       in-space based differencing for fluid
397      !!----------------------------------------------------------------------
398      INTEGER                         , INTENT(in   ) ::   Kmm             ! time level index
399      REAL(wp)                        , INTENT(in   ) ::   p2dt            ! tracer time-step
400      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pbef            ! before field
401      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(in   ) ::   paft            ! after field
402      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
403      !
404      INTEGER  ::   ji, jj, jk   ! dummy loop indices
405      INTEGER  ::   ikm1         ! local integer
406      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
407      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
408      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zbetup, zbetdo, zbup, zbdo
409      !!----------------------------------------------------------------------
410      !
411      zbig  = 1.e+40_dp
412      zrtrn = 1.e-15_dp
413      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
414
415      ! Search local extrema
416      ! --------------------
417      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
418      DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpk )
419         zbup(ji,jj,jk) = MAX( pbef(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
420            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) )  )
421         zbdo(ji,jj,jk) = MIN( pbef(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
422            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) )  )
423      END_3D
424
425      DO jk = 1, jpkm1
426         ikm1 = MAX(jk-1,1)
427         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
428
429            ! search maximum in neighbourhood
430            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
431               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
432               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
433               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
434
435            ! search minimum in neighbourhood
436            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
437               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
438               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
439               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
440
441            ! positive part of the flux
442            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
443               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
444               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
445
446            ! negative part of the flux
447            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
448               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
449               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
450
451            ! up & down beta terms
452            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
453            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
454            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
455         END_2D
456      END DO
457      IF (nn_hls==1) CALL lbc_lnk( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp, ld4only= .TRUE. )   ! lateral boundary cond. (unchanged sign)
458
459      ! 3. monotonic flux in the i & j direction (paa & pbb)
460      ! ----------------------------------------
461      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
462         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
463         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
464         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
465         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
466
467         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
468         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
469         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
470         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
471
472      ! monotonic flux in the k direction, i.e. pcc
473      ! -------------------------------------------
474         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
475         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
476         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
477         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
478      END_3D
479      !
480   END SUBROUTINE nonosc
481
482
483   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
484      !!----------------------------------------------------------------------
485      !!                  ***  ROUTINE interp_4th_cpt_org  ***
486      !!
487      !! **  Purpose :   Compute the interpolation of tracer at w-point
488      !!
489      !! **  Method  :   4th order compact interpolation
490      !!----------------------------------------------------------------------
491      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
492      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
493      !
494      INTEGER :: ji, jj, jk   ! dummy loop integers
495      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
496      !!----------------------------------------------------------------------
497
498      DO_3D( 1, 1, 1, 1, 3, jpkm1 )       !==  build the three diagonal matrix  ==!
499         zwd (ji,jj,jk) = 4._wp
500         zwi (ji,jj,jk) = 1._wp
501         zws (ji,jj,jk) = 1._wp
502         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
503         !
504         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
505            zwd (ji,jj,jk) = 1._wp
506            zwi (ji,jj,jk) = 0._wp
507            zws (ji,jj,jk) = 0._wp
508            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
509         ENDIF
510      END_3D
511      !
512      jk = 2                                    ! Switch to second order centered at top
513      DO_2D( 1, 1, 1, 1 )
514         zwd (ji,jj,jk) = 1._wp
515         zwi (ji,jj,jk) = 0._wp
516         zws (ji,jj,jk) = 0._wp
517         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
518      END_2D
519      !
520      !                       !==  tridiagonal solve  ==!
521      DO_2D( 1, 1, 1, 1 )           ! first recurrence
522         zwt(ji,jj,2) = zwd(ji,jj,2)
523      END_2D
524      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
525         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
526      END_3D
527      !
528      DO_2D( 1, 1, 1, 1 )           ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
529         pt_out(ji,jj,2) = zwrm(ji,jj,2)
530      END_2D
531      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
532         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
533      END_3D
534
535      DO_2D( 1, 1, 1, 1 )           ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
536         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
537      END_2D
538      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
539         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
540      END_3D
541      !
542   END SUBROUTINE interp_4th_cpt_org
543
544
545   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
546      !!----------------------------------------------------------------------
547      !!                  ***  ROUTINE interp_4th_cpt  ***
548      !!
549      !! **  Purpose :   Compute the interpolation of tracer at w-point
550      !!
551      !! **  Method  :   4th order compact interpolation
552      !!----------------------------------------------------------------------
553      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
554      REAL(wp),DIMENSION(A2D(nn_hls)    ,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
555      !
556      INTEGER ::   ji, jj, jk   ! dummy loop integers
557      INTEGER ::   ikt, ikb     ! local integers
558      REAL(wp),DIMENSION(A2D(nn_hls),jpk) :: zwd, zwi, zws, zwrm, zwt
559      !!----------------------------------------------------------------------
560      !
561      !                      !==  build the three diagonal matrix & the RHS  ==!
562      !
563      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )    ! interior (from jk=3 to jpk-1)
564         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
565         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
566         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
567         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
568            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
569      END_3D
570      !
571!!gm
572!      SELECT CASE( kbc )               !* boundary condition
573!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
574!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
575!      END SELECT
576!!gm
577      !
578      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
579         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
580      END IF
581      !
582      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! 2nd order centered at top & bottom
583         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
584         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
585         !
586         zwd (ji,jj,ikt) = 1._wp          ! top
587         zwi (ji,jj,ikt) = 0._wp
588         zws (ji,jj,ikt) = 0._wp
589         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
590         !
591         zwd (ji,jj,ikb) = 1._wp          ! bottom
592         zwi (ji,jj,ikb) = 0._wp
593         zws (ji,jj,ikb) = 0._wp
594         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )
595      END_2D
596      !
597      !                       !==  tridiagonal solver  ==!
598      !
599      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
600         zwt(ji,jj,2) = zwd(ji,jj,2)
601      END_2D
602      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
603         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
604      END_3D
605      !
606      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
607         pt_out(ji,jj,2) = zwrm(ji,jj,2)
608      END_2D
609      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
610         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
611      END_3D
612
613      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
614         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
615      END_2D
616      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, 2, -1 )
617         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
618      END_3D
619      !
620   END SUBROUTINE interp_4th_cpt
621
622
623   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
624      !!----------------------------------------------------------------------
625      !!                  ***  ROUTINE tridia_solver  ***
626      !!
627      !! **  Purpose :   solve a symmetric 3diagonal system
628      !!
629      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
630      !!
631      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
632      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
633      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
634      !!             (        ...          )( ... )   ( ...  )
635      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
636      !!
637      !!        M is decomposed in the product of an upper and lower triangular matrix.
638      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
639      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
640      !!        The solution is pta.
641      !!        The 3d array zwt is used as a work space array.
642      !!----------------------------------------------------------------------
643      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
644      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
645      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
646      INTEGER                    , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
647      !                                                             ! =0 pt at t-level
648      INTEGER ::   ji, jj, jk   ! dummy loop integers
649      INTEGER ::   kstart       ! local indices
650      REAL(wp),DIMENSION(A2D(nn_hls),jpk) ::   zwt   ! 3D work array
651      !!----------------------------------------------------------------------
652      !
653      kstart =  1  + klev
654      !
655      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                         !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
656         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
657      END_2D
658      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
659         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
660      END_3D
661      !
662      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                        !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
663         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
664      END_2D
665      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
666         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
667      END_3D
668
669      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                       !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
670         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
671      END_2D
672      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, kstart, -1 )
673         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
674      END_3D
675      !
676   END SUBROUTINE tridia_solver
677
678   !!======================================================================
679END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.