New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in NEMO/branches/2021/dev_r14393_HPC-03_Mele_Comm_Cleanup/src/OCE/TRA – NEMO

source: NEMO/branches/2021/dev_r14393_HPC-03_Mele_Comm_Cleanup/src/OCE/TRA/traadv_mus.F90 @ 14801

Last change on this file since 14801 was 14801, checked in by francesca, 3 years ago

add loop fusion to DYN and TRA modules - ticket #2607

  • Property svn:keywords set to Id
File size: 14.5 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26
27   !
28   USE iom            ! XIOS library
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
33#if defined key_loop_fusion
34   USE traadv_mus_lf  ! MUSCL    scheme            (tra_adv_mus  routine - loop fusion version)
35#endif
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
41
42   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
43   !                                                           !  and in closed seas (orca 2 and 1 configurations)
44   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
45
46   LOGICAL  ::   l_trd   ! flag to compute trends
47   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
48   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
49
50   !! * Substitutions
51#  include "do_loop_substitute.h90"
52#  include "domzgr_substitute.h90"
53   !!----------------------------------------------------------------------
54   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
55   !! $Id$
56   !! Software governed by the CeCILL license (see ./LICENSE)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pU, pV, pW,             &
61      &                    Kbb, Kmm, pt, kjpt, Krhs, ld_msc_ups )
62      !!----------------------------------------------------------------------
63      !!                    ***  ROUTINE tra_adv_mus  ***
64      !!
65      !! ** Purpose :   Compute the now trend due to total advection of tracers
66      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
67      !!              Conservation Laws) and add it to the general tracer trend.
68      !!
69      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
70      !!              ld_msc_ups=T :
71      !!
72      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
73      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
74      !!             - poleward advective heat and salt transport (ln_diaptr=T)
75      !!
76      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
77      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
78      !!----------------------------------------------------------------------
79      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
80      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
81      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
82      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
83      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
84      LOGICAL                                  , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
85      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
86      ! TEMP: [tiling] This can be A2D(nn_hls) if using XIOS (subdomain support)
87      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
88      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
89      !
90      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
91      INTEGER  ::   ierr             ! local integer
92      REAL(wp) ::   zu, z0u, zzwx, zw , zalpha   ! local scalars
93      REAL(wp) ::   zv, z0v, zzwy, z0w           !   -      -
94      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zwx, zslpx   ! 3D workspace
95      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zwy, zslpy   ! -      -
96      !!----------------------------------------------------------------------
97      !
98#if defined key_loop_fusion
99      CALL tra_adv_mus_lf ( kt, nit000, cdtype, p2dt, pU, pV, pW, Kbb, Kmm, pt, kjpt, Krhs, ld_msc_ups )
100#else
101      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
102         IF( kt == kit000 )  THEN
103            IF(lwp) WRITE(numout,*)
104            IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
105            IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
106            IF(lwp) WRITE(numout,*) '~~~~~~~'
107            IF(lwp) WRITE(numout,*)
108            !
109            ! Upstream / MUSCL scheme indicator
110            !
111            ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
112            xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
113            !
114            IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
115               ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
116               upsmsk(:,:) = 0._wp                             ! not upstream by default
117               !
118               DO jk = 1, jpkm1
119                  xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
120                     &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
121                     &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
122               END DO
123            ENDIF
124            !
125         ENDIF
126         !
127         l_trd = .FALSE.
128         l_hst = .FALSE.
129         l_ptr = .FALSE.
130         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
131         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) )  )   l_ptr = .TRUE.
132         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
133            &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
134      ENDIF
135      !
136      DO jn = 1, kjpt            !==  loop over the tracers  ==!
137         !
138         !                          !* Horizontal advective fluxes
139         !
140         !                                !-- first guess of the slopes
141         zwx(:,:,jpk) = 0._wp                   ! bottom values
142         zwy(:,:,jpk) = 0._wp
143         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
144            zwx(ji,jj,jk) = umask(ji,jj,jk) * ( pt(ji+1,jj,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
145            zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( pt(ji,jj+1,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
146         END_3D
147         !                                !-- Slopes of tracer
148         zslpx(:,:,jpk) = 0._wp                 ! bottom values
149         zslpy(:,:,jpk) = 0._wp
150         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
151            zslpx(ji,jj,jk) =                       ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
152               &            * ( 0.25 + SIGN( 0.25_wp, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
153            zslpy(ji,jj,jk) =                       ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
154               &            * ( 0.25 + SIGN( 0.25_wp, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
155         END_3D
156         !
157         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !-- Slopes limitation
158            zslpx(ji,jj,jk) = SIGN( 1.0_wp, zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
159               &                                                     2.*ABS( zwx  (ji-1,jj,jk) ),   &
160               &                                                     2.*ABS( zwx  (ji  ,jj,jk) ) )
161            zslpy(ji,jj,jk) = SIGN( 1.0_wp, zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
162               &                                                     2.*ABS( zwy  (ji,jj-1,jk) ),   &
163               &                                                     2.*ABS( zwy  (ji,jj  ,jk) ) )
164         END_3D
165         ! NOTE [ comm_cleanup ] : need to change sign to ensure halo 1 - halo 2 compatibility
166         IF ( nn_hls==1 ) CALL lbc_lnk( 'traadv_mus', zslpx, 'T', -1.0_wp , zslpy, 'T', -1.0_wp )   ! lateral boundary conditions   (changed sign)
167         !
168         DO_3D( 1, 0, 1, 0, 1, jpkm1 )    !-- MUSCL horizontal advective fluxes
169            ! MUSCL fluxes
170            z0u = SIGN( 0.5_wp, pU(ji,jj,jk) )
171            zalpha = 0.5 - z0u
172            zu  = z0u - 0.5 * pU(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,Kmm)
173            zzwx = pt(ji+1,jj,jk,jn,Kbb) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
174            zzwy = pt(ji  ,jj,jk,jn,Kbb) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
175            zwx(ji,jj,jk) = pU(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
176            !
177            z0v = SIGN( 0.5_wp, pV(ji,jj,jk) )
178            zalpha = 0.5 - z0v
179            zv  = z0v - 0.5 * pV(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,Kmm)
180            zzwx = pt(ji,jj+1,jk,jn,Kbb) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
181            zzwy = pt(ji,jj  ,jk,jn,Kbb) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
182            zwy(ji,jj,jk) = pV(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
183         END_3D
184         !
185         DO_3D( 0, 0, 0, 0, 1, jpkm1 )    !-- Tracer advective trend
186            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
187            &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
188            &                                   * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
189         END_3D
190         !                                ! trend diagnostics
191         IF( l_trd )  THEN
192            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, zwx, pU, pt(:,:,:,jn,Kbb) )
193            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, zwy, pV, pt(:,:,:,jn,Kbb) )
194         END IF
195         !                                 ! "Poleward" heat and salt transports
196         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
197         !                                 !  heat transport
198         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
199         !
200         !                          !* Vertical advective fluxes
201         !
202         !                                !-- first guess of the slopes
203         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
204         zwx(:,:,jpk) = 0._wp
205         DO_3D( 1, 1, 1, 1, 2, jpkm1 )                ! interior values
206            zwx(ji,jj,jk) = tmask(ji,jj,jk) * ( pt(ji,jj,jk-1,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
207         END_3D
208         !                                !-- Slopes of tracer
209         zslpx(:,:,1) = 0._wp                   ! surface values
210         DO_3D( 1, 1, 1, 1, 2, jpkm1 )
211            zslpx(ji,jj,jk) =                        ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
212               &            * (  0.25 + SIGN( 0.25_wp, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
213         END_3D
214         DO_3D( 1, 1, 1, 1, 2, jpkm1 )    !-- Slopes limitation
215            zslpx(ji,jj,jk) = SIGN( 1.0_wp, zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
216               &                                                     2.*ABS( zwx  (ji,jj,jk+1) ),   &
217               &                                                     2.*ABS( zwx  (ji,jj,jk  ) )  )
218         END_3D
219         DO_3D( 0, 0, 0, 0, 1, jpk-2 )    !-- vertical advective flux
220            z0w = SIGN( 0.5_wp, pW(ji,jj,jk+1) )
221            zalpha = 0.5 + z0w
222            zw  = z0w - 0.5 * pW(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w(ji,jj,jk+1,Kmm)
223            zzwx = pt(ji,jj,jk+1,jn,Kbb) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
224            zzwy = pt(ji,jj,jk  ,jn,Kbb) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
225            zwx(ji,jj,jk+1) = pW(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
226         END_3D
227         IF( ln_linssh ) THEN                   ! top values, linear free surface only
228            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
229               DO_2D( 1, 1, 1, 1 )
230                  zwx(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)
231               END_2D
232            ELSE                                      ! no cavities: only at the ocean surface
233               DO_2D( 1, 1, 1, 1 )
234                  zwx(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
235               END_2D
236            ENDIF
237         ENDIF
238         !
239         DO_3D( 0, 0, 0, 0, 1, jpkm1 )     !-- vertical advective trend
240            pt(ji,jj,jk,jn,Krhs) =  pt(ji,jj,jk,jn,Krhs) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )   &
241               &                                      * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
242         END_3D
243         !                                ! send trends for diagnostic
244         IF( l_trd )  CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zwx, pW, pt(:,:,:,jn,Kbb) )
245         !
246      END DO                     ! end of tracer loop
247      !
248#endif
249   END SUBROUTINE tra_adv_mus
250
251   !!======================================================================
252END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.