source: NEMO/branches/2021/dev_r14393_HPC-03_Mele_Comm_Cleanup/src/OCE/TRA/traldf_triad.F90 @ 14538

Last change on this file since 14538 was 14538, checked in by francesca, 4 months ago

[comm_cleanup] - ticket #2607

  • Property svn:keywords set to Id
File size: 26.2 KB
Line 
1MODULE traldf_triad
2   !!======================================================================
3   !!                   ***  MODULE  traldf_triad  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec)  Griffies operator (original code)
7   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and active tracers
14   USE dom_oce        ! ocean space and time domain
15   ! TEMP: [tiling] This change not necessary if XIOS has subdomain support
16   USE domtile
17   USE domutl, ONLY : is_tile
18   USE phycst         ! physical constants
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE zdf_oce        ! ocean vertical physics
21   USE ldftra         ! lateral physics: eddy diffusivity
22   USE ldfslp         ! lateral physics: iso-neutral slopes
23   USE traldf_iso     ! lateral diffusion (Madec operator)         (tra_ldf_iso routine)
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26   USE zpshde         ! partial step: hor. derivative     (zps_hde routine)
27   !
28   USE in_out_manager ! I/O manager
29   USE iom            ! I/O library
30   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
31   USE lib_mpp        ! MPP library
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_ldf_triad   ! routine called by traldf.F90
37
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat transport
40
41
42   !! * Substitutions
43#  include "do_loop_substitute.h90"
44#  include "domzgr_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
47   !! $Id$
48   !! Software governed by the CeCILL license (see ./LICENSE)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE tra_ldf_triad( kt, Kmm, kit000, cdtype, pahu, pahv,             &
53      &                                               pgu , pgv , pgui, pgvi, &
54      &                                               pt, pt2, pt_rhs, kjpt, kpass )
55      !!
56      INTEGER                     , INTENT(in   ) ::   kt         ! ocean time-step index
57      INTEGER                     , INTENT(in   ) ::   kit000     ! first time step index
58      CHARACTER(len=3)            , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
59      INTEGER                     , INTENT(in   ) ::   kjpt       ! number of tracers
60      INTEGER                     , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
61      INTEGER                     , INTENT(in   ) ::   Kmm        ! ocean time level indices
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pgu , pgv  ! tracer gradient at pstep levels
64      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
65      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pt         ! tracer (kpass=1) or laplacian of tracer (kpass=2)
66      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pt2        ! tracer (only used in kpass=2)
67      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pt_rhs     ! tracer trend
68      !!
69      CALL tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, is_tile(pahu),                            &
70      &                                              pgu , pgv , is_tile(pgu) , pgui, pgvi, is_tile(pgui), &
71      &                                              pt, is_tile(pt), pt2, is_tile(pt2), pt_rhs, is_tile(pt_rhs), kjpt, kpass )
72   END SUBROUTINE tra_ldf_triad
73
74
75  SUBROUTINE tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, ktah,                   &
76      &                                                pgu , pgv , ktg , pgui, pgvi, ktgi, &
77      &                                                pt, ktt, pt2, ktt2, pt_rhs, ktt_rhs, kjpt, kpass )
78      !!----------------------------------------------------------------------
79      !!                  ***  ROUTINE tra_ldf_triad  ***
80      !!
81      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
82      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
83      !!      add it to the general trend of tracer equation.
84      !!
85      !! ** Method  :   The horizontal component of the lateral diffusive trends
86      !!      is provided by a 2nd order operator rotated along neural or geopo-
87      !!      tential surfaces to which an eddy induced advection can be added
88      !!      It is computed using before fields (forward in time) and isopyc-
89      !!      nal or geopotential slopes computed in routine ldfslp.
90      !!
91      !!      see documentation for the desciption
92      !!
93      !! ** Action :   pt_rhs   updated with the before rotated diffusion
94      !!               ah_wslp2 ....
95      !!               akz   stabilizing vertical diffusivity coefficient (used in trazdf_imp)
96      !!----------------------------------------------------------------------
97      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
98      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
99      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
100      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
101      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
102      INTEGER                              , INTENT(in)    ::   Kmm        ! ocean time level indices
103      INTEGER                              , INTENT(in   ) ::   ktah, ktg, ktgi, ktt, ktt2, ktt_rhs
104      REAL(wp), DIMENSION(A2D_T(ktah),   JPK)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
105      REAL(wp), DIMENSION(A2D_T(ktg),        KJPT), INTENT(in   ) ::   pgu , pgv  ! tracer gradient at pstep levels
106      REAL(wp), DIMENSION(A2D_T(ktgi),       KJPT), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
107      REAL(wp), DIMENSION(A2D_T(ktt),    JPK,KJPT), INTENT(in   ) ::   pt         ! tracer (kpass=1) or laplacian of tracer (kpass=2)
108      REAL(wp), DIMENSION(A2D_T(ktt2),   JPK,KJPT), INTENT(in   ) ::   pt2        ! tracer (only used in kpass=2)
109      REAL(wp), DIMENSION(A2D_T(ktt_rhs),JPK,KJPT), INTENT(inout) ::   pt_rhs     ! tracer trend
110      !
111      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
112      INTEGER  ::  ip,jp,kp         ! dummy loop indices
113      INTEGER  ::  ierr            ! local integer
114      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3    ! local scalars
115      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4    !   -      -
116      REAL(wp) ::  zcoef0, ze3w_2, zsign          !   -      -
117      !
118      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
119      REAL(wp) ::   ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt
120      REAL(wp) ::   zah, zah_slp, zaei_slp
121      REAL(wp), DIMENSION(A2D(nn_hls),0:1)     ::   zdkt3d                         ! vertical tracer gradient at 2 levels
122      REAL(wp), DIMENSION(A2D(nn_hls)        ) ::   z2d                            ! 2D workspace
123      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk) ::   zdit, zdjt, zftu, zftv, ztfw   ! 3D     -
124      ! TEMP: [tiling] This can be A2D(nn_hls) if XIOS has subdomain support
125      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpsi_uw, zpsi_vw
126      !!----------------------------------------------------------------------
127      !
128      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
129         IF( kpass == 1 .AND. kt == kit000 )  THEN
130            IF(lwp) WRITE(numout,*)
131            IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype
132            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
133         ENDIF
134         !
135         l_hst = .FALSE.
136         l_ptr = .FALSE.
137         IF( cdtype == 'TRA' ) THEN
138            IF( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf') )      l_ptr = .TRUE.
139            IF( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.                   &
140            &   iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  )   l_hst = .TRUE.
141         ENDIF
142      ENDIF
143      !
144      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
145      ELSE                    ;   zsign = -1._wp
146      ENDIF
147      !
148      !!----------------------------------------------------------------------
149      !!   0 - calculate  ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw
150      !!----------------------------------------------------------------------
151      !
152      IF( kpass == 1 ) THEN         !==  first pass only  and whatever the tracer is  ==!
153         !
154         ! [comm_cleanup] ! DO_3D( 0, 0, 0, 0, 1, jpk )
155         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk ) 
156            akz     (ji,jj,jk) = 0._wp
157            ah_wslp2(ji,jj,jk) = 0._wp
158         END_3D
159         !
160         DO ip = 0, 1                            ! i-k triads
161            DO kp = 0, 1
162               ! [comm_cleanup] ! DO_3D( 0, 0, 0, 0, 1, jpkm1 )
163               DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 ) 
164                  ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm)
165                  zbu   = e1e2u(ji-ip,jj) * e3u(ji-ip,jj,jk,Kmm)
166                  zah   = 0.25_wp * pahu(ji-ip,jj,jk)
167                  zslope_skew = triadi_g(ji,jj,jk,1-ip,kp)
168                  ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth)
169                  zslope2 = zslope_skew + ( gdept(ji-ip+1,jj,jk,Kmm) - gdept(ji-ip,jj,jk,Kmm) ) * r1_e1u(ji-ip,jj) * umask(ji-ip,jj,jk+kp)
170                  zslope2 = zslope2 *zslope2
171                  ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji,jj) * zslope2
172                  akz     (ji,jj,jk+kp) = akz     (ji,jj,jk+kp) + zah * r1_e1u(ji-ip,jj)       &
173                     &                                                      * r1_e1u(ji-ip,jj) * umask(ji-ip,jj,jk+kp)
174                     !
175               END_3D
176            END DO
177         END DO
178         !
179         DO jp = 0, 1                            ! j-k triads
180            DO kp = 0, 1
181               ! [comm_cleanup] ! DO_3D( 0, 0, 0, 0, 1, jpkm1 )
182               DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 ) 
183                  ze3wr = 1.0_wp / e3w(ji,jj,jk+kp,Kmm)
184                  zbv   = e1e2v(ji,jj-jp) * e3v(ji,jj-jp,jk,Kmm)
185                  zah   = 0.25_wp * pahv(ji,jj-jp,jk)
186                  zslope_skew = triadj_g(ji,jj,jk,1-jp,kp)
187                  ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
188                  !    (do this by *adding* gradient of depth)
189                  zslope2 = zslope_skew + ( gdept(ji,jj-jp+1,jk,Kmm) - gdept(ji,jj-jp,jk,Kmm) ) * r1_e2v(ji,jj-jp) * vmask(ji,jj-jp,jk+kp)
190                  zslope2 = zslope2 * zslope2
191                  ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj) * zslope2
192                  akz     (ji,jj,jk+kp) = akz     (ji,jj,jk+kp) + zah * r1_e2v(ji,jj-jp)     &
193                     &                                                      * r1_e2v(ji,jj-jp) * vmask(ji,jj-jp,jk+kp)
194                  !
195               END_3D
196            END DO
197         END DO
198         !
199         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
200            !
201            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
202               ! [comm_cleanup] ! DO_3D( 0, 0, 0, 0, 2, jpkm1 )
203               DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) 
204                  akz(ji,jj,jk) = 16._wp           &
205                     &   * ah_wslp2   (ji,jj,jk)   &
206                     &   * (  akz     (ji,jj,jk)   &
207                     &      + ah_wslp2(ji,jj,jk)   &
208                     &        / ( e3w (ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) )  )
209               END_3D
210            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
211               ! [comm_cleanup] ! DO_3D( 0, 0, 0, 0, 2, jpkm1 )
212               DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) 
213                  ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm)
214                  zcoef0 = rDt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
215                  akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt
216               END_3D
217           ENDIF
218           !
219         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
220            ! [comm_cleanup] ! DO_3D( 0, 0, 0, 0, 1, jpk )
221            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk ) 
222               akz(ji,jj,jk) = ah_wslp2(ji,jj,jk)
223            END_3D
224         ENDIF
225         !
226         ! TEMP: [tiling] These changes not necessary if XIOS has subdomain support
227         IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
228            IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) THEN
229               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
230
231               zpsi_uw(:,:,:) = 0._wp
232               zpsi_vw(:,:,:) = 0._wp
233
234               DO jp = 0, 1
235                  DO kp = 0, 1
236                     ! [comm_cleanup] ! DO_3D( 1, 0, 1, 0, 1, jpkm1 )
237                     DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 ) 
238                        zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) &
239                           & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * triadi_g(ji+jp,jj,jk,1-jp,kp)
240                        zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) &
241                           & + 0.25_wp * aeiv(ji,jj,jk) * e1v(ji,jj) * triadj_g(ji,jj+jp,jk,1-jp,kp)
242                     END_3D
243                  END DO
244               END DO
245               CALL ldf_eiv_dia( zpsi_uw, zpsi_vw, Kmm )
246
247               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = nijtile )
248            ENDIF
249         ENDIF
250         !
251      ENDIF                                  !==  end 1st pass only  ==!
252      !
253      !                                                           ! ===========
254      DO jn = 1, kjpt                                             ! tracer loop
255         !                                                        ! ===========
256         ! Zero fluxes for each tracer
257!!gm  this should probably be done outside the jn loop
258         ztfw(:,:,:) = 0._wp
259         zftu(:,:,:) = 0._wp
260         zftv(:,:,:) = 0._wp
261         !
262         ! [comm_cleanup] ! DO_3D( 1, 0, 1, 0, 1, jpkm1 )    !==  before lateral T & S gradients at T-level jk  ==!
263         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 ) 
264            zdit(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk)
265            zdjt(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
266         END_3D
267         IF( ln_zps .AND. l_grad_zps ) THEN    ! partial steps: correction at top/bottom ocean level
268            ! [comm_cleanup] ! DO_2D( 1, 0, 1, 0 )                    ! bottom level
269            DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) 
270               zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)
271               zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
272            END_2D
273            IF( ln_isfcav ) THEN                   ! top level (ocean cavities only)
274               ! [comm_cleanup] ! DO_2D( 1, 0, 1, 0 )
275               DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) 
276                  IF( miku(ji,jj)  > 1 )   zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn)
277                  IF( mikv(ji,jj)  > 1 )   zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn)
278               END_2D
279            ENDIF
280         ENDIF
281         !
282         !!----------------------------------------------------------------------
283         !!   II - horizontal trend  (full)
284         !!----------------------------------------------------------------------
285         !
286         DO jk = 1, jpkm1
287            !                    !==  Vertical tracer gradient at level jk and jk+1
288            ! [comm_cleanup] ! DO_2D( 1, 1, 1, 1 )
289            DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) 
290               zdkt3d(ji,jj,1) = ( pt(ji,jj,jk,jn) - pt(ji,jj,jk+1,jn) ) * tmask(ji,jj,jk+1)
291            END_2D
292            !
293            !                    ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1)
294            IF( jk == 1 ) THEN   ;   zdkt3d(:,:,0) = zdkt3d(:,:,1)
295            ELSE
296               ! [comm_cleanup] ! DO_2D( 1, 1, 1, 1 )
297               DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) 
298                  zdkt3d(ji,jj,0) = ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) * tmask(ji,jj,jk)
299               END_2D
300            ENDIF
301            !
302            zaei_slp = 0._wp
303            !
304            IF( ln_botmix_triad ) THEN
305               DO ip = 0, 1              !==  Horizontal & vertical fluxes
306                  DO kp = 0, 1
307                     ! [comm_cleanup] ! DO_2D( 1, 0, 1, 0 )
308                     DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) 
309                        ze1ur = r1_e1u(ji,jj)
310                        zdxt  = zdit(ji,jj,jk) * ze1ur
311                        ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm)
312                        zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
313                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
314                        zslope_iso  = triadi  (ji+ip,jj,jk,1-ip,kp)
315                        !
316                        zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm)
317                        ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????   ahu is masked....
318                        zah = pahu(ji,jj,jk)
319                        zah_slp  = zah * zslope_iso
320                        IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew
321                        zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
322                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt                 * zbu * ze3wr
323                     END_2D
324                  END DO
325               END DO
326               !
327               DO jp = 0, 1
328                  DO kp = 0, 1
329                     ! [comm_cleanup] ! DO_2D( 1, 0, 1, 0 )
330                     DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) 
331                        ze2vr = r1_e2v(ji,jj)
332                        zdyt  = zdjt(ji,jj,jk) * ze2vr
333                        ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm)
334                        zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
335                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
336                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
337                        zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
338                        ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????  ahv is masked...
339                        zah = pahv(ji,jj,jk)
340                        zah_slp = zah * zslope_iso
341                        IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew
342                        zftv(ji,jj   ,jk   ) = zftv(ji,jj   ,jk   ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
343                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt                * zbv * ze3wr
344                     END_2D
345                  END DO
346               END DO
347               !
348            ELSE
349               !
350               DO ip = 0, 1               !==  Horizontal & vertical fluxes
351                  DO kp = 0, 1
352                     ! [comm_cleanup] ! DO_2D( 1, 0, 1, 0 )
353                     DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) 
354                        ze1ur = r1_e1u(ji,jj)
355                        zdxt  = zdit(ji,jj,jk) * ze1ur
356                        ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm)
357                        zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
358                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
359                        zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
360                        !
361                        zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm)
362                        ! ln_botmix_triad is .F. mask zah for bottom half cells
363                        zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp)         ! pahu(ji+ip,jj,jk)   ===>>  ????
364                        zah_slp  = zah * zslope_iso
365                        IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew        ! aeit(ji+ip,jj,jk)*zslope_skew
366                        zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
367                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
368                     END_2D
369                  END DO
370               END DO
371               !
372               DO jp = 0, 1
373                  DO kp = 0, 1
374                     ! [comm_cleanup] ! DO_2D( 1, 0, 1, 0 )
375                     DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) 
376                        ze2vr = r1_e2v(ji,jj)
377                        zdyt  = zdjt(ji,jj,jk) * ze2vr
378                        ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm)
379                        zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
380                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
381                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
382                        zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
383                        ! ln_botmix_triad is .F. mask zah for bottom half cells
384                        zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp)         ! pahv(ji,jj+jp,jk)  ????
385                        zah_slp = zah * zslope_iso
386                        IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew        ! aeit(ji,jj+jp,jk)*zslope_skew
387                        zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
388                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
389                     END_2D
390                  END DO
391               END DO
392            ENDIF
393            !                             !==  horizontal divergence and add to the general trend  ==!
394            ! [comm_cleanup] ! DO_2D( 0, 0, 0, 0 )
395            DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) 
396               pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn)    &
397                  &                       + zsign * (  zftu(ji-1,jj  ,jk) - zftu(ji,jj,jk)       &
398                  &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )   &
399                  &                                        / (  e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm)  )
400            END_2D
401            !
402         END DO
403         !
404         !                                !==  add the vertical 33 flux  ==!
405         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
406            ! [comm_cleanup] ! DO_3D( 0, 0, 1, 0, 2, jpkm1 )
407            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) 
408               ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk)   &
409                  &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
410                  &                            * (  pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) )
411            END_3D
412         ELSE                                   ! bilaplacian
413            SELECT CASE( kpass )
414            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
415               ! [comm_cleanup] ! DO_3D( 0, 0, 1, 0, 2, jpkm1 )
416               DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) 
417                  ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk)             &
418                     &                            * ah_wslp2(ji,jj,jk) * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) )
419               END_3D
420            CASE(  2  )                            ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt  and pt2 gradients, resp.
421               ! [comm_cleanup] ! DO_3D( 0, 0, 1, 0, 2, jpkm1 )
422               DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) 
423                  ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk)                      &
424                     &                            * (  ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) )   &
425                     &                               + akz     (ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) )   )
426               END_3D
427            END SELECT
428         ENDIF
429         !
430         ! [comm_cleanup] ! DO_3D( 0, 0, 0, 0, 1, jpkm1 )      !==  Divergence of vertical fluxes added to pta  ==!
431         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 ) 
432            pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn)    &
433            &                                  + zsign * (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
434               &                                              / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) )
435         END_3D
436         !
437         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
438             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
439            !
440            !                          ! "Poleward" diffusive heat or salt transports (T-S case only)
441            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:)  )
442            !                          ! Diffusive heat transports
443            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) )
444            !
445         ENDIF                                                    !== end pass selection  ==!
446         !
447         !                                                        ! ===============
448      END DO                                                      ! end tracer loop
449      !                                                           ! ===============
450   END SUBROUTINE tra_ldf_triad_t
451
452   !!==============================================================================
453END MODULE traldf_triad
Note: See TracBrowser for help on using the repository browser.