New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in NEMO/branches/2021/dev_r14393_HPC-03_Mele_Comm_Cleanup/src/TOP/TRP – NEMO

source: NEMO/branches/2021/dev_r14393_HPC-03_Mele_Comm_Cleanup/src/TOP/TRP/trcadv.F90 @ 14801

Last change on this file since 14801 was 14801, checked in by francesca, 3 years ago

add loop fusion to DYN and TRA modules - ticket #2607

  • Property svn:keywords set to Id
File size: 14.0 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2010-06  (C. Ethe)   Adapted to passive tracers
8   !!            3.7  !  2014-05  (G. Madec, C. Ethe)  Add 2nd/4th order cases for CEN and FCT schemes
9   !!            4.0  !  2017-09  (G. Madec)  remove vertical time-splitting option
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_adv       : compute ocean tracer advection trend
16   !!   trc_adv_ini   : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE par_trc        ! need jptra, number of passive tracers
19   USE oce_trc        ! ocean dynamics and active tracers
20   USE trc            ! ocean passive tracers variables
21   USE sbcwave        ! wave module
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE traadv_cen     ! centered scheme           (tra_adv_cen  routine)
24   USE traadv_fct     ! FCT      scheme           (tra_adv_fct  routine)
25   USE traadv_mus     ! MUSCL    scheme           (tra_adv_mus  routine)
26   USE traadv_ubs     ! UBS      scheme           (tra_adv_ubs  routine)
27   USE traadv_qck     ! QUICKEST scheme           (tra_adv_qck  routine)
28   USE tramle         ! ML eddy induced transport (tra_adv_mle  routine)
29   USE ldftra         ! lateral diffusion: eddy diffusivity & EIV coeff.
30   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
31   !
32   USE prtctl         ! control print
33   USE timing         ! Timing
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   trc_adv       ! called by trctrp.F90
39   PUBLIC   trc_adv_ini   ! called by trcini.F90
40
41   !                            !!* Namelist namtrc_adv *
42   LOGICAL ::   ln_trcadv_OFF    ! no advection on passive tracers
43   LOGICAL ::   ln_trcadv_cen    ! centered scheme flag
44   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
45   LOGICAL ::   ln_trcadv_fct    ! FCT scheme flag
46   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
47   LOGICAL ::   ln_trcadv_mus    ! MUSCL scheme flag
48   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
49   LOGICAL ::   ln_trcadv_ubs    ! UBS scheme flag
50   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
51   LOGICAL ::   ln_trcadv_qck    ! QUICKEST scheme flag
52
53   INTEGER ::   nadv             ! choice of the type of advection scheme
54   !                             ! associated indices:
55   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
56   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
57   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
58   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
59   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
60   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
61   
62#  include "domzgr_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
65   !! $Id$
66   !! Software governed by the CeCILL license (see ./LICENSE)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   SUBROUTINE trc_adv( kt, Kbb, Kmm, ptr, Krhs  )
71      !!----------------------------------------------------------------------
72      !!                  ***  ROUTINE trc_adv  ***
73      !!
74      !! ** Purpose :   compute the ocean tracer advection trend.
75      !!
76      !! ** Method  : - Update after tracers (tr(Krhs)) with the advection term following nadv
77      !!----------------------------------------------------------------------
78      INTEGER                                   , INTENT(in)    :: kt   ! ocean time-step index
79      INTEGER                                   , INTENT(in)    :: Kbb, Kmm, Krhs ! time level indices
80      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr            ! passive tracers and RHS of tracer equation
81      !
82      INTEGER ::   jk   ! dummy loop index
83      CHARACTER (len=22) ::   charout
84      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zuu, zvv, zww  ! effective velocity
85      !!----------------------------------------------------------------------
86      !
87      IF( ln_timing )   CALL timing_start('trc_adv')
88      !
89      !                                         !==  effective transport  ==!
90      IF( l_offline ) THEN
91         zuu(:,:,:) = uu(:,:,:,Kmm)                ! already in (uu(Kmm),vv(Kmm),ww)
92         zvv(:,:,:) = vv(:,:,:,Kmm)
93         zww(:,:,:) = ww(:,:,:)
94      ELSE                                         ! build the effective transport
95         zuu(:,:,jpk) = 0._wp
96         zvv(:,:,jpk) = 0._wp
97         zww(:,:,jpk) = 0._wp
98         IF( ln_wave .AND. ln_sdw )  THEN
99            DO jk = 1, jpkm1                                                       ! eulerian transport + Stokes Drift
100               zuu(:,:,jk) = e2u  (:,:) * e3u(:,:,jk,Kmm) * ( uu(:,:,jk,Kmm) + usd(:,:,jk) )
101               zvv(:,:,jk) = e1v  (:,:) * e3v(:,:,jk,Kmm) * ( vv(:,:,jk,Kmm) + vsd(:,:,jk) )
102               zww(:,:,jk) = e1e2t(:,:)                   * ( ww(:,:,jk) + wsd(:,:,jk) )
103            END DO
104         ELSE
105            DO jk = 1, jpkm1
106               zuu(:,:,jk) = e2u  (:,:) * e3u(:,:,jk,Kmm) * uu(:,:,jk,Kmm)                   ! eulerian transport
107               zvv(:,:,jk) = e1v  (:,:) * e3v(:,:,jk,Kmm) * vv(:,:,jk,Kmm)
108               zww(:,:,jk) = e1e2t(:,:)                   * ww(:,:,jk)
109            END DO
110         ENDIF
111         !
112         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                 ! add z-tilde and/or vvl corrections
113            zuu(:,:,:) = zuu(:,:,:) + un_td(:,:,:)
114            zvv(:,:,:) = zvv(:,:,:) + vn_td(:,:,:)
115         ENDIF
116         !
117         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   & 
118            &              CALL ldf_eiv_trp( kt, nittrc000, zuu, zvv, zww, 'TRC', Kmm, Krhs )  ! add the eiv transport
119         !
120         IF( ln_mle    )   CALL tra_mle_trp( kt, nittrc000, zuu, zvv, zww, 'TRC', Kmm       )  ! add the mle transport
121         !
122      ENDIF
123      !
124      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
125      !
126      CASE ( np_CEN )                                 ! Centered : 2nd / 4th order
127         CALL tra_adv_cen( kt, nittrc000,'TRC',          zuu, zvv, zww,      Kmm, ptr, jptra, Krhs, nn_cen_h, nn_cen_v )
128      CASE ( np_FCT )                                 ! FCT      : 2nd / 4th order
129            CALL tra_adv_fct( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, nn_fct_h, nn_fct_v )
130      CASE ( np_MUS )                                 ! MUSCL
131            CALL tra_adv_mus( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, ln_mus_ups ) 
132      CASE ( np_UBS )                                 ! UBS
133         CALL tra_adv_ubs( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs, nn_ubs_v           )
134      CASE ( np_QCK )                                 ! QUICKEST
135         CALL tra_adv_qck( kt, nittrc000,'TRC', rDt_trc, zuu, zvv, zww, Kbb, Kmm, ptr, jptra, Krhs                     )
136      !
137      END SELECT
138      !                 
139      IF( sn_cfctl%l_prttrc ) THEN        !== print mean trends (used for debugging)
140         WRITE(charout, FMT="('adv ')")
141         CALL prt_ctl_info( charout, cdcomp = 'top' )
142         CALL prt_ctl( tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm, clinfo3='trd' )
143      END IF
144      !
145      IF( ln_timing )   CALL timing_stop('trc_adv')
146      !
147   END SUBROUTINE trc_adv
148
149
150   SUBROUTINE trc_adv_ini
151      !!---------------------------------------------------------------------
152      !!                  ***  ROUTINE trc_adv_ini  ***
153      !!               
154      !! ** Purpose :   Control the consistency between namelist options for
155      !!              passive tracer advection schemes and set nadv
156      !!----------------------------------------------------------------------
157      INTEGER ::   ioptio, ios   ! Local integer
158      !!
159      NAMELIST/namtrc_adv/ ln_trcadv_OFF,                        &   ! No advection
160         &                 ln_trcadv_cen, nn_cen_h, nn_cen_v,    &   ! CEN
161         &                 ln_trcadv_fct, nn_fct_h, nn_fct_v,    &   ! FCT
162         &                 ln_trcadv_mus, ln_mus_ups,            &   ! MUSCL
163         &                 ln_trcadv_ubs,           nn_ubs_v,    &   ! UBS
164         &                 ln_trcadv_qck                             ! QCK
165      !!----------------------------------------------------------------------
166      !
167      !                                !==  Namelist  ==!
168      READ  ( numnat_ref, namtrc_adv, IOSTAT = ios, ERR = 901)
169901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_adv in reference namelist' )
170      READ  ( numnat_cfg, namtrc_adv, IOSTAT = ios, ERR = 902 )
171902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_adv in configuration namelist' )
172      IF(lwm) WRITE ( numont, namtrc_adv )
173      !
174      IF(lwp) THEN                           ! Namelist print
175         WRITE(numout,*)
176         WRITE(numout,*) 'trc_adv_ini : choice/control of the tracer advection scheme'
177         WRITE(numout,*) '~~~~~~~~~~~'
178         WRITE(numout,*) '   Namelist namtrc_adv : chose a advection scheme for tracers'
179         WRITE(numout,*) '      No advection on passive tracers           ln_trcadv_OFF = ', ln_trcadv_OFF
180         WRITE(numout,*) '      centered scheme                           ln_trcadv_cen = ', ln_trcadv_cen
181         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
182         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
183         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_trcadv_fct = ', ln_trcadv_fct
184         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
185         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
186         WRITE(numout,*) '      MUSCL scheme                              ln_trcadv_mus = ', ln_trcadv_mus
187         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
188         WRITE(numout,*) '      UBS scheme                                ln_trcadv_ubs = ', ln_trcadv_ubs
189         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
190         WRITE(numout,*) '      QUICKEST scheme                           ln_trcadv_qck = ', ln_trcadv_qck
191      ENDIF
192      !
193      !                                !==  Parameter control & set nadv ==!
194      ioptio = 0
195      IF( ln_trcadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
196      IF( ln_trcadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
197      IF( ln_trcadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
198      IF( ln_trcadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
199      IF( ln_trcadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
200      IF( ln_trcadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
201      !
202      IF( ioptio /= 1 )   CALL ctl_stop( 'trc_adv_ini: Choose ONE advection option in namelist namtrc_adv' )
203      !
204      IF( ln_trcadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &
205                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
206        CALL ctl_stop( 'trc_adv_ini: CEN scheme, choose 2nd or 4th order' )
207      ENDIF
208      IF( ln_trcadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &
209                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
210        CALL ctl_stop( 'trc_adv_ini: FCT scheme, choose 2nd or 4th order' )
211      ENDIF
212      IF( ln_trcadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN
213        CALL ctl_stop( 'trc_adv_ini: UBS scheme, choose 2nd or 4th order' )
214      ENDIF
215      IF( ln_trcadv_ubs .AND. nn_ubs_v == 4 ) THEN
216         CALL ctl_warn( 'trc_adv_ini: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
217      ENDIF
218      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
219         IF(  ln_trcadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
220            & ln_trcadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_ini: 4th order COMPACT scheme not allowed with ISF' )
221      ENDIF
222      !
223      !                                !==  Print the choice  ==! 
224      IF(lwp) THEN
225         WRITE(numout,*)
226         SELECT CASE ( nadv )
227         CASE( np_NO_adv  )   ;   WRITE(numout,*) '      ===>>   NO passive tracer advection'
228         CASE( np_CEN     )   ;   WRITE(numout,*) '      ===>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
229            &                                                                     ' Vertical   order: ', nn_cen_v
230         CASE( np_FCT     )   ;   WRITE(numout,*) '      ===>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
231            &                                                                      ' Vertical   order: ', nn_fct_v
232         CASE( np_MUS     )   ;   WRITE(numout,*) '      ===>>   MUSCL    scheme is used'
233         CASE( np_UBS     )   ;   WRITE(numout,*) '      ===>>   UBS      scheme is used'
234         CASE( np_QCK     )   ;   WRITE(numout,*) '      ===>>   QUICKEST scheme is used'
235         END SELECT
236      ENDIF
237      !
238   END SUBROUTINE trc_adv_ini
239   
240#endif
241
242  !!======================================================================
243END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.