source: NEMO/branches/MOI/NEMO_4.03_IODRAG/src/OCE/ZDF/zdfdrg.F90 @ 12953

Last change on this file since 12953 was 12953, checked in by jchanut, 15 months ago

Add ice-ocean implicit drag as namelist option ln_drgice_imp, #2468

  • Property svn:keywords set to Id
File size: 25.5 KB
Line 
1MODULE zdfdrg
2   !!======================================================================
3   !!                       ***  MODULE  zdfdrg  ***
4   !! Ocean physics: top and/or Bottom friction
5   !!======================================================================
6   !! History :  OPA  ! 1997-06  (G. Madec, A.-M. Treguier)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.2  ! 2009-09  (A.C.Coward)  Correction to include barotropic contribution
9   !!            3.3  ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
10   !!            3.4  ! 2011-11  (H. Liu) implementation of semi-implicit bottom friction option
11   !!                 ! 2012-06  (H. Liu) implementation of Log Layer bottom friction option
12   !!            4.0  ! 2017-05  (G. Madec) zdfbfr becomes zdfdrg + variable names change
13   !!                                     + drag defined at t-point + new user interface + top drag (ocean cavities)
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   zdf_drg       : update bottom friction coefficient (non-linear bottom friction only)
18   !!   zdf_drg_exp   : compute the top & bottom friction in explicit case
19   !!   zdf_drg_init  : read in namdrg namelist and control the bottom friction parameters.
20   !!       drg_init  :
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and tracers variables
23   USE phycst  , ONLY : vkarmn
24   USE dom_oce        ! ocean space and time domain variables
25   USE zdf_oce        ! ocean vertical physics variables
26   USE trd_oce        ! trends: ocean variables
27   USE trddyn         ! trend manager: dynamics
28   !
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O module
31   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
32   USE lib_mpp        ! distributed memory computing
33   USE prtctl         ! Print control
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   zdf_drg         ! called by zdf_phy
39   PUBLIC   zdf_drg_exp     ! called by dyn_zdf
40   PUBLIC   zdf_drg_init    ! called by zdf_phy_init
41
42   !                                 !!* Namelist namdrg: nature of drag coefficient namelist *
43   LOGICAL          ::   ln_OFF       ! free-slip       : Cd = 0
44   LOGICAL          ::   ln_lin       !     linear  drag: Cd = Cd0_lin
45   LOGICAL          ::   ln_non_lin   ! non-linear  drag: Cd = Cd0_nl |U|
46   LOGICAL          ::   ln_loglayer  ! logarithmic drag: Cd = vkarmn/log(z/z0)
47   LOGICAL , PUBLIC ::   ln_drgimp    ! implicit top/bottom friction flag
48   LOGICAL , PUBLIC ::   ln_drgice_imp ! implicit ice-ocean drag
49
50   !                                 !!* Namelist namdrg_top & _bot: TOP or BOTTOM coefficient namelist *
51   REAL(wp)         ::   rn_Cd0       !: drag coefficient                                           [ - ]
52   REAL(wp)         ::   rn_Uc0       !: characteristic velocity (linear case: tau=rho*Cd0*Uc0*u)   [m/s]
53   REAL(wp)         ::   rn_Cdmax     !: drag value maximum (ln_loglayer=T)                         [ - ]
54   REAL(wp)         ::   rn_z0        !: roughness          (ln_loglayer=T)                         [ m ]
55   REAL(wp)         ::   rn_ke0       !: background kinetic energy (non-linear case)                [m2/s2]
56   LOGICAL          ::   ln_boost     !: =T regional boost of Cd0 ; =F Cd0 horizontally uniform
57   REAL(wp)         ::   rn_boost     !: local boost factor                                         [ - ]
58
59   REAL(wp), PUBLIC ::   r_Cdmin_top, r_Cdmax_top, r_z0_top, r_ke0_top   ! set from namdrg_top namelist values
60   REAL(wp), PUBLIC ::   r_Cdmin_bot, r_Cdmax_bot, r_z0_bot, r_ke0_bot   !  -    -  namdrg_bot    -       -
61
62   INTEGER ::              ndrg       ! choice of the type of drag coefficient
63   !                                  ! associated indices:
64   INTEGER, PARAMETER ::   np_OFF      = 0   ! free-slip: drag set to zero
65   INTEGER, PARAMETER ::   np_lin      = 1   !     linear drag: Cd = Cd0_lin
66   INTEGER, PARAMETER ::   np_non_lin  = 2   ! non-linear drag: Cd = Cd0_nl |U|
67   INTEGER, PARAMETER ::   np_loglayer = 3   ! non linear drag (logarithmic formulation): Cd = vkarmn/log(z/z0)
68
69   LOGICAL , PUBLIC ::   l_zdfdrg           !: flag to update at each time step the top/bottom Cd
70   LOGICAL          ::   l_log_not_linssh   !: flag to update at each time step the position ot the velocity point
71   !
72   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::   rCd0_top, rCd0_bot   !: precomputed top/bottom drag coeff. at t-point (>0)
73   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::   rCdU_top, rCdU_bot   !: top/bottom drag coeff. at t-point (<0)  [m/s]
74   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::   rCdU_ice             !: ice-ocean drag (used if ln_drgice_imp=T)
75
76   !! * Substitutions
77#  include "vectopt_loop_substitute.h90"
78   !!----------------------------------------------------------------------
79   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
80   !! $Id$
81   !! Software governed by the CeCILL license (see ./LICENSE)
82   !!----------------------------------------------------------------------
83CONTAINS
84
85   SUBROUTINE zdf_drg( kt, k_mk, pCdmin, pCdmax, pz0, pke0, pCd0,   &   ! <<== in
86      &                                                     pCdU )      ! ==>> out : bottom drag [m/s]
87      !!----------------------------------------------------------------------
88      !!                   ***  ROUTINE zdf_drg  ***
89      !!
90      !! ** Purpose :   update the top/bottom drag coefficient (non-linear case only)
91      !!
92      !! ** Method  :   In non linear friction case, the drag coeficient is
93      !!              a function of the velocity:
94      !!                          Cd = cd0 * |U+Ut|   
95      !!              where U is the top or bottom velocity and
96      !!                    Ut a tidal velocity (Ut^2 = Tidal kinetic energy
97      !!                       assumed here here to be constant)
98      !!              Depending on the input variable, the top- or bottom drag is compted
99      !!
100      !! ** Action  :   p_Cd   drag coefficient at t-point
101      !!----------------------------------------------------------------------
102      INTEGER                 , INTENT(in   ) ::   kt       ! ocean time-step index
103      !                       !               !!         !==  top or bottom variables  ==!
104      INTEGER , DIMENSION(:,:), INTENT(in   ) ::   k_mk     ! wet level (1st or last)
105      REAL(wp)                , INTENT(in   ) ::   pCdmin   ! min drag value
106      REAL(wp)                , INTENT(in   ) ::   pCdmax   ! max drag value
107      REAL(wp)                , INTENT(in   ) ::   pz0      ! roughness
108      REAL(wp)                , INTENT(in   ) ::   pke0     ! background tidal KE
109      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   pCd0     ! masked precomputed part of Cd0
110      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   pCdU     ! = - Cd*|U|   (t-points) [m/s]
111      !!
112      INTEGER ::   ji, jj   ! dummy loop indices
113      INTEGER ::   imk      ! local integers
114      REAL(wp)::   zzz, zut, zvt, zcd   ! local scalars
115      !!----------------------------------------------------------------------
116      !
117      IF( l_log_not_linssh ) THEN     !==  "log layer"  ==!   compute Cd and -Cd*|U|
118         DO jj = 2, jpjm1
119            DO ji = 2, jpim1
120               imk = k_mk(ji,jj)          ! ocean bottom level at t-points
121               zut = un(ji,jj,imk) + un(ji-1,jj,imk)     ! 2 x velocity at t-point
122               zvt = vn(ji,jj,imk) + vn(ji,jj-1,imk)
123               zzz = 0.5_wp * e3t_n(ji,jj,imk)           ! altitude below/above (top/bottom) the boundary
124               !
125!!JC: possible WAD implementation should modify line below if layers vanish
126               zcd = (  vkarmn / LOG( zzz / pz0 )  )**2
127               zcd = pCd0(ji,jj) * MIN(  MAX( pCdmin , zcd ) , pCdmax  )   ! here pCd0 = mask*boost
128               pCdU(ji,jj) = - zcd * SQRT(  0.25 * ( zut*zut + zvt*zvt ) + pke0  )
129            END DO
130         END DO
131      ELSE                                            !==  standard Cd  ==!
132         DO jj = 2, jpjm1
133            DO ji = 2, jpim1
134               imk = k_mk(ji,jj)    ! ocean bottom level at t-points
135               zut = un(ji,jj,imk) + un(ji-1,jj,imk)     ! 2 x velocity at t-point
136               zvt = vn(ji,jj,imk) + vn(ji,jj-1,imk)
137               !                                                           ! here pCd0 = mask*boost * drag
138               pCdU(ji,jj) = - pCd0(ji,jj) * SQRT(  0.25 * ( zut*zut + zvt*zvt ) + pke0  )
139            END DO
140         END DO
141      ENDIF
142      !
143      IF(ln_ctl)   CALL prt_ctl( tab2d_1=pCdU, clinfo1=' Cd*U ')
144      !
145   END SUBROUTINE zdf_drg
146
147
148   SUBROUTINE zdf_drg_exp( kt, pub, pvb, pua, pva )
149      !!----------------------------------------------------------------------
150      !!                  ***  ROUTINE zdf_drg_exp  ***
151      !!
152      !! ** Purpose :   compute and add the explicit top and bottom frictions.
153      !!
154      !! ** Method  :   in explicit case,
155      !!
156      !!              NB: in implicit case the calculation is performed in dynzdf.F90
157      !!
158      !! ** Action  :   (pua,pva)   momentum trend increased by top & bottom friction trend
159      !!---------------------------------------------------------------------
160      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
161      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pub, pvb   ! the two components of the before velocity
162      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! the two components of the velocity tendency
163      !!
164      INTEGER  ::   ji, jj       ! dummy loop indexes
165      INTEGER  ::   ikbu, ikbv   ! local integers
166      REAL(wp) ::   zm1_2dt      ! local scalar
167      REAL(wp) ::   zCdu, zCdv   !   -      -
168      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv
169      !!---------------------------------------------------------------------
170      !
171!!gm bug : time step is only rdt (not 2 rdt if euler start !)
172      zm1_2dt = - 1._wp / ( 2._wp * rdt )
173
174      IF( l_trddyn ) THEN      ! trends: store the input trends
175         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
176         ztrdu(:,:,:) = pua(:,:,:)
177         ztrdv(:,:,:) = pva(:,:,:)
178      ENDIF
179
180      DO jj = 2, jpjm1
181         DO ji = 2, jpim1
182            ikbu = mbku(ji,jj)          ! deepest wet ocean u- & v-levels
183            ikbv = mbkv(ji,jj)
184            !
185            ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
186            zCdu = 0.5*( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) / e3u_n(ji,jj,ikbu)
187            zCdv = 0.5*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) / e3v_n(ji,jj,ikbv)
188            !
189            pua(ji,jj,ikbu) = pua(ji,jj,ikbu) + MAX(  zCdu , zm1_2dt  ) * pub(ji,jj,ikbu)
190            pva(ji,jj,ikbv) = pva(ji,jj,ikbv) + MAX(  zCdv , zm1_2dt  ) * pvb(ji,jj,ikbv)
191         END DO
192      END DO
193      !
194      IF( ln_isfcav ) THEN        ! ocean cavities
195         DO jj = 2, jpjm1
196            DO ji = 2, jpim1
197               ikbu = miku(ji,jj)          ! first wet ocean u- & v-levels
198               ikbv = mikv(ji,jj)
199               !
200               ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
201               zCdu = 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) / e3u_n(ji,jj,ikbu)    ! NB: Cdtop masked
202               zCdv = 0.5*( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) / e3v_n(ji,jj,ikbv)
203               !
204               pua(ji,jj,ikbu) = pua(ji,jj,ikbu) + MAX(  zCdu , zm1_2dt  ) * pub(ji,jj,ikbu)
205               pva(ji,jj,ikbv) = pva(ji,jj,ikbv) + MAX(  zCdv , zm1_2dt  ) * pvb(ji,jj,ikbv)
206           END DO
207         END DO
208      ENDIF
209      !
210      IF( l_trddyn ) THEN      ! trends: send trends to trddyn for further diagnostics
211         ztrdu(:,:,:) = pua(:,:,:) - ztrdu(:,:,:)
212         ztrdv(:,:,:) = pva(:,:,:) - ztrdv(:,:,:)
213         CALL trd_dyn( ztrdu(:,:,:), ztrdv(:,:,:), jpdyn_bfr, kt )
214         DEALLOCATE( ztrdu, ztrdv )
215      ENDIF
216      !                                          ! print mean trends (used for debugging)
217      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pua, clinfo1=' bfr  - Ua: ', mask1=umask,               &
218         &                       tab3d_2=pva, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
219      !
220   END SUBROUTINE zdf_drg_exp
221
222
223   SUBROUTINE zdf_drg_init
224      !!----------------------------------------------------------------------
225      !!                  ***  ROUTINE zdf_brg_init  ***
226      !!
227      !! ** Purpose :   Initialization of the bottom friction
228      !!
229      !! ** Method  :   Read the namdrg namelist and check their consistency
230      !!                called at the first timestep (nit000)
231      !!----------------------------------------------------------------------
232      INTEGER   ::   ji, jj      ! dummy loop indexes
233      INTEGER   ::   ios, ioptio   ! local integers
234      !!
235      NAMELIST/namdrg/ ln_OFF, ln_lin, ln_non_lin, ln_loglayer, ln_drgimp, ln_drgice_imp
236      !!----------------------------------------------------------------------
237      !
238      !                     !==  drag nature  ==!
239      !
240      REWIND( numnam_ref )                   ! Namelist namdrg in reference namelist
241      READ  ( numnam_ref, namdrg, IOSTAT = ios, ERR = 901)
242901   IF( ios /= 0 )   CALL ctl_nam( ios , 'namdrg in reference namelist' )
243      REWIND( numnam_cfg )                   ! Namelist namdrg in configuration namelist
244      READ  ( numnam_cfg, namdrg, IOSTAT = ios, ERR = 902 )
245902   IF( ios >  0 )   CALL ctl_nam( ios , 'namdrg in configuration namelist' )
246      IF(lwm) WRITE ( numond, namdrg )
247      !
248      IF(lwp) THEN
249         WRITE(numout,*)
250         WRITE(numout,*) 'zdf_drg_init : top and/or bottom drag setting'
251         WRITE(numout,*) '~~~~~~~~~~~~'
252         WRITE(numout,*) '   Namelist namdrg : top/bottom friction choices'
253         WRITE(numout,*) '      free-slip       : Cd = 0                  ln_OFF      = ', ln_OFF 
254         WRITE(numout,*) '      linear  drag    : Cd = Cd0                ln_lin      = ', ln_lin
255         WRITE(numout,*) '      non-linear  drag: Cd = Cd0_nl |U|         ln_non_lin  = ', ln_non_lin
256         WRITE(numout,*) '      logarithmic drag: Cd = vkarmn/log(z/z0)   ln_loglayer = ', ln_loglayer
257         WRITE(numout,*) '      implicit friction                         ln_drgimp   = ', ln_drgimp
258         WRITE(numout,*) '      implicit ice-ocean drag                   ln_drgice_imp  =', ln_drgice_imp
259      ENDIF
260      !
261      ioptio = 0                       ! set ndrg and control check
262      IF( ln_OFF      ) THEN   ;   ndrg = np_OFF        ;   ioptio = ioptio + 1   ;   ENDIF
263      IF( ln_lin      ) THEN   ;   ndrg = np_lin        ;   ioptio = ioptio + 1   ;   ENDIF
264      IF( ln_non_lin  ) THEN   ;   ndrg = np_non_lin    ;   ioptio = ioptio + 1   ;   ENDIF
265      IF( ln_loglayer ) THEN   ;   ndrg = np_loglayer   ;   ioptio = ioptio + 1   ;   ENDIF
266      !
267      IF( ioptio /= 1 )   CALL ctl_stop( 'zdf_drg_init: Choose ONE type of drag coef in namdrg' )
268      !
269      IF ( ln_drgice_imp.AND.(.NOT.ln_drgimp) ) & 
270         &                CALL ctl_stop( 'zdf_drg_init: ln_drgice_imp=T requires ln_drgimp=T' )
271      !
272      !                     !==  BOTTOM drag setting  ==!   (applied at seafloor)
273      !
274      ALLOCATE( rCd0_bot(jpi,jpj), rCdU_bot(jpi,jpj) )
275      CALL drg_init( 'BOTTOM'   , mbkt       ,                                         &   ! <== in
276         &           r_Cdmin_bot, r_Cdmax_bot, r_z0_bot, r_ke0_bot, rCd0_bot, rCdU_bot )   ! ==> out
277
278      !
279      !                     !==  TOP drag setting  ==!   (applied at the top of ocean cavities)
280      !
281      IF( ln_isfcav.OR.ln_drgice_imp ) THEN              ! Ocean cavities: top friction setting
282         ALLOCATE( rCdU_top(jpi,jpj) )
283         rCdU_top(:,:) = 0._wp
284      ENDIF
285      !
286      IF (ln_drgice_imp) ALLOCATE( rCdU_ice(jpi,jpj) )
287      !
288      IF( ln_isfcav ) THEN
289         ALLOCATE( rCd0_top(jpi,jpj))
290         CALL drg_init( 'TOP   '   , mikt       ,                                         &   ! <== in
291            &           r_Cdmin_top, r_Cdmax_top, r_z0_top, r_ke0_top, rCd0_top, rCdU_top )   ! ==> out
292      ENDIF
293      !
294   END SUBROUTINE zdf_drg_init
295
296
297   SUBROUTINE drg_init( cd_topbot, k_mk,  &
298      &                 pCdmin, pCdmax, pz0, pke0, pCd0, pCdU ) 
299      !!----------------------------------------------------------------------
300      !!                  ***  ROUTINE drg_init  ***
301      !!
302      !! ** Purpose :   Initialization of the top/bottom friction CdO and Cd
303      !!              from namelist parameters
304      !!----------------------------------------------------------------------
305      CHARACTER(len=6)        , INTENT(in   ) ::   cd_topbot       ! top/ bot indicator
306      INTEGER , DIMENSION(:,:), INTENT(in   ) ::   k_mk            ! 1st/last  wet level
307      REAL(wp)                , INTENT(  out) ::   pCdmin, pCdmax  ! min and max drag coef. [-]
308      REAL(wp)                , INTENT(  out) ::   pz0             ! roughness              [m]
309      REAL(wp)                , INTENT(  out) ::   pke0            ! background KE          [m2/s2]
310      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   pCd0            ! masked precomputed part of the non-linear drag coefficient
311      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   pCdU            ! minus linear drag*|U| at t-points  [m/s]
312      !!
313      CHARACTER(len=40) ::   cl_namdrg, cl_file, cl_varname, cl_namref, cl_namcfg  ! local names
314      INTEGER ::   ji, jj              ! dummy loop indexes
315      LOGICAL ::   ll_top, ll_bot      ! local logical
316      INTEGER ::   ios, inum, imk      ! local integers
317      REAL(wp)::   zmsk, zzz, zcd      ! local scalars
318      REAL(wp), DIMENSION(jpi,jpj) ::   zmsk_boost   ! 2D workspace
319      !!
320      NAMELIST/namdrg_top/ rn_Cd0, rn_Uc0, rn_Cdmax, rn_ke0, rn_z0, ln_boost, rn_boost
321      NAMELIST/namdrg_bot/ rn_Cd0, rn_Uc0, rn_Cdmax, rn_ke0, rn_z0, ln_boost, rn_boost
322      !!----------------------------------------------------------------------
323      !
324      !                          !==  set TOP / BOTTOM specificities  ==!
325      ll_top = .FALSE.
326      ll_bot = .FALSE.
327      !
328      SELECT CASE (cd_topbot)
329      CASE( 'TOP   ' )
330         ll_top = .TRUE.
331         cl_namdrg  = 'namdrg_top'
332         cl_namref  = 'namdrg_top in reference     namelist'
333         cl_namcfg  = 'namdrg_top in configuration namelist'
334         cl_file    = 'tfr_coef.nc'
335         cl_varname = 'tfr_coef'
336      CASE( 'BOTTOM' )
337         ll_bot = .TRUE.
338         cl_namdrg  = 'namdrg_bot'
339         cl_namref  = 'namdrg_bot  in reference     namelist'
340         cl_namcfg  = 'namdrg_bot  in configuration namelist'
341         cl_file    = 'bfr_coef.nc'
342         cl_varname = 'bfr_coef'
343      CASE DEFAULT
344         CALL ctl_stop( 'drg_init: bad value for cd_topbot ' )
345      END SELECT
346      !
347      !                          !==  read namlist  ==!
348      !
349      REWIND( numnam_ref )                   ! Namelist cl_namdrg in reference namelist
350      IF(ll_top)   READ  ( numnam_ref, namdrg_top, IOSTAT = ios, ERR = 901)
351      IF(ll_bot)   READ  ( numnam_ref, namdrg_bot, IOSTAT = ios, ERR = 901)
352901   IF( ios /= 0 )   CALL ctl_nam( ios , TRIM(cl_namref) )
353      REWIND( numnam_cfg )                   ! Namelist cd_namdrg in configuration namelist
354      IF(ll_top)   READ  ( numnam_cfg, namdrg_top, IOSTAT = ios, ERR = 902 )
355      IF(ll_bot)   READ  ( numnam_cfg, namdrg_bot, IOSTAT = ios, ERR = 902 )
356902   IF( ios >  0 )   CALL ctl_nam( ios , TRIM(cl_namcfg) )
357      IF(lwm .AND. ll_top)   WRITE ( numond, namdrg_top )
358      IF(lwm .AND. ll_bot)   WRITE ( numond, namdrg_bot )
359      !
360      IF(lwp) THEN
361         WRITE(numout,*)
362         WRITE(numout,*) '   Namelist ',TRIM(cl_namdrg),' : set ',TRIM(cd_topbot),' friction parameters'
363         WRITE(numout,*) '      drag coefficient                        rn_Cd0   = ', rn_Cd0
364         WRITE(numout,*) '      characteristic velocity (linear case)   rn_Uc0   = ', rn_Uc0, ' m/s'
365         WRITE(numout,*) '      non-linear drag maximum                 rn_Cdmax = ', rn_Cdmax
366         WRITE(numout,*) '      background kinetic energy  (n-l case)   rn_ke0   = ', rn_ke0
367         WRITE(numout,*) '      bottom roughness           (n-l case)   rn_z0    = ', rn_z0
368         WRITE(numout,*) '      set a regional boost of Cd0             ln_boost = ', ln_boost
369         WRITE(numout,*) '         associated boost factor              rn_boost = ', rn_boost
370      ENDIF
371      !
372      !                          !==  return some namelist parametres  ==!   (used in non_lin and loglayer cases)
373      pCdmin = rn_Cd0
374      pCdmax = rn_Cdmax
375      pz0    = rn_z0
376      pke0   = rn_ke0
377      !
378      !                          !==  mask * boost factor  ==!
379      !
380      IF( ln_boost ) THEN           !* regional boost:   boost factor = 1 + regional boost
381         IF(lwp) WRITE(numout,*)
382         IF(lwp) WRITE(numout,*) '   ==>>>   use a regional boost read in ', TRIM(cl_file), ' file'
383         IF(lwp) WRITE(numout,*) '           using enhancement factor of ', rn_boost
384         ! cl_varname is a coefficient in [0,1] giving where to apply the regional boost
385         CALL iom_open ( TRIM(cl_file), inum )
386         CALL iom_get  ( inum, jpdom_data, TRIM(cl_varname), zmsk_boost, 1 )
387         CALL iom_close( inum)
388         zmsk_boost(:,:) = 1._wp + rn_boost * zmsk_boost(:,:)
389         !
390      ELSE                          !* no boost:   boost factor = 1
391         zmsk_boost(:,:) = 1._wp
392      ENDIF
393      !                             !* mask outside ocean cavities area (top) or land area (bot)
394      IF(ll_top)   zmsk_boost(:,:) = zmsk_boost(:,:) * ssmask(:,:) * (1. - tmask(:,:,1) )  ! none zero in ocean cavities only
395      IF(ll_bot)   zmsk_boost(:,:) = zmsk_boost(:,:) * ssmask(:,:)                         ! x seafloor mask
396      !
397      !
398      SELECT CASE( ndrg )
399      !
400      CASE( np_OFF  )            !==  No top/bottom friction  ==!   (pCdU = 0)
401         IF(lwp) WRITE(numout,*)
402         IF(lwp) WRITE(numout,*) '   ==>>>   ',TRIM(cd_topbot),' free-slip, friction set to zero'
403         !
404         l_zdfdrg = .FALSE.         ! no time variation of the drag: set it one for all
405         !
406         pCdU(:,:) = 0._wp
407         pCd0(:,:) = 0._wp
408         !
409      CASE( np_lin )             !==  linear friction  ==!   (pCdU = Cd0 * Uc0)
410         IF(lwp) WRITE(numout,*)
411         IF(lwp) WRITE(numout,*) '   ==>>>   linear ',TRIM(cd_topbot),' friction (constant coef = Cd0*Uc0 = ', rn_Cd0*rn_Uc0, ')'
412         !
413         l_zdfdrg = .FALSE.         ! no time variation of the Cd*|U| : set it one for all
414         !                     
415         pCd0(:,:) = rn_Cd0 * zmsk_boost(:,:)  !* constant in time drag coefficient (= mask (and boost) Cd0)
416         pCdU(:,:) = - pCd0(:,:) * rn_Uc0      !  using a constant velocity
417         !
418      CASE( np_non_lin )         !== non-linear friction  ==!   (pCd0 = Cd0 )
419         IF(lwp) WRITE(numout,*)
420         IF(lwp) WRITE(numout,*) '   ==>>>   quadratic ',TRIM(cd_topbot),' friction (propotional to module of the velocity)'
421         IF(lwp) WRITE(numout,*) '   with    a drag coefficient Cd0 = ', rn_Cd0, ', and'
422         IF(lwp) WRITE(numout,*) '           a background velocity module of (rn_ke0)^1/2 = ', SQRT(rn_ke0), 'm/s)'
423         !
424         l_zdfdrg = .TRUE.          !* Cd*|U| updated at each time-step (it depends on ocean velocity)
425         !
426         pCd0(:,:) = rn_Cd0 * zmsk_boost(:,:)  !* constant in time proportionality coefficient (= mask (and boost) Cd0)
427         pCdU(:,:) = 0._wp                     
428         !
429      CASE( np_loglayer )       !== logarithmic layer formulation of friction  ==!   (CdU = (vkarman log(z/z0))^2 |U| )
430         IF(lwp) WRITE(numout,*)
431         IF(lwp) WRITE(numout,*) '   ==>>>   quadratic ',TRIM(cd_topbot),' drag (propotional to module of the velocity)'
432         IF(lwp) WRITE(numout,*) '   with   a logarithmic Cd0 formulation Cd0 = ( vkarman log(z/z0) )^2 ,'
433         IF(lwp) WRITE(numout,*) '          a background velocity module of (rn_ke0)^1/2 = ', SQRT(pke0), 'm/s), '
434         IF(lwp) WRITE(numout,*) '          a logarithmic formulation: a roughness of ', pz0, ' meters,   and '
435         IF(lwp) WRITE(numout,*) '          a proportionality factor bounded by min/max values of ', pCdmin, pCdmax
436         !
437         l_zdfdrg = .TRUE.          !* Cd*|U| updated at each time-step (it depends on ocean velocity)
438         !
439         IF( ln_linssh ) THEN       !* pCd0 = (v log(z/z0))^2   as velocity points have a fixed z position
440            IF(lwp) WRITE(numout,*)
441            IF(lwp) WRITE(numout,*) '   N.B.   linear free surface case, Cd0 computed one for all'
442            !
443            l_log_not_linssh = .FALSE.    !- don't update Cd at each time step
444            !
445            DO jj = 1, jpj                   ! pCd0 = mask (and boosted) logarithmic drag coef.
446               DO ji = 1, jpi
447                  zzz =  0.5_wp * e3t_0(ji,jj,k_mk(ji,jj))
448                  zcd = (  vkarmn / LOG( zzz / rn_z0 )  )**2
449                  pCd0(ji,jj) = zmsk_boost(ji,jj) * MIN(  MAX( rn_Cd0 , zcd ) , rn_Cdmax  )  ! rn_Cd0 < Cd0 < rn_Cdmax
450               END DO
451            END DO
452         ELSE                       !* Cd updated at each time-step ==> pCd0 = mask * boost
453            IF(lwp) WRITE(numout,*)
454            IF(lwp) WRITE(numout,*) '   N.B.   non-linear free surface case, Cd0 updated at each time-step '
455            !
456            l_log_not_linssh = .TRUE.     ! compute the drag coef. at each time-step
457            !
458            pCd0(:,:) = zmsk_boost(:,:)
459         ENDIF
460         pCdU(:,:) = 0._wp          ! initialisation to zero (will be updated at each time step)
461         !
462      CASE DEFAULT
463         CALL ctl_stop( 'drg_init: bad flag value for ndrg ' )
464      END SELECT
465      !
466   END SUBROUTINE drg_init
467
468   !!======================================================================
469END MODULE zdfdrg
Note: See TracBrowser for help on using the repository browser.