New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldftra.F90 in NEMO/branches/UKMO/NEMO_4.0.1_GM_rossby_radius_cutoff/src/OCE/LDF – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.1_GM_rossby_radius_cutoff/src/OCE/LDF/ldftra.F90 @ 13002

Last change on this file since 13002 was 13002, checked in by davestorkey, 3 years ago

UKMO/NEMO_4.0.1_GM_rossby_radius_cutoff : Add two versions of a ramp in addition to the abrupt cutoff on the RR/GS ratio.

File size: 55.7 KB
Line 
1MODULE ldftra
2   !!======================================================================
3   !!                       ***  MODULE  ldftra  ***
4   !! Ocean physics:  lateral diffusivity coefficients
5   !!=====================================================================
6   !! History :       ! 1997-07  (G. Madec)  from inimix.F split in 2 routines
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            2.0  ! 2005-11  (G. Madec) 
9   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  restructuration/simplification of aht/aeiv specification,
10   !!                 !                                  add velocity dependent coefficient and optional read in file
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   ldf_tra_init : initialization, namelist read, and parameters control
15   !!   ldf_tra      : update lateral eddy diffusivity coefficients at each time step
16   !!   ldf_eiv_init : initialization of the eiv coeff. from namelist choices
17   !!   ldf_eiv      : time evolution of the eiv coefficients (function of the growth rate of baroclinic instability)
18   !!   ldf_eiv_trp  : add to the input ocean transport the contribution of the EIV parametrization
19   !!   ldf_eiv_dia  : diagnose the eddy induced velocity from the eiv streamfunction
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and tracers
22   USE dom_oce         ! ocean space and time domain
23   USE phycst          ! physical constants
24   USE ldfslp          ! lateral diffusion: slope of iso-neutral surfaces
25   USE ldfc1d_c2d      ! lateral diffusion: 1D & 2D cases
26   USE diaptr
27   !
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O module for ehanced bottom friction file
30   USE lib_mpp         ! distribued memory computing library
31   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   ldf_tra_init   ! called by nemogcm.F90
37   PUBLIC   ldf_tra        ! called by step.F90
38   PUBLIC   ldf_eiv_init   ! called by nemogcm.F90
39   PUBLIC   ldf_eiv        ! called by step.F90
40   PUBLIC   ldf_eiv_trp    ! called by traadv.F90
41   PUBLIC   ldf_eiv_dia    ! called by traldf_iso and traldf_iso_triad.F90
42   
43   !                                   !!* Namelist namtra_ldf : lateral mixing on tracers *
44   !                                    != Operator type =!
45   LOGICAL , PUBLIC ::   ln_traldf_OFF       !: no operator: No explicit diffusion
46   LOGICAL , PUBLIC ::   ln_traldf_lap       !: laplacian operator
47   LOGICAL , PUBLIC ::   ln_traldf_blp       !: bilaplacian operator
48   !                                    != Direction of action =!
49   LOGICAL , PUBLIC ::   ln_traldf_lev       !: iso-level direction
50   LOGICAL , PUBLIC ::   ln_traldf_hor       !: horizontal (geopotential) direction
51!  LOGICAL , PUBLIC ::   ln_traldf_iso       !: iso-neutral direction                    (see ldfslp)
52   !                                    != iso-neutral options =!
53!  LOGICAL , PUBLIC ::   ln_traldf_triad     !: griffies triad scheme                    (see ldfslp)
54   LOGICAL , PUBLIC ::   ln_traldf_msc       !: Method of Stabilizing Correction
55!  LOGICAL , PUBLIC ::   ln_triad_iso        !: pure horizontal mixing in ML             (see ldfslp)
56!  LOGICAL , PUBLIC ::   ln_botmix_triad     !: mixing on bottom                         (see ldfslp)
57!  REAL(wp), PUBLIC ::   rn_sw_triad         !: =1/0 switching triad / all 4 triads used (see ldfslp)
58!  REAL(wp), PUBLIC ::   rn_slpmax           !: slope limit                              (see ldfslp)
59   !                                    !=  Coefficients =!
60   INTEGER , PUBLIC ::   nn_aht_ijk_t        !: choice of time & space variations of the lateral eddy diffusivity coef.
61   !                                            !  time invariant coefficients:  aht_0 = 1/2  Ud*Ld   (lap case)
62   !                                            !                                bht_0 = 1/12 Ud*Ld^3 (blp case)
63   REAL(wp), PUBLIC ::      rn_Ud               !: lateral diffusive velocity  [m/s]
64   REAL(wp), PUBLIC ::      rn_Ld               !: lateral diffusive length    [m]
65
66   !                                   !!* Namelist namtra_eiv : eddy induced velocity param. *
67   !                                    != Use/diagnose eiv =!
68   LOGICAL , PUBLIC ::   ln_ldfeiv           !: eddy induced velocity flag
69   LOGICAL , PUBLIC ::   ln_ldfeiv_dia       !: diagnose & output eiv streamfunction and velocity (IOM)
70   !                                    != Coefficients =!
71   INTEGER , PUBLIC ::   nn_aei_ijk_t        !: choice of time/space variation of the eiv coeff.
72   REAL(wp), PUBLIC ::      rn_Ue               !: lateral diffusive velocity  [m/s]
73   REAL(wp), PUBLIC ::      rn_Le               !: lateral diffusive length    [m]
74   INTEGER,  PUBLIC ::   nn_ldfeiv_shape     !: shape of bounding coefficient (Treguier et al formulation only)
75   
76   !                                  ! Flag to control the type of lateral diffusive operator
77   INTEGER, PARAMETER, PUBLIC ::   np_ERROR  =-10   ! error in specification of lateral diffusion
78   INTEGER, PARAMETER, PUBLIC ::   np_no_ldf = 00   ! without operator (i.e. no lateral diffusive trend)
79   !                          !!      laplacian     !    bilaplacian    !
80   INTEGER, PARAMETER, PUBLIC ::   np_lap    = 10   ,   np_blp    = 20  ! iso-level operator
81   INTEGER, PARAMETER, PUBLIC ::   np_lap_i  = 11   ,   np_blp_i  = 21  ! standard iso-neutral or geopotential operator
82   INTEGER, PARAMETER, PUBLIC ::   np_lap_it = 12   ,   np_blp_it = 22  ! triad    iso-neutral or geopotential operator
83
84   INTEGER , PUBLIC ::   nldf_tra      = 0         !: type of lateral diffusion used defined from ln_traldf_... (namlist logicals)
85   LOGICAL , PUBLIC ::   l_ldftra_time = .FALSE.   !: flag for time variation of the lateral eddy diffusivity coef.
86   LOGICAL , PUBLIC ::   l_ldfeiv_time = .FALSE.   !: flag for time variation of the eiv coef.
87   LOGICAL , PUBLIC ::   l_Ro_cutoff   = .FALSE.   !: flag for Rossby-radius cutoff in calcn of eiv coeff
88
89   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ahtu, ahtv   !: eddy diffusivity coef. at U- and V-points   [m2/s]
90   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aeiu, aeiv   !: eddy induced velocity coeff.                [m2/s]
91
92   REAL(wp) ::   aht0, aei0               ! constant eddy coefficients (deduced from namelist values)                     [m2/s]
93   REAL(wp) ::   r1_2  = 0.5_wp           ! =1/2
94   REAL(wp) ::   r1_4  = 0.25_wp          ! =1/4
95   REAL(wp) ::   r1_12 = 1._wp / 12._wp   ! =1/12
96
97   !! * Substitutions
98#  include "vectopt_loop_substitute.h90"
99   !!----------------------------------------------------------------------
100   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
101   !! $Id$
102   !! Software governed by the CeCILL license (see ./LICENSE)
103   !!----------------------------------------------------------------------
104CONTAINS
105
106   SUBROUTINE ldf_tra_init
107      !!----------------------------------------------------------------------
108      !!                  ***  ROUTINE ldf_tra_init  ***
109      !!
110      !! ** Purpose :   initializations of the tracer lateral mixing coeff.
111      !!
112      !! ** Method  : * the eddy diffusivity coef. specification depends on:
113      !!
114      !!    ln_traldf_lap = T     laplacian operator
115      !!    ln_traldf_blp = T   bilaplacian operator
116      !!
117      !!    nn_aht_ijk_t  =  0 => = constant
118      !!                  !
119      !!                  = 10 => = F(z) : constant with a reduction of 1/4 with depth
120      !!                  !
121      !!                  =-20 => = F(i,j)   = shape read in 'eddy_diffusivity.nc' file
122      !!                  = 20    = F(i,j)   = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
123      !!                  = 21    = F(i,j,t) = F(growth rate of baroclinic instability)
124      !!                  !
125      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_diffusivity.nc' file
126      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
127      !!                  = 31    = F(i,j,k,t) = F(local velocity) (  1/2  |u|e     laplacian operator
128      !!                                                           or 1/12 |u|e^3 bilaplacian operator )
129      !!              * initialisation of the eddy induced velocity coefficient by a call to ldf_eiv_init
130      !!           
131      !! ** action  : ahtu, ahtv initialized one for all or l_ldftra_time set to true
132      !!              aeiu, aeiv initialized one for all or l_ldfeiv_time set to true
133      !!----------------------------------------------------------------------
134      INTEGER  ::   jk                             ! dummy loop indices
135      INTEGER  ::   ioptio, ierr, inum, ios, inn   ! local integer
136      REAL(wp) ::   zah_max, zUfac                 !   -      -
137      CHARACTER(len=5) ::   cl_Units               ! units (m2/s or m4/s)
138      !!
139      NAMELIST/namtra_ldf/ ln_traldf_OFF, ln_traldf_lap  , ln_traldf_blp  ,   &   ! type of operator
140         &                 ln_traldf_lev, ln_traldf_hor  , ln_traldf_triad,   &   ! acting direction of the operator
141         &                 ln_traldf_iso, ln_traldf_msc  ,  rn_slpmax     ,   &   ! option for iso-neutral operator
142         &                 ln_triad_iso , ln_botmix_triad, rn_sw_triad    ,   &   ! option for triad operator
143         &                 nn_aht_ijk_t , rn_Ud          , rn_Ld                  ! lateral eddy coefficient
144      !!----------------------------------------------------------------------
145      !
146      IF(lwp) THEN                      ! control print
147         WRITE(numout,*)
148         WRITE(numout,*) 'ldf_tra_init : lateral tracer diffusion'
149         WRITE(numout,*) '~~~~~~~~~~~~ '
150      ENDIF
151     
152      !
153      !  Choice of lateral tracer physics
154      ! =================================
155      !
156      REWIND( numnam_ref )              ! Namelist namtra_ldf in reference namelist : Lateral physics on tracers
157      READ  ( numnam_ref, namtra_ldf, IOSTAT = ios, ERR = 901)
158901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_ldf in reference namelist' )
159      REWIND( numnam_cfg )              ! Namelist namtra_ldf in configuration namelist : Lateral physics on tracers
160      READ  ( numnam_cfg, namtra_ldf, IOSTAT = ios, ERR = 902 )
161902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_ldf in configuration namelist' )
162      IF(lwm) WRITE( numond, namtra_ldf )
163      !
164      IF(lwp) THEN                      ! control print
165         WRITE(numout,*) '   Namelist : namtra_ldf --- lateral mixing parameters (type, direction, coefficients)'
166         WRITE(numout,*) '      type :'
167         WRITE(numout,*) '         no explicit diffusion                   ln_traldf_OFF   = ', ln_traldf_OFF
168         WRITE(numout,*) '         laplacian operator                      ln_traldf_lap   = ', ln_traldf_lap
169         WRITE(numout,*) '         bilaplacian operator                    ln_traldf_blp   = ', ln_traldf_blp
170         WRITE(numout,*) '      direction of action :'
171         WRITE(numout,*) '         iso-level                               ln_traldf_lev   = ', ln_traldf_lev
172         WRITE(numout,*) '         horizontal (geopotential)               ln_traldf_hor   = ', ln_traldf_hor
173         WRITE(numout,*) '         iso-neutral Madec operator              ln_traldf_iso   = ', ln_traldf_iso
174         WRITE(numout,*) '         iso-neutral triad operator              ln_traldf_triad = ', ln_traldf_triad
175         WRITE(numout,*) '            use the Method of Stab. Correction   ln_traldf_msc   = ', ln_traldf_msc
176         WRITE(numout,*) '            maximum isoppycnal slope             rn_slpmax       = ', rn_slpmax
177         WRITE(numout,*) '            pure lateral mixing in ML            ln_triad_iso    = ', ln_triad_iso
178         WRITE(numout,*) '            switching triad or not               rn_sw_triad     = ', rn_sw_triad
179         WRITE(numout,*) '            lateral mixing on bottom             ln_botmix_triad = ', ln_botmix_triad
180         WRITE(numout,*) '      coefficients :'
181         WRITE(numout,*) '         type of time-space variation            nn_aht_ijk_t    = ', nn_aht_ijk_t
182         WRITE(numout,*) '            lateral diffusive velocity (if cst)  rn_Ud           = ', rn_Ud, ' m/s'
183         WRITE(numout,*) '            lateral diffusive length   (if cst)  rn_Ld           = ', rn_Ld, ' m'
184      ENDIF
185      !
186      !
187      ! Operator and its acting direction   (set nldf_tra) 
188      ! =================================
189      !
190      nldf_tra = np_ERROR
191      ioptio   = 0
192      IF( ln_traldf_OFF ) THEN   ;   nldf_tra = np_no_ldf   ;   ioptio = ioptio + 1   ;   ENDIF
193      IF( ln_traldf_lap ) THEN   ;                              ioptio = ioptio + 1   ;   ENDIF
194      IF( ln_traldf_blp ) THEN   ;                              ioptio = ioptio + 1   ;   ENDIF
195      IF( ioptio /=  1  )   CALL ctl_stop( 'tra_ldf_init: use ONE of the 3 operator options (NONE/lap/blp)' )
196      !
197      IF( .NOT.ln_traldf_OFF ) THEN    !==  direction ==>> type of operator  ==!
198         ioptio = 0
199         IF( ln_traldf_lev   )   ioptio = ioptio + 1
200         IF( ln_traldf_hor   )   ioptio = ioptio + 1
201         IF( ln_traldf_iso   )   ioptio = ioptio + 1
202         IF( ln_traldf_triad )   ioptio = ioptio + 1
203         IF( ioptio /=  1  )   CALL ctl_stop( 'tra_ldf_init: use ONE direction (level/hor/iso/triad)' )
204         !
205         !                                ! defined the type of lateral diffusion from ln_traldf_... logicals
206         ierr = 0
207         IF ( ln_traldf_lap ) THEN        ! laplacian operator
208            IF ( ln_zco ) THEN                  ! z-coordinate
209               IF ( ln_traldf_lev   )   nldf_tra = np_lap     ! iso-level = horizontal (no rotation)
210               IF ( ln_traldf_hor   )   nldf_tra = np_lap     ! iso-level = horizontal (no rotation)
211               IF ( ln_traldf_iso   )   nldf_tra = np_lap_i   ! iso-neutral: standard  (   rotation)
212               IF ( ln_traldf_triad )   nldf_tra = np_lap_it  ! iso-neutral: triad     (   rotation)
213            ENDIF
214            IF ( ln_zps ) THEN                  ! z-coordinate with partial step
215               IF ( ln_traldf_lev   )   ierr     = 1          ! iso-level not allowed
216               IF ( ln_traldf_hor   )   nldf_tra = np_lap     ! horizontal             (no rotation)
217               IF ( ln_traldf_iso   )   nldf_tra = np_lap_i   ! iso-neutral: standard     (rotation)
218               IF ( ln_traldf_triad )   nldf_tra = np_lap_it  ! iso-neutral: triad        (rotation)
219            ENDIF
220            IF ( ln_sco ) THEN                  ! s-coordinate
221               IF ( ln_traldf_lev   )   nldf_tra = np_lap     ! iso-level              (no rotation)
222               IF ( ln_traldf_hor   )   nldf_tra = np_lap_i   ! horizontal             (   rotation)
223               IF ( ln_traldf_iso   )   nldf_tra = np_lap_i   ! iso-neutral: standard  (   rotation)
224               IF ( ln_traldf_triad )   nldf_tra = np_lap_it  ! iso-neutral: triad     (   rotation)
225            ENDIF
226         ENDIF
227         !
228         IF( ln_traldf_blp ) THEN         ! bilaplacian operator
229            IF ( ln_zco ) THEN                  ! z-coordinate
230               IF ( ln_traldf_lev   )   nldf_tra = np_blp     ! iso-level = horizontal (no rotation)
231               IF ( ln_traldf_hor   )   nldf_tra = np_blp     ! iso-level = horizontal (no rotation)
232               IF ( ln_traldf_iso   )   nldf_tra = np_blp_i   ! iso-neutral: standard  (   rotation)
233               IF ( ln_traldf_triad )   nldf_tra = np_blp_it  ! iso-neutral: triad     (   rotation)
234            ENDIF
235            IF ( ln_zps ) THEN                  ! z-coordinate with partial step
236               IF ( ln_traldf_lev   )   ierr     = 1          ! iso-level not allowed
237               IF ( ln_traldf_hor   )   nldf_tra = np_blp     ! horizontal             (no rotation)
238               IF ( ln_traldf_iso   )   nldf_tra = np_blp_i   ! iso-neutral: standard  (   rotation)
239               IF ( ln_traldf_triad )   nldf_tra = np_blp_it  ! iso-neutral: triad     (   rotation)
240            ENDIF
241            IF ( ln_sco ) THEN                  ! s-coordinate
242               IF ( ln_traldf_lev   )   nldf_tra = np_blp     ! iso-level              (no rotation)
243               IF ( ln_traldf_hor   )   nldf_tra = np_blp_it  ! horizontal             (   rotation)
244               IF ( ln_traldf_iso   )   nldf_tra = np_blp_i   ! iso-neutral: standard  (   rotation)
245               IF ( ln_traldf_triad )   nldf_tra = np_blp_it  ! iso-neutral: triad     (   rotation)
246            ENDIF
247         ENDIF
248         IF ( ierr == 1 )   CALL ctl_stop( 'iso-level in z-partial step, not allowed' )
249      ENDIF
250      !
251      IF( ln_ldfeiv .AND. .NOT.( ln_traldf_iso .OR. ln_traldf_triad ) )                &
252           &            CALL ctl_stop( 'ln_ldfeiv=T requires iso-neutral laplacian diffusion' )
253      IF( ln_isfcav .AND. ln_traldf_triad ) &
254           &            CALL ctl_stop( ' ice shelf cavity and traldf_triad not tested' )
255           !
256      IF(  nldf_tra == np_lap_i .OR. nldf_tra == np_lap_it .OR. &
257         & nldf_tra == np_blp_i .OR. nldf_tra == np_blp_it  )   l_ldfslp = .TRUE.    ! slope of neutral surfaces required
258      !
259      IF( ln_traldf_blp .AND. ( ln_traldf_iso .OR. ln_traldf_triad) ) THEN     ! iso-neutral bilaplacian need MSC
260         IF( .NOT.ln_traldf_msc )   CALL ctl_stop( 'tra_ldf_init: iso-neutral bilaplacian requires ln_traldf_msc=.true.' )
261      ENDIF
262      !
263      IF(lwp) THEN
264         WRITE(numout,*)
265         SELECT CASE( nldf_tra )
266         CASE( np_no_ldf )   ;   WRITE(numout,*) '   ==>>>   NO lateral diffusion'
267         CASE( np_lap    )   ;   WRITE(numout,*) '   ==>>>   laplacian iso-level operator'
268         CASE( np_lap_i  )   ;   WRITE(numout,*) '   ==>>>   Rotated laplacian operator (standard)'
269         CASE( np_lap_it )   ;   WRITE(numout,*) '   ==>>>   Rotated laplacian operator (triad)'
270         CASE( np_blp    )   ;   WRITE(numout,*) '   ==>>>   bilaplacian iso-level operator'
271         CASE( np_blp_i  )   ;   WRITE(numout,*) '   ==>>>   Rotated bilaplacian operator (standard)'
272         CASE( np_blp_it )   ;   WRITE(numout,*) '   ==>>>   Rotated bilaplacian operator (triad)'
273         END SELECT
274         WRITE(numout,*)
275      ENDIF
276
277      !
278      !  Space/time variation of eddy coefficients
279      ! ===========================================
280      !
281      l_ldftra_time = .FALSE.                ! no time variation except in case defined below
282      !
283      IF( ln_traldf_OFF ) THEN               !== no explicit diffusive operator  ==!
284         !
285         IF(lwp) WRITE(numout,*) '   ==>>>   No diffusive operator selected. ahtu and ahtv are not allocated'
286         RETURN
287         !
288      ELSE                                   !==  a lateral diffusion operator is used  ==!
289         !
290         !                                         ! allocate the aht arrays
291         ALLOCATE( ahtu(jpi,jpj,jpk) , ahtv(jpi,jpj,jpk) , STAT=ierr )
292         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'ldf_tra_init: failed to allocate arrays')
293         !
294         ahtu(:,:,jpk) = 0._wp                     ! last level always 0 
295         ahtv(:,:,jpk) = 0._wp
296         !.
297         !                                         ! value of lap/blp eddy mixing coef.
298         IF(     ln_traldf_lap ) THEN   ;   zUfac = r1_2 *rn_Ud   ;   inn = 1   ;   cl_Units = ' m2/s'   !   laplacian
299         ELSEIF( ln_traldf_blp ) THEN   ;   zUfac = r1_12*rn_Ud   ;   inn = 3   ;   cl_Units = ' m4/s'   ! bilaplacian
300         ENDIF
301         aht0    = zUfac *    rn_Ld**inn              ! mixing coefficient
302         zah_max = zUfac * (ra*rad)**inn              ! maximum reachable coefficient (value at the Equator for e1=1 degree)
303         !
304         !
305         SELECT CASE(  nn_aht_ijk_t  )             !* Specification of space-time variations of ahtu, ahtv
306         !
307         CASE(   0  )      !==  constant  ==!
308            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = constant = ', aht0, cl_Units
309            ahtu(:,:,1:jpkm1) = aht0
310            ahtv(:,:,1:jpkm1) = aht0
311            !
312         CASE(  10  )      !==  fixed profile  ==!
313            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( depth )'
314            IF(lwp) WRITE(numout,*) '           surface eddy diffusivity = constant = ', aht0, cl_Units
315            ahtu(:,:,1) = aht0                        ! constant surface value
316            ahtv(:,:,1) = aht0
317            CALL ldf_c1d( 'TRA', ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )
318            !
319         CASE ( -20 )      !== fixed horizontal shape and magnitude read in file  ==!
320            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F(i,j) read in eddy_diffusivity.nc file'
321            CALL iom_open( 'eddy_diffusivity_2D.nc', inum )
322            CALL iom_get ( inum, jpdom_data, 'ahtu_2D', ahtu(:,:,1) )
323            CALL iom_get ( inum, jpdom_data, 'ahtv_2D', ahtv(:,:,1) )
324            CALL iom_close( inum )
325            DO jk = 2, jpkm1
326               ahtu(:,:,jk) = ahtu(:,:,1)
327               ahtv(:,:,jk) = ahtv(:,:,1)
328            END DO
329            !
330         CASE(  20  )      !== fixed horizontal shape  ==!
331            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( e1, e2 ) or F( e1^3, e2^3 ) (lap or blp case)'
332            IF(lwp) WRITE(numout,*) '           using a fixed diffusive velocity = ', rn_Ud,' m/s   and   Ld = Max(e1,e2)'
333            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
334            CALL ldf_c2d( 'TRA', zUfac      , inn        , ahtu, ahtv )    ! value proportional to scale factor^inn
335            !
336         CASE(  21  )      !==  time varying 2D field  ==!
337            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( latitude, longitude, time )'
338            IF(lwp) WRITE(numout,*) '                            = F( growth rate of baroclinic instability )'
339            IF(lwp) WRITE(numout,*) '            min value = 0.2 * aht0 (with aht0= 1/2 rn_Ud*rn_Ld)'
340            IF(lwp) WRITE(numout,*) '            max value =       aei0 (with aei0=1/2 rn_Ue*Le  increased to aht0 within 20N-20S'
341            !
342            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
343            !
344            IF( ln_traldf_blp )   CALL ctl_stop( 'ldf_tra_init: aht=F( growth rate of baroc. insta .)',   &
345               &                                 '              incompatible with bilaplacian operator' )
346            !
347         CASE( -30  )      !== fixed 3D shape read in file  ==!
348            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F(i,j,k) read in eddy_diffusivity.nc file'
349            CALL iom_open( 'eddy_diffusivity_3D.nc', inum )
350            CALL iom_get ( inum, jpdom_data, 'ahtu_3D', ahtu )
351            CALL iom_get ( inum, jpdom_data, 'ahtv_3D', ahtv )
352            CALL iom_close( inum )
353            !
354         CASE(  30  )      !==  fixed 3D shape  ==!
355            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( latitude, longitude, depth )'
356            IF(lwp) WRITE(numout,*) '           using a fixed diffusive velocity = ', rn_Ud,' m/s   and   Ld = Max(e1,e2)'
357            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
358            CALL ldf_c2d( 'TRA', zUfac      , inn        , ahtu, ahtv )    ! surface value proportional to scale factor^inn
359            CALL ldf_c1d( 'TRA', ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )    ! reduction with depth
360            !
361         CASE(  31  )      !==  time varying 3D field  ==!
362            IF(lwp) WRITE(numout,*) '   ==>>>   eddy diffusivity = F( latitude, longitude, depth , time )'
363            IF(lwp) WRITE(numout,*) '           proportional to the velocity : 1/2 |u|e or 1/12 |u|e^3'
364            !
365            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
366            !
367         CASE DEFAULT
368            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aht_ijk_t, the type of space-time variation of aht')
369         END SELECT
370         !
371         IF( .NOT.l_ldftra_time ) THEN             !* No time variation
372            IF(     ln_traldf_lap ) THEN                 !   laplacian operator (mask only)
373               ahtu(:,:,1:jpkm1) =       ahtu(:,:,1:jpkm1)   * umask(:,:,1:jpkm1)
374               ahtv(:,:,1:jpkm1) =       ahtv(:,:,1:jpkm1)   * vmask(:,:,1:jpkm1)
375            ELSEIF( ln_traldf_blp ) THEN                 ! bilaplacian operator (square root + mask)
376               ahtu(:,:,1:jpkm1) = SQRT( ahtu(:,:,1:jpkm1) ) * umask(:,:,1:jpkm1)
377               ahtv(:,:,1:jpkm1) = SQRT( ahtv(:,:,1:jpkm1) ) * vmask(:,:,1:jpkm1)
378            ENDIF
379         ENDIF
380         !
381      ENDIF
382      !
383   END SUBROUTINE ldf_tra_init
384
385
386   SUBROUTINE ldf_tra( kt )
387      !!----------------------------------------------------------------------
388      !!                  ***  ROUTINE ldf_tra  ***
389      !!
390      !! ** Purpose :   update at kt the tracer lateral mixing coeff. (aht and aeiv)
391      !!
392      !! ** Method  : * time varying eddy diffusivity coefficients:
393      !!
394      !!    nn_aei_ijk_t = 21    aeiu, aeiv = F(i,j,  t) = F(growth rate of baroclinic instability)
395      !!                                                   with a reduction to 0 in vicinity of the Equator
396      !!    nn_aht_ijk_t = 21    ahtu, ahtv = F(i,j,  t) = F(growth rate of baroclinic instability)
397      !!
398      !!                 = 31    ahtu, ahtv = F(i,j,k,t) = F(local velocity) (  |u|e  /12   laplacian operator
399      !!                                                                     or |u|e^3/12 bilaplacian operator )
400      !!
401      !!              * time varying EIV coefficients: call to ldf_eiv routine
402      !!
403      !! ** action  :   ahtu, ahtv   update at each time step   
404      !!                aeiu, aeiv      -       -     -    -   (if ln_ldfeiv=T)
405      !!----------------------------------------------------------------------
406      INTEGER, INTENT(in) ::   kt   ! time step
407      !
408      INTEGER  ::   ji, jj, jk   ! dummy loop indices
409      REAL(wp) ::   zaht, zahf, zaht_min, zDaht, z1_f20   ! local scalar
410      !!----------------------------------------------------------------------
411      !
412      IF( ln_ldfeiv .AND. ( nn_aei_ijk_t == 21 .OR. nn_aei_ijk_t == 22 ) ) THEN       
413         !                                ! eddy induced velocity coefficients
414         !                                ! =F(growth rate of baroclinic instability)
415         !                                ! max value aeiv_0 ; decreased to 0 within 20N-20S
416         CALL ldf_eiv( kt, aei0, aeiu, aeiv, l_Ro_cutoff )
417      ENDIF
418      !
419      SELECT CASE(  nn_aht_ijk_t  )       ! Eddy diffusivity coefficients
420      !
421      CASE(  21  )       !==  time varying 2D field  ==!   = F( growth rate of baroclinic instability )
422         !                                             !   min value 0.2*aht0
423         !                                             !   max value aht0 (aei0 if nn_aei_ijk_t=21)
424         !                                             !   increase to aht0 within 20N-20S
425         IF( ln_ldfeiv .AND. nn_aei_ijk_t == 21 ) THEN   ! use the already computed aei.
426            ahtu(:,:,1) = aeiu(:,:,1)
427            ahtv(:,:,1) = aeiv(:,:,1)
428         ELSE                                            ! compute aht.
429            CALL ldf_eiv( kt, aht0, ahtu, ahtv, .false. )
430         ENDIF
431         !
432         z1_f20   = 1._wp / (  2._wp * omega * SIN( rad * 20._wp )  )   ! 1 / ff(20 degrees)   
433         zaht_min = 0.2_wp * aht0                                       ! minimum value for aht
434         zDaht    = aht0 - zaht_min                                     
435         DO jj = 1, jpj
436            DO ji = 1, jpi
437               !!gm CAUTION : here we assume lat/lon grid in 20deg N/S band (like all ORCA cfg)
438               !!     ==>>>   The Coriolis value is identical for t- & u_points, and for v- and f-points
439               zaht = ( 1._wp -  MIN( 1._wp , ABS( ff_t(ji,jj) * z1_f20 ) ) ) * zDaht
440               zahf = ( 1._wp -  MIN( 1._wp , ABS( ff_f(ji,jj) * z1_f20 ) ) ) * zDaht
441               ahtu(ji,jj,1) = (  MAX( zaht_min, ahtu(ji,jj,1) ) + zaht  )     ! min value zaht_min
442               ahtv(ji,jj,1) = (  MAX( zaht_min, ahtv(ji,jj,1) ) + zahf  )     ! increase within 20S-20N
443            END DO
444         END DO
445         DO jk = 1, jpkm1                             ! deeper value = surface value + mask for all levels
446            ahtu(:,:,jk) = ahtu(:,:,1) * umask(:,:,jk)
447            ahtv(:,:,jk) = ahtv(:,:,1) * vmask(:,:,jk)
448         END DO
449         !
450      CASE(  31  )       !==  time varying 3D field  ==!   = F( local velocity )
451         IF( ln_traldf_lap     ) THEN          !   laplacian operator |u| e /12
452            DO jk = 1, jpkm1
453               ahtu(:,:,jk) = ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12   ! n.b. ub,vb are masked
454               ahtv(:,:,jk) = ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12
455            END DO
456         ELSEIF( ln_traldf_blp ) THEN      ! bilaplacian operator      sqrt( |u| e^3 /12 ) = sqrt( |u| e /12 ) * e
457            DO jk = 1, jpkm1
458               ahtu(:,:,jk) = SQRT(  ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12  ) * e1u(:,:)
459               ahtv(:,:,jk) = SQRT(  ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12  ) * e2v(:,:)
460            END DO
461         ENDIF
462         !
463      END SELECT
464      !
465      CALL iom_put( "ahtu_2d", ahtu(:,:,1) )   ! surface u-eddy diffusivity coeff.
466      CALL iom_put( "ahtv_2d", ahtv(:,:,1) )   ! surface v-eddy diffusivity coeff.
467      CALL iom_put( "ahtu_3d", ahtu(:,:,:) )   ! 3D      u-eddy diffusivity coeff.
468      CALL iom_put( "ahtv_3d", ahtv(:,:,:) )   ! 3D      v-eddy diffusivity coeff.
469      !
470      IF( ln_ldfeiv ) THEN
471        CALL iom_put( "aeiu_2d", aeiu(:,:,1) )   ! surface u-EIV coeff.
472        CALL iom_put( "aeiv_2d", aeiv(:,:,1) )   ! surface v-EIV coeff.
473        CALL iom_put( "aeiu_3d", aeiu(:,:,:) )   ! 3D      u-EIV coeff.
474        CALL iom_put( "aeiv_3d", aeiv(:,:,:) )   ! 3D      v-EIV coeff.
475      ENDIF
476      !
477   END SUBROUTINE ldf_tra
478
479
480   SUBROUTINE ldf_eiv_init
481      !!----------------------------------------------------------------------
482      !!                  ***  ROUTINE ldf_eiv_init  ***
483      !!
484      !! ** Purpose :   initialization of the eiv coeff. from namelist choices.
485      !!
486      !! ** Method  :   the eiv diffusivity coef. specification depends on:
487      !!    nn_aei_ijk_t  =  0 => = constant
488      !!                  !
489      !!                  = 10 => = F(z) : constant with a reduction of 1/4 with depth
490      !!                  !
491      !!                  =-20 => = F(i,j)   = shape read in 'eddy_diffusivity.nc' file
492      !!                  = 20    = F(i,j)   = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
493      !!                  = 21    = F(i,j,t) = F(growth rate of baroclinic instability)
494      !!                  !
495      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_diffusivity.nc' file
496      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
497      !!
498      !! ** Action  :   aeiu , aeiv   :  initialized one for all or l_ldftra_time set to true
499      !!                l_ldfeiv_time : =T if EIV coefficients vary with time
500      !!----------------------------------------------------------------------
501      INTEGER  ::   jk                     ! dummy loop indices
502      INTEGER  ::   ierr, inum, ios, inn   ! local integer
503      REAL(wp) ::   zah_max, zUfac         !   -   scalar
504      !!
505      NAMELIST/namtra_eiv/ ln_ldfeiv   , ln_ldfeiv_dia,   &   ! eddy induced velocity (eiv)
506         &                 nn_aei_ijk_t, rn_Ue, rn_Le,    &   ! eiv  coefficient
507         &                 nn_ldfeiv_shape
508      !!----------------------------------------------------------------------
509      !
510      IF(lwp) THEN                      ! control print
511         WRITE(numout,*)
512         WRITE(numout,*) 'ldf_eiv_init : eddy induced velocity parametrization'
513         WRITE(numout,*) '~~~~~~~~~~~~ '
514      ENDIF
515      !
516      REWIND( numnam_ref )              ! Namelist namtra_eiv in reference namelist : eddy induced velocity param.
517      READ  ( numnam_ref, namtra_eiv, IOSTAT = ios, ERR = 901)
518901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_eiv in reference namelist' )
519      !
520      REWIND( numnam_cfg )              ! Namelist namtra_eiv in configuration namelist : eddy induced velocity param.
521      READ  ( numnam_cfg, namtra_eiv, IOSTAT = ios, ERR = 902 )
522902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_eiv in configuration namelist' )
523      IF(lwm)  WRITE ( numond, namtra_eiv )
524
525      IF(lwp) THEN                      ! control print
526         WRITE(numout,*) '   Namelist namtra_eiv : '
527         WRITE(numout,*) '      Eddy Induced Velocity (eiv) param.         ln_ldfeiv     = ', ln_ldfeiv
528         WRITE(numout,*) '      eiv streamfunction & velocity diag.        ln_ldfeiv_dia = ', ln_ldfeiv_dia
529         WRITE(numout,*) '      coefficients :'
530         WRITE(numout,*) '         type of time-space variation            nn_aei_ijk_t  = ', nn_aei_ijk_t
531         WRITE(numout,*) '         lateral diffusive velocity (if cst)     rn_Ue         = ', rn_Ue, ' m/s'
532         WRITE(numout,*) '         lateral diffusive length   (if cst)     rn_Le         = ', rn_Le, ' m'
533         WRITE(numout,*)
534      ENDIF
535      !
536      l_ldfeiv_time = .FALSE.       ! no time variation except in case defined below
537      !
538      !
539      IF( .NOT.ln_ldfeiv ) THEN     !== Parametrization not used  ==!
540         !
541         IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity param is NOT used'
542         ln_ldfeiv_dia = .FALSE.
543         !
544      ELSE                          !== use the parametrization  ==!
545         !
546         IF(lwp) WRITE(numout,*) '   ==>>>   use eddy induced velocity parametrization'
547         IF(lwp) WRITE(numout,*)
548         !
549         IF( ln_traldf_blp )   CALL ctl_stop( 'ldf_eiv_init: eddy induced velocity ONLY with laplacian diffusivity' )
550         !
551         !                                != allocate the aei arrays
552         ALLOCATE( aeiu(jpi,jpj,jpk), aeiv(jpi,jpj,jpk), STAT=ierr )
553         IF( ierr /= 0 )   CALL ctl_stop('STOP', 'ldf_eiv: failed to allocate arrays')
554         !
555         !                                != Specification of space-time variations of eaiu, aeiv
556         !
557         aeiu(:,:,jpk) = 0._wp               ! last level always 0 
558         aeiv(:,:,jpk) = 0._wp
559         !                                   ! value of EIV coef. (laplacian operator)
560         zUfac = r1_2 *rn_Ue                    ! velocity factor
561         inn = 1                                ! L-exponent
562         aei0    = zUfac *    rn_Le**inn        ! mixing coefficient
563         zah_max = zUfac * (ra*rad)**inn        ! maximum reachable coefficient (value at the Equator)
564
565         l_Ro_cutoff = .FALSE.
566         SELECT CASE( nn_aei_ijk_t )         !* Specification of space-time variations
567         !
568         CASE(   0  )                        !--  constant  --!
569            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = constant = ', aei0, ' m2/s'
570            aeiu(:,:,1:jpkm1) = aei0
571            aeiv(:,:,1:jpkm1) = aei0
572            !
573         CASE(  10  )                        !--  fixed profile  --!
574            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( depth )'
575            IF(lwp) WRITE(numout,*) '           surface eddy diffusivity = constant = ', aht0, ' m2/s'
576            aeiu(:,:,1) = aei0                  ! constant surface value
577            aeiv(:,:,1) = aei0
578            CALL ldf_c1d( 'TRA', aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )
579            !
580         CASE ( -20 )                        !--  fixed horizontal shape read in file  --!
581            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F(i,j) read in eddy_diffusivity_2D.nc file'
582            CALL iom_open ( 'eddy_induced_velocity_2D.nc', inum )
583            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu(:,:,1) )
584            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv(:,:,1) )
585            CALL iom_close( inum )
586            DO jk = 2, jpkm1
587               aeiu(:,:,jk) = aeiu(:,:,1)
588               aeiv(:,:,jk) = aeiv(:,:,1)
589            END DO
590            !
591         CASE(  20  )                        !--  fixed horizontal shape  --!
592            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( e1, e2 )'
593            IF(lwp) WRITE(numout,*) '           using a fixed diffusive velocity = ', rn_Ue, ' m/s   and   Le = Max(e1,e2)'
594            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, ' m2/s   for e1=1°)'
595            CALL ldf_c2d( 'TRA', zUfac      , inn        , aeiu, aeiv )    ! value proportional to scale factor^inn
596            !
597         CASE(  21  )                        !--  time varying 2D field  --!
598            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( latitude, longitude, time )'
599            IF(lwp) WRITE(numout,*) '                                       = F( growth rate of baroclinic instability )'
600            IF(lwp) WRITE(numout,*) '           maximum allowed value: aei0 = ', aei0, ' m2/s'
601            IF(lwp) WRITE(numout,*) '           shape of bounding coefficient : ',nn_ldfeiv_shape
602            !
603            l_ldfeiv_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
604            !
605         CASE(  22  )                        !--  time varying 2D field with cutoff --!
606            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( latitude, longitude, time )'
607            IF(lwp) WRITE(numout,*) '                                       = F( growth rate of baroclinic instability )'
608            IF(lwp) WRITE(numout,*) '           maximum allowed value: aei0 = ', aei0, ' m2/s'
609            IF(lwp) WRITE(numout,*) '           Applied only where Rossby radius resolved by 2.dx'
610            !
611            l_Ro_cutoff   = .TRUE.
612            l_ldfeiv_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
613            !
614         CASE( -30  )                        !-- fixed 3D shape read in file  --!
615            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F(i,j,k) read in eddy_diffusivity_3D.nc file'
616            CALL iom_open ( 'eddy_induced_velocity_3D.nc', inum )
617            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu )
618            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv )
619            CALL iom_close( inum )
620            !
621         CASE(  30  )                        !--  fixed 3D shape  --!
622            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( latitude, longitude, depth )'
623            CALL ldf_c2d( 'TRA', zUfac      , inn        , aeiu, aeiv )    ! surface value proportional to scale factor^inn
624            CALL ldf_c1d( 'TRA', aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )    ! reduction with depth
625            !
626         CASE DEFAULT
627            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aei_ijk_t, the type of space-time variation of aei')
628         END SELECT
629         !
630         IF( .NOT.l_ldfeiv_time ) THEN             !* mask if No time variation
631            DO jk = 1, jpkm1
632               aeiu(:,:,jk) = aeiu(:,:,jk) * umask(:,:,jk)
633               ahtv(:,:,jk) = ahtv(:,:,jk) * vmask(:,:,jk)
634            END DO
635         ENDIF
636         !
637      ENDIF
638      !                   
639   END SUBROUTINE ldf_eiv_init
640
641
642   SUBROUTINE ldf_eiv( kt, paei0, paeiu, paeiv, l_Ro_cutoff )
643      !!----------------------------------------------------------------------
644      !!                  ***  ROUTINE ldf_eiv  ***
645      !!
646      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
647      !!              growth rate of baroclinic instability.
648      !!
649      !! ** Method  :   coefficient function of the growth rate of baroclinic instability
650      !!
651      !! Reference : Treguier et al. JPO 1997   ; Held and Larichev JAS 1996
652      !!----------------------------------------------------------------------
653      INTEGER                         , INTENT(in   ) ::   kt             ! ocean time-step index
654      REAL(wp)                        , INTENT(inout) ::   paei0          ! max value            [m2/s]
655      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   paeiu, paeiv   ! eiv coefficient      [m2/s]
656      LOGICAL                         , INTENT(in   ) ::   l_Ro_cutoff    ! Rossby radius cutoff yes/no
657      !
658      INTEGER  ::   ji, jj, jk    ! dummy loop indices
659      REAL(wp) ::   zfw, ze3w, zn2, z1_f20, zaht, zaht_min, zzaei, z2_3    ! local scalars
660      REAL(wp), DIMENSION(jpi,jpj) ::   zn, zah, zhw, zRo, zRo_lim, zaeiw, zratio   ! 2D workspace
661      !!----------------------------------------------------------------------
662      !
663      zn (:,:) = 0._wp        ! Local initialization
664      zhw(:,:) = 5._wp
665      zah(:,:) = 0._wp
666      zRo(:,:) = 0._wp
667      zRo_lim(:,:) = 0._wp
668      !                       ! Compute lateral diffusive coefficient at T-point
669      IF( ln_traldf_triad ) THEN
670         DO jk = 1, jpk
671            DO jj = 2, jpjm1
672               DO ji = 2, jpim1
673                  ! Take the max of N^2 and zero then take the vertical sum
674                  ! of the square root of the resulting N^2 ( required to compute
675                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
676                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
677                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
678                  ! Compute elements required for the inverse time scale of baroclinic
679                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
680                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
681                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
682                  zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w
683                  zhw(ji,jj) = zhw(ji,jj) + ze3w
684               END DO
685            END DO
686         END DO
687      ELSE
688         DO jk = 1, jpk
689            DO jj = 2, jpjm1
690               DO ji = 2, jpim1
691                  ! Take the max of N^2 and zero then take the vertical sum
692                  ! of the square root of the resulting N^2 ( required to compute
693                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
694                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
695                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
696                  ! Compute elements required for the inverse time scale of baroclinic
697                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
698                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
699                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
700                  zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
701                     &                            + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w
702                  zhw(ji,jj) = zhw(ji,jj) + ze3w
703               END DO
704            END DO
705         END DO
706      ENDIF
707
708      DO jj = 2, jpjm1
709         DO ji = fs_2, fs_jpim1   ! vector opt.
710            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
711            ! Rossby radius at w-point taken between 2 km and  40km
712            zRo(ji,jj) = .4 * zn(ji,jj) / zfw
713            zRo_lim(ji,jj) = MAX(  2.e3 , MIN( zRo(ji,jj), 40.e3 )  )
714            ! Compute aeiw by multiplying Ro^2 and T^-1
715            zaeiw(ji,jj) = zRo_lim(ji,jj) * zRo_lim(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1)
716         END DO
717      END DO
718      IF( iom_use('N_2d') ) CALL iom_put('N_2d',zn(:,:)/ht_0(:,:))
719      CALL iom_put('RossRad',zRo)
720      !                                         !==  Bound on eiv coeff.  ==!
721      z1_f20 = 1._wp / (  2._wp * omega * sin( rad * 20._wp )  )
722      z2_3 = 2._wp/3._wp
723      DO jj = 2, jpjm1
724         DO ji = fs_2, fs_jpim1   ! vector opt.
725            zzaei = MIN( 1._wp, ABS( ff_t(ji,jj) * z1_f20 ) ) * zaeiw(ji,jj)     ! tropical decrease
726            zaeiw(ji,jj) = MIN( zzaei, paei0 )
727         END DO
728      END DO
729
730      !! temporary fudge for diagnostic purposes:
731      !! zaeiw(:,:) = paei0
732
733      SELECT CASE(nn_ldfeiv_shape)
734         CASE(1) !! Abrupt cut-off on Rossby radius:
735! JD : modifications here to introduce scaling by local rossby radius of deformation vs local grid scale
736! arbitrary decision that GM is de-activated if local rossy radius larger than 2 times local grid scale
737! based on Hallberg (2013)
738            DO jj = 2, jpjm1
739               DO ji = fs_2, fs_jpim1   ! vector opt.
740                  IF ( l_Ro_cutoff .AND. zRo(ji,jj) >= ( 2._wp * MIN( e1t(ji,jj), e2t(ji,jj) ) ) ) THEN
741! TODO : use a version of zRo that integrates over a few time steps ?
742                      zaeiw(ji,jj) = 0._wp
743                  ELSE
744                      zaeiw(ji,jj) = MIN( zaeiw(ji,jj), paei0 )
745                  ENDIF
746               END DO
747            END DO
748
749         CASE(2) !! Rossby radius ramp type 1:
750            DO jj = 2, jpjm1
751               DO ji = fs_2, fs_jpim1   ! vector opt.
752                  zratio(ji,jj) = zRo(ji,jj)/MIN(e1t(ji,jj),e2t(ji,jj))
753                  zaeiw(ji,jj) = MIN( zaeiw(ji,jj), MAX( 0._wp, MIN( 1._wp, z2_3*(2._wp - zratio(ji,jj)) ) ) * paei0 )
754               END DO
755            END DO
756            CALL iom_put('RR_GS',zratio)
757
758         CASE(3) !! Rossby radius ramp type 2:
759            DO jj = 2, jpjm1
760               DO ji = fs_2, fs_jpim1   ! vector opt.
761                  zratio(ji,jj) = MIN(e1t(ji,jj),e2t(ji,jj))/zRo(ji,jj)
762                  zaeiw(ji,jj) = MIN( zaeiw(ji,jj), MAX( 0._wp, MIN( 1._wp, z2_3*( zratio(ji,jj) - 0.5_wp ) ) ) * paei0 )
763               END DO
764            END DO
765            CALL iom_put('GS_RR',zratio)
766
767      END SELECT
768
769      CALL lbc_lnk( 'ldftra', zaeiw(:,:), 'W', 1. )       ! lateral boundary condition
770      !               
771      DO jj = 2, jpjm1                          !== aei at u- and v-points  ==!
772         DO ji = fs_2, fs_jpim1   ! vector opt.
773            paeiu(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji+1,jj  ) ) * umask(ji,jj,1)
774            paeiv(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji  ,jj+1) ) * vmask(ji,jj,1)
775         END DO
776      END DO
777      CALL lbc_lnk_multi( 'ldftra', paeiu(:,:,1), 'U', 1. , paeiv(:,:,1), 'V', 1. )      ! lateral boundary condition
778
779      DO jk = 2, jpkm1                          !==  deeper values equal the surface one  ==!
780         paeiu(:,:,jk) = paeiu(:,:,1) * umask(:,:,jk)
781         paeiv(:,:,jk) = paeiv(:,:,1) * vmask(:,:,jk)
782      END DO
783     
784   END SUBROUTINE ldf_eiv
785
786
787   SUBROUTINE ldf_eiv_trp( kt, kit000, pun, pvn, pwn, cdtype )
788      !!----------------------------------------------------------------------
789      !!                  ***  ROUTINE ldf_eiv_trp  ***
790      !!
791      !! ** Purpose :   add to the input ocean transport the contribution of
792      !!              the eddy induced velocity parametrization.
793      !!
794      !! ** Method  :   The eddy induced transport is computed from a flux stream-
795      !!              function which depends on the slope of iso-neutral surfaces
796      !!              (see ldf_slp). For example, in the i-k plan :
797      !!                   psi_uw = mk(aeiu) e2u mi(wslpi)   [in m3/s]
798      !!                   Utr_eiv = - dk[psi_uw]
799      !!                   Vtr_eiv = + di[psi_uw]
800      !!                ln_ldfeiv_dia = T : output the associated streamfunction,
801      !!                                    velocity and heat transport (call ldf_eiv_dia)
802      !!
803      !! ** Action  : pun, pvn increased by the eiv transport
804      !!----------------------------------------------------------------------
805      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
806      INTEGER                         , INTENT(in   ) ::   kit000   ! first time step index
807      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
808      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean transport components   [m3/s]
809      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean transport components   [m3/s]
810      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv                [m3/s]
811      !!
812      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
813      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
814      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
815      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpsi_uw, zpsi_vw
816      !!----------------------------------------------------------------------
817      !
818      IF( kt == kit000 )  THEN
819         IF(lwp) WRITE(numout,*)
820         IF(lwp) WRITE(numout,*) 'ldf_eiv_trp : eddy induced advection on ', cdtype,' :'
821         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
822      ENDIF
823
824     
825      zpsi_uw(:,:, 1 ) = 0._wp   ;   zpsi_vw(:,:, 1 ) = 0._wp
826      zpsi_uw(:,:,jpk) = 0._wp   ;   zpsi_vw(:,:,jpk) = 0._wp
827      !
828      DO jk = 2, jpkm1
829         DO jj = 1, jpjm1
830            DO ji = 1, fs_jpim1   ! vector opt.
831               zpsi_uw(ji,jj,jk) = - r1_4 * e2u(ji,jj) * ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk) )   &
832                  &                                    * ( aeiu (ji,jj,jk-1) + aeiu (ji  ,jj,jk) ) * umask(ji,jj,jk)
833               zpsi_vw(ji,jj,jk) = - r1_4 * e1v(ji,jj) * ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk) )   &
834                  &                                    * ( aeiv (ji,jj,jk-1) + aeiv (ji,jj  ,jk) ) * vmask(ji,jj,jk)
835            END DO
836         END DO
837      END DO
838      !
839      DO jk = 1, jpkm1
840         DO jj = 1, jpjm1
841            DO ji = 1, fs_jpim1   ! vector opt.               
842               pun(ji,jj,jk) = pun(ji,jj,jk) - ( zpsi_uw(ji,jj,jk) - zpsi_uw(ji,jj,jk+1) )
843               pvn(ji,jj,jk) = pvn(ji,jj,jk) - ( zpsi_vw(ji,jj,jk) - zpsi_vw(ji,jj,jk+1) )
844            END DO
845         END DO
846      END DO
847      DO jk = 1, jpkm1
848         DO jj = 2, jpjm1
849            DO ji = fs_2, fs_jpim1   ! vector opt.
850               pwn(ji,jj,jk) = pwn(ji,jj,jk) + (  zpsi_uw(ji,jj,jk) - zpsi_uw(ji-1,jj  ,jk)   &
851                  &                             + zpsi_vw(ji,jj,jk) - zpsi_vw(ji  ,jj-1,jk) )
852            END DO
853         END DO
854      END DO
855      !
856      !                              ! diagnose the eddy induced velocity and associated heat transport
857      IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' )   CALL ldf_eiv_dia( zpsi_uw, zpsi_vw )
858      !
859    END SUBROUTINE ldf_eiv_trp
860
861
862   SUBROUTINE ldf_eiv_dia( psi_uw, psi_vw )
863      !!----------------------------------------------------------------------
864      !!                  ***  ROUTINE ldf_eiv_dia  ***
865      !!
866      !! ** Purpose :   diagnose the eddy induced velocity and its associated
867      !!              vertically integrated heat transport.
868      !!
869      !! ** Method :
870      !!
871      !!----------------------------------------------------------------------
872      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   psi_uw, psi_vw   ! streamfunction   [m3/s]
873      !
874      INTEGER  ::   ji, jj, jk    ! dummy loop indices
875      REAL(wp) ::   zztmp   ! local scalar
876      REAL(wp), DIMENSION(jpi,jpj)     ::   zw2d   ! 2D workspace
877      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zw3d   ! 3D workspace
878      !!----------------------------------------------------------------------
879      !
880!!gm I don't like this routine....   Crazy  way of doing things, not optimal at all...
881!!gm     to be redesigned....   
882      !                                                  !==  eiv stream function: output  ==!
883      CALL lbc_lnk_multi( 'ldftra', psi_uw, 'U', -1. , psi_vw, 'V', -1. )
884      !
885!!gm      CALL iom_put( "psi_eiv_uw", psi_uw )                 ! output
886!!gm      CALL iom_put( "psi_eiv_vw", psi_vw )
887      !
888      !                                                  !==  eiv velocities: calculate and output  ==!
889      !
890      zw3d(:,:,jpk) = 0._wp                                    ! bottom value always 0
891      !
892      DO jk = 1, jpkm1                                         ! e2u e3u u_eiv = -dk[psi_uw]
893         zw3d(:,:,jk) = ( psi_uw(:,:,jk+1) - psi_uw(:,:,jk) ) / ( e2u(:,:) * e3u_n(:,:,jk) )
894      END DO
895      CALL iom_put( "uoce_eiv", zw3d )
896      !
897      DO jk = 1, jpkm1                                         ! e1v e3v v_eiv = -dk[psi_vw]
898         zw3d(:,:,jk) = ( psi_vw(:,:,jk+1) - psi_vw(:,:,jk) ) / ( e1v(:,:) * e3v_n(:,:,jk) )
899      END DO
900      CALL iom_put( "voce_eiv", zw3d )
901      !
902      DO jk = 1, jpkm1                                         ! e1 e2 w_eiv = dk[psix] + dk[psix]
903         DO jj = 2, jpjm1
904            DO ji = fs_2, fs_jpim1  ! vector opt.
905               zw3d(ji,jj,jk) = (  psi_vw(ji,jj,jk) - psi_vw(ji  ,jj-1,jk)    &
906                  &              + psi_uw(ji,jj,jk) - psi_uw(ji-1,jj  ,jk)  ) / e1e2t(ji,jj)
907            END DO
908         END DO
909      END DO
910      CALL lbc_lnk( 'ldftra', zw3d, 'T', 1. )      ! lateral boundary condition
911      CALL iom_put( "woce_eiv", zw3d )
912      !
913      !
914      zztmp = 0.5_wp * rau0 * rcp 
915      IF( iom_use('ueiv_heattr') .OR. iom_use('ueiv_heattr3d') ) THEN
916        zw2d(:,:)   = 0._wp 
917        zw3d(:,:,:) = 0._wp 
918        DO jk = 1, jpkm1
919           DO jj = 2, jpjm1
920              DO ji = fs_2, fs_jpim1   ! vector opt.
921                 zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_uw(ji,jj,jk+1)      - psi_uw(ji,jj,jk)          )   &
922                    &                            * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji+1,jj,jk,jp_tem) ) 
923                 zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
924              END DO
925           END DO
926        END DO
927        CALL lbc_lnk( 'ldftra', zw2d, 'U', -1. )
928        CALL lbc_lnk( 'ldftra', zw3d, 'U', -1. )
929        CALL iom_put( "ueiv_heattr"  , zztmp * zw2d )                  ! heat transport in i-direction
930        CALL iom_put( "ueiv_heattr3d", zztmp * zw3d )                  ! heat transport in i-direction
931      ENDIF
932      zw2d(:,:)   = 0._wp 
933      zw3d(:,:,:) = 0._wp 
934      DO jk = 1, jpkm1
935         DO jj = 2, jpjm1
936            DO ji = fs_2, fs_jpim1   ! vector opt.
937               zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_vw(ji,jj,jk+1)      - psi_vw(ji,jj,jk)          )   &
938                  &                            * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji,jj+1,jk,jp_tem) ) 
939               zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
940            END DO
941         END DO
942      END DO
943      CALL lbc_lnk( 'ldftra', zw2d, 'V', -1. )
944      CALL iom_put( "veiv_heattr", zztmp * zw2d )                  !  heat transport in j-direction
945      CALL iom_put( "veiv_heattr", zztmp * zw3d )                  !  heat transport in j-direction
946      !
947      IF( ln_diaptr )  CALL dia_ptr_hst( jp_tem, 'eiv', 0.5 * zw3d )
948      !
949      zztmp = 0.5_wp * 0.5
950      IF( iom_use('ueiv_salttr') .OR. iom_use('ueiv_salttr3d')) THEN
951        zw2d(:,:) = 0._wp 
952        zw3d(:,:,:) = 0._wp 
953        DO jk = 1, jpkm1
954           DO jj = 2, jpjm1
955              DO ji = fs_2, fs_jpim1   ! vector opt.
956                 zw3d(ji,jj,jk) = zw3d(ji,jj,jk) * ( psi_uw(ji,jj,jk+1)      - psi_uw(ji,jj,jk)          )   &
957                    &                            * ( tsn   (ji,jj,jk,jp_sal) + tsn   (ji+1,jj,jk,jp_sal) ) 
958                 zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
959              END DO
960           END DO
961        END DO
962        CALL lbc_lnk( 'ldftra', zw2d, 'U', -1. )
963        CALL lbc_lnk( 'ldftra', zw3d, 'U', -1. )
964        CALL iom_put( "ueiv_salttr", zztmp * zw2d )                  ! salt transport in i-direction
965        CALL iom_put( "ueiv_salttr3d", zztmp * zw3d )                  ! salt transport in i-direction
966      ENDIF
967      zw2d(:,:) = 0._wp 
968      zw3d(:,:,:) = 0._wp 
969      DO jk = 1, jpkm1
970         DO jj = 2, jpjm1
971            DO ji = fs_2, fs_jpim1   ! vector opt.
972               zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_vw(ji,jj,jk+1)      - psi_vw(ji,jj,jk)          )   &
973                  &                            * ( tsn   (ji,jj,jk,jp_sal) + tsn   (ji,jj+1,jk,jp_sal) ) 
974               zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
975            END DO
976         END DO
977      END DO
978      CALL lbc_lnk( 'ldftra', zw2d, 'V', -1. )
979      CALL iom_put( "veiv_salttr", zztmp * zw2d )                  !  salt transport in j-direction
980      CALL iom_put( "veiv_salttr", zztmp * zw3d )                  !  salt transport in j-direction
981      !
982      IF( ln_diaptr ) CALL dia_ptr_hst( jp_sal, 'eiv', 0.5 * zw3d )
983      !
984      !
985   END SUBROUTINE ldf_eiv_dia
986
987   !!======================================================================
988END MODULE ldftra
Note: See TracBrowser for help on using the repository browser.