source: NEMO/branches/UKMO/NEMO_4.0.1_NGMS_couple_pkg/src/OCE/SBC/cpl_oasis3.F90 @ 13311

Last change on this file since 13311 was 13311, checked in by frrh, 17 months ago

Save dev changes for concurrent LFRIC + GO8 running

File size: 27.4 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5   !!=====================================================================
6   !! History :  1.0  !  2004-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
7   !!             -   !  2004-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
8   !!             -   !  2004-11  (V. Gayler, MPI M&D) Grid writing
9   !!            2.0  !  2005-08  (R. Redler, W. Park) frld initialization, paral(2) revision
10   !!             -   !  2005-09  (R. Redler) extended to allow for communication over root only
11   !!             -   !  2006-01  (W. Park) modification of physical part
12   !!             -   !  2006-02  (R. Redler, W. Park) buffer array fix for root exchange
13   !!            3.4  !  2011-11  (C. Harris) Changes to allow mutiple category fields
14   !!            3.6  !  2014-11  (S. Masson) OASIS3-MCT
15   !!----------------------------------------------------------------------
16   
17   !!----------------------------------------------------------------------
18   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3-MCT
19   !!   'key_oa3mct_v3'                 to be added for OASIS3-MCT version 3
20   !!----------------------------------------------------------------------
21   !!   cpl_init     : initialization of coupled mode communication
22   !!   cpl_define   : definition of grid and fields
23   !!   cpl_snd      : snd out fields in coupled mode
24   !!   cpl_rcv      : receive fields in coupled mode
25   !!   cpl_finalize : finalize the coupled mode communication
26   !!----------------------------------------------------------------------
27#if defined key_oasis3
28   USE mod_oasis                    ! OASIS3-MCT module
29#endif
30   USE par_oce                      ! ocean parameters
31   USE dom_oce                      ! ocean space and time domain
32   USE in_out_manager               ! I/O manager
33   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   cpl_init
39   PUBLIC   cpl_define
40   PUBLIC   cpl_snd
41   PUBLIC   cpl_rcv
42   PUBLIC   cpl_freq
43   PUBLIC   cpl_finalize
44   
45
46   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
47   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
48   INTEGER                    ::   ncomp_id          ! id returned by oasis_init_comp
49   INTEGER                    ::   nerror            ! return error code
50#if ! defined key_oasis3
51   ! OASIS Variables not used. defined only for compilation purpose
52   INTEGER                    ::   OASIS_Out         = -1
53   INTEGER                    ::   OASIS_REAL        = -1
54   INTEGER                    ::   OASIS_Ok          = -1
55   INTEGER                    ::   OASIS_In          = -1
56   INTEGER                    ::   OASIS_Sent        = -1
57   INTEGER                    ::   OASIS_SentOut     = -1
58   INTEGER                    ::   OASIS_ToRest      = -1
59   INTEGER                    ::   OASIS_ToRestOut   = -1
60   INTEGER                    ::   OASIS_Recvd       = -1
61   INTEGER                    ::   OASIS_RecvOut     = -1
62   INTEGER                    ::   OASIS_FromRest    = -1
63   INTEGER                    ::   OASIS_FromRestOut = -1
64#endif
65
66   INTEGER                    ::   nrcv         ! total number of fields received
67   INTEGER                    ::   nsnd         ! total number of fields sent
68   INTEGER                    ::   ncplmodel    ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
69   INTEGER, PUBLIC, PARAMETER ::   nmaxfld=60   ! Maximum number of coupling fields
70   INTEGER, PUBLIC, PARAMETER ::   nmaxcat=5    ! Maximum number of coupling fields
71   INTEGER, PUBLIC, PARAMETER ::   nmaxcpl=5    ! Maximum number of coupling fields
72   LOGICAL, PARAMETER         ::   ltmp_wapatch = .TRUE.   ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define 
73   INTEGER                    ::   nldi_save, nlei_save
74   INTEGER                    ::   nldj_save, nlej_save
75   
76   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
77      LOGICAL               ::   laction   ! To be coupled or not
78      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
79      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
80      REAL(wp)              ::   nsgn      ! Control of the sign change
81      INTEGER, DIMENSION(nmaxcat,nmaxcpl) ::   nid   ! Id of the field (no more than 9 categories and 9 extrena models)
82      INTEGER               ::   nct       ! Number of categories in field
83      INTEGER               ::   ncplmodel ! Maximum number of models to/from which this variable may be sent/received
84   END TYPE FLD_CPL
85
86   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
87
88   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
89     
90   !!----------------------------------------------------------------------
91   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
92   !! $Id$
93   !! Software governed by the CeCILL license (see ./LICENSE)
94   !!----------------------------------------------------------------------
95CONTAINS
96
97   SUBROUTINE cpl_init( cd_modname, kl_comm ) 
98
99      !!-------------------------------------------------------------------
100      !!             ***  ROUTINE cpl_init  ***
101      !!
102      !! ** Purpose :   Initialize coupled mode communication for ocean
103      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
104      !!
105      !! ** Method  :   OASIS3 MPI communication
106      !!--------------------------------------------------------------------
107      USE sbc_oce , ONLY :   ln_cpl
108      CHARACTER(len = *), INTENT(in   ) ::   cd_modname   ! model name as set in namcouple file
109      INTEGER           , INTENT(  out) ::   kl_comm      ! local communicator of the model
110      !!--------------------------------------------------------------------
111
112      ! WARNING: No write in numout in this routine
113      !============================================
114
115      !------------------------------------------------------------------
116      ! 1st Initialize the OASIS system for the application
117      !------------------------------------------------------------------
118      CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror, ln_cpl )
119      IF ( nerror /= OASIS_Ok ) &
120         CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
121
122      !------------------------------------------------------------------
123      ! 3rd Get an MPI communicator for OPA local communication
124      !------------------------------------------------------------------
125
126      CALL oasis_get_localcomm ( kl_comm, nerror )
127      IF ( nerror /= OASIS_Ok ) &
128         CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
129      !
130   END SUBROUTINE cpl_init
131
132
133   SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
134      !!-------------------------------------------------------------------
135      !!             ***  ROUTINE cpl_define  ***
136      !!
137      !! ** Purpose :   Define grid and field information for ocean
138      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
139      !!
140      !! ** Method  :   OASIS3 MPI communication
141      !!--------------------------------------------------------------------
142      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
143      INTEGER, INTENT(in) ::   kcplmodel      ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
144      !
145      INTEGER :: id_part
146      INTEGER :: paral(5)       ! OASIS3 box partition
147      INTEGER :: ishape(4)    ! shape of arrays passed to PSMILe
148      INTEGER :: ji,jc,jm       ! local loop indicees
149      CHARACTER(LEN=64) :: zclname
150      CHARACTER(LEN=2) :: cli2
151      !!--------------------------------------------------------------------
152
153      ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define
154      IF ( ltmp_wapatch ) THEN
155         nldi_save = nldi   ;   nlei_save = nlei
156         nldj_save = nldj   ;   nlej_save = nlej
157         IF( nimpp           ==      1 ) nldi = 1
158         IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
159         IF( njmpp           ==      1 ) nldj = 1
160         IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
161      ENDIF
162      IF(lwp) WRITE(numout,*)
163      IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
164      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
165      IF(lwp) WRITE(numout,*)
166
167      ncplmodel = kcplmodel
168      IF( kcplmodel > nmaxcpl ) THEN
169         CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl')   ;   RETURN
170      ENDIF
171
172      nrcv = krcv
173      IF( nrcv > nmaxfld ) THEN
174         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld')   ;   RETURN
175      ENDIF
176
177      nsnd = ksnd
178      IF( nsnd > nmaxfld ) THEN
179         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld')   ;   RETURN
180      ENDIF
181      !
182      ! ... Define the shape for the area that excludes the halo
183      !     For serial configuration (key_mpp_mpi not being active)
184      !     nl* is set to the global values 1 and jp*glo.
185      !
186      ishape(1) = 1
187      ishape(2) = nlei-nldi+1
188      ishape(3) = 1
189      ishape(4) = nlej-nldj+1
190      !
191      ! ... Allocate memory for data exchange
192      !
193      ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
194      IF( nerror > 0 ) THEN
195         CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld')   ;   RETURN
196      ENDIF
197      !
198      ! -----------------------------------------------------------------
199      ! ... Define the partition
200      ! -----------------------------------------------------------------
201     
202      paral(1) = 2                                              ! box partitioning
203      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
204      paral(3) = nlei-nldi+1                                    ! local extent in i
205      paral(4) = nlej-nldj+1                                    ! local extent in j
206      paral(5) = jpiglo                                         ! global extent in x
207     
208      IF( ln_ctl ) THEN
209         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
210         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
211         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
212         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
213      ENDIF
214   
215      CALL oasis_def_partition ( id_part, paral, nerror, jpiglo*jpjglo )
216      !
217      ! ... Announce send variables.
218      !
219      ssnd(:)%ncplmodel = kcplmodel
220      !
221      DO ji = 1, ksnd
222         IF ( ssnd(ji)%laction ) THEN
223
224            IF( ssnd(ji)%nct > nmaxcat ) THEN
225               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
226                  &              TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
227               RETURN
228            ENDIF
229           
230            DO jc = 1, ssnd(ji)%nct
231               DO jm = 1, kcplmodel
232
233                  IF ( ssnd(ji)%nct .GT. 1 ) THEN
234                     WRITE(cli2,'(i2.2)') jc
235                     zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
236                  ELSE
237                     zclname = ssnd(ji)%clname
238                  ENDIF
239                  IF ( kcplmodel  > 1 ) THEN
240                     WRITE(cli2,'(i2.2)') jm
241                     zclname = 'model'//cli2//'_'//TRIM(zclname)
242                  ENDIF
243#if defined key_agrif
244                  IF( agrif_fixed() /= 0 ) THEN
245                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
246                  END IF
247#endif
248                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
249                  CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 1 /),   &
250                     &                OASIS_Out          , ishape , OASIS_REAL, nerror )
251                  IF ( nerror /= OASIS_Ok ) THEN
252                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
253                     CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
254                  ENDIF
255                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
256                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
257               END DO
258            END DO
259         ENDIF
260      END DO
261      !
262      ! ... Announce received variables.
263      !
264      srcv(:)%ncplmodel = kcplmodel
265      !
266      DO ji = 1, krcv
267         IF ( srcv(ji)%laction ) THEN
268           
269            IF( srcv(ji)%nct > nmaxcat ) THEN
270               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
271                  &              TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
272               RETURN
273            ENDIF
274           
275            DO jc = 1, srcv(ji)%nct
276               DO jm = 1, kcplmodel
277                 
278                  IF ( srcv(ji)%nct .GT. 1 ) THEN
279                     WRITE(cli2,'(i2.2)') jc
280                     zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
281                  ELSE
282                     zclname = srcv(ji)%clname
283                  ENDIF
284                  IF ( kcplmodel  > 1 ) THEN
285                     WRITE(cli2,'(i2.2)') jm
286                     zclname = 'model'//cli2//'_'//TRIM(zclname)
287                  ENDIF
288#if defined key_agrif
289                  IF( agrif_fixed() /= 0 ) THEN
290                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
291                  END IF
292#endif
293                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
294                  CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 1 /),   &
295                     &                OASIS_In           , ishape , OASIS_REAL, nerror )
296                  IF ( nerror /= OASIS_Ok ) THEN
297                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
298                     CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
299                  ENDIF
300                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
301                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
302
303               END DO
304            END DO
305         ENDIF
306      END DO
307     
308      !------------------------------------------------------------------
309      ! End of definition phase
310      !------------------------------------------------------------------
311     
312      CALL oasis_enddef(nerror)
313      IF( nerror /= OASIS_Ok )   CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef')
314      !
315      IF ( ltmp_wapatch ) THEN
316         nldi = nldi_save   ;   nlei = nlei_save
317         nldj = nldj_save   ;   nlej = nlej_save
318      ENDIF
319   END SUBROUTINE cpl_define
320   
321   
322   SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
323      !!---------------------------------------------------------------------
324      !!              ***  ROUTINE cpl_snd  ***
325      !!
326      !! ** Purpose : - At each coupling time-step,this routine sends fields
327      !!      like sst or ice cover to the coupler or remote application.
328      !!----------------------------------------------------------------------
329      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
330      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
331      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
332      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
333      !!
334      INTEGER                                   ::   jc,jm     ! local loop index
335      !!--------------------------------------------------------------------
336      ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define
337      IF ( ltmp_wapatch ) THEN
338         nldi_save = nldi   ;   nlei_save = nlei
339         nldj_save = nldj   ;   nlej_save = nlej
340         IF( nimpp           ==      1 ) nldi = 1
341         IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
342         IF( njmpp           ==      1 ) nldj = 1
343         IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
344      ENDIF
345      !
346      ! snd data to OASIS3
347      !
348      DO jc = 1, ssnd(kid)%nct
349         DO jm = 1, ssnd(kid)%ncplmodel
350       
351            IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN
352               CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
353               
354               IF ( ln_ctl ) THEN       
355                  IF ( kinfo == OASIS_Sent     .OR. kinfo == OASIS_ToRest .OR.   &
356                     & kinfo == OASIS_SentOut  .OR. kinfo == OASIS_ToRestOut ) THEN
357                     WRITE(numout,*) '****************'
358                     WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
359                     WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
360                     WRITE(numout,*) 'oasis_put:  kstep ', kstep
361                     WRITE(numout,*) 'oasis_put:   info ', kinfo
362                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
363                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
364                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
365                     WRITE(numout,*) '****************'
366                  ENDIF
367               ENDIF
368               
369            ENDIF
370           
371         ENDDO
372      ENDDO
373      IF ( ltmp_wapatch ) THEN
374         nldi = nldi_save   ;   nlei = nlei_save
375         nldj = nldj_save   ;   nlej = nlej_save
376      ENDIF
377      !
378    END SUBROUTINE cpl_snd
379
380
381   SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
382      !!---------------------------------------------------------------------
383      !!              ***  ROUTINE cpl_rcv  ***
384      !!
385      !! ** Purpose : - At each coupling time-step,this routine receives fields
386      !!      like stresses and fluxes from the coupler or remote application.
387      !!----------------------------------------------------------------------
388      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
389      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
390      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
391      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pmask     ! coupling mask
392      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
393      !!
394      INTEGER                                   ::   jc,jm     ! local loop index
395      LOGICAL                                   ::   llaction, llfisrt
396      !!--------------------------------------------------------------------
397      ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define
398      IF ( ltmp_wapatch ) THEN
399         nldi_save = nldi   ;   nlei_save = nlei
400         nldj_save = nldj   ;   nlej_save = nlej
401      ENDIF
402      !
403      ! receive local data from OASIS3 on every process
404      !
405      kinfo = OASIS_idle
406      !
407      DO jc = 1, srcv(kid)%nct
408         IF ( ltmp_wapatch ) THEN
409            IF( nimpp           ==      1 ) nldi = 1
410            IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
411            IF( njmpp           ==      1 ) nldj = 1
412            IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
413         ENDIF
414         llfisrt = .TRUE.
415
416         DO jm = 1, srcv(kid)%ncplmodel
417
418            IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
419
420               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo )         
421               
422               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
423                  &        kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
424               
425               IF ( ln_ctl )   WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
426               
427               IF ( llaction ) THEN
428                 
429                  kinfo = OASIS_Rcv
430                  IF( llfisrt ) THEN
431                     pdata(nldi:nlei,nldj:nlej,jc) =                                 exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
432                     llfisrt = .FALSE.
433                  ELSE
434                     pdata(nldi:nlei,nldj:nlej,jc) = pdata(nldi:nlei,nldj:nlej,jc) + exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
435                  ENDIF
436                 
437                  IF ( ln_ctl ) THEN       
438                     WRITE(numout,*) '****************'
439                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
440                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
441                     WRITE(numout,*) 'oasis_get:   kstep', kstep
442                     WRITE(numout,*) 'oasis_get:   info ', kinfo
443                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
444                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
445                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
446                     WRITE(numout,*) '****************'
447                     CALL FLUSH(numout)
448                  ENDIF
449                 
450               ENDIF
451               
452            ENDIF
453           
454         ENDDO
455
456         IF ( ltmp_wapatch ) THEN
457            nldi = nldi_save   ;   nlei = nlei_save
458            nldj = nldj_save   ;   nlej = nlej_save
459         ENDIF
460         !--- Fill the overlap areas and extra hallows (mpp)
461         !--- check periodicity conditions (all cases)
462         IF( .not. llfisrt ) THEN
463            CALL lbc_lnk( 'cpl_oasis3', pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
464         ENDIF
465 
466      ENDDO
467      !
468   END SUBROUTINE cpl_rcv
469
470
471   INTEGER FUNCTION cpl_freq( cdfieldname ) 
472      !!---------------------------------------------------------------------
473      !!              ***  ROUTINE cpl_freq  ***
474      !!
475      !! ** Purpose : - send back the coupling frequency for a particular field
476      !!----------------------------------------------------------------------
477      CHARACTER(len = *), INTENT(in) ::   cdfieldname    ! field name as set in namcouple file
478      !!
479      INTEGER               :: id
480      INTEGER               :: info
481      INTEGER, DIMENSION(1) :: itmp
482      INTEGER               :: ji,jm     ! local loop index
483      INTEGER               :: mop
484      !!----------------------------------------------------------------------
485      cpl_freq = 0   ! defaut definition
486      id = -1        ! defaut definition
487      !
488      DO ji = 1, nsnd
489         IF (ssnd(ji)%laction ) THEN
490            DO jm = 1, ncplmodel
491               IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
492                  IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
493                     id = ssnd(ji)%nid(1,jm)
494                     mop = OASIS_Out
495                  ENDIF
496               ENDIF
497            ENDDO
498         ENDIF
499      ENDDO
500      DO ji = 1, nrcv
501         IF (srcv(ji)%laction ) THEN
502            DO jm = 1, ncplmodel
503               IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
504                  IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
505                     id = srcv(ji)%nid(1,jm)
506                     mop = OASIS_In
507                  ENDIF
508               ENDIF
509            ENDDO
510         ENDIF
511      ENDDO
512      !
513      IF( id /= -1 ) THEN
514#if ! defined key_oa3mct_v1v2
515         CALL oasis_get_freqs(id, mop, 1, itmp, info)
516#else
517         CALL oasis_get_freqs(id,      1, itmp, info)
518#endif
519         cpl_freq = itmp(1) 
520      ENDIF
521      !
522   END FUNCTION cpl_freq
523
524
525   SUBROUTINE cpl_finalize
526      !!---------------------------------------------------------------------
527      !!              ***  ROUTINE cpl_finalize  ***
528      !!
529      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
530      !!      called explicitly before cpl_init it will also close
531      !!      MPI communication.
532      !!----------------------------------------------------------------------
533      !
534      IF (ALLOCATED(exfld)) DEALLOCATE( exfld )
535
536      IF (nstop == 0) THEN
537         CALL oasis_terminate( nerror )         
538      ELSE
539         CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
540      ENDIF       
541      !
542   END SUBROUTINE cpl_finalize
543
544#if ! defined key_oasis3
545
546   !!----------------------------------------------------------------------
547   !!   No OASIS Library          OASIS3 Dummy module...
548   !!----------------------------------------------------------------------
549
550   SUBROUTINE oasis_init_comp(k1,cd1,k2,l1)
551      CHARACTER(*), INTENT(in   ) ::  cd1
552      INTEGER     , INTENT(  out) ::  k1,k2
553      k1 = -1 ; k2 = -1
554      WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
555   END SUBROUTINE oasis_init_comp
556
557   SUBROUTINE oasis_abort(k1,cd1,cd2)
558      INTEGER     , INTENT(in   ) ::  k1
559      CHARACTER(*), INTENT(in   ) ::  cd1,cd2     
560      LOGICAL     , OPTIONAL,  INTENT(in   ) ::  l1
561      WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
562   END SUBROUTINE oasis_abort
563
564   SUBROUTINE oasis_get_localcomm(k1,k2)
565      INTEGER     , INTENT(  out) ::  k1,k2
566      k1 = -1 ; k2 = -1
567      WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
568   END SUBROUTINE oasis_get_localcomm
569
570   SUBROUTINE oasis_def_partition(k1,k2,k3,k4)
571      INTEGER     , INTENT(  out) ::  k1,k3
572      INTEGER     , INTENT(in   ) ::  k2(5)
573      INTEGER     , INTENT(in   ) ::  k4
574      k1 = k2(1) ; k3 = k2(5)+k4
575      WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
576   END SUBROUTINE oasis_def_partition
577
578   SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
579      CHARACTER(*), INTENT(in   ) ::  cd1
580      INTEGER     , INTENT(in   ) ::  k2,k3(2),k4,k5(2,2),k6
581      INTEGER     , INTENT(  out) ::  k1,k7
582      k1 = -1 ; k7 = -1
583      WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
584   END SUBROUTINE oasis_def_var
585
586   SUBROUTINE oasis_enddef(k1)
587      INTEGER     , INTENT(  out) ::  k1
588      k1 = -1
589      WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
590   END SUBROUTINE oasis_enddef
591 
592   SUBROUTINE oasis_put(k1,k2,p1,k3)
593      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::  p1
594      INTEGER                 , INTENT(in   ) ::  k1,k2
595      INTEGER                 , INTENT(  out) ::  k3
596      k3 = -1
597      WRITE(numout,*) 'oasis_put: Error you sould not be there...'
598   END SUBROUTINE oasis_put
599
600   SUBROUTINE oasis_get(k1,k2,p1,k3)
601      REAL(wp), DIMENSION(:,:), INTENT(  out) ::  p1
602      INTEGER                 , INTENT(in   ) ::  k1,k2
603      INTEGER                 , INTENT(  out) ::  k3
604      p1(1,1) = -1. ; k3 = -1
605      WRITE(numout,*) 'oasis_get: Error you sould not be there...'
606   END SUBROUTINE oasis_get
607
608   SUBROUTINE oasis_get_freqs(k1,k5,k2,k3,k4)
609      INTEGER              , INTENT(in   ) ::  k1,k2
610      INTEGER, DIMENSION(1), INTENT(  out) ::  k3
611      INTEGER              , INTENT(  out) ::  k4,k5
612      k3(1) = k1 ; k4 = k2 ; k5 = k2
613      WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
614   END SUBROUTINE oasis_get_freqs
615
616   SUBROUTINE oasis_terminate(k1)
617      INTEGER     , INTENT(  out) ::  k1
618      k1 = -1
619      WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
620   END SUBROUTINE oasis_terminate
621   
622#endif
623
624   !!=====================================================================
625END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.