source: NEMO/branches/UKMO/NEMO_4.0.1_NGMS_couple_pkg/src/OCE/nemogcm.F90 @ 13311

Last change on this file since 13311 was 13311, checked in by frrh, 17 months ago

Save dev changes for concurrent LFRIC + GO8 running

File size: 36.6 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE mod_oasis ! RSRH temp
44   USE step_oce       ! module used in the ocean time stepping module (step.F90)
45   USE phycst         ! physical constant                  (par_cst routine)
46   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
47   USE closea         ! treatment of closed seas (for ln_closea)
48   USE usrdef_nam     ! user defined configuration
49   USE tideini        ! tidal components initialization   (tide_ini routine)
50   USE bdy_oce,  ONLY : ln_bdy
51   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
52   USE istate         ! initial state setting          (istate_init routine)
53   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
54   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
55   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
56   USE asminc         ! assimilation increments     
57   USE asmbkg         ! writing out state trajectory
58   USE diaptr         ! poleward transports           (dia_ptr_init routine)
59   USE diadct         ! sections transports           (dia_dct_init routine)
60   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
61   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
62   USE diaharm        ! tidal harmonics diagnostics  (dia_harm_init routine)
63   USE step           ! NEMO time-stepping                 (stp     routine)
64   USE icbini         ! handle bergs, initialisation
65   USE icbstp         ! handle bergs, calving, themodynamics and transport
66   USE cpl_oasis3     ! OASIS3 coupling
67   USE c1d            ! 1D configuration
68   USE step_c1d       ! Time stepping loop for the 1D configuration
69   USE dyndmp         ! Momentum damping
70   USE stopar         ! Stochastic param.: ???
71   USE stopts         ! Stochastic param.: ???
72   USE diurnal_bulk   ! diurnal bulk SST
73   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
74   USE crsini         ! initialise grid coarsening utility
75   USE diatmb         ! Top,middle,bottom output
76   USE dia25h         ! 25h mean output
77   USE sbc_oce , ONLY : lk_oasis
78   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
79#if defined key_top
80   USE trcini         ! passive tracer initialisation
81#endif
82#if defined key_nemocice_decomp
83   USE ice_domain_size, only: nx_global, ny_global
84#endif
85   !
86   USE lib_mpp        ! distributed memory computing
87   USE mppini         ! shared/distributed memory setting (mpp_init routine)
88   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
89   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
90   USE sbccpl 
91#if defined key_iomput
92   USE xios           ! xIOserver
93#endif
94#if defined key_agrif
95   USE agrif_all_update   ! Master Agrif update
96#endif
97
98   IMPLICIT NONE
99   PRIVATE
100
101   PUBLIC   nemo_gcm    ! called by model.F90
102   PUBLIC   nemo_init   ! needed by AGRIF
103   PUBLIC   nemo_alloc  ! needed by TAM
104
105   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
106
107#if defined key_mpp_mpi
108   ! need MPI_Wtime
109   INCLUDE 'mpif.h'
110#endif
111
112   !!----------------------------------------------------------------------
113   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
114   !! $Id$
115   !! Software governed by the CeCILL license (see ./LICENSE)
116   !!----------------------------------------------------------------------
117CONTAINS
118
119   SUBROUTINE nemo_gcm
120      !!----------------------------------------------------------------------
121      !!                     ***  ROUTINE nemo_gcm  ***
122      !!
123      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
124      !!              curvilinear mesh on the sphere.
125      !!
126      !! ** Method  : - model general initialization
127      !!              - launch the time-stepping (stp routine)
128      !!              - finalize the run by closing files and communications
129      !!
130      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
131      !!              Madec, 2008, internal report, IPSL.
132      !!----------------------------------------------------------------------
133      INTEGER ::   istp, nerror   ! time step index
134      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
135      !!----------------------------------------------------------------------
136      !
137#if defined key_agrif
138      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
139#endif
140      !                            !-----------------------!
141      CALL nemo_init               !==  Initialisations  ==!
142      !                            !-----------------------!
143#if defined key_agrif
144      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
145      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
146# if defined key_top
147      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
148# endif
149# if defined key_si3
150      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
151# endif
152#endif
153      ! check that all process are still there... If some process have an error,
154      ! they will never enter in step and other processes will wait until the end of the cpu time!
155      CALL mpp_max( 'nemogcm', nstop )
156
157      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
158
159      !                            !-----------------------!
160      !                            !==   time stepping   ==!
161      !                            !-----------------------!
162      istp = nit000
163      !
164#if defined key_c1d
165      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
166         CALL stp_c1d( istp )
167         istp = istp + 1
168      END DO
169#else
170      !
171# if defined key_agrif
172      !                                               !==  AGRIF time-stepping  ==!
173      CALL Agrif_Regrid()
174      !
175      ! Recursive update from highest nested level to lowest:
176      CALL Agrif_step_child_adj(Agrif_Update_All)
177      !
178      DO WHILE( istp <= nitend .AND. nstop == 0 )
179         CALL stp
180         istp = istp + 1
181      END DO
182      !
183      IF( .NOT. Agrif_Root() ) THEN
184         CALL Agrif_ParentGrid_To_ChildGrid()
185         IF( ln_diaobs )   CALL dia_obs_wri
186         IF( ln_timing )   CALL timing_finalize
187         CALL Agrif_ChildGrid_To_ParentGrid()
188      ENDIF
189      !
190# else
191      !
192      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
193         !
194         DO WHILE( istp <= nitend .AND. nstop == 0 )
195
196            ncom_stp = istp
197            IF( ln_timing ) THEN
198               zstptiming = MPI_Wtime()
199               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
200               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
201            ENDIF
202           
203            ! RSRH. You can compile with OASIS but not want to do any
204            ! coupling. We need to cater for that properly!
205            IF (ln_cpl) CALL sbc_cpl_snd( istp )  ! Coupling to atmos
206
207            CALL stp        ( istp ) 
208            istp = istp + 1
209
210            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
211
212         END DO
213         !
214      ELSE                                            !==  diurnal SST time-steeping only  ==!
215         !
216         DO WHILE( istp <= nitend .AND. nstop == 0 )
217            CALL stp_diurnal( istp )   ! time step only the diurnal SST
218            istp = istp + 1
219         END DO
220         !
221      ENDIF
222      !
223# endif
224      !
225#endif
226      !
227      IF( ln_diaobs   )   CALL dia_obs_wri
228      !
229      IF( ln_icebergs )   CALL icb_end( nitend )
230
231      !                            !------------------------!
232      !                            !==  finalize the run  ==!
233      !                            !------------------------!
234      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
235      !
236      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
237         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
238         CALL ctl_stop( ctmp1 )
239      ENDIF
240      !
241      IF( ln_timing )   CALL timing_finalize
242      !
243      write(numout,*) "RSRH calling nemo_closefile " , lk_oasis; flush(numout)
244      CALL nemo_closefile
245      write(numout,*) "RSRH done closefiles " , lk_oasis; flush(numout)
246      !
247#if defined key_iomput
248      CALL xios_finalize()  ! end mpp communications with xios
249
250      IF (lk_oasis)  CALL oasis_terminate(nerror)
251      CALL mppstop ! RSRH temp for development
252      !IF( lk_oasis     )            CALL cpl_finalize()   ! end coupling and mpp communications with OASIS
253#else
254      IF    ( lk_oasis ) THEN   
255          CALL cpl_finalize()   ! end coupling and mpp communications with OASIS
256      ELSEIF( lk_mpp   ) THEN
257          CALL mppstop      ! end mpp communications
258      ENDIF
259#endif
260      !
261      IF(lwm) THEN
262         IF( nstop == 0 ) THEN   
263                STOP 0
264         ELSE       
265                STOP 123
266         ENDIF
267      ENDIF
268      !
269   END SUBROUTINE nemo_gcm
270
271
272   SUBROUTINE nemo_init
273      !!----------------------------------------------------------------------
274      !!                     ***  ROUTINE nemo_init  ***
275      !!
276      !! ** Purpose :   initialization of the NEMO GCM
277      !!----------------------------------------------------------------------
278      INTEGER ::   ios, ilocal_comm, nerror, ncomp_id, llmpi_init, ierr  ! local integers
279      !!
280      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
281         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
282         &             ln_timing, ln_diacfl
283      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
284      !!----------------------------------------------------------------------
285      !
286      cxios_context = 'nemo'
287      !
288      !                             !-------------------------------------------------!
289      !                             !     set communicator & select the local rank    !
290      !                             !  must be done as soon as possible to get narea  !
291      !                             !-------------------------------------------------!
292      !
293#if defined key_iomput
294!      IF( Agrif_Root() ) THEN
295!         IF( lk_oasis ) THEN
296!            CALL cpl_init( "toyoce", ilocal_comm )                     ! nemo local communicator given by oasis
297!            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
298!         ELSE
299!            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
300!         ENDIF
301!      ENDIF
302! RSRH simplify initialisaton for test
303      IF( lk_oasis ) THEN
304          CALL mpi_init(nerror)
305          CALL oasis_init_comp ( ncomp_id, "toyoce", nerror, .FALSE. )
306!          CALL cpl_init( "toyoce", ilocal_comm )
307          CALL oasis_get_localcomm ( ilocal_comm , nerror )
308          CALL xios_initialize( "toyoce", local_comm =ilocal_comm )
309      ENDIF
310      CALL mpp_start( ilocal_comm )
311#else
312      IF( lk_oasis ) THEN
313         IF( Agrif_Root() ) THEN
314            CALL cpl_init( "toyoce", ilocal_comm )                      ! nemo local communicator given by oasis
315         ENDIF
316         CALL mpp_start( ilocal_comm )
317      ELSE
318         CALL mpp_start( )
319      ENDIF
320#endif
321      !
322      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
323      lwm = (narea == 1)                ! control of output namelists
324      !
325      !                             !---------------------------------------------------------------!
326      !                             ! Open output files, reference and configuration namelist files !
327      !                             !---------------------------------------------------------------!
328      !
329      ! open ocean.output as soon as possible to get all output prints (including errors messages)
330      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
331      ! open reference and configuration namelist files
332                  CALL ctl_opn( numnam_ref,        'namelist_ref',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
333                  CALL ctl_opn( numnam_cfg,        'namelist_cfg',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
334      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
335      ! open /dev/null file to be able to supress output write easily
336                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
337      !
338      !                             !--------------------!
339      !                             ! Open listing units !  -> need ln_ctl from namctl to define lwp
340      !                             !--------------------!
341      !
342      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
343      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
344901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
345      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
346      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
347902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
348      !
349      lwp = (narea == 1) .OR. ln_ctl    ! control of all listing output print
350      !
351WRITE(numout,*) "RSRH NEMO start local com=",ilocal_comm ; flush(numout) 
352WRITE(numout,*) "RSRH NEMO my rank=",mpprank ; flush(numout) 
353      IF(lwp) THEN                      ! open listing units
354         !
355         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
356            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
357         !
358
359WRITE(numout,*) "RSRH NEMO start local com=",ilocal_comm ; flush(numout) 
360WRITE(numout,*) "RSRH NEMO my rank=",mpprank ; flush(numout) 
361
362         WRITE(numout,*)
363         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
364         WRITE(numout,*) '                       NEMO team'
365         WRITE(numout,*) '            Ocean General Circulation Model'
366         WRITE(numout,*) '                NEMO version 4.0  (2019) '
367         WRITE(numout,*)
368         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
369         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
370         WRITE(numout,*)
371         WRITE(numout,*) "           o         _,           _,             "
372         WRITE(numout,*) "            o      .' (        .-' /             "
373         WRITE(numout,*) "           o     _/..._'.    .'   /              "
374         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
375         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
376         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
377         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
378         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
379         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
380         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
381         WRITE(numout,*)
382         !
383         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
384         !
385      ENDIF
386      !
387      ! finalize the definition of namctl variables
388      IF( sn_cfctl%l_config ) THEN
389         ! Activate finer control of report outputs
390         ! optionally switch off output from selected areas (note this only
391         ! applies to output which does not involve global communications)
392         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
393           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
394           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
395      ELSE
396         ! Use ln_ctl to turn on or off all options.
397         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
398      ENDIF
399      !
400      IF(lwm) WRITE( numond, namctl )
401      !
402      !                             !------------------------------------!
403      !                             !  Set global domain size parameters !
404      !                             !------------------------------------!
405      !
406      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
407      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
408903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
409      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
410      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
411904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
412      !
413      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
414         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
415      ELSE                              ! user-defined namelist
416         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
417      ENDIF
418      !
419      IF(lwm)   WRITE( numond, namcfg )
420      !
421      !                             !-----------------------------------------!
422      !                             ! mpp parameters and domain decomposition !
423      !                             !-----------------------------------------!
424      CALL mpp_init
425
426      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
427      CALL nemo_alloc()
428
429      !                             !-------------------------------!
430      !                             !  NEMO general initialization  !
431      !                             !-------------------------------!
432
433      CALL nemo_ctl                          ! Control prints
434      !
435      !                                      ! General initialization
436      IF( ln_timing    )   CALL timing_init     ! timing
437      IF( ln_timing    )   CALL timing_start( 'nemo_init')
438      !
439                           CALL     phy_cst         ! Physical constants
440                           CALL     eos_init        ! Equation of state
441      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
442                           CALL     wad_init        ! Wetting and drying options
443                           CALL     dom_init("OPA") ! Domain
444      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
445      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
446     
447      CALL diurnal_sst_bulk_init                ! diurnal sst
448      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
449      !                           
450      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
451         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
452         CALL     sbc_init                            ! Forcings : surface module
453         CALL tra_qsr_init                            ! penetrative solar radiation qsr
454         IF( ln_diaobs ) THEN                         ! Observation & model comparison
455            CALL dia_obs_init                            ! Initialize observational data
456            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
457         ENDIF     
458         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
459         !
460         RETURN                                       ! end of initialization
461      ENDIF
462     
463                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
464
465      !                                      ! external forcing
466                           CALL    tide_init    ! tidal harmonics
467                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
468                           CALL     bdy_init    ! Open boundaries initialisation
469
470      !                                      ! Ocean physics
471                           CALL zdf_phy_init    ! Vertical physics
472                                     
473      !                                         ! Lateral physics
474                           CALL ldf_tra_init      ! Lateral ocean tracer physics
475                           CALL ldf_eiv_init      ! eddy induced velocity param.
476                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
477
478      !                                      ! Active tracers
479      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
480                           CALL tra_bbc_init      ! bottom heat flux
481                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
482                           CALL tra_dmp_init      ! internal tracer damping
483                           CALL tra_adv_init      ! horizontal & vertical advection
484                           CALL tra_ldf_init      ! lateral mixing
485
486      !                                      ! Dynamics
487      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
488                           CALL dyn_adv_init      ! advection (vector or flux form)
489                           CALL dyn_vor_init      ! vorticity term including Coriolis
490                           CALL dyn_ldf_init      ! lateral mixing
491                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
492                           CALL dyn_spg_init      ! surface pressure gradient
493
494#if defined key_top
495      !                                      ! Passive tracers
496                           CALL     trc_init
497#endif
498      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
499
500      !                                      ! Icebergs
501                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
502
503      !                                      ! Misc. options
504                           CALL sto_par_init    ! Stochastic parametrization
505      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
506     
507      !                                      ! Diagnostics
508                           CALL     flo_init    ! drifting Floats
509      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
510                           CALL dia_ptr_init    ! Poleward TRansports initialization
511                           CALL dia_dct_init    ! Sections tranports
512                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
513                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
514                           CALL dia_obs_init    ! Initialize observational data
515                           CALL dia_tmb_init    ! TMB outputs
516                           CALL dia_25h_init    ! 25h mean  outputs
517                           CALL dia_harm_init   ! tidal harmonics outputs
518     IF( ln_diaobs    )    CALL dia_obs( nit000-1 )   ! Observation operator for restart
519
520      !                                      ! Assimilation increments
521      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
522      !
523      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
524     
525      IF (nstop > 0) THEN
526        CALL CTL_STOP('STOP','Critical errors in NEMO initialisation')
527      END IF
528     
529      !
530      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
531      !
532   END SUBROUTINE nemo_init
533
534
535   SUBROUTINE nemo_ctl
536      !!----------------------------------------------------------------------
537      !!                     ***  ROUTINE nemo_ctl  ***
538      !!
539      !! ** Purpose :   control print setting
540      !!
541      !! ** Method  : - print namctl and namcfg information and check some consistencies
542      !!----------------------------------------------------------------------
543      !
544      IF(lwp) THEN                  ! control print
545         WRITE(numout,*)
546         WRITE(numout,*) 'nemo_ctl: Control prints'
547         WRITE(numout,*) '~~~~~~~~'
548         WRITE(numout,*) '   Namelist namctl'
549         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
550         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
551         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
552         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
553         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
554         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
555         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
556         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
557         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
558         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
559         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
560         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
561         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
562         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
563         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
564         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
565         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
566         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
567         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
568         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
569         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
570      ENDIF
571      !
572      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
573      nictls    = nn_ictls
574      nictle    = nn_ictle
575      njctls    = nn_jctls
576      njctle    = nn_jctle
577      isplt     = nn_isplt
578      jsplt     = nn_jsplt
579
580      IF(lwp) THEN                  ! control print
581         WRITE(numout,*)
582         WRITE(numout,*) '   Namelist namcfg'
583         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
584         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
585         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
586         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
587         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
588         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
589      ENDIF
590      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
591      !
592      !                             ! Parameter control
593      !
594      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
595         IF( lk_mpp .AND. jpnij > 1 ) THEN
596            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
597         ELSE
598            IF( isplt == 1 .AND. jsplt == 1  ) THEN
599               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
600                  &           ' - the print control will be done over the whole domain' )
601            ENDIF
602            ijsplt = isplt * jsplt            ! total number of processors ijsplt
603         ENDIF
604         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
605         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
606         !
607         !                              ! indices used for the SUM control
608         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
609            lsp_area = .FALSE.
610         ELSE                                             ! print control done over a specific  area
611            lsp_area = .TRUE.
612            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
613               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
614               nictls = 1
615            ENDIF
616            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
617               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
618               nictle = jpiglo
619            ENDIF
620            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
621               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
622               njctls = 1
623            ENDIF
624            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
625               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
626               njctle = jpjglo
627            ENDIF
628         ENDIF
629      ENDIF
630      !
631      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
632         &                                                'Compile with key_nosignedzero enabled:',   &
633         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
634      !
635#if defined key_agrif
636      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
637#endif
638      !
639   END SUBROUTINE nemo_ctl
640
641
642   SUBROUTINE nemo_closefile
643      !!----------------------------------------------------------------------
644      !!                     ***  ROUTINE nemo_closefile  ***
645      !!
646      !! ** Purpose :   Close the files
647      !!----------------------------------------------------------------------
648      !
649      IF( lk_mpp )   CALL mppsync
650      !
651      CALL iom_close                                 ! close all input/output files managed by iom_*
652
653write(numout,*) "RSRH after iom_close";flush(numout)
654      !
655      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
656      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
657      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
658      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
659      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
660      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
661      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
662      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
663      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
664      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
665      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
666      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
667      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
668      !
669!      numout = 6                                     ! redefine numout in case it is used after this point...
670      !
671   END SUBROUTINE nemo_closefile
672
673
674   SUBROUTINE nemo_alloc
675      !!----------------------------------------------------------------------
676      !!                     ***  ROUTINE nemo_alloc  ***
677      !!
678      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
679      !!
680      !! ** Method  :
681      !!----------------------------------------------------------------------
682      USE diawri    , ONLY : dia_wri_alloc
683      USE dom_oce   , ONLY : dom_oce_alloc
684      USE trc_oce   , ONLY : trc_oce_alloc
685      USE bdy_oce   , ONLY : bdy_oce_alloc
686      !
687      INTEGER :: ierr
688      !!----------------------------------------------------------------------
689      !
690      ierr =        oce_alloc    ()    ! ocean
691      ierr = ierr + dia_wri_alloc()
692      ierr = ierr + dom_oce_alloc()    ! ocean domain
693      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
694      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
695      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
696      !
697      CALL mpp_sum( 'nemogcm', ierr )
698      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
699      !
700   END SUBROUTINE nemo_alloc
701
702   
703   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
704      !!----------------------------------------------------------------------
705      !!                     ***  ROUTINE nemo_set_cfctl  ***
706      !!
707      !! ** Purpose :   Set elements of the output control structure to setto.
708      !!                for_all should be .false. unless all areas are to be
709      !!                treated identically.
710      !!
711      !! ** Method  :   Note this routine can be used to switch on/off some
712      !!                types of output for selected areas but any output types
713      !!                that involve global communications (e.g. mpp_max, glob_sum)
714      !!                should be protected from selective switching by the
715      !!                for_all argument
716      !!----------------------------------------------------------------------
717      LOGICAL :: setto, for_all
718      TYPE(sn_ctl) :: sn_cfctl
719      !!----------------------------------------------------------------------
720      IF( for_all ) THEN
721         sn_cfctl%l_runstat = setto
722         sn_cfctl%l_trcstat = setto
723      ENDIF
724      sn_cfctl%l_oceout  = setto
725      sn_cfctl%l_layout  = setto
726      sn_cfctl%l_mppout  = setto
727      sn_cfctl%l_mpptop  = setto
728   END SUBROUTINE nemo_set_cfctl
729
730   !!======================================================================
731END MODULE nemogcm
732
Note: See TracBrowser for help on using the repository browser.