New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in NEMO/branches/UKMO/NEMO_4.0.1_fix_cpl_v2/src/OCE/BDY – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.1_fix_cpl_v2/src/OCE/BDY/bdydta.F90 @ 12937

Last change on this file since 12937 was 12937, checked in by dancopsey, 3 years ago

Merge in Clem's branch. It was originally here:

svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/NEMO/branches/UKMO/NEMO_4.0.1_dan_test_clems_branch

File size: 40.9 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!            3.6  !  2012-01  (C. Rousset) add ice boundary conditions for sea ice
14   !!            4.0  !  2018     (C. Rousset) SI3 compatibility
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!    bdy_dta      : read external data along open boundaries from file
19   !!    bdy_dta_init : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE oce            ! ocean dynamics and tracers
22   USE dom_oce        ! ocean space and time domain
23   USE phycst         ! physical constants
24   USE sbcapr         ! atmospheric pressure forcing
25   USE sbctide        ! Tidal forcing or not
26   USE bdy_oce        ! ocean open boundary conditions 
27   USE bdytides       ! tidal forcing at boundaries
28#if defined key_si3
29   USE ice            ! sea-ice variables
30   USE icevar         ! redistribute ice input into categories
31#endif
32   !
33   USE lib_mpp, ONLY: ctl_stop, ctl_nam
34   USE fldread        ! read input fields
35   USE iom            ! IOM library
36   USE in_out_manager ! I/O logical units
37   USE timing         ! Timing
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
43   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
44
45   INTEGER , PARAMETER ::   jpbdyfld  = 17    ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_bdyssh = 1     !
47   INTEGER , PARAMETER ::   jp_bdyu2d = 2     !
48   INTEGER , PARAMETER ::   jp_bdyv2d = 3     !
49   INTEGER , PARAMETER ::   jp_bdyu3d = 4     !
50   INTEGER , PARAMETER ::   jp_bdyv3d = 5     !
51   INTEGER , PARAMETER ::   jp_bdytem = 6     !
52   INTEGER , PARAMETER ::   jp_bdysal = 7     !
53   INTEGER , PARAMETER ::   jp_bdya_i = 8     !
54   INTEGER , PARAMETER ::   jp_bdyh_i = 9     !
55   INTEGER , PARAMETER ::   jp_bdyh_s = 10    !
56   INTEGER , PARAMETER ::   jp_bdyt_i = 11    !
57   INTEGER , PARAMETER ::   jp_bdyt_s = 12    !
58   INTEGER , PARAMETER ::   jp_bdytsu = 13    !
59   INTEGER , PARAMETER ::   jp_bdys_i = 14    !
60   INTEGER , PARAMETER ::   jp_bdyaip = 15    !
61   INTEGER , PARAMETER ::   jp_bdyhip = 16    !
62   INTEGER , PARAMETER ::   jp_bdyhil = 17    !
63#if ! defined key_si3
64   INTEGER , PARAMETER ::   jpl = 1
65#endif
66
67!$AGRIF_DO_NOT_TREAT
68   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:,:), TARGET ::   bf   ! structure of input fields (file informations, fields read)
69!$AGRIF_END_DO_NOT_TREAT
70
71   !!----------------------------------------------------------------------
72   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
73   !! $Id$
74   !! Software governed by the CeCILL license (see ./LICENSE)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE bdy_dta( kt, kit, kt_offset )
79      !!----------------------------------------------------------------------
80      !!                   ***  SUBROUTINE bdy_dta  ***
81      !!                   
82      !! ** Purpose :   Update external data for open boundary conditions
83      !!
84      !! ** Method  :   Use fldread.F90
85      !!               
86      !!----------------------------------------------------------------------
87      INTEGER, INTENT(in)           ::   kt           ! ocean time-step index
88      INTEGER, INTENT(in), OPTIONAL ::   kit          ! subcycle time-step index (for timesplitting option)
89      INTEGER, INTENT(in), OPTIONAL ::   kt_offset    ! time offset in units of timesteps. NB. if kit
90      !                                               ! is present then units = subcycle timesteps.
91      !                                               ! kt_offset = 0 => get data at "now" time level
92      !                                               ! kt_offset = -1 => get data at "before" time level
93      !                                               ! kt_offset = +1 => get data at "after" time level
94      !                                               ! etc.
95      !
96      INTEGER ::  jbdy, jfld, jstart, jend, ib, jl    ! dummy loop indices
97      INTEGER ::  ii, ij, ik, igrd, ipl               ! local integers
98      INTEGER,   DIMENSION(jpbgrd)     ::   ilen1 
99      INTEGER,   DIMENSION(:), POINTER ::   nblen, nblenrim  ! short cuts
100      TYPE(OBC_DATA)         , POINTER ::   dta_alias        ! short cut
101      TYPE(FLD), DIMENSION(:), POINTER ::   bf_alias
102      !!---------------------------------------------------------------------------
103      !
104      IF( ln_timing )   CALL timing_start('bdy_dta')
105      !
106      ! Initialise data arrays once for all from initial conditions where required
107      !---------------------------------------------------------------------------
108      IF( kt == nit000 .AND. .NOT.PRESENT(kit) ) THEN
109
110         ! Calculate depth-mean currents
111         !-----------------------------
112
113         DO jbdy = 1, nb_bdy
114            !
115            nblen    => idx_bdy(jbdy)%nblen
116            nblenrim => idx_bdy(jbdy)%nblenrim
117            !
118            IF( nn_dyn2d_dta(jbdy) == 0 ) THEN
119               ilen1(:) = nblen(:)
120               IF( dta_bdy(jbdy)%lneed_ssh ) THEN
121                  igrd = 1
122                  DO ib = 1, ilen1(igrd)
123                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
124                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
125                     dta_bdy(jbdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
126                  END DO
127               ENDIF
128               IF( dta_bdy(jbdy)%lneed_dyn2d) THEN
129                  igrd = 2
130                  DO ib = 1, ilen1(igrd)
131                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
132                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
133                     dta_bdy(jbdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)         
134                  END DO
135                  igrd = 3
136                  DO ib = 1, ilen1(igrd)
137                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
138                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
139                     dta_bdy(jbdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)         
140                  END DO
141               ENDIF
142            ENDIF
143            !
144            IF( nn_dyn3d_dta(jbdy) == 0 ) THEN
145               ilen1(:) = nblen(:)
146               IF( dta_bdy(jbdy)%lneed_dyn3d ) THEN
147                  igrd = 2 
148                  DO ib = 1, ilen1(igrd)
149                     DO ik = 1, jpkm1
150                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
151                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
152                        dta_bdy(jbdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)         
153                     END DO
154                  END DO
155                  igrd = 3 
156                  DO ib = 1, ilen1(igrd)
157                     DO ik = 1, jpkm1
158                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
159                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
160                        dta_bdy(jbdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)         
161                     END DO
162                  END DO
163               ENDIF
164            ENDIF
165
166            IF( nn_tra_dta(jbdy) == 0 ) THEN
167               ilen1(:) = nblen(:)
168               IF( dta_bdy(jbdy)%lneed_tra ) THEN
169                  igrd = 1 
170                  DO ib = 1, ilen1(igrd)
171                     DO ik = 1, jpkm1
172                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
173                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
174                        dta_bdy(jbdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_bdytem) * tmask(ii,ij,ik)         
175                        dta_bdy(jbdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_bdysal) * tmask(ii,ij,ik)         
176                     END DO
177                  END DO
178               ENDIF
179            ENDIF
180
181#if defined key_si3
182            IF( nn_ice_dta(jbdy) == 0 ) THEN    ! set ice to initial values
183               ilen1(:) = nblen(:)
184               IF( dta_bdy(jbdy)%lneed_ice ) THEN
185                  igrd = 1   
186                  DO jl = 1, jpl
187                     DO ib = 1, ilen1(igrd)
188                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
189                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
190                        dta_bdy(jbdy)%a_i(ib,jl) =  a_i (ii,ij,jl) * tmask(ii,ij,1) 
191                        dta_bdy(jbdy)%h_i(ib,jl) =  h_i (ii,ij,jl) * tmask(ii,ij,1) 
192                        dta_bdy(jbdy)%h_s(ib,jl) =  h_s (ii,ij,jl) * tmask(ii,ij,1) 
193                        dta_bdy(jbdy)%t_i(ib,jl) =  SUM(t_i (ii,ij,:,jl)) * r1_nlay_i * tmask(ii,ij,1) 
194                        dta_bdy(jbdy)%t_s(ib,jl) =  SUM(t_s (ii,ij,:,jl)) * r1_nlay_s * tmask(ii,ij,1)
195                        dta_bdy(jbdy)%tsu(ib,jl) =  t_su(ii,ij,jl) * tmask(ii,ij,1) 
196                        dta_bdy(jbdy)%s_i(ib,jl) =  s_i (ii,ij,jl) * tmask(ii,ij,1)
197                        ! melt ponds
198                        dta_bdy(jbdy)%aip(ib,jl) =  a_ip(ii,ij,jl) * tmask(ii,ij,1) 
199                        dta_bdy(jbdy)%hip(ib,jl) =  h_ip(ii,ij,jl) * tmask(ii,ij,1) 
200                        dta_bdy(jbdy)%hil(ib,jl) =  h_il(ii,ij,jl) * tmask(ii,ij,1) 
201                     END DO
202                  END DO
203               ENDIF
204            ENDIF
205#endif
206         END DO ! jbdy
207         !
208      ENDIF ! kt == nit000
209
210      ! update external data from files
211      !--------------------------------
212
213      DO jbdy = 1, nb_bdy
214
215         dta_alias => dta_bdy(jbdy)
216         bf_alias  => bf(:,jbdy)
217
218         ! read/update all bdy data
219         ! ------------------------
220         CALL fld_read( kt, 1, bf_alias, kit = kit, kt_offset = kt_offset )
221
222         ! apply some corrections in some specific cases...
223         ! --------------------------------------------------
224         !
225         ! if runoff condition: change river flow we read (in m3/s) into barotropic velocity (m/s)
226         IF( cn_tra(jbdy) == 'runoff' .AND. TRIM(bf_alias(jp_bdyu2d)%clrootname) /= 'NOT USED' ) THEN   ! runoff and we read u/v2d
227            !
228            igrd = 2                      ! zonal flow (m3/s) to barotropic zonal velocity (m/s)
229            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
230               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
231               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
232               dta_alias%u2d(ib) = dta_alias%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
233            END DO
234            igrd = 3                      ! meridional flow (m3/s) to barotropic meridional velocity (m/s)
235            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
236               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
237               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
238               dta_alias%v2d(ib) = dta_alias%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
239            END DO
240         ENDIF
241
242         ! tidal harmonic forcing ONLY: initialise arrays
243         IF( nn_dyn2d_dta(jbdy) == 2 ) THEN   ! we did not read ssh, u/v2d
244            IF( dta_alias%lneed_ssh   ) dta_alias%ssh(:) = 0._wp
245            IF( dta_alias%lneed_dyn2d ) dta_alias%u2d(:) = 0._wp
246            IF( dta_alias%lneed_dyn2d ) dta_alias%v2d(:) = 0._wp
247         ENDIF
248
249         ! If full velocities in boundary data, then split it into barotropic and baroclinic component
250         IF( bf_alias(jp_bdyu3d)%ltotvel ) THEN     ! if we read 3D total velocity (can be true only if u3d was read)
251            !
252            igrd = 2                       ! zonal velocity
253            dta_alias%u2d(:) = 0._wp       ! compute barotrope zonal velocity and put it in u2d
254            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
255               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
256               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
257               DO ik = 1, jpkm1
258                  dta_alias%u2d(ib) = dta_alias%u2d(ib) + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta_alias%u3d(ib,ik)
259               END DO
260               dta_alias%u2d(ib) =  dta_alias%u2d(ib) * r1_hu_n(ii,ij)
261               DO ik = 1, jpkm1            ! compute barocline zonal velocity and put it in u3d
262                  dta_alias%u3d(ib,ik) = dta_alias%u3d(ib,ik) - dta_alias%u2d(ib)
263               END DO
264            END DO
265            igrd = 3                       ! meridional velocity
266            dta_alias%v2d(:) = 0._wp       ! compute barotrope meridional velocity and put it in v2d
267            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
268               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
269               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
270               DO ik = 1, jpkm1
271                  dta_alias%v2d(ib) = dta_alias%v2d(ib) + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta_alias%v3d(ib,ik)
272               END DO
273               dta_alias%v2d(ib) =  dta_alias%v2d(ib) * r1_hv_n(ii,ij)
274               DO ik = 1, jpkm1            ! compute barocline meridional velocity and put it in v3d
275                  dta_alias%v3d(ib,ik) = dta_alias%v3d(ib,ik) - dta_alias%v2d(ib)
276               END DO
277            END DO
278         ENDIF   ! ltotvel
279
280         ! update tidal harmonic forcing
281         IF( PRESENT(kit) .AND. nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
282            CALL bdytide_update( kt = kt, idx = idx_bdy(jbdy), dta = dta_alias, td = tides(jbdy),   & 
283               &                 kit = kit, kt_offset = kt_offset )
284         ENDIF
285
286         !  atm surface pressure : add inverted barometer effect to ssh if it was read
287         IF ( ln_apr_obc .AND. TRIM(bf_alias(jp_bdyssh)%clrootname) /= 'NOT USED' ) THEN
288            igrd = 1
289            DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is used only on the rim
290               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
291               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
292               dta_alias%ssh(ib) = dta_alias%ssh(ib) + ssh_ib(ii,ij)
293            END DO
294         ENDIF
295
296#if defined key_si3
297         IF( dta_alias%lneed_ice ) THEN
298            ! fill temperature and salinity arrays
299            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_i)%fnow(:,1,:) = rice_tem (jbdy)
300            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_s)%fnow(:,1,:) = rice_tem (jbdy)
301            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' )   bf_alias(jp_bdytsu)%fnow(:,1,:) = rice_tem (jbdy)
302            IF( TRIM(bf_alias(jp_bdys_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdys_i)%fnow(:,1,:) = rice_sal (jbdy)
303            IF( TRIM(bf_alias(jp_bdyaip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyaip)%fnow(:,1,:) = rice_apnd(jbdy) * & ! rice_apnd is the pond fraction
304               &                                                                         bf_alias(jp_bdya_i)%fnow(:,1,:)     !   ( a_ip = rice_apnd * a_i )
305            IF( TRIM(bf_alias(jp_bdyhip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyhip)%fnow(:,1,:) = rice_hpnd(jbdy)
306            IF( TRIM(bf_alias(jp_bdyhil)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyhil)%fnow(:,1,:) = rice_hlid(jbdy)
307            ! if T_su is read and not T_i, set T_i = (T_su + T_freeze)/2
308            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
309               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdytsu)%fnow(:,1,:) + 271.15 )
310            ! if T_su is read and not T_s, set T_s = T_su
311            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' ) &
312               &   bf_alias(jp_bdyt_s)%fnow(:,1,:) = bf_alias(jp_bdytsu)%fnow(:,1,:)
313            ! if T_s is read and not T_su, set T_su = T_s
314            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' ) &
315               &   bf_alias(jp_bdytsu)%fnow(:,1,:) = bf_alias(jp_bdyt_s)%fnow(:,1,:)
316            ! if T_s is read and not T_i, set T_i = (T_s + T_freeze)/2
317            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
318               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdyt_s)%fnow(:,1,:) + 271.15 )
319
320            ! make sure ponds = 0 if no ponds scheme
321            IF ( .NOT.ln_pnd ) THEN
322               bf_alias(jp_bdyaip)%fnow(:,1,:) = 0._wp
323               bf_alias(jp_bdyhip)%fnow(:,1,:) = 0._wp
324               bf_alias(jp_bdyhil)%fnow(:,1,:) = 0._wp
325            ENDIF
326            IF ( .NOT.ln_pnd_lids ) THEN
327               bf_alias(jp_bdyhil)%fnow(:,1,:) = 0._wp
328            ENDIF
329           
330            ! convert N-cat fields (input) into jpl-cat (output)
331            ipl = SIZE(bf_alias(jp_bdya_i)%fnow, 3)           
332            IF( ipl /= jpl ) THEN      ! ice: convert N-cat fields (input) into jpl-cat (output)
333               CALL ice_var_itd( bf_alias(jp_bdyh_i)%fnow(:,1,:), bf_alias(jp_bdyh_s)%fnow(:,1,:), bf_alias(jp_bdya_i)%fnow(:,1,:), & ! in
334                  &              dta_alias%h_i                  , dta_alias%h_s                  , dta_alias%a_i                  , & ! out
335                  &              bf_alias(jp_bdyt_i)%fnow(:,1,:), bf_alias(jp_bdyt_s)%fnow(:,1,:), &                                  ! in (optional)
336                  &              bf_alias(jp_bdytsu)%fnow(:,1,:), bf_alias(jp_bdys_i)%fnow(:,1,:), &                                  ! in     -
337                  &              bf_alias(jp_bdyaip)%fnow(:,1,:), bf_alias(jp_bdyhip)%fnow(:,1,:), bf_alias(jp_bdyhil)%fnow(:,1,:), & ! in     -
338                  &              dta_alias%t_i                  , dta_alias%t_s                  , &                                  ! out    -
339                  &              dta_alias%tsu                  , dta_alias%s_i                  , &                                  ! out    -
340                  &              dta_alias%aip                  , dta_alias%hip                  , dta_alias%hil )                    ! out    -
341            ENDIF
342         ENDIF
343#endif
344      END DO  ! jbdy
345
346      IF ( ln_tide ) THEN
347         IF (ln_dynspg_ts) THEN      ! Fill temporary arrays with slow-varying bdy data                           
348            DO jbdy = 1, nb_bdy      ! Tidal component added in ts loop
349               IF ( nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
350                  nblen => idx_bdy(jbdy)%nblen
351                  nblenrim => idx_bdy(jbdy)%nblenrim
352                  IF( cn_dyn2d(jbdy) == 'frs' ) THEN ; ilen1(:)=nblen(:) ; ELSE ; ilen1(:)=nblenrim(:) ; ENDIF
353                     IF ( dta_bdy(jbdy)%lneed_ssh   ) dta_bdy_s(jbdy)%ssh(1:ilen1(1)) = dta_bdy(jbdy)%ssh(1:ilen1(1))
354                     IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%u2d(1:ilen1(2)) = dta_bdy(jbdy)%u2d(1:ilen1(2))
355                     IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%v2d(1:ilen1(3)) = dta_bdy(jbdy)%v2d(1:ilen1(3))
356                  ENDIF
357               END DO
358            ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
359               !
360               CALL bdy_dta_tides( kt=kt, kt_offset=kt_offset )
361            ENDIF
362         ENDIF
363         !
364         IF( ln_timing )   CALL timing_stop('bdy_dta')
365         !
366      END SUBROUTINE bdy_dta
367
368
369   SUBROUTINE bdy_dta_init
370      !!----------------------------------------------------------------------
371      !!                   ***  SUBROUTINE bdy_dta_init  ***
372      !!                   
373      !! ** Purpose :   Initialise arrays for reading of external data
374      !!                for open boundary conditions
375      !!
376      !! ** Method  :   
377      !!               
378      !!----------------------------------------------------------------------
379      INTEGER ::   jbdy, jfld    ! Local integers
380      INTEGER ::   ierror, ios     !
381      !
382      CHARACTER(len=3)                       ::   cl3           !
383      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
384      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
385      !                                                         ! =F => baroclinic velocities in 3D boundary data
386      LOGICAL                                ::   ln_zinterp    ! =T => requires a vertical interpolation of the bdydta
387      REAL(wp)                               ::   rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd, rn_ice_hlid
388      INTEGER                                ::   ipk,ipl       !
389      INTEGER                                ::   idvar         ! variable ID
390      INTEGER                                ::   indims        ! number of dimensions of the variable
391      INTEGER                                ::   iszdim        ! number of dimensions of the variable
392      INTEGER, DIMENSION(4)                  ::   i4dimsz       ! size of variable dimensions
393      INTEGER                                ::   igrd          ! index for grid type (1,2,3 = T,U,V)
394      LOGICAL                                ::   lluld         ! is the variable using the unlimited dimension
395      LOGICAL                                ::   llneed        !
396      LOGICAL                                ::   llread        !
397      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_tem, bn_sal, bn_u3d, bn_v3d   ! must be an array to be used with fld_fill
398      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
399      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip, bn_hil       
400      TYPE(FLD_N), DIMENSION(:), POINTER ::   bn_alias                        ! must be an array to be used with fld_fill
401      TYPE(FLD  ), DIMENSION(:), POINTER ::   bf_alias
402      !
403      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
404      NAMELIST/nambdy_dta/ bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip, bn_hil
405      NAMELIST/nambdy_dta/ rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd, rn_ice_hlid
406      NAMELIST/nambdy_dta/ ln_full_vel, ln_zinterp
407      !!---------------------------------------------------------------------------
408      !
409      IF(lwp) WRITE(numout,*)
410      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
411      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
412      IF(lwp) WRITE(numout,*) ''
413
414      ALLOCATE( bf(jpbdyfld,nb_bdy), STAT=ierror )
415      IF( ierror > 0 ) THEN   
416         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
417      ENDIF
418      bf(:,:)%clrootname = 'NOT USED'   ! default definition used as a flag in fld_read to do nothing.
419      bf(:,:)%lzint      = .FALSE.      ! default definition
420      bf(:,:)%ltotvel    = .FALSE.      ! default definition
421 
422      ! Read namelists
423      ! --------------
424      REWIND(numnam_cfg)
425      DO jbdy = 1, nb_bdy
426
427         WRITE(ctmp1, '(a,i2)') 'BDY number ', jbdy
428         WRITE(ctmp2, '(a,i2)') 'block nambdy_dta number ', jbdy
429
430         ! There is only one nambdy_dta block in namelist_ref -> use it for each bdy so we do a rewind
431         REWIND(numnam_ref)
432         READ  ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
433901      IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in reference namelist' )
434
435         !   by-pass nambdy_dta reading if no input data used in this bdy   
436         IF(       ( dta_bdy(jbdy)%lneed_dyn2d .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1 )   &
437            & .OR. ( dta_bdy(jbdy)%lneed_dyn3d .AND.     nn_dyn3d_dta(jbdy)    == 1 )   &
438            & .OR. ( dta_bdy(jbdy)%lneed_tra   .AND.       nn_tra_dta(jbdy)    == 1 )   &
439            & .OR. ( dta_bdy(jbdy)%lneed_ice   .AND.       nn_ice_dta(jbdy)    == 1 )   )   THEN
440            ! WARNING: we don't do a rewind here, each bdy reads its own nambdy_dta block one after another
441            READ  ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 )
442902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist' )
443            IF(lwm) WRITE( numond, nambdy_dta )           
444         ENDIF
445
446         ! get the number of ice categories in bdy data file (use a_i information to do this)
447         ipl = jpl   ! default definition
448         IF( dta_bdy(jbdy)%lneed_ice ) THEN    ! if we need ice bdy data
449            IF( nn_ice_dta(jbdy) == 1 ) THEN   ! if we get ice bdy data from netcdf file
450               CALL fld_fill(  bf(jp_bdya_i,jbdy:jbdy), bn_a_i, cn_dir, 'bdy_dta', 'a_i'//' '//ctmp1, ctmp2 )   ! use namelist info
451               CALL fld_clopn( bf(jp_bdya_i,jbdy), nyear, nmonth, nday )   ! not a problem when we call it again after
452               idvar = iom_varid( bf(jp_bdya_i,jbdy)%num, bf(jp_bdya_i,jbdy)%clvar, kndims=indims, kdimsz=i4dimsz, lduld=lluld )
453               IF( indims == 4 .OR. ( indims == 3 .AND. .NOT. lluld ) ) THEN   ;   ipl = i4dimsz(3)   ! xylt or xyl
454               ELSE                                                            ;   ipl = 1            ! xy or xyt
455               ENDIF
456            ENDIF
457         ENDIF
458
459#if defined key_si3
460         IF( .NOT.ln_pnd ) THEN
461            rn_ice_apnd = 0. ; rn_ice_hpnd = 0. ; rn_ice_hlid = 0.
462            CALL ctl_warn( 'rn_ice_apnd & rn_ice_hpnd = 0 & rn_ice_hlid = 0 when no ponds' )
463         ENDIF
464         IF( .NOT.ln_pnd_lids ) THEN
465            rn_ice_hlid = 0.
466         ENDIF
467#endif
468
469         ! temp, salt, age and ponds of incoming ice
470         rice_tem (jbdy) = rn_ice_tem
471         rice_sal (jbdy) = rn_ice_sal
472         rice_age (jbdy) = rn_ice_age
473         rice_apnd(jbdy) = rn_ice_apnd
474         rice_hpnd(jbdy) = rn_ice_hpnd
475         rice_hlid(jbdy) = rn_ice_hlid
476
477         
478         DO jfld = 1, jpbdyfld
479
480            ! =====================
481            !          ssh
482            ! =====================
483            IF( jfld == jp_bdyssh ) THEN
484               cl3 = 'ssh'
485               igrd = 1                                                    ! T point
486               ipk = 1                                                     ! surface data
487               llneed = dta_bdy(jbdy)%lneed_ssh                            ! dta_bdy(jbdy)%ssh will be needed
488               llread = MOD(nn_dyn2d_dta(jbdy),2) == 1                     ! get data from NetCDF file
489               bf_alias => bf(jp_bdyssh,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
490               bn_alias => bn_ssh                                          ! alias for ssh structure of nambdy_dta
491               iszdim = idx_bdy(jbdy)%nblenrim(igrd)                       ! length of this bdy on this MPI processus : used only on the rim
492            ENDIF
493            ! =====================
494            !         dyn2d
495            ! =====================
496            IF( jfld == jp_bdyu2d ) THEN
497               cl3 = 'u2d'
498               igrd = 2                                                    ! U point
499               ipk = 1                                                     ! surface data
500               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
501               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get u2d from u3d and read NetCDF file
502               bf_alias => bf(jp_bdyu2d,jbdy:jbdy)                         ! alias for u2d structure of bdy number jbdy
503               bn_alias => bn_u2d                                          ! alias for u2d structure of nambdy_dta
504               IF( ln_full_vel ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)      ! will be computed from u3d -> need on the full bdy
505               ELSE                    ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)   ! used only on the rim
506               ENDIF
507            ENDIF
508            IF( jfld == jp_bdyv2d ) THEN
509               cl3 = 'v2d'
510               igrd = 3                                                    ! V point
511               ipk = 1                                                     ! surface data
512               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
513               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get v2d from v3d and read NetCDF file
514               bf_alias => bf(jp_bdyv2d,jbdy:jbdy)                         ! alias for v2d structure of bdy number jbdy
515               bn_alias => bn_v2d                                          ! alias for v2d structure of nambdy_dta
516               IF( ln_full_vel ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)      ! will be computed from v3d -> need on the full bdy
517               ELSE                    ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)   ! used only on the rim
518               ENDIF
519            ENDIF
520            ! =====================
521            !         dyn3d
522            ! =====================
523            IF( jfld == jp_bdyu3d ) THEN
524               cl3 = 'u3d'
525               igrd = 2                                                    ! U point
526               ipk = jpk                                                   ! 3d data
527               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%u3d will be needed
528                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   u3d needed to compute u2d
529               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
530               bf_alias => bf(jp_bdyu3d,jbdy:jbdy)                         ! alias for u3d structure of bdy number jbdy
531               bn_alias => bn_u3d                                          ! alias for u3d structure of nambdy_dta
532               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
533           ENDIF
534            IF( jfld == jp_bdyv3d ) THEN
535               cl3 = 'v3d'
536               igrd = 3                                                    ! V point
537               ipk = jpk                                                   ! 3d data
538               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%v3d will be needed
539                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   v3d needed to compute v2d
540               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
541               bf_alias => bf(jp_bdyv3d,jbdy:jbdy)                         ! alias for v3d structure of bdy number jbdy
542               bn_alias => bn_v3d                                          ! alias for v3d structure of nambdy_dta
543               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
544           ENDIF
545
546            ! =====================
547            !          tra
548            ! =====================
549            IF( jfld == jp_bdytem ) THEN
550               cl3 = 'tem'
551               igrd = 1                                                    ! T point
552               ipk = jpk                                                   ! 3d data
553               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%tem will be needed
554               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
555               bf_alias => bf(jp_bdytem,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
556               bn_alias => bn_tem                                          ! alias for ssh structure of nambdy_dta
557               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
558            ENDIF
559            IF( jfld == jp_bdysal ) THEN
560               cl3 = 'sal'
561               igrd = 1                                                    ! T point
562               ipk = jpk                                                   ! 3d data
563               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%sal will be needed
564               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
565               bf_alias => bf(jp_bdysal,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
566               bn_alias => bn_sal                                          ! alias for ssh structure of nambdy_dta
567               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
568            ENDIF
569
570            ! =====================
571            !          ice
572            ! =====================
573            IF(  jfld == jp_bdya_i .OR. jfld == jp_bdyh_i .OR. jfld == jp_bdyh_s .OR. &
574               & jfld == jp_bdyt_i .OR. jfld == jp_bdyt_s .OR. jfld == jp_bdytsu .OR. &
575               & jfld == jp_bdys_i .OR. jfld == jp_bdyaip .OR. jfld == jp_bdyhip .OR. jfld == jp_bdyhil ) THEN
576               igrd = 1                                                    ! T point
577               ipk = ipl                                                   ! jpl-cat data
578               llneed = dta_bdy(jbdy)%lneed_ice                            ! ice will be needed
579               llread = nn_ice_dta(jbdy) == 1                              ! get data from NetCDF file
580               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
581            ENDIF
582            IF( jfld == jp_bdya_i ) THEN
583               cl3 = 'a_i'
584               bf_alias => bf(jp_bdya_i,jbdy:jbdy)                         ! alias for a_i structure of bdy number jbdy
585               bn_alias => bn_a_i                                          ! alias for a_i structure of nambdy_dta
586            ENDIF
587            IF( jfld == jp_bdyh_i ) THEN
588               cl3 = 'h_i'
589               bf_alias => bf(jp_bdyh_i,jbdy:jbdy)                         ! alias for h_i structure of bdy number jbdy
590               bn_alias => bn_h_i                                          ! alias for h_i structure of nambdy_dta
591            ENDIF
592            IF( jfld == jp_bdyh_s ) THEN
593               cl3 = 'h_s'
594               bf_alias => bf(jp_bdyh_s,jbdy:jbdy)                         ! alias for h_s structure of bdy number jbdy
595               bn_alias => bn_h_s                                          ! alias for h_s structure of nambdy_dta
596            ENDIF
597            IF( jfld == jp_bdyt_i ) THEN
598               cl3 = 't_i'
599               bf_alias => bf(jp_bdyt_i,jbdy:jbdy)                         ! alias for t_i structure of bdy number jbdy
600               bn_alias => bn_t_i                                          ! alias for t_i structure of nambdy_dta
601            ENDIF
602            IF( jfld == jp_bdyt_s ) THEN
603               cl3 = 't_s'
604               bf_alias => bf(jp_bdyt_s,jbdy:jbdy)                         ! alias for t_s structure of bdy number jbdy
605               bn_alias => bn_t_s                                          ! alias for t_s structure of nambdy_dta
606            ENDIF
607            IF( jfld == jp_bdytsu ) THEN
608               cl3 = 'tsu'
609               bf_alias => bf(jp_bdytsu,jbdy:jbdy)                         ! alias for tsu structure of bdy number jbdy
610               bn_alias => bn_tsu                                          ! alias for tsu structure of nambdy_dta
611            ENDIF
612            IF( jfld == jp_bdys_i ) THEN
613               cl3 = 's_i'
614               bf_alias => bf(jp_bdys_i,jbdy:jbdy)                         ! alias for s_i structure of bdy number jbdy
615               bn_alias => bn_s_i                                          ! alias for s_i structure of nambdy_dta
616            ENDIF
617            IF( jfld == jp_bdyaip ) THEN
618               cl3 = 'aip'
619               bf_alias => bf(jp_bdyaip,jbdy:jbdy)                         ! alias for aip structure of bdy number jbdy
620               bn_alias => bn_aip                                          ! alias for aip structure of nambdy_dta
621            ENDIF
622            IF( jfld == jp_bdyhip ) THEN
623               cl3 = 'hip'
624               bf_alias => bf(jp_bdyhip,jbdy:jbdy)                         ! alias for hip structure of bdy number jbdy
625               bn_alias => bn_hip                                          ! alias for hip structure of nambdy_dta
626            ENDIF
627            IF( jfld == jp_bdyhil ) THEN
628               cl3 = 'hil'
629               bf_alias => bf(jp_bdyhil,jbdy:jbdy)                         ! alias for hil structure of bdy number jbdy
630               bn_alias => bn_hil                                          ! alias for hil structure of nambdy_dta
631            ENDIF
632
633            IF( llneed ) THEN                                              ! dta_bdy(jbdy)%xxx will be needed
634               !                                                           !   -> must be associated with an allocated target
635               ALLOCATE( bf_alias(1)%fnow( iszdim, 1, ipk ) )              ! allocate the target
636               !
637               IF( llread ) THEN                                           ! get data from NetCDF file
638                  CALL fld_fill( bf_alias, bn_alias, cn_dir, 'bdy_dta', cl3//' '//ctmp1, ctmp2 )   ! use namelist info
639                  IF( bf_alias(1)%ln_tint ) ALLOCATE( bf_alias(1)%fdta( iszdim, 1, ipk, 2 ) )
640                  bf_alias(1)%imap    => idx_bdy(jbdy)%nbmap(1:iszdim,igrd)   ! associate the mapping used for this bdy
641                  bf_alias(1)%igrd    = igrd                                  ! used only for vertical integration of 3D arrays
642                  bf_alias(1)%ltotvel = ln_full_vel                           ! T if u3d is full velocity
643                  bf_alias(1)%lzint   = ln_zinterp                            ! T if it requires a vertical interpolation
644               ENDIF
645
646               ! associate the pointer and get rid of the dimensions with a size equal to 1
647               IF( jfld == jp_bdyssh )        dta_bdy(jbdy)%ssh => bf_alias(1)%fnow(:,1,1)
648               IF( jfld == jp_bdyu2d )        dta_bdy(jbdy)%u2d => bf_alias(1)%fnow(:,1,1)
649               IF( jfld == jp_bdyv2d )        dta_bdy(jbdy)%v2d => bf_alias(1)%fnow(:,1,1)
650               IF( jfld == jp_bdyu3d )        dta_bdy(jbdy)%u3d => bf_alias(1)%fnow(:,1,:)
651               IF( jfld == jp_bdyv3d )        dta_bdy(jbdy)%v3d => bf_alias(1)%fnow(:,1,:)
652               IF( jfld == jp_bdytem )        dta_bdy(jbdy)%tem => bf_alias(1)%fnow(:,1,:)
653               IF( jfld == jp_bdysal )        dta_bdy(jbdy)%sal => bf_alias(1)%fnow(:,1,:)
654               IF( jfld == jp_bdya_i ) THEN
655                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%a_i => bf_alias(1)%fnow(:,1,:)
656                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%a_i(iszdim,jpl) )
657                  ENDIF
658               ENDIF
659               IF( jfld == jp_bdyh_i ) THEN
660                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_i => bf_alias(1)%fnow(:,1,:)
661                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_i(iszdim,jpl) )
662                  ENDIF
663               ENDIF
664               IF( jfld == jp_bdyh_s ) THEN
665                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_s => bf_alias(1)%fnow(:,1,:)
666                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_s(iszdim,jpl) )
667                  ENDIF
668               ENDIF
669               IF( jfld == jp_bdyt_i ) THEN
670                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_i => bf_alias(1)%fnow(:,1,:)
671                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_i(iszdim,jpl) )
672                  ENDIF
673               ENDIF
674               IF( jfld == jp_bdyt_s ) THEN
675                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_s => bf_alias(1)%fnow(:,1,:)
676                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_s(iszdim,jpl) )
677                  ENDIF
678               ENDIF
679               IF( jfld == jp_bdytsu ) THEN
680                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%tsu => bf_alias(1)%fnow(:,1,:)
681                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%tsu(iszdim,jpl) )
682                  ENDIF
683               ENDIF
684               IF( jfld == jp_bdys_i ) THEN
685                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%s_i => bf_alias(1)%fnow(:,1,:)
686                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%s_i(iszdim,jpl) )
687                  ENDIF
688               ENDIF
689               IF( jfld == jp_bdyaip ) THEN
690                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%aip => bf_alias(1)%fnow(:,1,:)
691                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%aip(iszdim,jpl) )
692                  ENDIF
693               ENDIF
694               IF( jfld == jp_bdyhip ) THEN
695                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%hip => bf_alias(1)%fnow(:,1,:)
696                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%hip(iszdim,jpl) )
697                  ENDIF
698               ENDIF
699               IF( jfld == jp_bdyhil ) THEN
700                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%hil => bf_alias(1)%fnow(:,1,:)
701                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%hil(iszdim,jpl) )
702                  ENDIF
703               ENDIF
704            ENDIF
705
706         END DO   ! jpbdyfld
707         !
708      END DO ! jbdy
709      !
710   END SUBROUTINE bdy_dta_init
711   
712   !!==============================================================================
713END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.