New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
cpl_oasis3.F90 in NEMO/branches/UKMO/NEMO_4.0.4_CO9_package-mix-lyr/src/OCE/SBC – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.4_CO9_package-mix-lyr/src/OCE/SBC/cpl_oasis3.F90 @ 15505

Last change on this file since 15505 was 15505, checked in by jcastill, 7 months ago

Changes in zdfmxl as in 4.0.1 version of the branch: NEMO/branches/UKMO/r12083_mix-lyr_diag@12836

File size: 27.7 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5   !!=====================================================================
6   !! History :  1.0  !  2004-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
7   !!             -   !  2004-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
8   !!             -   !  2004-11  (V. Gayler, MPI M&D) Grid writing
9   !!            2.0  !  2005-08  (R. Redler, W. Park) frld initialization, paral(2) revision
10   !!             -   !  2005-09  (R. Redler) extended to allow for communication over root only
11   !!             -   !  2006-01  (W. Park) modification of physical part
12   !!             -   !  2006-02  (R. Redler, W. Park) buffer array fix for root exchange
13   !!            3.4  !  2011-11  (C. Harris) Changes to allow mutiple category fields
14   !!            3.6  !  2014-11  (S. Masson) OASIS3-MCT
15   !!----------------------------------------------------------------------
16   
17   !!----------------------------------------------------------------------
18   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3-MCT
19   !!   'key_oa3mct_v3'                 to be added for OASIS3-MCT version 3
20   !!----------------------------------------------------------------------
21   !!   cpl_init     : initialization of coupled mode communication
22   !!   cpl_define   : definition of grid and fields
23   !!   cpl_snd      : snd out fields in coupled mode
24   !!   cpl_rcv      : receive fields in coupled mode
25   !!   cpl_finalize : finalize the coupled mode communication
26   !!----------------------------------------------------------------------
27#if defined key_oasis3
28   USE mod_oasis                    ! OASIS3-MCT module
29#endif 
30#if defined key_iomput && defined key_xios25 
31   USE xios, ONLY:xios_oasis_enddef
32#endif
33   USE par_oce                      ! ocean parameters
34   USE dom_oce                      ! ocean space and time domain
35   USE in_out_manager               ! I/O manager
36   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   cpl_init
42   PUBLIC   cpl_define
43   PUBLIC   cpl_snd
44   PUBLIC   cpl_rcv
45   PUBLIC   cpl_freq
46   PUBLIC   cpl_finalize
47
48   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
49   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
50   INTEGER                    ::   ncomp_id          ! id returned by oasis_init_comp
51   INTEGER                    ::   nerror            ! return error code
52#if ! defined key_oasis3
53   ! OASIS Variables not used. defined only for compilation purpose
54   INTEGER                    ::   OASIS_Out         = -1
55   INTEGER                    ::   OASIS_REAL        = -1
56   INTEGER                    ::   OASIS_Ok          = -1
57   INTEGER                    ::   OASIS_In          = -1
58   INTEGER                    ::   OASIS_Sent        = -1
59   INTEGER                    ::   OASIS_SentOut     = -1
60   INTEGER                    ::   OASIS_ToRest      = -1
61   INTEGER                    ::   OASIS_ToRestOut   = -1
62   INTEGER                    ::   OASIS_Recvd       = -1
63   INTEGER                    ::   OASIS_RecvOut     = -1
64   INTEGER                    ::   OASIS_FromRest    = -1
65   INTEGER                    ::   OASIS_FromRestOut = -1
66#endif
67
68   INTEGER                    ::   nrcv         ! total number of fields received
69   INTEGER                    ::   nsnd         ! total number of fields sent
70   INTEGER                    ::   ncplmodel    ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
71   INTEGER, PUBLIC, PARAMETER ::   nmaxfld=60   ! Maximum number of coupling fields
72   INTEGER, PUBLIC, PARAMETER ::   nmaxcat=5    ! Maximum number of coupling fields
73   INTEGER, PUBLIC, PARAMETER ::   nmaxcpl=5    ! Maximum number of coupling fields
74   LOGICAL, PARAMETER         ::   ltmp_wapatch = .TRUE.   ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define 
75   INTEGER                    ::   nldi_save, nlei_save
76   INTEGER                    ::   nldj_save, nlej_save
77   
78   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
79      LOGICAL               ::   laction   ! To be coupled or not
80      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
81      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
82      REAL(wp)              ::   nsgn      ! Control of the sign change
83      INTEGER, DIMENSION(nmaxcat,nmaxcpl) ::   nid   ! Id of the field (no more than 9 categories and 9 extrena models)
84      INTEGER               ::   nct       ! Number of categories in field
85      INTEGER               ::   ncplmodel ! Maximum number of models to/from which this variable may be sent/received
86   END TYPE FLD_CPL
87
88   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
89
90   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
91
92   !!----------------------------------------------------------------------
93   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
94   !! $Id$
95   !! Software governed by the CeCILL license (see ./LICENSE)
96   !!----------------------------------------------------------------------
97CONTAINS
98
99   SUBROUTINE cpl_init( cd_modname, kl_comm )
100      !!-------------------------------------------------------------------
101      !!             ***  ROUTINE cpl_init  ***
102      !!
103      !! ** Purpose :   Initialize coupled mode communication for ocean
104      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
105      !!
106      !! ** Method  :   OASIS3 MPI communication
107      !!--------------------------------------------------------------------
108      CHARACTER(len = *), INTENT(in   ) ::   cd_modname   ! model name as set in namcouple file
109      INTEGER           , INTENT(  out) ::   kl_comm      ! local communicator of the model
110      !!--------------------------------------------------------------------
111
112      ! WARNING: No write in numout in this routine
113      !============================================
114
115      !------------------------------------------------------------------
116      ! 1st Initialize the OASIS system for the application
117      !------------------------------------------------------------------
118      CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror )
119      IF ( nerror /= OASIS_Ok ) &
120         CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
121
122      !------------------------------------------------------------------
123      ! 3rd Get an MPI communicator for OPA local communication
124      !------------------------------------------------------------------
125
126      CALL oasis_get_localcomm ( kl_comm, nerror )
127      IF ( nerror /= OASIS_Ok ) &
128         CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
129      !
130   END SUBROUTINE cpl_init
131
132
133   SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
134      !!-------------------------------------------------------------------
135      !!             ***  ROUTINE cpl_define  ***
136      !!
137      !! ** Purpose :   Define grid and field information for ocean
138      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
139      !!
140      !! ** Method  :   OASIS3 MPI communication
141      !!--------------------------------------------------------------------
142      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
143      INTEGER, INTENT(in) ::   kcplmodel      ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
144      !
145      INTEGER :: id_part
146      INTEGER :: paral(5)       ! OASIS3 box partition
147      INTEGER :: ishape(4)    ! shape of arrays passed to PSMILe
148      INTEGER :: ji,jc,jm       ! local loop indicees
149      CHARACTER(LEN=64) :: zclname
150      CHARACTER(LEN=2) :: cli2
151      !!--------------------------------------------------------------------
152
153      ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define
154      IF ( ltmp_wapatch ) THEN
155         nldi_save = nldi   ;   nlei_save = nlei
156         nldj_save = nldj   ;   nlej_save = nlej
157         IF( nimpp           ==      1 ) nldi = 1
158         IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
159         IF( njmpp           ==      1 ) nldj = 1
160         IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
161      ENDIF
162      IF(lwp) WRITE(numout,*)
163      IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
164      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
165      IF(lwp) WRITE(numout,*)
166
167      ncplmodel = kcplmodel
168      IF( kcplmodel > nmaxcpl ) THEN
169         CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl')   ;   RETURN
170      ENDIF
171
172      nrcv = krcv
173      IF( nrcv > nmaxfld ) THEN
174         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld')   ;   RETURN
175      ENDIF
176
177      nsnd = ksnd
178      IF( nsnd > nmaxfld ) THEN
179         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld')   ;   RETURN
180      ENDIF
181      !
182      ! ... Define the shape for the area that excludes the halo
183      !     For serial configuration (key_mpp_mpi not being active)
184      !     nl* is set to the global values 1 and jp*glo.
185      !
186      ishape(1) = 1
187      ishape(2) = nlei-nldi+1
188      ishape(3) = 1
189      ishape(4) = nlej-nldj+1
190      !
191      ! ... Allocate memory for data exchange
192      !
193      ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
194      IF( nerror > 0 ) THEN
195         CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld')   ;   RETURN
196      ENDIF
197      !
198      ! -----------------------------------------------------------------
199      ! ... Define the partition
200      ! -----------------------------------------------------------------
201     
202      paral(1) = 2                                              ! box partitioning
203      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
204      paral(3) = nlei-nldi+1                                    ! local extent in i
205      paral(4) = nlej-nldj+1                                    ! local extent in j
206      paral(5) = jpiglo                                         ! global extent in x
207     
208      IF( ln_ctl ) THEN
209         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
210         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
211         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
212         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
213      ENDIF
214   
215      CALL oasis_def_partition ( id_part, paral, nerror, jpiglo*jpjglo )
216      !
217      ! ... Announce send variables.
218      !
219      ssnd(:)%ncplmodel = kcplmodel
220      !
221      DO ji = 1, ksnd
222         IF ( ssnd(ji)%laction ) THEN
223
224            IF( ssnd(ji)%nct > nmaxcat ) THEN
225               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
226                  &              TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
227               RETURN
228            ENDIF
229           
230            DO jc = 1, ssnd(ji)%nct
231               DO jm = 1, kcplmodel
232
233                  IF ( ssnd(ji)%nct .GT. 1 ) THEN
234                     WRITE(cli2,'(i2.2)') jc
235                     zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
236                  ELSE
237                     zclname = ssnd(ji)%clname
238                  ENDIF
239                  IF ( kcplmodel  > 1 ) THEN
240                     WRITE(cli2,'(i2.2)') jm
241                     zclname = 'model'//cli2//'_'//TRIM(zclname)
242                  ENDIF
243#if defined key_agrif
244                  IF( agrif_fixed() /= 0 ) THEN
245                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
246                  END IF
247#endif
248                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
249                  CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 1 /),   &
250                     &                OASIS_Out          , ishape , OASIS_REAL, nerror )
251                  IF ( nerror /= OASIS_Ok ) THEN
252                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
253                     CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
254                  ENDIF
255                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
256                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
257               END DO
258            END DO
259         ENDIF
260      END DO
261      !
262      ! ... Announce received variables.
263      !
264      srcv(:)%ncplmodel = kcplmodel
265      !
266      DO ji = 1, krcv
267         IF ( srcv(ji)%laction ) THEN
268           
269            IF( srcv(ji)%nct > nmaxcat ) THEN
270               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
271                  &              TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
272               RETURN
273            ENDIF
274           
275            DO jc = 1, srcv(ji)%nct
276               DO jm = 1, kcplmodel
277                 
278                  IF ( srcv(ji)%nct .GT. 1 ) THEN
279                     WRITE(cli2,'(i2.2)') jc
280                     zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
281                  ELSE
282                     zclname = srcv(ji)%clname
283                  ENDIF
284                  IF ( kcplmodel  > 1 ) THEN
285                     WRITE(cli2,'(i2.2)') jm
286                     zclname = 'model'//cli2//'_'//TRIM(zclname)
287                  ENDIF
288#if defined key_agrif
289                  IF( agrif_fixed() /= 0 ) THEN
290                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
291                  END IF
292#endif
293                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
294                  CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 1 /),   &
295                     &                OASIS_In           , ishape , OASIS_REAL, nerror )
296                  IF ( nerror /= OASIS_Ok ) THEN
297                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
298                     CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
299                  ENDIF
300                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
301                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
302
303               END DO
304            END DO
305         ENDIF
306      END DO
307     
308      !------------------------------------------------------------------
309      ! End of definition phase
310      !------------------------------------------------------------------
311      !     
312#if defined key_agrif
313      IF( agrif_fixed() == Agrif_Nb_Fine_Grids() ) THEN
314#endif
315     
316#if defined key_iomput && defined key_xios25 
317!needed for XIOS 2.5 
318      CALL xios_oasis_enddef() 
319#endif 
320      !
321      CALL oasis_enddef(nerror)
322      IF( nerror /= OASIS_Ok )   CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef')
323#if defined key_agrif
324      ENDIF
325#endif
326      !
327      IF ( ltmp_wapatch ) THEN
328         nldi = nldi_save   ;   nlei = nlei_save
329         nldj = nldj_save   ;   nlej = nlej_save
330      ENDIF
331   END SUBROUTINE cpl_define
332   
333   
334   SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
335      !!---------------------------------------------------------------------
336      !!              ***  ROUTINE cpl_snd  ***
337      !!
338      !! ** Purpose : - At each coupling time-step,this routine sends fields
339      !!      like sst or ice cover to the coupler or remote application.
340      !!----------------------------------------------------------------------
341      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
342      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
343      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
344      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
345      !!
346      INTEGER                                   ::   jc,jm     ! local loop index
347      !!--------------------------------------------------------------------
348      ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define
349      IF ( ltmp_wapatch ) THEN
350         nldi_save = nldi   ;   nlei_save = nlei
351         nldj_save = nldj   ;   nlej_save = nlej
352         IF( nimpp           ==      1 ) nldi = 1
353         IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
354         IF( njmpp           ==      1 ) nldj = 1
355         IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
356      ENDIF
357      !
358      ! snd data to OASIS3
359      !
360      DO jc = 1, ssnd(kid)%nct
361         DO jm = 1, ssnd(kid)%ncplmodel
362       
363            IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN
364               CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
365               
366               IF ( ln_ctl ) THEN       
367                  IF ( kinfo == OASIS_Sent     .OR. kinfo == OASIS_ToRest .OR.   &
368                     & kinfo == OASIS_SentOut  .OR. kinfo == OASIS_ToRestOut ) THEN
369                     WRITE(numout,*) '****************'
370                     WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
371                     WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
372                     WRITE(numout,*) 'oasis_put:  kstep ', kstep
373                     WRITE(numout,*) 'oasis_put:   info ', kinfo
374                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(nldi:nlei,nldj:nlej,jc))
375                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(nldi:nlei,nldj:nlej,jc))
376                     WRITE(numout,*) '     -     Sum value is ',    SUM(pdata(nldi:nlei,nldj:nlej,jc))
377                     WRITE(numout,*) '****************'
378                  ENDIF
379               ENDIF
380               
381            ENDIF
382           
383         ENDDO
384      ENDDO
385      IF ( ltmp_wapatch ) THEN
386         nldi = nldi_save   ;   nlei = nlei_save
387         nldj = nldj_save   ;   nlej = nlej_save
388      ENDIF
389      !
390    END SUBROUTINE cpl_snd
391
392
393   SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
394      !!---------------------------------------------------------------------
395      !!              ***  ROUTINE cpl_rcv  ***
396      !!
397      !! ** Purpose : - At each coupling time-step,this routine receives fields
398      !!      like stresses and fluxes from the coupler or remote application.
399      !!----------------------------------------------------------------------
400      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
401      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
402      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
403      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pmask     ! coupling mask
404      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
405      !!
406      INTEGER                                   ::   jc,jm     ! local loop index
407      LOGICAL                                   ::   llaction, llfisrt
408      !!--------------------------------------------------------------------
409      ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define
410      IF ( ltmp_wapatch ) THEN
411         nldi_save = nldi   ;   nlei_save = nlei
412         nldj_save = nldj   ;   nlej_save = nlej
413      ENDIF
414      !
415      ! receive local data from OASIS3 on every process
416      !
417      kinfo = OASIS_idle
418      !
419      DO jc = 1, srcv(kid)%nct
420         IF ( ltmp_wapatch ) THEN
421            IF( nimpp           ==      1 ) nldi = 1
422            IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
423            IF( njmpp           ==      1 ) nldj = 1
424            IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
425         ENDIF
426         llfisrt = .TRUE.
427
428         DO jm = 1, srcv(kid)%ncplmodel
429
430            IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
431
432               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo )         
433               
434               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
435                  &        kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
436               
437               IF ( ln_ctl )   WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
438               
439               IF ( llaction ) THEN
440                 
441                  kinfo = OASIS_Rcv
442                  IF( llfisrt ) THEN
443                     pdata(nldi:nlei,nldj:nlej,jc) =                                 exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
444                     llfisrt = .FALSE.
445                  ELSE
446                     pdata(nldi:nlei,nldj:nlej,jc) = pdata(nldi:nlei,nldj:nlej,jc) + exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
447                  ENDIF
448                 
449                  IF ( ln_ctl ) THEN       
450                     WRITE(numout,*) '****************'
451                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
452                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
453                     WRITE(numout,*) 'oasis_get:   kstep', kstep
454                     WRITE(numout,*) 'oasis_get:   info ', kinfo
455                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(nldi:nlei,nldj:nlej,jc))
456                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(nldi:nlei,nldj:nlej,jc))
457                     WRITE(numout,*) '     -     Sum value is ',    SUM(pdata(nldi:nlei,nldj:nlej,jc))
458                     WRITE(numout,*) '****************'
459                  ENDIF
460                 
461               ENDIF
462               
463            ENDIF
464           
465         ENDDO
466
467         IF ( ltmp_wapatch ) THEN
468            nldi = nldi_save   ;   nlei = nlei_save
469            nldj = nldj_save   ;   nlej = nlej_save
470         ENDIF
471         !--- Fill the overlap areas and extra hallows (mpp)
472         !--- check periodicity conditions (all cases)
473         IF( .not. llfisrt ) THEN
474            CALL lbc_lnk( 'cpl_oasis3', pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
475         ENDIF
476 
477      ENDDO
478      !
479   END SUBROUTINE cpl_rcv
480
481
482   INTEGER FUNCTION cpl_freq( cdfieldname ) 
483      !!---------------------------------------------------------------------
484      !!              ***  ROUTINE cpl_freq  ***
485      !!
486      !! ** Purpose : - send back the coupling frequency for a particular field
487      !!----------------------------------------------------------------------
488      CHARACTER(len = *), INTENT(in) ::   cdfieldname    ! field name as set in namcouple file
489      !!
490      INTEGER               :: id
491      INTEGER               :: info
492      INTEGER, DIMENSION(1) :: itmp
493      INTEGER               :: ji,jm     ! local loop index
494      INTEGER               :: mop
495      !!----------------------------------------------------------------------
496      cpl_freq = 0   ! defaut definition
497      id = -1        ! defaut definition
498      !
499      DO ji = 1, nsnd
500         IF (ssnd(ji)%laction ) THEN
501            DO jm = 1, ncplmodel
502               IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
503                  IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
504                     id = ssnd(ji)%nid(1,jm)
505                     mop = OASIS_Out
506                  ENDIF
507               ENDIF
508            ENDDO
509         ENDIF
510      ENDDO
511      DO ji = 1, nrcv
512         IF (srcv(ji)%laction ) THEN
513            DO jm = 1, ncplmodel
514               IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
515                  IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
516                     id = srcv(ji)%nid(1,jm)
517                     mop = OASIS_In
518                  ENDIF
519               ENDIF
520            ENDDO
521         ENDIF
522      ENDDO
523      !
524      IF( id /= -1 ) THEN
525#if ! defined key_oa3mct_v1v2
526         CALL oasis_get_freqs(id, mop, 1, itmp, info)
527#else
528         CALL oasis_get_freqs(id,      1, itmp, info)
529#endif
530         cpl_freq = itmp(1)
531      ENDIF
532      !
533   END FUNCTION cpl_freq
534
535
536   SUBROUTINE cpl_finalize
537      !!---------------------------------------------------------------------
538      !!              ***  ROUTINE cpl_finalize  ***
539      !!
540      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
541      !!      called explicitly before cpl_init it will also close
542      !!      MPI communication.
543      !!----------------------------------------------------------------------
544      !
545      DEALLOCATE( exfld )
546      IF (nstop == 0) THEN
547         CALL oasis_terminate( nerror )         
548      ELSE
549         CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
550      ENDIF       
551      !
552   END SUBROUTINE cpl_finalize
553
554#if ! defined key_oasis3
555
556   !!----------------------------------------------------------------------
557   !!   No OASIS Library          OASIS3 Dummy module...
558   !!----------------------------------------------------------------------
559
560   SUBROUTINE oasis_init_comp(k1,cd1,k2)
561      CHARACTER(*), INTENT(in   ) ::  cd1
562      INTEGER     , INTENT(  out) ::  k1,k2
563      k1 = -1 ; k2 = -1
564      WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
565   END SUBROUTINE oasis_init_comp
566
567   SUBROUTINE oasis_abort(k1,cd1,cd2)
568      INTEGER     , INTENT(in   ) ::  k1
569      CHARACTER(*), INTENT(in   ) ::  cd1,cd2
570      WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
571   END SUBROUTINE oasis_abort
572
573   SUBROUTINE oasis_get_localcomm(k1,k2)
574      INTEGER     , INTENT(  out) ::  k1,k2
575      k1 = -1 ; k2 = -1
576      WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
577   END SUBROUTINE oasis_get_localcomm
578
579   SUBROUTINE oasis_def_partition(k1,k2,k3,k4)
580      INTEGER     , INTENT(  out) ::  k1,k3
581      INTEGER     , INTENT(in   ) ::  k2(5)
582      INTEGER     , INTENT(in   ) ::  k4
583      k1 = k2(1) ; k3 = k2(5)+k4
584      WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
585   END SUBROUTINE oasis_def_partition
586
587   SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
588      CHARACTER(*), INTENT(in   ) ::  cd1
589      INTEGER     , INTENT(in   ) ::  k2,k3(2),k4,k5(2,2),k6
590      INTEGER     , INTENT(  out) ::  k1,k7
591      k1 = -1 ; k7 = -1
592      WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
593   END SUBROUTINE oasis_def_var
594
595   SUBROUTINE oasis_enddef(k1)
596      INTEGER     , INTENT(  out) ::  k1
597      k1 = -1
598      WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
599   END SUBROUTINE oasis_enddef
600 
601   SUBROUTINE oasis_put(k1,k2,p1,k3)
602      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::  p1
603      INTEGER                 , INTENT(in   ) ::  k1,k2
604      INTEGER                 , INTENT(  out) ::  k3
605      k3 = -1
606      WRITE(numout,*) 'oasis_put: Error you sould not be there...'
607   END SUBROUTINE oasis_put
608
609   SUBROUTINE oasis_get(k1,k2,p1,k3)
610      REAL(wp), DIMENSION(:,:), INTENT(  out) ::  p1
611      INTEGER                 , INTENT(in   ) ::  k1,k2
612      INTEGER                 , INTENT(  out) ::  k3
613      p1(1,1) = -1. ; k3 = -1
614      WRITE(numout,*) 'oasis_get: Error you sould not be there...'
615   END SUBROUTINE oasis_get
616
617   SUBROUTINE oasis_get_freqs(k1,k5,k2,k3,k4)
618      INTEGER              , INTENT(in   ) ::  k1,k2
619      INTEGER, DIMENSION(1), INTENT(  out) ::  k3
620      INTEGER              , INTENT(  out) ::  k4,k5
621      k3(1) = k1 ; k4 = k2 ; k5 = k2
622      WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
623   END SUBROUTINE oasis_get_freqs
624
625   SUBROUTINE oasis_terminate(k1)
626      INTEGER     , INTENT(  out) ::  k1
627      k1 = -1
628      WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
629   END SUBROUTINE oasis_terminate
630   
631#endif
632
633   !!=====================================================================
634END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.