New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd_do.F90 in NEMO/branches/UKMO/NEMO_4.0.4_FOAM_IAU_SI3_SIC/src/ICE – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.4_FOAM_IAU_SI3_SIC/src/ICE/icethd_do.F90 @ 15177

Last change on this file since 15177 was 15177, checked in by dcarneir, 14 months ago

Options for SIC IAU with SI3

File size: 23.6 KB
Line 
1MODULE icethd_do
2   !!======================================================================
3   !!                       ***  MODULE icethd_do   ***
4   !!   sea-ice: sea ice growth in the leads (open water) 
5   !!======================================================================
6   !! History :       !  2005-12  (M. Vancoppenolle) Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd_do        : ice growth in open water (=lateral accretion of ice)
14   !!   ice_thd_do_init   : initialization
15   !!----------------------------------------------------------------------
16   USE dom_oce        ! ocean space and time domain
17   USE phycst         ! physical constants
18   USE sbc_oce , ONLY : sss_m
19   USE sbc_ice , ONLY : utau_ice, vtau_ice
20   USE ice1D          ! sea-ice: thermodynamics variables
21   USE ice            ! sea-ice: variables
22   USE icetab         ! sea-ice: 2D <==> 1D
23   USE icectl         ! sea-ice: conservation
24   USE icethd_ent     ! sea-ice: thermodynamics, enthalpy
25   USE icevar         ! sea-ice: operations
26   USE icethd_sal     ! sea-ice: salinity profiles
27   !
28   USE in_out_manager ! I/O manager
29   USE lib_mpp        ! MPP library
30   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
31   USE lbclnk         ! lateral boundary conditions (or mpp links)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   ice_thd_do        ! called by ice_thd
37   PUBLIC   ice_thd_do_init   ! called by ice_stp
38
39   !                          !!** namelist (namthd_do) **
40   REAL(wp), PUBLIC :: rn_hinew     ! thickness for new ice formation (m)
41   LOGICAL  ::   ln_frazil     ! use of frazil ice collection as function of wind (T) or not (F)
42   REAL(wp) ::   rn_maxfraz    ! maximum portion of frazil ice collecting at the ice bottom
43   REAL(wp) ::   rn_vfraz      ! threshold drift speed for collection of bottom frazil ice
44   REAL(wp) ::   rn_Cfraz      ! squeezing coefficient for collection of bottom frazil ice
45
46   !!----------------------------------------------------------------------
47   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE ice_thd_do
54      !!-------------------------------------------------------------------
55      !!               ***   ROUTINE ice_thd_do  ***
56      !! 
57      !! ** Purpose : Computation of the evolution of the ice thickness and
58      !!              concentration as a function of the heat balance in the leads
59      !!       
60      !! ** Method  : Ice is formed in the open water when ocean looses heat
61      !!              (heat budget of open water is negative) following
62      !!
63      !!       (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ]
64      !!          where - h0 is the thickness of ice created in the lead
65      !!                - a is a minimum fraction for leads
66      !!                - F is a monotonic non-increasing function defined as:
67      !!                  F(X)=( 1 - X**exld )**(1.0/exld)
68      !!                - exld is the exponent closure rate (=2 default val.)
69      !!
70      !! ** Action : - Adjustment of snow and ice thicknesses and heat
71      !!                content in brine pockets
72      !!             - Updating ice internal temperature
73      !!             - Computation of variation of ice volume and mass
74      !!             - Computation of a_i after lateral accretion and
75      !!               update h_s_1d, h_i_1d     
76      !!------------------------------------------------------------------------
77      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
78      INTEGER  ::   iter             !   -       -
79      REAL(wp) ::   ztmelts, zfrazb, zweight, zde                               ! local scalars
80      REAL(wp) ::   zgamafr, zvfrx, zvgx, ztaux, ztwogp, zf                     !   -      -
81      REAL(wp) ::   ztenagm, zvfry, zvgy, ztauy, zvrel2, zfp, zsqcd , zhicrit   !   -      -
82      !
83      REAL(wp) ::   zQm          ! enthalpy exchanged with the ocean (J/m2, >0 towards ocean)
84      REAL(wp) ::   zEi          ! sea ice specific enthalpy (J/kg)
85      REAL(wp) ::   zEw          ! seawater specific enthalpy (J/kg)
86      REAL(wp) ::   zfmdt        ! mass flux x time step (kg/m2, >0 towards ocean)
87      !
88      REAL(wp) ::   zv_newfra
89      !
90      INTEGER , DIMENSION(jpij) ::   jcat        ! indexes of categories where new ice grows
91      REAL(wp), DIMENSION(jpij) ::   zswinew     ! switch for new ice or not
92      !
93      REAL(wp), DIMENSION(jpij) ::   zv_newice   ! volume of accreted ice
94      REAL(wp), DIMENSION(jpij) ::   za_newice   ! fractional area of accreted ice
95      REAL(wp), DIMENSION(jpij) ::   zh_newice   ! thickness of accreted ice
96      REAL(wp), DIMENSION(jpij) ::   ze_newice   ! heat content of accreted ice
97      REAL(wp), DIMENSION(jpij) ::   zs_newice   ! salinity of accreted ice
98      REAL(wp), DIMENSION(jpij) ::   zo_newice   ! age of accreted ice
99      REAL(wp), DIMENSION(jpij) ::   zdv_res     ! residual volume in case of excessive heat budget
100      REAL(wp), DIMENSION(jpij) ::   zda_res     ! residual area in case of excessive heat budget
101      REAL(wp), DIMENSION(jpij) ::   zv_frazb    ! accretion of frazil ice at the ice bottom
102      REAL(wp), DIMENSION(jpij) ::   zvrel_1d    ! relative ice / frazil velocity (1D vector)
103      !
104      REAL(wp), DIMENSION(jpij,jpl) ::   zv_b    ! old volume of ice in category jl
105      REAL(wp), DIMENSION(jpij,jpl) ::   za_b    ! old area of ice in category jl
106      !
107      REAL(wp), DIMENSION(jpij,nlay_i,jpl) ::   ze_i_2d !: 1-D version of e_i
108      !
109      REAL(wp), DIMENSION(jpi,jpj) ::   zvrel    ! relative ice / frazil velocity
110      !
111      REAL(wp) :: zcai = 1.4e-3_wp               ! ice-air drag (clem: should be dependent on coupling/forcing used)
112      !!-----------------------------------------------------------------------!
113
114      IF( ln_icediachk )   CALL ice_cons_hsm( 0, 'icethd_do', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft )
115      IF( ln_icediachk )   CALL ice_cons2D  ( 0, 'icethd_do',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft )
116
117      at_i(:,:) = SUM( a_i, dim=3 )
118      !------------------------------------------------------------------------------!
119      ! 1) Collection thickness of ice formed in leads and polynyas
120      !------------------------------------------------------------------------------!   
121      ! ht_i_new is the thickness of new ice formed in open water
122      ! ht_i_new can be either prescribed (ln_frazil=F) or computed (ln_frazil=T)
123      ! Frazil ice forms in open water, is transported by wind
124      ! accumulates at the edge of the consolidated ice edge
125      ! where it forms aggregates of a specific thickness called
126      ! collection thickness.
127
128      zvrel(:,:) = 0._wp
129
130      ! Default new ice thickness
131      WHERE( qlead(:,:) < 0._wp ) ! cooling
132         ht_i_new(:,:) = rn_hinew
133      ELSEWHERE
134         ht_i_new(:,:) = 0._wp
135      END WHERE
136
137      IF( ln_frazil ) THEN
138         !
139         ht_i_new(:,:) = 0._wp
140         !
141         ! Physical constants
142         zhicrit = 0.04                                          ! frazil ice thickness
143         ztwogp  = 2. * rau0 / ( grav * 0.3 * ( rau0 - rhoi ) )  ! reduced grav
144         zsqcd   = 1.0 / SQRT( 1.3 * zcai )                      ! 1/SQRT(airdensity*drag)
145         zgamafr = 0.03
146         !
147         DO jj = 2, jpjm1
148            DO ji = 2, jpim1
149               IF ( qlead(ji,jj) < 0._wp ) THEN ! cooling
150                  ! -- Wind stress -- !
151                  ztaux         = ( utau_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)   &
152                     &          +   utau_ice(ji  ,jj  ) * umask(ji  ,jj  ,1) ) * 0.5_wp
153                  ztauy         = ( vtau_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)   &
154                     &          +   vtau_ice(ji  ,jj  ) * vmask(ji  ,jj  ,1) ) * 0.5_wp
155                  ! Square root of wind stress
156                  ztenagm       =  SQRT( SQRT( ztaux * ztaux + ztauy * ztauy ) )
157
158                  ! -- Frazil ice velocity -- !
159                  rswitch = MAX( 0._wp, SIGN( 1._wp , ztenagm - epsi10 ) )
160                  zvfrx   = rswitch * zgamafr * zsqcd * ztaux / MAX( ztenagm, epsi10 )
161                  zvfry   = rswitch * zgamafr * zsqcd * ztauy / MAX( ztenagm, epsi10 )
162
163                  ! -- Pack ice velocity -- !
164                  zvgx    = ( u_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)  + u_ice(ji,jj) * umask(ji,jj,1) ) * 0.5_wp
165                  zvgy    = ( v_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)  + v_ice(ji,jj) * vmask(ji,jj,1) ) * 0.5_wp
166
167                  ! -- Relative frazil/pack ice velocity -- !
168                  rswitch      = MAX( 0._wp, SIGN( 1._wp , at_i(ji,jj) - epsi10 ) )
169                  zvrel2       = MAX(  ( zvfrx - zvgx ) * ( zvfrx - zvgx )   &
170                     &               + ( zvfry - zvgy ) * ( zvfry - zvgy ) , 0.15 * 0.15 ) * rswitch
171                  zvrel(ji,jj) = SQRT( zvrel2 )
172
173                  ! -- new ice thickness (iterative loop) -- !
174                  ht_i_new(ji,jj) = zhicrit +   ( zhicrit + 0.1 )    &
175                     &                   / ( ( zhicrit + 0.1 ) * ( zhicrit + 0.1 ) -  zhicrit * zhicrit ) * ztwogp * zvrel2
176
177                  iter = 1
178                  DO WHILE ( iter < 20 ) 
179                     zf  = ( ht_i_new(ji,jj) - zhicrit ) * ( ht_i_new(ji,jj) * ht_i_new(ji,jj) - zhicrit * zhicrit ) -   &
180                        &    ht_i_new(ji,jj) * zhicrit * ztwogp * zvrel2
181                     zfp = ( ht_i_new(ji,jj) - zhicrit ) * ( 3.0 * ht_i_new(ji,jj) + zhicrit ) - zhicrit * ztwogp * zvrel2
182
183                     ht_i_new(ji,jj) = ht_i_new(ji,jj) - zf / MAX( zfp, epsi20 )
184                     iter = iter + 1
185                  END DO
186                  !
187                  ! bound ht_i_new (though I don't see why it should be necessary)
188                  ht_i_new(ji,jj) = MAX( 0.01_wp, MIN( ht_i_new(ji,jj), hi_max(jpl) ) )
189                  !
190               ENDIF
191               !
192            END DO
193         END DO 
194         !
195         CALL lbc_lnk_multi( 'icethd_do', zvrel, 'T', 1., ht_i_new, 'T', 1.  )
196
197      ENDIF
198
199      !------------------------------------------------------------------------------!
200      ! 2) Compute thickness, salinity, enthalpy, age, area and volume of new ice
201      !------------------------------------------------------------------------------!
202      ! it occurs if cooling
203
204      ! Identify grid points where new ice forms
205      npti = 0   ;   nptidx(:) = 0
206      DO jj = 1, jpj
207         DO ji = 1, jpi
208            IF ( qlead(ji,jj) < 0._wp ) THEN
209               npti = npti + 1
210               nptidx( npti ) = (jj - 1) * jpi + ji
211            ENDIF
212         END DO
213      END DO
214
215      ! Move from 2-D to 1-D vectors
216      IF ( npti > 0 ) THEN
217
218         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti)      , at_i        )
219         CALL tab_3d_2d( npti, nptidx(1:npti), a_i_2d (1:npti,1:jpl), a_i (:,:,:) )
220         CALL tab_3d_2d( npti, nptidx(1:npti), v_i_2d (1:npti,1:jpl), v_i (:,:,:) )
221         CALL tab_3d_2d( npti, nptidx(1:npti), sv_i_2d(1:npti,1:jpl), sv_i(:,:,:) )
222         DO jl = 1, jpl
223            DO jk = 1, nlay_i
224               CALL tab_2d_1d( npti, nptidx(1:npti), ze_i_2d(1:npti,jk,jl), e_i(:,:,jk,jl) )
225            END DO
226         END DO
227         CALL tab_2d_1d( npti, nptidx(1:npti), qlead_1d  (1:npti) , qlead      )
228         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d   (1:npti) , t_bo       )
229         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_opw_1d(1:npti) , sfx_opw    )
230         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_opw_1d(1:npti) , wfx_opw    )
231         CALL tab_2d_1d( npti, nptidx(1:npti), zh_newice (1:npti) , ht_i_new   )
232         CALL tab_2d_1d( npti, nptidx(1:npti), zvrel_1d  (1:npti) , zvrel      )
233
234         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d(1:npti) , hfx_thd    )
235         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d(1:npti) , hfx_opw    )
236         CALL tab_2d_1d( npti, nptidx(1:npti), rn_amax_1d(1:npti) , rn_amax_2d )
237         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d    (1:npti) , sss_m      )
238
239         ! Convert units for ice internal energy
240         DO jl = 1, jpl
241            DO jk = 1, nlay_i               
242               WHERE( v_i_2d(1:npti,jl) > 0._wp )
243                  ze_i_2d(1:npti,jk,jl) = ze_i_2d(1:npti,jk,jl) / v_i_2d(1:npti,jl) * REAL( nlay_i )
244               ELSEWHERE
245                  ze_i_2d(1:npti,jk,jl) = 0._wp
246               END WHERE
247            END DO
248         END DO
249
250         ! Keep old ice areas and volume in memory
251         zv_b(1:npti,:) = v_i_2d(1:npti,:) 
252         za_b(1:npti,:) = a_i_2d(1:npti,:)
253
254         ! --- Salinity of new ice --- !
255         SELECT CASE ( nn_icesal )
256         CASE ( 1 )                    ! Sice = constant
257            zs_newice(1:npti) = rn_icesal
258         CASE ( 2 )                    ! Sice = F(z,t) [Vancoppenolle et al (2005)]
259            DO ji = 1, npti
260               zs_newice(ji) = MIN(  4.606 + 0.91 / zh_newice(ji) , rn_simax , 0.5 * sss_1d(ji) )
261            END DO
262         CASE ( 3 )                    ! Sice = F(z) [multiyear ice]
263            zs_newice(1:npti) =   2.3
264         END SELECT
265
266         ! --- Heat content of new ice --- !
267         ! We assume that new ice is formed at the seawater freezing point
268         DO ji = 1, npti
269            ztmelts       = - rTmlt * zs_newice(ji)                  ! Melting point (C)
270            ze_newice(ji) =   rhoi * (  rcpi  * ( ztmelts - ( t_bo_1d(ji) - rt0 ) )                     &
271               &                      + rLfus * ( 1.0 - ztmelts / MIN( t_bo_1d(ji) - rt0, -epsi10 ) )   &
272               &                      - rcp   *         ztmelts )
273         END DO
274
275         ! --- Age of new ice --- !
276         zo_newice(1:npti) = 0._wp
277
278         ! --- Volume of new ice --- !
279         DO ji = 1, npti
280
281            zEi           = - ze_newice(ji) * r1_rhoi              ! specific enthalpy of forming ice [J/kg]
282
283            zEw           = rcp * ( t_bo_1d(ji) - rt0 )            ! specific enthalpy of seawater at t_bo_1d [J/kg]
284                                                                   ! clem: we suppose we are already at the freezing point (condition qlead<0 is satisfyied)
285                                                                   
286            zdE           = zEi - zEw                              ! specific enthalpy difference [J/kg]
287                                             
288            zfmdt         = - qlead_1d(ji) / zdE                   ! Fm.dt [kg/m2] (<0)
289                                                                   ! clem: we use qlead instead of zqld (icethd) because we suppose we are at the freezing point   
290            zv_newice(ji) = - zfmdt * r1_rhoi
291
292            zQm           = zfmdt * zEw                            ! heat to the ocean >0 associated with mass flux 
293
294            ! Contribution to heat flux to the ocean [W.m-2], >0 
295            hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * zEw * r1_rdtice
296            ! Total heat flux used in this process [W.m-2] 
297            hfx_opw_1d(ji) = hfx_opw_1d(ji) - zfmdt * zdE * r1_rdtice
298            ! mass flux
299            wfx_opw_1d(ji) = wfx_opw_1d(ji) - zv_newice(ji) * rhoi * r1_rdtice
300            ! salt flux
301            sfx_opw_1d(ji) = sfx_opw_1d(ji) - zv_newice(ji) * rhoi * zs_newice(ji) * r1_rdtice
302         END DO
303         
304         zv_frazb(1:npti) = 0._wp
305         IF( ln_frazil ) THEN
306            ! A fraction zfrazb of frazil ice is accreted at the ice bottom
307            DO ji = 1, npti
308               rswitch       = 1._wp - MAX( 0._wp, SIGN( 1._wp , - at_i_1d(ji) ) )
309               zfrazb        = rswitch * ( TANH( rn_Cfraz * ( zvrel_1d(ji) - rn_vfraz ) ) + 1.0 ) * 0.5 * rn_maxfraz
310               zv_frazb(ji)  =         zfrazb   * zv_newice(ji)
311               zv_newice(ji) = ( 1.0 - zfrazb ) * zv_newice(ji)
312            END DO
313         END IF
314         
315         ! --- Area of new ice --- !
316         DO ji = 1, npti
317            za_newice(ji) = zv_newice(ji) / zh_newice(ji)
318         END DO
319
320         !------------------------------------------------------------------------------!
321         ! 3) Redistribute new ice area and volume into ice categories                  !
322         !------------------------------------------------------------------------------!
323
324         ! --- lateral ice growth --- !
325         ! If lateral ice growth gives an ice concentration > amax, then
326         ! we keep the excessive volume in memory and attribute it later to bottom accretion
327         DO ji = 1, npti
328            IF ( za_newice(ji) >  MAX( 0._wp, rn_amax_1d(ji) - at_i_1d(ji) ) ) THEN ! max is for roundoff error
329               zda_res(ji)   = za_newice(ji) - MAX( 0._wp, rn_amax_1d(ji) - at_i_1d(ji) )
330               zdv_res(ji)   = zda_res  (ji) * zh_newice(ji) 
331               za_newice(ji) = MAX( 0._wp, za_newice(ji) - zda_res  (ji) )
332               zv_newice(ji) = MAX( 0._wp, zv_newice(ji) - zdv_res  (ji) )
333            ELSE
334               zda_res(ji) = 0._wp
335               zdv_res(ji) = 0._wp
336            ENDIF
337         END DO
338
339         ! find which category to fill
340         DO jl = 1, jpl
341            DO ji = 1, npti
342               IF( zh_newice(ji) > hi_max(jl-1) .AND. zh_newice(ji) <= hi_max(jl) ) THEN
343                  a_i_2d(ji,jl) = a_i_2d(ji,jl) + za_newice(ji)
344                  v_i_2d(ji,jl) = v_i_2d(ji,jl) + zv_newice(ji)
345                  jcat(ji) = jl
346               ENDIF
347            END DO
348         END DO
349         at_i_1d(1:npti) = SUM( a_i_2d(1:npti,:), dim=2 )
350
351         ! Heat content
352         DO ji = 1, npti
353            jl = jcat(ji)                                                    ! categroy in which new ice is put
354            zswinew  (ji) = MAX( 0._wp , SIGN( 1._wp , - za_b(ji,jl) ) )   ! 0 if old ice
355         END DO
356
357         DO jk = 1, nlay_i
358            DO ji = 1, npti
359               jl = jcat(ji)
360               rswitch = MAX( 0._wp, SIGN( 1._wp , v_i_2d(ji,jl) - epsi20 ) )
361               ze_i_2d(ji,jk,jl) = zswinew(ji)   *   ze_newice(ji) +                                                    &
362                  &        ( 1.0 - zswinew(ji) ) * ( ze_newice(ji) * zv_newice(ji) + ze_i_2d(ji,jk,jl) * zv_b(ji,jl) )  &
363                  &        * rswitch / MAX( v_i_2d(ji,jl), epsi20 )
364            END DO
365         END DO
366
367         ! --- bottom ice growth + ice enthalpy remapping --- !
368         DO jl = 1, jpl
369
370            ! for remapping
371            h_i_old (1:npti,0:nlay_i+1) = 0._wp
372            eh_i_old(1:npti,0:nlay_i+1) = 0._wp
373            DO jk = 1, nlay_i
374               DO ji = 1, npti
375                  h_i_old (ji,jk) = v_i_2d(ji,jl) * r1_nlay_i
376                  eh_i_old(ji,jk) = ze_i_2d(ji,jk,jl) * h_i_old(ji,jk)
377               END DO
378            END DO
379
380            ! new volumes including lateral/bottom accretion + residual
381            DO ji = 1, npti
382               rswitch        = MAX( 0._wp, SIGN( 1._wp , at_i_1d(ji) - epsi20 ) )
383               zv_newfra     = rswitch * ( zdv_res(ji) + zv_frazb(ji) ) * a_i_2d(ji,jl) / MAX( at_i_1d(ji) , epsi20 )
384               a_i_2d(ji,jl) = rswitch * a_i_2d(ji,jl)               
385               v_i_2d(ji,jl) = v_i_2d(ji,jl) + zv_newfra
386               ! for remapping
387               h_i_old (ji,nlay_i+1) = zv_newfra
388               eh_i_old(ji,nlay_i+1) = ze_newice(ji) * zv_newfra
389            END DO
390            ! --- Ice enthalpy remapping --- !
391            CALL ice_thd_ent( ze_i_2d(1:npti,:,jl) ) 
392         END DO
393
394         ! --- Update salinity --- !
395         DO jl = 1, jpl
396            DO ji = 1, npti
397               sv_i_2d(ji,jl) = sv_i_2d(ji,jl) + zs_newice(ji) * ( v_i_2d(ji,jl) - zv_b(ji,jl) )
398            END DO
399         END DO
400
401         ! Change units for e_i
402         DO jl = 1, jpl
403            DO jk = 1, nlay_i
404               ze_i_2d(1:npti,jk,jl) = ze_i_2d(1:npti,jk,jl) * v_i_2d(1:npti,jl) * r1_nlay_i 
405            END DO
406         END DO
407
408         ! Move 2D vectors to 1D vectors
409         CALL tab_2d_3d( npti, nptidx(1:npti), a_i_2d (1:npti,1:jpl), a_i (:,:,:) )
410         CALL tab_2d_3d( npti, nptidx(1:npti), v_i_2d (1:npti,1:jpl), v_i (:,:,:) )
411         CALL tab_2d_3d( npti, nptidx(1:npti), sv_i_2d(1:npti,1:jpl), sv_i(:,:,:) )
412          DO jl = 1, jpl
413            DO jk = 1, nlay_i
414               CALL tab_1d_2d( npti, nptidx(1:npti), ze_i_2d(1:npti,jk,jl), e_i(:,:,jk,jl) )
415            END DO
416         END DO
417         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_opw_1d(1:npti), sfx_opw )
418         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_opw_1d(1:npti), wfx_opw )
419         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d(1:npti), hfx_thd )
420         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d(1:npti), hfx_opw )
421         !
422      ENDIF ! npti > 0
423      !
424      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd_do', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
425      IF( ln_icediachk )   CALL ice_cons2D  (1, 'icethd_do',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft)
426      !
427   END SUBROUTINE ice_thd_do
428
429
430   SUBROUTINE ice_thd_do_init
431      !!-----------------------------------------------------------------------
432      !!                   ***  ROUTINE ice_thd_do_init ***
433      !!                 
434      !! ** Purpose :   Physical constants and parameters associated with
435      !!                ice growth in the leads
436      !!
437      !! ** Method  :   Read the namthd_do namelist and check the parameters
438      !!                called at the first timestep (nit000)
439      !!
440      !! ** input   :   Namelist namthd_do
441      !!-------------------------------------------------------------------
442      INTEGER  ::   ios   ! Local integer
443      !!
444      NAMELIST/namthd_do/ rn_hinew, ln_frazil, rn_maxfraz, rn_vfraz, rn_Cfraz
445      !!-------------------------------------------------------------------
446      !
447      REWIND( numnam_ice_ref )              ! Namelist namthd_do in reference namelist : Ice thermodynamics
448      READ  ( numnam_ice_ref, namthd_do, IOSTAT = ios, ERR = 901)
449901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd_do in reference namelist' )
450      REWIND( numnam_ice_cfg )              ! Namelist namthd_do in configuration namelist : Ice thermodynamics
451      READ  ( numnam_ice_cfg, namthd_do, IOSTAT = ios, ERR = 902 )
452902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd_do in configuration namelist' )
453      IF(lwm) WRITE( numoni, namthd_do )
454      !
455      IF(lwp) THEN                          ! control print
456         WRITE(numout,*)
457         WRITE(numout,*) 'ice_thd_do_init: Ice growth in open water'
458         WRITE(numout,*) '~~~~~~~~~~~~~~~'
459         WRITE(numout,*) '   Namelist namthd_do:'
460         WRITE(numout,*) '      ice thickness for lateral accretion                       rn_hinew   = ', rn_hinew
461         WRITE(numout,*) '      Frazil ice thickness as a function of wind or not         ln_frazil  = ', ln_frazil
462         WRITE(numout,*) '      Maximum proportion of frazil ice collecting at bottom     rn_maxfraz = ', rn_maxfraz
463         WRITE(numout,*) '      Threshold relative drift speed for collection of frazil   rn_vfraz   = ', rn_vfraz
464         WRITE(numout,*) '      Squeezing coefficient for collection of frazil            rn_Cfraz   = ', rn_Cfraz
465      ENDIF
466      !
467      IF ( rn_hinew < rn_himin )   CALL ctl_stop( 'ice_thd_do_init : rn_hinew should be >= rn_himin' )
468      !
469   END SUBROUTINE ice_thd_do_init
470   
471#else
472   !!----------------------------------------------------------------------
473   !!   Default option                                NO SI3 sea-ice model
474   !!----------------------------------------------------------------------
475#endif
476
477   !!======================================================================
478END MODULE icethd_do
Note: See TracBrowser for help on using the repository browser.