New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in NEMO/branches/UKMO/NEMO_4.0.4_GO8_package/src/OCE/SBC – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.4_GO8_package/src/OCE/SBC/sbcrnf.F90 @ 15525

Last change on this file since 15525 was 15525, checked in by cguiavarch, 8 months ago

Bug fix: when using ln_rnf_temp temperature of runoff > 0 (runoff are considered as freshwater and should not be below 0)

File size: 30.8 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf       : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init  : runoffs initialisation
16   !!   rnf_mouth     : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean space and time domain
19   USE phycst         ! physical constants
20   USE sbcisf         ! surface boundary condition: ice-shelf
21   USE sbc_oce        ! surface boundary condition variables
22   USE eosbn2         ! Equation Of State
23   USE closea, ONLY: l_clo_rnf, clo_rnf ! closed seas
24   !
25   USE in_out_manager ! I/O manager
26   USE fldread        ! read input field at current time step
27   USE iom            ! I/O module
28   USE lib_mpp        ! MPP library
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   sbc_rnf       ! called in sbcmod module
34   PUBLIC   sbc_rnf_div   ! called in divhor module
35   PUBLIC   sbc_rnf_alloc ! called in sbcmod module
36   PUBLIC   sbc_rnf_init  ! called in sbcmod module
37   
38   !                                                !!* namsbc_rnf namelist *
39   CHARACTER(len=100)         ::   cn_dir            !: Root directory for location of rnf files
40   LOGICAL           , PUBLIC ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
41   LOGICAL                    ::      ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
42   REAL(wp)                   ::      rn_rnf_max        !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
43   REAL(wp)                   ::      rn_dep_max        !: depth over which runoffs is spread       (ln_rnf_depth_ini =T)
44   INTEGER                    ::      nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
45   LOGICAL                    ::   ln_rnf_icb        !: iceberg flux is specified in a file
46   LOGICAL                    ::   ln_rnf_tem        !: temperature river runoffs attribute specified in a file
47   LOGICAL           , PUBLIC ::   ln_rnf_sal        !: salinity    river runoffs attribute specified in a file
48   TYPE(FLD_N)       , PUBLIC ::   sn_rnf            !: information about the runoff file to be read
49   TYPE(FLD_N)                ::   sn_cnf            !: information about the runoff mouth file to be read
50   TYPE(FLD_N)                ::   sn_i_rnf          !: information about the iceberg flux file to be read
51   TYPE(FLD_N)                ::   sn_s_rnf          !: information about the salinities of runoff file to be read
52   TYPE(FLD_N)                ::   sn_t_rnf          !: information about the temperatures of runoff file to be read
53   TYPE(FLD_N)                ::   sn_dep_rnf        !: information about the depth which river inflow affects
54   LOGICAL           , PUBLIC ::   ln_rnf_mouth      !: specific treatment in mouths vicinity
55   REAL(wp)                   ::   rn_hrnf           !: runoffs, depth over which enhanced vertical mixing is used
56   REAL(wp)          , PUBLIC ::   rn_avt_rnf        !: runoffs, value of the additional vertical mixing coef. [m2/s]
57   REAL(wp)          , PUBLIC ::   rn_rfact          !: multiplicative factor for runoff
58
59   LOGICAL , PUBLIC ::   l_rnfcpl = .false.   !: runoffs recieved from oasis
60   INTEGER , PUBLIC ::   nkrnf = 0            !: nb of levels over which Kz is increased at river mouths
61   
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
64   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
65   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
66   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
67
68   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
69   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_i_rnf     ! structure: iceberg flux (file information, fields read)
70   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
71   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
72 
73   !!----------------------------------------------------------------------
74   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
75   !! $Id$
76   !! Software governed by the CeCILL license (see ./LICENSE)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   INTEGER FUNCTION sbc_rnf_alloc()
81      !!----------------------------------------------------------------------
82      !!                ***  ROUTINE sbc_rnf_alloc  ***
83      !!----------------------------------------------------------------------
84      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
85         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
86         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
87         !
88      CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
89      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
90   END FUNCTION sbc_rnf_alloc
91
92
93   SUBROUTINE sbc_rnf( kt )
94      !!----------------------------------------------------------------------
95      !!                  ***  ROUTINE sbc_rnf  ***
96      !!
97      !! ** Purpose :   Introduce a climatological run off forcing
98      !!
99      !! ** Method  :   Set each river mouth with a monthly climatology
100      !!                provided from different data.
101      !!                CAUTION : upward water flux, runoff forced to be < 0
102      !!
103      !! ** Action  :   runoff updated runoff field at time-step kt
104      !!----------------------------------------------------------------------
105      INTEGER, INTENT(in) ::   kt          ! ocean time step
106      !
107      INTEGER  ::   ji, jj    ! dummy loop indices
108      INTEGER  ::   z_err = 0 ! dummy integer for error handling
109      !!----------------------------------------------------------------------
110      REAL(wp), DIMENSION(jpi,jpj) ::   ztfrz   ! freezing point used for temperature correction
111      !
112      !
113      !                                            !-------------------!
114      !                                            !   Update runoff   !
115      !                                            !-------------------!
116      !
117      !
118      IF( .NOT. l_rnfcpl )  THEN
119                            CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt ( runoffs + iceberg )
120         IF( ln_rnf_icb )   CALL fld_read ( kt, nn_fsbc, sf_i_rnf )    ! idem for iceberg flux if required
121      ENDIF
122      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
123      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
124      !
125      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
126         !
127         IF( .NOT. l_rnfcpl ) THEN
128             rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
129             IF( ln_rnf_icb ) THEN
130                fwficb(:,:) = rn_rfact * ( sf_i_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)  ! updated runoff value at time step kt
131                CALL iom_put( 'iceberg_cea'  , fwficb(:,:)  )         ! output iceberg flux
132                CALL iom_put( 'hflx_icb_cea' , fwficb(:,:) * rLfus )   ! output Heat Flux into Sea Water due to Iceberg Thermodynamics -->
133             ENDIF
134         ENDIF
135         !
136         !                                                           ! set temperature & salinity content of runoffs
137         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
138            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
139            CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
140            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
141               rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rau0
142            END WHERE
143            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp )
144            ! where fwf comes from melting of ice shelves or iceberg
145            rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * rLfusisf * r1_rau0_rcp
146            END WHERE
147         ELSE                                                        ! use SST as runoffs temperature
148            !CEOD River is fresh water so must at least be 0 unless we consider ice
149            rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rau0
150         ENDIF
151         !                                                           ! use runoffs salinity data
152         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
153         !                                                           ! else use S=0 for runoffs (done one for all in the init)
154                                         CALL iom_put( 'runoffs'     , rnf(:,:)                         )   ! output runoff mass flux
155         IF( iom_use('hflx_rnf_cea') )   CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rau0 * rcp )   ! output runoff sensible heat (W/m2)
156      ENDIF
157      !
158      !                                                ! ---------------------------------------- !
159      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
160         !                                             ! ---------------------------------------- !
161         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
162            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
163            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file', lrxios
164            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b, ldxios = lrxios )     ! before runoff
165            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem), ldxios = lrxios )   ! before heat content of runoff
166            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal), ldxios = lrxios )   ! before salinity content of runoff
167         ELSE                                                   !* no restart: set from nit000 values
168            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
169            rnf_b    (:,:  ) = rnf    (:,:  )
170            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
171         ENDIF
172      ENDIF
173      !                                                ! ---------------------------------------- !
174      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
175         !                                             ! ---------------------------------------- !
176         IF(lwp) WRITE(numout,*)
177         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
178            &                    'at it= ', kt,' date= ', ndastp
179         IF(lwp) WRITE(numout,*) '~~~~'
180         IF( lwxios ) CALL iom_swap(      cwxios_context          )
181         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf, ldxios = lwxios )
182         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem), ldxios = lwxios )
183         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal), ldxios = lwxios )
184         IF( lwxios ) CALL iom_swap(      cxios_context          )
185      ENDIF
186      !
187   END SUBROUTINE sbc_rnf
188
189
190   SUBROUTINE sbc_rnf_div( phdivn )
191      !!----------------------------------------------------------------------
192      !!                  ***  ROUTINE sbc_rnf  ***
193      !!
194      !! ** Purpose :   update the horizontal divergence with the runoff inflow
195      !!
196      !! ** Method  :
197      !!                CAUTION : rnf is positive (inflow) decreasing the
198      !!                          divergence and expressed in m/s
199      !!
200      !! ** Action  :   phdivn   decreased by the runoff inflow
201      !!----------------------------------------------------------------------
202      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
203      !!
204      INTEGER  ::   ji, jj, jk   ! dummy loop indices
205      REAL(wp) ::   zfact     ! local scalar
206      !!----------------------------------------------------------------------
207      !
208      zfact = 0.5_wp
209      !
210      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
211         IF( ln_linssh ) THEN    !* constant volume case : just apply the runoff input flow
212            DO jj = 1, jpj
213               DO ji = 1, jpi
214                  DO jk = 1, nk_rnf(ji,jj)
215                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
216                  END DO
217               END DO
218            END DO
219         ELSE                    !* variable volume case
220            DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
221               DO ji = 1, jpi
222                  h_rnf(ji,jj) = 0._wp
223                  DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
224                     h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)   ! to the bottom of the relevant grid box
225                  END DO
226                  !                          ! apply the runoff input flow
227                  DO jk = 1, nk_rnf(ji,jj)
228                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
229                  END DO
230               END DO
231            END DO
232         ENDIF
233      ELSE                       !==   runoff put only at the surface   ==!
234         h_rnf (:,:)   = e3t_n (:,:,1)        ! update h_rnf to be depth of top box
235         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / e3t_n(:,:,1)
236      ENDIF
237      !
238   END SUBROUTINE sbc_rnf_div
239
240
241   SUBROUTINE sbc_rnf_init
242      !!----------------------------------------------------------------------
243      !!                  ***  ROUTINE sbc_rnf_init  ***
244      !!
245      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
246      !!
247      !! ** Method  : - read the runoff namsbc_rnf namelist
248      !!
249      !! ** Action  : - read parameters
250      !!----------------------------------------------------------------------
251      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
252      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
253      INTEGER           ::   ierror, inum  ! temporary integer
254      INTEGER           ::   ios           ! Local integer output status for namelist read
255      INTEGER           ::   nbrec         ! temporary integer
256      REAL(wp)          ::   zacoef 
257      REAL(wp), DIMENSION(jpi,jpj,2) :: zrnfcl   
258      !!
259      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, ln_rnf_icb,   &
260         &                 sn_rnf, sn_cnf    , sn_i_rnf, sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
261         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
262         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
263      !!----------------------------------------------------------------------
264      !
265      !                                         !==  allocate runoff arrays
266      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
267      !
268      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
269         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
270         nkrnf         = 0
271         rnf     (:,:) = 0.0_wp
272         rnf_b   (:,:) = 0.0_wp
273         rnfmsk  (:,:) = 0.0_wp
274         rnfmsk_z(:)   = 0.0_wp
275         RETURN
276      ENDIF
277      !
278      !                                   ! ============
279      !                                   !   Namelist
280      !                                   ! ============
281      !
282      REWIND( numnam_ref )
283      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
284901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist' )
285
286      REWIND( numnam_cfg )
287      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
288902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist' )
289      IF(lwm) WRITE ( numond, namsbc_rnf )
290      !
291      !                                         ! Control print
292      IF(lwp) THEN
293         WRITE(numout,*)
294         WRITE(numout,*) 'sbc_rnf_init : runoff '
295         WRITE(numout,*) '~~~~~~~~~~~~ '
296         WRITE(numout,*) '   Namelist namsbc_rnf'
297         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
298         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
299         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
300         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
301      ENDIF
302      !                                   ! ==================
303      !                                   !   Type of runoff
304      !                                   ! ==================
305      !
306      IF( .NOT. l_rnfcpl ) THEN                   
307         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
308         IF(lwp) WRITE(numout,*)
309         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs inflow read in a file'
310         IF( ierror > 0 ) THEN
311            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' )   ;   RETURN
312         ENDIF
313         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
314         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
315         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
316         !
317         IF( ln_rnf_icb ) THEN                      ! Create (if required) sf_i_rnf structure
318            IF(lwp) WRITE(numout,*)
319            IF(lwp) WRITE(numout,*) '          iceberg flux read in a file'
320            ALLOCATE( sf_i_rnf(1), STAT=ierror  )
321            IF( ierror > 0 ) THEN
322               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_i_rnf structure' )   ;   RETURN
323            ENDIF
324            ALLOCATE( sf_i_rnf(1)%fnow(jpi,jpj,1)   )
325            IF( sn_i_rnf%ln_tint ) ALLOCATE( sf_i_rnf(1)%fdta(jpi,jpj,1,2) )
326            CALL fld_fill (sf_i_rnf, (/ sn_i_rnf /), cn_dir, 'sbc_rnf_init', 'read iceberg flux data', 'namsbc_rnf' )
327         ELSE
328            fwficb(:,:) = 0._wp
329         ENDIF
330
331      ENDIF
332      !
333      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
334         IF(lwp) WRITE(numout,*)
335         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs temperatures read in a file'
336         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
337         IF( ierror > 0 ) THEN
338            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
339         ENDIF
340         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
341         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
342         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
343      ENDIF
344      !
345      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
346         IF(lwp) WRITE(numout,*)
347         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs salinities read in a file'
348         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
349         IF( ierror > 0 ) THEN
350            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
351         ENDIF
352         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
353         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
354         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
355      ENDIF
356      !
357      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
358         IF(lwp) WRITE(numout,*)
359         IF(lwp) WRITE(numout,*) '   ==>>>   runoffs depth read in a file'
360         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
361         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
362            IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
363         ENDIF
364         CALL iom_open ( rn_dep_file, inum )                           ! open file
365         CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
366         CALL iom_close( inum )                                        ! close file
367         !
368         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
369         DO jj = 1, jpj
370            DO ji = 1, jpi
371               IF( h_rnf(ji,jj) > 0._wp ) THEN
372                  jk = 2
373                  DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
374                  END DO
375                  nk_rnf(ji,jj) = jk
376               ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
377               ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
378               ELSE
379                  CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
380                  WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
381               ENDIF
382            END DO
383         END DO
384         DO jj = 1, jpj                                ! set the associated depth
385            DO ji = 1, jpi
386               h_rnf(ji,jj) = 0._wp
387               DO jk = 1, nk_rnf(ji,jj)
388                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)
389               END DO
390            END DO
391         END DO
392         !
393      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
394         !
395         IF(lwp) WRITE(numout,*)
396         IF(lwp) WRITE(numout,*) '   ==>>>   depth of runoff computed once from max value of runoff'
397         IF(lwp) WRITE(numout,*) '        max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
398         IF(lwp) WRITE(numout,*) '        depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
399         IF(lwp) WRITE(numout,*) '        create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
400
401         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
402         nbrec = iom_getszuld( inum )
403         zrnfcl(:,:,1) = 0._wp                                                          ! init the max to 0. in 1
404         DO jm = 1, nbrec
405            CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm )   ! read the value in 2
406            zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 )                              ! store the maximum value in time in 1
407         END DO
408         CALL iom_close( inum )
409         !
410         h_rnf(:,:) = 1.
411         !
412         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
413         !
414         WHERE( zrnfcl(:,:,1) > 0._wp )  h_rnf(:,:) = zacoef * zrnfcl(:,:,1)   ! compute depth for all runoffs
415         !
416         DO jj = 1, jpj                     ! take in account min depth of ocean rn_hmin
417            DO ji = 1, jpi
418               IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
419                  jk = mbkt(ji,jj)
420                  h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
421               ENDIF
422            END DO
423         END DO
424         !
425         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
426         DO jj = 1, jpj
427            DO ji = 1, jpi
428               IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
429                  jk = 2
430                  DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
431                  END DO
432                  nk_rnf(ji,jj) = jk
433               ELSE
434                  nk_rnf(ji,jj) = 1
435               ENDIF
436            END DO
437         END DO
438         !
439         DO jj = 1, jpj                                ! set the associated depth
440            DO ji = 1, jpi
441               h_rnf(ji,jj) = 0._wp
442               DO jk = 1, nk_rnf(ji,jj)
443                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)
444               END DO
445            END DO
446         END DO
447         !
448         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
449            IF(lwp) WRITE(numout,*) '   ==>>>   create runoff depht file'
450            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
451            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
452            CALL iom_close ( inum )
453         ENDIF
454      ELSE                                       ! runoffs applied at the surface
455         nk_rnf(:,:) = 1
456         h_rnf (:,:) = e3t_n(:,:,1)
457      ENDIF
458      !
459      rnf(:,:) =  0._wp                         ! runoff initialisation
460      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
461      !
462      !                                   ! ========================
463      !                                   !   River mouth vicinity
464      !                                   ! ========================
465      !
466      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
467         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
468         !                                      !    - set to zero SSS damping (ln_ssr=T)
469         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
470         !
471         IF( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
472            &                                              'be spread through depth by ln_rnf_depth'               )
473         !
474         nkrnf = 0                                  ! Number of level over which Kz increase
475         IF( rn_hrnf > 0._wp ) THEN
476            nkrnf = 2
477            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
478            END DO
479            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
480         ENDIF
481         IF(lwp) WRITE(numout,*)
482         IF(lwp) WRITE(numout,*) '   ==>>>   Specific treatment used in vicinity of river mouths :'
483         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
484         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
485         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
486         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
487         !
488         CALL rnf_mouth                             ! set river mouth mask
489         !
490      ELSE                                      ! No treatment at river mouths
491         IF(lwp) WRITE(numout,*)
492         IF(lwp) WRITE(numout,*) '   ==>>>   No specific treatment at river mouths'
493         rnfmsk  (:,:) = 0._wp
494         rnfmsk_z(:)   = 0._wp
495         nkrnf = 0
496      ENDIF
497      !
498      IF( lwxios ) THEN
499         CALL iom_set_rstw_var_active('rnf_b')
500         CALL iom_set_rstw_var_active('rnf_hc_b')
501         CALL iom_set_rstw_var_active('rnf_sc_b')
502      ENDIF
503
504   END SUBROUTINE sbc_rnf_init
505
506
507   SUBROUTINE rnf_mouth
508      !!----------------------------------------------------------------------
509      !!                  ***  ROUTINE rnf_mouth  ***
510      !!
511      !! ** Purpose :   define the river mouths mask
512      !!
513      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
514      !!                climatological file. Defined a given vertical structure.
515      !!                CAUTION, the vertical structure is hard coded on the
516      !!                first 5 levels.
517      !!                This fields can be used to:
518      !!                 - set an upstream advection scheme
519      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
520      !!                 - increase vertical on the top nn_krnf vertical levels
521      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
522      !!                 - set to zero SSS restoring flux at river mouth grid points
523      !!
524      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
525      !!                rnfmsk_z vertical structure
526      !!----------------------------------------------------------------------
527      INTEGER            ::   inum        ! temporary integers
528      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
529      !!----------------------------------------------------------------------
530      !
531      IF(lwp) WRITE(numout,*)
532      IF(lwp) WRITE(numout,*) '   rnf_mouth : river mouth mask'
533      IF(lwp) WRITE(numout,*) '   ~~~~~~~~~ '
534      !
535      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
536      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
537         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
538      ENDIF
539      !
540      ! horizontal mask (read in NetCDF file)
541      CALL iom_open ( cl_rnfile, inum )                           ! open file
542      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
543      CALL iom_close( inum )                                      ! close file
544      !
545      IF( l_clo_rnf )   CALL clo_rnf( rnfmsk )   ! closed sea inflow set as river mouth
546      !
547      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
548      rnfmsk_z(1)   = 1.0
549      rnfmsk_z(2)   = 1.0                                         ! **********
550      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
551      rnfmsk_z(4)   = 0.25                                        ! **********
552      rnfmsk_z(5)   = 0.125
553      !
554   END SUBROUTINE rnf_mouth
555
556   !!======================================================================
557END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.