New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in NEMO/branches/UKMO/NEMO_4.0.4_hpge_ovf/src/OCE/DOM – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.4_hpge_ovf/src/OCE/DOM/dtatsd.F90 @ 15366

Last change on this file since 15366 was 15366, checked in by dbruciaferri, 12 months ago

Changing for including JMMP-CO idealised profiles for HPG errors test

File size: 14.7 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + remove CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE phycst          ! physical constants
19   USE dom_oce         ! ocean space and time domain
20   USE fldread         ! read input fields
21   !
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! MPP library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   dta_tsd_init   ! called by opa.F90
29   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
30
31   !                                  !!* namtsd  namelist : Temperature & Salinity Data *
32   LOGICAL , PUBLIC ::   ln_tsd_init   !: T & S data flag
33   LOGICAL , PUBLIC ::   ln_tsd_dmp    !: internal damping toward input data flag
34   !
35   !                          !!* parameters for HPGE experiment
36   INTEGER , PUBLIC ::   nn_tsd_type   !: 1 = July on-shelf
37                                       !: 2 = July off-shelf
38                                       !: 3 = Jan on-shelf
39                                       !: 4 = Jan off-shelf
40                                       !: 5 = Siddorn & Furner 2013
41   REAL(wp), PUBLIC ::   rn_sal_sf, rn_mld_sf, rn_maxdep_sf, rn_c0_sf, rn_c1_sf !: Siddorn & Furner 2013
42                                                                                !: idealised profile
43   !
44   !
45   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
46
47   !!----------------------------------------------------------------------
48   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE dta_tsd_init( ld_tradmp )
55      !!----------------------------------------------------------------------
56      !!                   ***  ROUTINE dta_tsd_init  ***
57      !!                   
58      !! ** Purpose :   initialisation of T & S input data
59      !!
60      !! ** Method  : - Read namtsd namelist
61      !!              - allocates T & S data structure
62      !!----------------------------------------------------------------------
63      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
64      !
65      INTEGER ::   ios, ierr0, ierr1, ierr2, ierr3   ! local integers
66      !!
67      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
68      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
69      TYPE(FLD_N)                   ::   sn_tem, sn_sal
70      !!
71      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_dmp, cn_dir, sn_tem, sn_sal, nn_tsd_type, &
72                      &  rn_sal_sf, rn_mld_sf, rn_maxdep_sf, rn_c0_sf, rn_c1_sf
73      !!----------------------------------------------------------------------
74      !
75      !  Initialisation
76      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
77      !
78      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
79      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
80901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtsd in reference namelist' )
81      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
82      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
83902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtsd in configuration namelist' )
84      IF(lwm) WRITE ( numond, namtsd )
85
86      IF( PRESENT( ld_tradmp ) )   ln_tsd_dmp = .TRUE.     ! forces the initialization when tradmp is used
87     
88      IF(lwp) THEN                  ! control print
89         WRITE(numout,*)
90         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
91         WRITE(numout,*) '~~~~~~~~~~~~ '
92         WRITE(numout,*) '   Namelist namtsd'
93         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init = ', ln_tsd_init
94         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_dmp  = ', ln_tsd_dmp
95         WRITE(numout,*)
96         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_dmp ) THEN
97            WRITE(numout,*)
98            WRITE(numout,*) '   ===>>   T & S data not used'
99         ENDIF
100         WRITE(numout,*)
101         WRITE(numout,*) 'dta_tsd_init : HPGE test parameters'
102         WRITE(numout,*) '~~~~~~~~~~~~ '
103         WRITE(numout,*) '   Namelist namtsd'
104         WRITE(numout,*) '      Type of intial profile nn_tsd_type = ', nn_tsd_type
105         IF (nn_tsd_type == 5) THEN
106            WRITE(numout,*) '      Siddorn and Furner 2013 idalised initial profile'
107            WRITE(numout,*) '            rn_sal_sf    = ', rn_sal_sf
108            WRITE(numout,*) '            rn_mld_sf    = ', rn_mld_sf
109            WRITE(numout,*) '            rn_maxdep_sf = ', rn_maxdep_sf
110            WRITE(numout,*) '            rn_c0_sf     = ', rn_c0_sf
111            WRITE(numout,*) '            rn_c1_sf     = ', rn_c1_sf
112         ENDIF
113      ENDIF
114      !
115      IF( ln_rstart .AND. ln_tsd_init ) THEN
116         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
117            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
118         ln_tsd_init = .FALSE.
119      ENDIF
120      !
121      !                             ! allocate the arrays (if necessary)
122      IF( ln_tsd_init .OR. ln_tsd_dmp ) THEN
123         !
124         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
125         IF( ierr0 > 0 ) THEN
126            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
127         ENDIF
128         !
129                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
130         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
131                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
132         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
133         !
134         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
135            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
136         ENDIF
137         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
138         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
139         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd', no_print )
140         !
141      ENDIF
142      !
143   END SUBROUTINE dta_tsd_init
144
145
146   SUBROUTINE dta_tsd( kt, ptsd )
147      !!----------------------------------------------------------------------
148      !!                   ***  ROUTINE dta_tsd  ***
149      !!                   
150      !! ** Purpose :   provides T and S data at kt
151      !!
152      !! ** Method  : - call fldread routine
153      !!              - ORCA_R2: add some hand made alteration to read data 
154      !!              - 'key_orca_lev10' interpolates on 10 times more levels
155      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
156      !!              - ln_tsd_dmp=F: deallocates the T-S data structure
157      !!                as T-S data are no are used
158      !!
159      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
160      !!----------------------------------------------------------------------
161      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
162      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
163      !
164      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
165      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
166      REAL(wp)::   zl, zi                             ! local scalars
167      REAL(wp), DIMENSION(jpk) ::  ztp, zsp   ! 1D workspace
168      !!----------------------------------------------------------------------
169      !
170      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
171      !
172      !
173!!gm  This should be removed from the code   ===>>>>  T & S files has to be changed
174      !
175      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
176      IF( cn_cfg == "orca" .OR. cn_cfg == "ORCA" ) THEN
177         IF( nn_cfg == 2 .AND. ln_tsd_dmp ) THEN    ! some hand made alterations
178            !
179            ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
180            ii0 = 141   ;   ii1 = 155
181            DO jj = mj0(ij0), mj1(ij1)
182               DO ji = mi0(ii0), mi1(ii1)
183                  sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
184                  sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
185                  sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
186                  !
187                  sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
188                  sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
189                  sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
190                  sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
191               END DO
192            END DO
193            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
194            ii0 = 148   ;   ii1 = 160
195            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
196            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
197            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
198         ENDIF
199      ENDIF
200!!gm end
201      !
202      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
203      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
204      !
205      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
206         !
207         IF( kt == nit000 .AND. lwp )THEN
208            WRITE(numout,*)
209            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
210         ENDIF
211         !
212         DO jj = 1, jpj                         ! vertical interpolation of T & S
213            DO ji = 1, jpi
214               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
215                  zl = gdept_0(ji,jj,jk)
216                  IF(     zl < gdept_1d(1  ) ) THEN          ! above the first level of data
217                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
218                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
219                  ELSEIF( zl > gdept_1d(jpk) ) THEN          ! below the last level of data
220                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
221                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
222                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
223                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
224                        IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
225                           zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
226                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
227                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
228                        ENDIF
229                     END DO
230                  ENDIF
231               END DO
232               DO jk = 1, jpkm1
233                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
234                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
235               END DO
236               ptsd(ji,jj,jpk,jp_tem) = 0._wp
237               ptsd(ji,jj,jpk,jp_sal) = 0._wp
238            END DO
239         END DO
240         !
241      ELSE                                !==   z- or zps- coordinate   ==!
242         !                             
243         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
244         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
245         !
246         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
247            DO jj = 1, jpj
248               DO ji = 1, jpi
249                  ik = mbkt(ji,jj) 
250                  IF( ik > 1 ) THEN
251                     zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
252                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
253                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
254                  ENDIF
255                  ik = mikt(ji,jj)
256                  IF( ik > 1 ) THEN
257                     zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) 
258                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem)
259                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal)
260                  END IF
261               END DO
262            END DO
263         ENDIF
264         !
265      ENDIF
266      !
267      IF( .NOT.ln_tsd_dmp ) THEN                   !==   deallocate T & S structure   ==!
268         !                                              (data used only for initialisation)
269         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
270                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
271         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
272                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
273         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
274                                        DEALLOCATE( sf_tsd              )     ! the structure itself
275      ENDIF
276      !
277   END SUBROUTINE dta_tsd
278
279   !!======================================================================
280END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.