source: NEMO/branches/UKMO/NEMO_4.0.4_mirror/src/ICE/iceupdate.F90 @ 14075

Last change on this file since 14075 was 14075, checked in by cguiavarch, 7 months ago

UKMO/NEMO_4.0.4_mirror : Remove SVN keywords.

File size: 27.6 KB
Line 
1MODULE iceupdate
2   !!======================================================================
3   !!                       ***  MODULE iceupdate   ***
4   !!  Sea-ice :   computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :  4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_update_alloc : allocate the iceupdate arrays
13   !!   ice_update_init  : initialisation
14   !!   ice_update_flx   : updates mass, heat and salt fluxes at the ocean surface
15   !!   ice_update_tau   : update i- and j-stresses, and its modulus at the ocean surface
16   !!----------------------------------------------------------------------
17   USE oce     , ONLY : sshn, sshb
18   USE phycst         ! physical constants
19   USE dom_oce        ! ocean domain
20   USE ice            ! sea-ice: variables
21   USE sbc_ice        ! Surface boundary condition: ice   fields
22   USE sbc_oce        ! Surface boundary condition: ocean fields
23   USE sbccpl         ! Surface boundary condition: coupled interface
24   USE icealb         ! sea-ice: albedo parameters
25   USE traqsr         ! add penetration of solar flux in the calculation of heat budget
26   USE icectl         ! sea-ice: control prints
27   USE zdfdrg  , ONLY : ln_drgice_imp
28   !
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O manager library
31   USE lib_mpp        ! MPP library
32   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
33   USE lbclnk         ! lateral boundary conditions (or mpp links)
34   USE timing         ! Timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   ice_update_init   ! called by ice_init
40   PUBLIC   ice_update_flx    ! called by ice_stp
41   PUBLIC   ice_update_tau    ! called by ice_stp
42
43   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
44   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
45
46   !! * Substitutions
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   INTEGER FUNCTION ice_update_alloc()
56      !!-------------------------------------------------------------------
57      !!             ***  ROUTINE ice_update_alloc ***
58      !!-------------------------------------------------------------------
59      ALLOCATE( utau_oce(jpi,jpj), vtau_oce(jpi,jpj), tmod_io(jpi,jpj), STAT=ice_update_alloc )
60      !
61      CALL mpp_sum( 'iceupdate', ice_update_alloc )
62      IF( ice_update_alloc /= 0 )   CALL ctl_stop( 'STOP', 'ice_update_alloc: failed to allocate arrays' )
63      !
64   END FUNCTION ice_update_alloc
65
66
67   SUBROUTINE ice_update_flx( kt )
68      !!-------------------------------------------------------------------
69      !!                ***  ROUTINE ice_update_flx ***
70      !! 
71      !! ** Purpose :   Update the surface ocean boundary condition for heat
72      !!                salt and mass over areas where sea-ice is non-zero
73      !!         
74      !! ** Action  : - computes the heat and freshwater/salt fluxes
75      !!                at the ice-ocean interface.
76      !!              - Update the ocean sbc
77      !!     
78      !! ** Outputs : - qsr     : sea heat flux:     solar
79      !!              - qns     : sea heat flux: non solar
80      !!              - emp     : freshwater budget: volume flux
81      !!              - sfx     : salt flux
82      !!              - fr_i    : ice fraction
83      !!              - tn_ice  : sea-ice surface temperature
84      !!              - alb_ice : sea-ice albedo (recomputed only for coupled mode)
85      !!
86      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
87      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
88      !!              These refs are now obsolete since everything has been revised
89      !!              The ref should be Rousset et al., 2015
90      !!---------------------------------------------------------------------
91      INTEGER, INTENT(in) ::   kt   ! number of iteration
92      !
93      INTEGER  ::   ji, jj, jl, jk   ! dummy loop indices
94      REAL(wp) ::   zqsr             ! New solar flux received by the ocean
95      REAL(wp), DIMENSION(jpi,jpj) ::   z2d                  ! 2D workspace
96      !!---------------------------------------------------------------------
97      IF( ln_timing )   CALL timing_start('ice_update')
98
99      IF( kt == nit000 .AND. lwp ) THEN
100         WRITE(numout,*)
101         WRITE(numout,*)'ice_update_flx: update fluxes (mass, salt and heat) at the ice-ocean interface'
102         WRITE(numout,*)'~~~~~~~~~~~~~~'
103      ENDIF
104
105      ! Net heat flux on top of the ice-ocean (W.m-2)
106      !----------------------------------------------
107      qt_atm_oi(:,:) = qns_tot(:,:) + qsr_tot(:,:) 
108
109      ! --- case we bypass ice thermodynamics --- !
110      IF( .NOT. ln_icethd ) THEN   ! we suppose ice is impermeable => ocean is isolated from atmosphere
111         qt_atm_oi  (:,:)   = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
112         qt_oce_ai  (:,:)   = ( 1._wp - at_i_b(:,:) ) *   qns_oce(:,:)                  + qemp_oce(:,:)
113         emp_ice    (:,:)   = 0._wp
114         qemp_ice   (:,:)   = 0._wp
115         qevap_ice  (:,:,:) = 0._wp
116      ENDIF
117     
118      DO jj = 1, jpj
119         DO ji = 1, jpi
120
121            ! Solar heat flux reaching the ocean (max) = zqsr (W.m-2)
122            !---------------------------------------------------
123            zqsr = qsr_tot(ji,jj) - SUM( a_i_b(ji,jj,:) * ( qsr_ice(ji,jj,:) - qtr_ice_bot(ji,jj,:) ) )
124
125            ! Total heat flux reaching the ocean = qt_oce_ai (W.m-2)
126            !---------------------------------------------------
127            qt_oce_ai(ji,jj) = qt_atm_oi(ji,jj) - hfx_sum(ji,jj) - hfx_bom(ji,jj) - hfx_bog(ji,jj) &
128               &                                - hfx_dif(ji,jj) - hfx_opw(ji,jj) - hfx_snw(ji,jj) &
129               &                                + hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) &
130               &                                + hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) + hfx_spr(ji,jj)                 
131           
132            ! New qsr and qns used to compute the oceanic heat flux at the next time step
133            !----------------------------------------------------------------------------
134            ! if warming and some ice remains, then we suppose that the whole solar flux has been consumed to melt the ice
135            ! else ( cooling or no ice left ), then we suppose that     no    solar flux has been consumed
136            !
137            IF( fhld(ji,jj) > 0._wp .AND. at_i(ji,jj) > 0._wp ) THEN   !-- warming and some ice remains
138               !                                        solar flux transmitted thru the 1st level of the ocean (i.e. not used by sea-ice)
139               qsr(ji,jj) = ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * ( 1._wp - frq_m(ji,jj) ) &
140                  !                                   + solar flux transmitted thru ice and the 1st ocean level (also not used by sea-ice)
141                  &             + SUM( a_i_b(ji,jj,:) * qtr_ice_bot(ji,jj,:) ) * ( 1._wp - frq_m(ji,jj) )
142               !
143            ELSE                                                       !-- cooling or no ice left
144               qsr(ji,jj) = zqsr
145            ENDIF
146            !
147            ! the non-solar is simply derived from the solar flux
148            qns(ji,jj) = qt_oce_ai(ji,jj) - zqsr             
149
150            ! Mass flux at the atm. surface       
151            !-----------------------------------
152            wfx_sub(ji,jj) = wfx_snw_sub(ji,jj) + wfx_ice_sub(ji,jj)
153
154            ! Mass flux at the ocean surface     
155            !------------------------------------
156            ! ice-ocean  mass flux
157            wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj)   &
158               &           + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) + wfx_pnd(ji,jj)
159
160            ! snw-ocean mass flux
161            wfx_snw(ji,jj) = wfx_snw_sni(ji,jj) + wfx_snw_dyn(ji,jj) + wfx_snw_sum(ji,jj)
162
163            ! total mass flux at the ocean/ice interface
164            fmmflx(ji,jj) =                - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj)   ! ice-ocean mass flux saved at least for biogeochemical model
165            emp   (ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj)   ! atm-ocean + ice-ocean mass flux
166
167            ! Salt flux at the ocean surface     
168            !------------------------------------------
169            sfx(ji,jj) = sfx_bog(ji,jj) + sfx_bom(ji,jj) + sfx_sum(ji,jj) + sfx_sni(ji,jj) + sfx_opw(ji,jj)   &
170               &       + sfx_res(ji,jj) + sfx_dyn(ji,jj) + sfx_bri(ji,jj) + sfx_sub(ji,jj) + sfx_lam(ji,jj)
171           
172            ! Mass of snow and ice per unit area   
173            !----------------------------------------
174            snwice_mass_b(ji,jj) = snwice_mass(ji,jj)       ! save mass from the previous ice time step
175            !                                               ! new mass per unit area
176            snwice_mass  (ji,jj) = tmask(ji,jj,1) * ( rhos * vt_s(ji,jj) + rhoi * vt_i(ji,jj)  ) 
177            !                                               ! time evolution of snow+ice mass
178            snwice_fmass (ji,jj) = ( snwice_mass(ji,jj) - snwice_mass_b(ji,jj) ) * r1_rdtice
179           
180         END DO
181      END DO
182
183      ! Storing the transmitted variables
184      !----------------------------------
185      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
186      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
187
188      ! Snow/ice albedo (only if sent to coupler, useless in forced mode)
189      !------------------------------------------------------------------
190      CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_eff, h_ip, cloud_fra, alb_ice ) ! ice albedo
191
192      !
193      IF( lrst_ice ) THEN                       !* write snwice_mass fields in the restart file
194         CALL update_rst( 'WRITE', kt )
195      ENDIF
196      !
197      ! output all fluxes
198      !------------------
199      !
200      ! --- salt fluxes [kg/m2/s] --- !
201      !                           ! sfxice =  sfxbog + sfxbom + sfxsum + sfxsni + sfxopw + sfxres + sfxdyn + sfxbri + sfxsub + sfxlam
202      IF( iom_use('sfxice'  ) )   CALL iom_put( 'sfxice', sfx     * 1.e-03 )   ! salt flux from total ice growth/melt
203      IF( iom_use('sfxbog'  ) )   CALL iom_put( 'sfxbog', sfx_bog * 1.e-03 )   ! salt flux from bottom growth
204      IF( iom_use('sfxbom'  ) )   CALL iom_put( 'sfxbom', sfx_bom * 1.e-03 )   ! salt flux from bottom melting
205      IF( iom_use('sfxsum'  ) )   CALL iom_put( 'sfxsum', sfx_sum * 1.e-03 )   ! salt flux from surface melting
206      IF( iom_use('sfxlam'  ) )   CALL iom_put( 'sfxlam', sfx_lam * 1.e-03 )   ! salt flux from lateral melting
207      IF( iom_use('sfxsni'  ) )   CALL iom_put( 'sfxsni', sfx_sni * 1.e-03 )   ! salt flux from snow ice formation
208      IF( iom_use('sfxopw'  ) )   CALL iom_put( 'sfxopw', sfx_opw * 1.e-03 )   ! salt flux from open water formation
209      IF( iom_use('sfxdyn'  ) )   CALL iom_put( 'sfxdyn', sfx_dyn * 1.e-03 )   ! salt flux from ridging rafting
210      IF( iom_use('sfxbri'  ) )   CALL iom_put( 'sfxbri', sfx_bri * 1.e-03 )   ! salt flux from brines
211      IF( iom_use('sfxres'  ) )   CALL iom_put( 'sfxres', sfx_res * 1.e-03 )   ! salt flux from undiagnosed processes
212      IF( iom_use('sfxsub'  ) )   CALL iom_put( 'sfxsub', sfx_sub * 1.e-03 )   ! salt flux from sublimation
213
214      ! --- mass fluxes [kg/m2/s] --- !
215      CALL iom_put( 'emp_oce', emp_oce )   ! emp over ocean (taking into account the snow blown away from the ice)
216      CALL iom_put( 'emp_ice', emp_ice )   ! emp over ice   (taking into account the snow blown away from the ice)
217
218      !                           ! vfxice = vfxbog + vfxbom + vfxsum + vfxsni + vfxopw + vfxdyn + vfxres + vfxlam + vfxpnd
219      CALL iom_put( 'vfxice'    , wfx_ice     )   ! mass flux from total ice growth/melt
220      CALL iom_put( 'vfxbog'    , wfx_bog     )   ! mass flux from bottom growth
221      CALL iom_put( 'vfxbom'    , wfx_bom     )   ! mass flux from bottom melt
222      CALL iom_put( 'vfxsum'    , wfx_sum     )   ! mass flux from surface melt
223      CALL iom_put( 'vfxlam'    , wfx_lam     )   ! mass flux from lateral melt
224      CALL iom_put( 'vfxsni'    , wfx_sni     )   ! mass flux from snow-ice formation
225      CALL iom_put( 'vfxopw'    , wfx_opw     )   ! mass flux from growth in open water
226      CALL iom_put( 'vfxdyn'    , wfx_dyn     )   ! mass flux from dynamics (ridging)
227      CALL iom_put( 'vfxres'    , wfx_res     )   ! mass flux from undiagnosed processes
228      CALL iom_put( 'vfxpnd'    , wfx_pnd     )   ! mass flux from melt ponds
229      CALL iom_put( 'vfxsub'    , wfx_ice_sub )   ! mass flux from ice sublimation (ice-atm.)
230      CALL iom_put( 'vfxsub_err', wfx_err_sub )   ! "excess" of sublimation sent to ocean     
231
232      IF ( iom_use( 'vfxthin' ) ) THEN   ! mass flux from ice growth in open water + thin ice (<20cm) => comparable to observations 
233         WHERE( hm_i(:,:) < 0.2 .AND. hm_i(:,:) > 0. ) ; z2d = wfx_bog
234         ELSEWHERE                                     ; z2d = 0._wp
235         END WHERE
236         CALL iom_put( 'vfxthin', wfx_opw + z2d )
237      ENDIF
238
239      !                            ! vfxsnw = vfxsnw_sni + vfxsnw_dyn + vfxsnw_sum
240      CALL iom_put( 'vfxsnw'     , wfx_snw     )   ! mass flux from total snow growth/melt
241      CALL iom_put( 'vfxsnw_sum' , wfx_snw_sum )   ! mass flux from snow melt at the surface
242      CALL iom_put( 'vfxsnw_sni' , wfx_snw_sni )   ! mass flux from snow melt during snow-ice formation
243      CALL iom_put( 'vfxsnw_dyn' , wfx_snw_dyn )   ! mass flux from dynamics (ridging)
244      CALL iom_put( 'vfxsnw_sub' , wfx_snw_sub )   ! mass flux from snow sublimation (ice-atm.)
245      CALL iom_put( 'vfxsnw_pre' , wfx_spr     )   ! snow precip
246
247      ! --- heat fluxes [W/m2] --- !
248      !                              ! qt_atm_oi - qt_oce_ai = hfxdhc - ( dihctrp + dshctrp )
249      IF( iom_use('qsr_oce'    ) )   CALL iom_put( 'qsr_oce'    , qsr_oce * ( 1._wp - at_i_b )                               )   !     solar flux at ocean surface
250      IF( iom_use('qns_oce'    ) )   CALL iom_put( 'qns_oce'    , qns_oce * ( 1._wp - at_i_b ) + qemp_oce                    )   ! non-solar flux at ocean surface
251      IF( iom_use('qsr_ice'    ) )   CALL iom_put( 'qsr_ice'    , SUM( qsr_ice * a_i_b, dim=3 )                              )   !     solar flux at ice surface
252      IF( iom_use('qns_ice'    ) )   CALL iom_put( 'qns_ice'    , SUM( qns_ice * a_i_b, dim=3 ) + qemp_ice                   )   ! non-solar flux at ice surface
253      IF( iom_use('qtr_ice_bot') )   CALL iom_put( 'qtr_ice_bot', SUM( qtr_ice_bot * a_i_b, dim=3 )                          )   !     solar flux transmitted thru ice
254      IF( iom_use('qtr_ice_top') )   CALL iom_put( 'qtr_ice_top', SUM( qtr_ice_top * a_i_b, dim=3 )                          )   !     solar flux transmitted thru ice surface
255      IF( iom_use('qt_oce'     ) )   CALL iom_put( 'qt_oce'     ,      ( qsr_oce + qns_oce ) * ( 1._wp - at_i_b ) + qemp_oce )
256      IF( iom_use('qt_ice'     ) )   CALL iom_put( 'qt_ice'     , SUM( ( qns_ice + qsr_ice ) * a_i_b, dim=3 )     + qemp_ice )
257      IF( iom_use('qt_oce_ai'  ) )   CALL iom_put( 'qt_oce_ai'  , qt_oce_ai * tmask(:,:,1)                                   )   ! total heat flux at the ocean   surface: interface oce-(ice+atm)
258      IF( iom_use('qt_atm_oi'  ) )   CALL iom_put( 'qt_atm_oi'  , qt_atm_oi * tmask(:,:,1)                                   )   ! total heat flux at the oce-ice surface: interface atm-(ice+oce)
259      IF( iom_use('qemp_oce'   ) )   CALL iom_put( 'qemp_oce'   , qemp_oce                                                   )   ! Downward Heat Flux from E-P over ocean
260      IF( iom_use('qemp_ice'   ) )   CALL iom_put( 'qemp_ice'   , qemp_ice                                                   )   ! Downward Heat Flux from E-P over ice
261
262      ! heat fluxes from ice transformations
263      !                            ! hfxdhc = hfxbog + hfxbom + hfxsum + hfxopw + hfxdif + hfxsnw - ( hfxthd + hfxdyn + hfxres + hfxsub + hfxspr )
264      CALL iom_put ('hfxbog'     , hfx_bog     )   ! heat flux used for ice bottom growth
265      CALL iom_put ('hfxbom'     , hfx_bom     )   ! heat flux used for ice bottom melt
266      CALL iom_put ('hfxsum'     , hfx_sum     )   ! heat flux used for ice surface melt
267      CALL iom_put ('hfxopw'     , hfx_opw     )   ! heat flux used for ice formation in open water
268      CALL iom_put ('hfxdif'     , hfx_dif     )   ! heat flux used for ice temperature change
269      CALL iom_put ('hfxsnw'     , hfx_snw     )   ! heat flux used for snow melt
270      CALL iom_put ('hfxerr'     , hfx_err_dif )   ! heat flux error after heat diffusion
271
272      ! heat fluxes associated with mass exchange (freeze/melt/precip...)
273      CALL iom_put ('hfxthd'     , hfx_thd     )   
274      CALL iom_put ('hfxdyn'     , hfx_dyn     )   
275      CALL iom_put ('hfxres'     , hfx_res     )   
276      CALL iom_put ('hfxsub'     , hfx_sub     )   
277      CALL iom_put ('hfxspr'     , hfx_spr     )   ! Heat flux from snow precip heat content
278
279      ! other heat fluxes
280      IF( iom_use('hfxsensib'  ) )   CALL iom_put( 'hfxsensib'  ,     -qsb_ice_bot * at_i_b         )   ! Sensible oceanic heat flux
281      IF( iom_use('hfxcndbot'  ) )   CALL iom_put( 'hfxcndbot'  , SUM( qcn_ice_bot * a_i_b, dim=3 ) )   ! Bottom conduction flux
282      IF( iom_use('hfxcndtop'  ) )   CALL iom_put( 'hfxcndtop'  , SUM( qcn_ice_top * a_i_b, dim=3 ) )   ! Surface conduction flux
283
284      ! controls
285      !---------
286#if ! defined key_agrif
287      IF( ln_icediachk )   CALL ice_cons_final('iceupdate')                                       ! conservation
288#endif
289      IF( ln_icectl    )   CALL ice_prt       (kt, iiceprt, jiceprt, 3, 'Final state ice_update') ! prints
290      IF( ln_ctl       )   CALL ice_prt3D     ('iceupdate')                                       ! prints
291      IF( ln_timing    )   CALL timing_stop   ('ice_update')                                      ! timing
292      !
293   END SUBROUTINE ice_update_flx
294
295
296   SUBROUTINE ice_update_tau( kt, pu_oce, pv_oce )
297      !!-------------------------------------------------------------------
298      !!                ***  ROUTINE ice_update_tau ***
299      !! 
300      !! ** Purpose : Update the ocean surface stresses due to the ice
301      !!         
302      !! ** Action  : * at each ice time step (every nn_fsbc time step):
303      !!                - compute the modulus of ice-ocean relative velocity
304      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
305      !!                      tmod_io = rhoco * | U_ice-U_oce |
306      !!                - update the modulus of stress at ocean surface
307      !!                      taum = (1-a) * taum + a * tmod_io * | U_ice-U_oce |
308      !!              * at each ocean time step (every kt):
309      !!                  compute linearized ice-ocean stresses as
310      !!                      Utau = tmod_io * | U_ice - pU_oce |
311      !!                using instantaneous current ocean velocity (usually before)
312      !!
313      !!    NB: - ice-ocean rotation angle no more allowed
314      !!        - here we make an approximation: taum is only computed every ice time step
315      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
316      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
317      !!
318      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
319      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
320      !!---------------------------------------------------------------------
321      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
322      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
323      !
324      INTEGER  ::   ji, jj   ! dummy loop indices
325      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
326      REAL(wp) ::   zat_v, zvtau_ice, zv_t, zrhoco  !   -      -
327      REAL(wp) ::   zflagi                          !   -      -
328      !!---------------------------------------------------------------------
329      IF( ln_timing )   CALL timing_start('ice_update_tau')
330
331      IF( kt == nit000 .AND. lwp ) THEN
332         WRITE(numout,*)
333         WRITE(numout,*)'ice_update_tau: update stress at the ice-ocean interface'
334         WRITE(numout,*)'~~~~~~~~~~~~~~'
335      ENDIF
336
337      zrhoco = rau0 * rn_cio
338      !
339      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
340         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
341            DO ji = fs_2, fs_jpim1
342               !                                               ! 2*(U_ice-U_oce) at T-point
343               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
344               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
345               !                                              ! |U_ice-U_oce|^2
346               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
347               !                                               ! update the ocean stress modulus
348               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt
349               tmod_io(ji,jj) = zrhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
350            END DO
351         END DO
352         CALL lbc_lnk_multi( 'iceupdate', taum, 'T', 1., tmod_io, 'T', 1. )
353         !
354         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
355         vtau_oce(:,:) = vtau(:,:)
356         !
357      ENDIF
358      !
359      !                                      !==  every ocean time-step  ==!
360      IF ( ln_drgice_imp ) THEN
361         ! Save drag with right sign to update top drag in the ocean implicit friction
362         rCdU_ice(:,:) = -r1_rau0 * tmod_io(:,:) * at_i(:,:) * tmask(:,:,1) 
363         zflagi = 0._wp
364      ELSE
365         zflagi = 1._wp
366      ENDIF
367      !
368      DO jj = 2, jpjm1                                !* update the stress WITHOUT an ice-ocean rotation angle
369         DO ji = fs_2, fs_jpim1   ! Vect. Opt.   
370            ! ice area at u and v-points
371            zat_u  = ( at_i(ji,jj) * tmask(ji,jj,1) + at_i (ji+1,jj    ) * tmask(ji+1,jj  ,1) )  &
372               &     / MAX( 1.0_wp , tmask(ji,jj,1) + tmask(ji+1,jj  ,1) )
373            zat_v  = ( at_i(ji,jj) * tmask(ji,jj,1) + at_i (ji  ,jj+1  ) * tmask(ji  ,jj+1,1) )  &
374               &     / MAX( 1.0_wp , tmask(ji,jj,1) + tmask(ji  ,jj+1,1) )
375            !                                                   ! linearized quadratic drag formulation
376            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - zflagi * pu_oce(ji,jj) )
377            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - zflagi * pv_oce(ji,jj) )
378            !                                                   ! stresses at the ocean surface
379            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
380            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
381         END DO
382      END DO
383      CALL lbc_lnk_multi( 'iceupdate', utau, 'U', -1., vtau, 'V', -1. )   ! lateral boundary condition
384      !
385      IF( ln_timing )   CALL timing_stop('ice_update_tau')
386     
387   END SUBROUTINE ice_update_tau
388
389
390   SUBROUTINE ice_update_init
391      !!-------------------------------------------------------------------
392      !!                  ***  ROUTINE ice_update_init  ***
393      !!             
394      !! ** Purpose :   allocate ice-ocean stress fields and read restarts
395      !!                containing the snow & ice mass
396      !!
397      !!-------------------------------------------------------------------
398      INTEGER  ::   ji, jj, jk               ! dummy loop indices
399      REAL(wp) ::   zcoefu, zcoefv, zcoeff   ! local scalar
400      !!-------------------------------------------------------------------
401      !
402      IF(lwp) WRITE(numout,*)
403      IF(lwp) WRITE(numout,*) 'ice_update_init: ice-ocean stress init'
404      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
405      !
406      !                                      ! allocate ice_update array
407      IF( ice_update_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'ice_update_init : unable to allocate standard arrays' )
408      !
409      CALL update_rst( 'READ' )  !* read or initialize all required files
410      !
411   END SUBROUTINE ice_update_init
412
413
414   SUBROUTINE update_rst( cdrw, kt )
415      !!---------------------------------------------------------------------
416      !!                   ***  ROUTINE rhg_evp_rst  ***
417      !!                     
418      !! ** Purpose :   Read or write RHG file in restart file
419      !!
420      !! ** Method  :   use of IOM library
421      !!----------------------------------------------------------------------
422      CHARACTER(len=*) , INTENT(in) ::   cdrw   ! 'READ'/'WRITE' flag
423      INTEGER, OPTIONAL, INTENT(in) ::   kt     ! ice time-step
424      !
425      INTEGER  ::   iter   ! local integer
426      INTEGER  ::   id1    ! local integer
427      !!----------------------------------------------------------------------
428      !
429      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialize
430         !                                   ! ---------------
431         IF( ln_rstart ) THEN                   !* Read the restart file
432            !
433            id1 = iom_varid( numrir, 'snwice_mass' , ldstop = .FALSE. )
434            !
435            IF( id1 > 0 ) THEN                       ! fields exist
436               CALL iom_get( numrir, jpdom_autoglo, 'snwice_mass'  , snwice_mass   )
437               CALL iom_get( numrir, jpdom_autoglo, 'snwice_mass_b', snwice_mass_b )
438            ELSE                                     ! start from rest
439               IF(lwp) WRITE(numout,*) '   ==>>   previous run without snow-ice mass output then set it'
440               snwice_mass  (:,:) = tmask(:,:,1) * ( rhos * vt_s(:,:) + rhoi * vt_i(:,:) )
441               snwice_mass_b(:,:) = snwice_mass(:,:)
442            ENDIF
443         ELSE                                   !* Start from rest
444            IF(lwp) WRITE(numout,*) '   ==>>   start from rest: set the snow-ice mass'
445            snwice_mass  (:,:) = tmask(:,:,1) * ( rhos * vt_s(:,:) + rhoi * vt_i(:,:) )
446            snwice_mass_b(:,:) = snwice_mass(:,:)
447         ENDIF
448         !
449      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
450         !                                   ! -------------------
451         IF(lwp) WRITE(numout,*) '---- update-rst ----'
452         iter = kt + nn_fsbc - 1             ! ice restarts are written at kt == nitrst - nn_fsbc + 1
453         !
454         CALL iom_rstput( iter, nitrst, numriw, 'snwice_mass'  , snwice_mass   )
455         CALL iom_rstput( iter, nitrst, numriw, 'snwice_mass_b', snwice_mass_b )
456         !
457      ENDIF
458      !
459   END SUBROUTINE update_rst
460
461#else
462   !!----------------------------------------------------------------------
463   !!   Default option         Dummy module           NO SI3 sea-ice model
464   !!----------------------------------------------------------------------
465#endif 
466
467   !!======================================================================
468END MODULE iceupdate
Note: See TracBrowser for help on using the repository browser.