New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in NEMO/branches/UKMO/NEMO_4.0.4_mirror/src/OCE/SBC – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.4_mirror/src/OCE/SBC/sbcssm.F90 @ 14075

Last change on this file since 14075 was 14075, checked in by cguiavarch, 4 years ago

UKMO/NEMO_4.0.4_mirror : Remove SVN keywords.

File size: 14.1 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   USE traqsr, ONLY: ln_traqsr
21   !
22   USE in_out_manager ! I/O manager
23   USE prtctl         ! Print control
24   USE iom            ! IOM library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_ssm        ! routine called by step.F90
30   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
31
32   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
33   
34   !!----------------------------------------------------------------------
35   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE sbc_ssm( kt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE sbc_oce  ***
44      !!                     
45      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
46      !!                condition computation
47      !!               
48      !! ** Method  :   compute mean surface velocity (2 components at U and
49      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
50      !!      the periode (kt - nn_fsbc) to kt
51      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
52      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt   ! ocean time step
55      !
56      INTEGER  ::   ji, jj               ! loop index
57      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
58      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
59      !!---------------------------------------------------------------------
60      !
61      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
62      DO jj = 1, jpj
63         DO ji = 1, jpi
64            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
65            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
66         END DO
67      END DO
68      !
69      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
70         !                                                ! ---------------------------------------- !
71         ssu_m(:,:) = ub(:,:,1)
72         ssv_m(:,:) = vb(:,:,1)
73         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
74         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
75         ENDIF
76         sss_m(:,:) = zts(:,:,jp_sal)
77         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
78         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
79         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
80         ENDIF
81         !
82         e3t_m(:,:) = e3t_n(:,:,1)
83         !
84         frq_m(:,:) = fraqsr_1lev(:,:)
85         !
86      ELSE
87         !                                                ! ----------------------------------------------- !
88         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
89            !                                             ! ----------------------------------------------- !
90            IF(lwp) WRITE(numout,*)
91            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
92            IF(lwp) WRITE(numout,*) '~~~~~~~   '
93            zcoef = REAL( nn_fsbc - 1, wp )
94            ssu_m(:,:) = zcoef * ub(:,:,1)
95            ssv_m(:,:) = zcoef * vb(:,:,1)
96            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
97            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
98            ENDIF
99            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
100            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
101            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
102            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
103            ENDIF
104            !
105            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
106            !
107            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
108            !                                             ! ---------------------------------------- !
109         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
110            !                                             ! ---------------------------------------- !
111            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
112            ssv_m(:,:) = 0._wp
113            sst_m(:,:) = 0._wp
114            sss_m(:,:) = 0._wp
115            ssh_m(:,:) = 0._wp
116            e3t_m(:,:) = 0._wp
117            frq_m(:,:) = 0._wp
118         ENDIF
119         !                                                ! ---------------------------------------- !
120         !                                                !        Cumulate at each time step        !
121         !                                                ! ---------------------------------------- !
122         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
123         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
124         IF( l_useCT )  THEN     ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
125         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
126         ENDIF
127         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
128         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
129         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
130         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
131         ENDIF
132         !
133         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
134         !
135         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
136
137         !                                                ! ---------------------------------------- !
138         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
139            !                                             ! ---------------------------------------- !
140            zcoef = 1. / REAL( nn_fsbc, wp )
141            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
142            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
143            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
144            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
145            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
146            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
147            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
148            !
149         ENDIF
150         !                                                ! ---------------------------------------- !
151         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
152            !                                             ! ---------------------------------------- !
153            IF(lwp) WRITE(numout,*)
154            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
155               &                    'at it= ', kt,' date= ', ndastp
156            IF(lwp) WRITE(numout,*) '~~~~~~~'
157            zf_sbc = REAL( nn_fsbc, wp )
158            IF( lwxios ) CALL iom_swap(      cwxios_context          )
159            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc, ldxios = lwxios )    ! sbc frequency
160            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m, ldxios = lwxios  )    ! sea surface mean fields
161            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m, ldxios = lwxios  )
162            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m, ldxios = lwxios  )
163            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m, ldxios = lwxios  )
164            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m, ldxios = lwxios  )
165            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m, ldxios = lwxios  )
166            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m, ldxios = lwxios  )
167            !
168            IF( lwxios ) CALL iom_swap(      cxios_context          )
169         ENDIF
170         !
171      ENDIF
172      !
173      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
174         CALL iom_put( 'ssu_m', ssu_m )
175         CALL iom_put( 'ssv_m', ssv_m )
176         CALL iom_put( 'sst_m', sst_m )
177         CALL iom_put( 'sss_m', sss_m )
178         CALL iom_put( 'ssh_m', ssh_m )
179         CALL iom_put( 'e3t_m', e3t_m )
180         CALL iom_put( 'frq_m', frq_m )
181      ENDIF
182      !
183   END SUBROUTINE sbc_ssm
184
185
186   SUBROUTINE sbc_ssm_init
187      !!----------------------------------------------------------------------
188      !!                  ***  ROUTINE sbc_ssm_init  ***
189      !!
190      !! ** Purpose :   Initialisation of the sbc data
191      !!
192      !! ** Action  : - read parameters
193      !!----------------------------------------------------------------------
194      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
195      !!----------------------------------------------------------------------
196      !
197      IF( nn_fsbc == 1 ) THEN
198         !
199         IF(lwp) WRITE(numout,*)
200         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
201         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
202         !
203      ELSE
204         !               
205         IF(lwp) WRITE(numout,*)
206         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
207         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
208         !
209         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
210            l_ssm_mean = .TRUE.
211            CALL iom_get( numror               , 'nn_fsbc', zf_sbc, ldxios = lrxios )    ! sbc frequency of previous run
212            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m, ldxios = lrxios  )    ! sea surface mean velocity    (U-point)
213            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m, ldxios = lrxios  )    !   "         "    velocity    (V-point)
214            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m, ldxios = lrxios  )    !   "         "    temperature (T-point)
215            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m, ldxios = lrxios  )    !   "         "    salinity    (T-point)
216            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m, ldxios = lrxios  )    !   "         "    height      (T-point)
217            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m, ldxios = lrxios  )    ! 1st level thickness          (T-point)
218            ! fraction of solar net radiation absorbed in 1st T level
219            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
220               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m, ldxios = lrxios  )
221            ELSE
222               frq_m(:,:) = 1._wp   ! default definition
223            ENDIF
224            !
225            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
226               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
227               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
228               ssu_m(:,:) = zcoef * ssu_m(:,:) 
229               ssv_m(:,:) = zcoef * ssv_m(:,:)
230               sst_m(:,:) = zcoef * sst_m(:,:)
231               sss_m(:,:) = zcoef * sss_m(:,:)
232               ssh_m(:,:) = zcoef * ssh_m(:,:)
233               e3t_m(:,:) = zcoef * e3t_m(:,:)
234               frq_m(:,:) = zcoef * frq_m(:,:)
235            ELSE
236               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
237            ENDIF
238         ENDIF
239      ENDIF
240      !
241      IF( .NOT.l_ssm_mean ) THEN   ! default initialisation. needed by iceistate
242         !
243         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
244         ssu_m(:,:) = ub(:,:,1)
245         ssv_m(:,:) = vb(:,:,1)
246         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
247         ELSE                   ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
248         ENDIF
249         sss_m(:,:) = tsn  (:,:,1,jp_sal)
250         ssh_m(:,:) = sshn (:,:)
251         e3t_m(:,:) = e3t_n(:,:,1)
252         frq_m(:,:) = 1._wp
253         !
254      ENDIF
255      !
256      IF( .NOT. ln_traqsr )   fraqsr_1lev(:,:) = 1._wp   ! default definition: qsr 100% in the fisrt level
257      !
258      IF( lwxios.AND.nn_fsbc > 1 ) THEN
259         CALL iom_set_rstw_var_active('nn_fsbc')
260         CALL iom_set_rstw_var_active('ssu_m')
261         CALL iom_set_rstw_var_active('ssv_m')
262         CALL iom_set_rstw_var_active('sst_m')
263         CALL iom_set_rstw_var_active('sss_m')
264         CALL iom_set_rstw_var_active('ssh_m')
265         CALL iom_set_rstw_var_active('e3t_m')
266         CALL iom_set_rstw_var_active('frq_m')
267      ENDIF
268
269   END SUBROUTINE sbc_ssm_init
270
271   !!======================================================================
272END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.