source: NEMO/branches/UKMO/NEMO_4.0.4_penetrating_solar/src/ICE/iceupdate.F90 @ 14562

Last change on this file since 14562 was 14562, checked in by dancopsey, 3 months ago

Remove sublimation and snow precip from surface energy balance

File size: 27.4 KB
Line 
1MODULE iceupdate
2   !!======================================================================
3   !!                       ***  MODULE iceupdate   ***
4   !!  Sea-ice :   computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :  4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_update_alloc : allocate the iceupdate arrays
13   !!   ice_update_init  : initialisation
14   !!   ice_update_flx   : updates mass, heat and salt fluxes at the ocean surface
15   !!   ice_update_tau   : update i- and j-stresses, and its modulus at the ocean surface
16   !!----------------------------------------------------------------------
17   USE oce     , ONLY : sshn, sshb
18   USE phycst         ! physical constants
19   USE dom_oce        ! ocean domain
20   USE ice            ! sea-ice: variables
21   USE sbc_ice        ! Surface boundary condition: ice   fields
22   USE sbc_oce        ! Surface boundary condition: ocean fields
23   USE sbccpl         ! Surface boundary condition: coupled interface
24   USE icealb         ! sea-ice: albedo parameters
25   USE traqsr         ! add penetration of solar flux in the calculation of heat budget
26   USE icectl         ! sea-ice: control prints
27   USE zdfdrg  , ONLY : ln_drgice_imp
28   !
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O manager library
31   USE lib_mpp        ! MPP library
32   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
33   USE lbclnk         ! lateral boundary conditions (or mpp links)
34   USE timing         ! Timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   ice_update_init   ! called by ice_init
40   PUBLIC   ice_update_flx    ! called by ice_stp
41   PUBLIC   ice_update_tau    ! called by ice_stp
42
43   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
44   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
45
46   !! * Substitutions
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   INTEGER FUNCTION ice_update_alloc()
56      !!-------------------------------------------------------------------
57      !!             ***  ROUTINE ice_update_alloc ***
58      !!-------------------------------------------------------------------
59      ALLOCATE( utau_oce(jpi,jpj), vtau_oce(jpi,jpj), tmod_io(jpi,jpj), STAT=ice_update_alloc )
60      !
61      CALL mpp_sum( 'iceupdate', ice_update_alloc )
62      IF( ice_update_alloc /= 0 )   CALL ctl_stop( 'STOP', 'ice_update_alloc: failed to allocate arrays' )
63      !
64   END FUNCTION ice_update_alloc
65
66
67   SUBROUTINE ice_update_flx( kt )
68      !!-------------------------------------------------------------------
69      !!                ***  ROUTINE ice_update_flx ***
70      !! 
71      !! ** Purpose :   Update the surface ocean boundary condition for heat
72      !!                salt and mass over areas where sea-ice is non-zero
73      !!         
74      !! ** Action  : - computes the heat and freshwater/salt fluxes
75      !!                at the ice-ocean interface.
76      !!              - Update the ocean sbc
77      !!     
78      !! ** Outputs : - qsr     : sea heat flux:     solar
79      !!              - qns     : sea heat flux: non solar
80      !!              - emp     : freshwater budget: volume flux
81      !!              - sfx     : salt flux
82      !!              - fr_i    : ice fraction
83      !!              - tn_ice  : sea-ice surface temperature
84      !!              - alb_ice : sea-ice albedo (recomputed only for coupled mode)
85      !!
86      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
87      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
88      !!              These refs are now obsolete since everything has been revised
89      !!              The ref should be Rousset et al., 2015
90      !!---------------------------------------------------------------------
91      INTEGER, INTENT(in) ::   kt   ! number of iteration
92      !
93      INTEGER  ::   ji, jj, jl, jk   ! dummy loop indices
94      REAL(wp) ::   zqsr             ! New solar flux received by the ocean
95      REAL(wp), DIMENSION(jpi,jpj) ::   z2d                  ! 2D workspace
96      !!---------------------------------------------------------------------
97      IF( ln_timing )   CALL timing_start('ice_update')
98
99      IF( kt == nit000 .AND. lwp ) THEN
100         WRITE(numout,*)
101         WRITE(numout,*)'ice_update_flx: update fluxes (mass, salt and heat) at the ice-ocean interface'
102         WRITE(numout,*)'~~~~~~~~~~~~~~'
103      ENDIF
104
105      ! Net heat flux on top of the ice-ocean (W.m-2)
106      !----------------------------------------------
107      qt_atm_oi(:,:) = qns_tot(:,:) + qsr_tot(:,:) 
108
109      ! --- case we bypass ice thermodynamics --- !
110      IF( .NOT. ln_icethd ) THEN   ! we suppose ice is impermeable => ocean is isolated from atmosphere
111         qt_atm_oi  (:,:)   = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
112         qt_oce_ai  (:,:)   = ( 1._wp - at_i_b(:,:) ) *   qns_oce(:,:)                  + qemp_oce(:,:)
113         emp_ice    (:,:)   = 0._wp
114         qemp_ice   (:,:)   = 0._wp
115         qevap_ice  (:,:,:) = 0._wp
116      ENDIF
117     
118      DO jj = 1, jpj
119         DO ji = 1, jpi
120
121            ! Solar heat flux reaching the ocean (max) = zqsr (W.m-2)
122            !---------------------------------------------------
123            zqsr = qsr_tot(ji,jj) - SUM( a_i_b(ji,jj,:) * ( qsr_ice(ji,jj,:) - qtr_ice_bot(ji,jj,:) ) )
124
125            ! Total heat flux reaching the ocean = qt_oce_ai (W.m-2)
126            !---------------------------------------------------
127            qt_oce_ai(ji,jj) = qt_atm_oi(ji,jj) - hfx_sum(ji,jj) - hfx_bom(ji,jj) - hfx_bog(ji,jj) &
128               &                                - hfx_dif(ji,jj) - hfx_opw(ji,jj) - hfx_snw(ji,jj) &
129               &                                + hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj)                 
130           
131            ! New qsr and qns used to compute the oceanic heat flux at the next time step
132            !----------------------------------------------------------------------------
133            ! if warming and some ice remains, then we suppose that the whole solar flux has been consumed to melt the ice
134            ! else ( cooling or no ice left ), then we suppose that     no    solar flux has been consumed
135            !
136            IF( fhld(ji,jj) > 0._wp .AND. at_i(ji,jj) > 0._wp ) THEN   !-- warming and some ice remains
137               !                                        solar flux transmitted thru the 1st level of the ocean (i.e. not used by sea-ice)
138               qsr(ji,jj) = ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * ( 1._wp - frq_m(ji,jj) ) &
139                  !                                   + solar flux transmitted thru ice and the 1st ocean level (also not used by sea-ice)
140                  &             + SUM( a_i_b(ji,jj,:) * qtr_ice_bot(ji,jj,:) ) * ( 1._wp - frq_m(ji,jj) )
141               !
142            ELSE                                                       !-- cooling or no ice left
143               qsr(ji,jj) = zqsr
144            ENDIF
145            !
146            ! the non-solar is simply derived from the solar flux
147            qns(ji,jj) = qt_oce_ai(ji,jj) - zqsr             
148
149            ! Mass flux at the atm. surface       
150            !-----------------------------------
151            wfx_sub(ji,jj) = wfx_snw_sub(ji,jj) + wfx_ice_sub(ji,jj)
152
153            ! Mass flux at the ocean surface     
154            !------------------------------------
155            ! ice-ocean  mass flux
156            wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj)   &
157               &           + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) + wfx_pnd(ji,jj)
158
159            ! snw-ocean mass flux
160            wfx_snw(ji,jj) = wfx_snw_sni(ji,jj) + wfx_snw_dyn(ji,jj) + wfx_snw_sum(ji,jj)
161
162            ! total mass flux at the ocean/ice interface
163            fmmflx(ji,jj) =                - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj)   ! ice-ocean mass flux saved at least for biogeochemical model
164            emp   (ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj)   ! atm-ocean + ice-ocean mass flux
165
166            ! Salt flux at the ocean surface     
167            !------------------------------------------
168            sfx(ji,jj) = sfx_bog(ji,jj) + sfx_bom(ji,jj) + sfx_sum(ji,jj) + sfx_sni(ji,jj) + sfx_opw(ji,jj)   &
169               &       + sfx_res(ji,jj) + sfx_dyn(ji,jj) + sfx_bri(ji,jj) + sfx_sub(ji,jj) + sfx_lam(ji,jj)
170           
171            ! Mass of snow and ice per unit area   
172            !----------------------------------------
173            snwice_mass_b(ji,jj) = snwice_mass(ji,jj)       ! save mass from the previous ice time step
174            !                                               ! new mass per unit area
175            snwice_mass  (ji,jj) = tmask(ji,jj,1) * ( rhos * vt_s(ji,jj) + rhoi * vt_i(ji,jj)  ) 
176            !                                               ! time evolution of snow+ice mass
177            snwice_fmass (ji,jj) = ( snwice_mass(ji,jj) - snwice_mass_b(ji,jj) ) * r1_rdtice
178           
179         END DO
180      END DO
181
182      ! Storing the transmitted variables
183      !----------------------------------
184      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
185      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
186
187      ! Snow/ice albedo (only if sent to coupler, useless in forced mode)
188      !------------------------------------------------------------------
189      CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_eff, h_ip, cloud_fra, alb_ice ) ! ice albedo
190
191      !
192      IF( lrst_ice ) THEN                       !* write snwice_mass fields in the restart file
193         CALL update_rst( 'WRITE', kt )
194      ENDIF
195      !
196      ! output all fluxes
197      !------------------
198      !
199      ! --- salt fluxes [kg/m2/s] --- !
200      !                           ! sfxice =  sfxbog + sfxbom + sfxsum + sfxsni + sfxopw + sfxres + sfxdyn + sfxbri + sfxsub + sfxlam
201      IF( iom_use('sfxice'  ) )   CALL iom_put( 'sfxice', sfx     * 1.e-03 )   ! salt flux from total ice growth/melt
202      IF( iom_use('sfxbog'  ) )   CALL iom_put( 'sfxbog', sfx_bog * 1.e-03 )   ! salt flux from bottom growth
203      IF( iom_use('sfxbom'  ) )   CALL iom_put( 'sfxbom', sfx_bom * 1.e-03 )   ! salt flux from bottom melting
204      IF( iom_use('sfxsum'  ) )   CALL iom_put( 'sfxsum', sfx_sum * 1.e-03 )   ! salt flux from surface melting
205      IF( iom_use('sfxlam'  ) )   CALL iom_put( 'sfxlam', sfx_lam * 1.e-03 )   ! salt flux from lateral melting
206      IF( iom_use('sfxsni'  ) )   CALL iom_put( 'sfxsni', sfx_sni * 1.e-03 )   ! salt flux from snow ice formation
207      IF( iom_use('sfxopw'  ) )   CALL iom_put( 'sfxopw', sfx_opw * 1.e-03 )   ! salt flux from open water formation
208      IF( iom_use('sfxdyn'  ) )   CALL iom_put( 'sfxdyn', sfx_dyn * 1.e-03 )   ! salt flux from ridging rafting
209      IF( iom_use('sfxbri'  ) )   CALL iom_put( 'sfxbri', sfx_bri * 1.e-03 )   ! salt flux from brines
210      IF( iom_use('sfxres'  ) )   CALL iom_put( 'sfxres', sfx_res * 1.e-03 )   ! salt flux from undiagnosed processes
211      IF( iom_use('sfxsub'  ) )   CALL iom_put( 'sfxsub', sfx_sub * 1.e-03 )   ! salt flux from sublimation
212
213      ! --- mass fluxes [kg/m2/s] --- !
214      CALL iom_put( 'emp_oce', emp_oce )   ! emp over ocean (taking into account the snow blown away from the ice)
215      CALL iom_put( 'emp_ice', emp_ice )   ! emp over ice   (taking into account the snow blown away from the ice)
216
217      !                           ! vfxice = vfxbog + vfxbom + vfxsum + vfxsni + vfxopw + vfxdyn + vfxres + vfxlam + vfxpnd
218      CALL iom_put( 'vfxice'    , wfx_ice     )   ! mass flux from total ice growth/melt
219      CALL iom_put( 'vfxbog'    , wfx_bog     )   ! mass flux from bottom growth
220      CALL iom_put( 'vfxbom'    , wfx_bom     )   ! mass flux from bottom melt
221      CALL iom_put( 'vfxsum'    , wfx_sum     )   ! mass flux from surface melt
222      CALL iom_put( 'vfxlam'    , wfx_lam     )   ! mass flux from lateral melt
223      CALL iom_put( 'vfxsni'    , wfx_sni     )   ! mass flux from snow-ice formation
224      CALL iom_put( 'vfxopw'    , wfx_opw     )   ! mass flux from growth in open water
225      CALL iom_put( 'vfxdyn'    , wfx_dyn     )   ! mass flux from dynamics (ridging)
226      CALL iom_put( 'vfxres'    , wfx_res     )   ! mass flux from undiagnosed processes
227      CALL iom_put( 'vfxpnd'    , wfx_pnd     )   ! mass flux from melt ponds
228      CALL iom_put( 'vfxsub'    , wfx_ice_sub )   ! mass flux from ice sublimation (ice-atm.)
229      CALL iom_put( 'vfxsub_err', wfx_err_sub )   ! "excess" of sublimation sent to ocean     
230
231      IF ( iom_use( 'vfxthin' ) ) THEN   ! mass flux from ice growth in open water + thin ice (<20cm) => comparable to observations 
232         WHERE( hm_i(:,:) < 0.2 .AND. hm_i(:,:) > 0. ) ; z2d = wfx_bog
233         ELSEWHERE                                     ; z2d = 0._wp
234         END WHERE
235         CALL iom_put( 'vfxthin', wfx_opw + z2d )
236      ENDIF
237
238      !                            ! vfxsnw = vfxsnw_sni + vfxsnw_dyn + vfxsnw_sum
239      CALL iom_put( 'vfxsnw'     , wfx_snw     )   ! mass flux from total snow growth/melt
240      CALL iom_put( 'vfxsnw_sum' , wfx_snw_sum )   ! mass flux from snow melt at the surface
241      CALL iom_put( 'vfxsnw_sni' , wfx_snw_sni )   ! mass flux from snow melt during snow-ice formation
242      CALL iom_put( 'vfxsnw_dyn' , wfx_snw_dyn )   ! mass flux from dynamics (ridging)
243      CALL iom_put( 'vfxsnw_sub' , wfx_snw_sub )   ! mass flux from snow sublimation (ice-atm.)
244      CALL iom_put( 'vfxsnw_pre' , wfx_spr     )   ! snow precip
245
246      ! --- heat fluxes [W/m2] --- !
247      !                              ! qt_atm_oi - qt_oce_ai = hfxdhc - ( dihctrp + dshctrp )
248      IF( iom_use('qsr_oce'    ) )   CALL iom_put( 'qsr_oce'    , qsr_oce * ( 1._wp - at_i_b )                               )   !     solar flux at ocean surface
249      IF( iom_use('qns_oce'    ) )   CALL iom_put( 'qns_oce'    , qns_oce * ( 1._wp - at_i_b ) + qemp_oce                    )   ! non-solar flux at ocean surface
250      IF( iom_use('qsr_ice'    ) )   CALL iom_put( 'qsr_ice'    , SUM( qsr_ice * a_i_b, dim=3 )                              )   !     solar flux at ice surface
251      IF( iom_use('qns_ice'    ) )   CALL iom_put( 'qns_ice'    , SUM( qns_ice * a_i_b, dim=3 ) + qemp_ice                   )   ! non-solar flux at ice surface
252      IF( iom_use('qtr_ice_bot') )   CALL iom_put( 'qtr_ice_bot', SUM( qtr_ice_bot * a_i_b, dim=3 )                          )   !     solar flux transmitted thru ice
253      IF( iom_use('qtr_ice_top') )   CALL iom_put( 'qtr_ice_top', SUM( qtr_ice_top * a_i_b, dim=3 )                          )   !     solar flux transmitted thru ice surface
254      IF( iom_use('qt_oce'     ) )   CALL iom_put( 'qt_oce'     ,      ( qsr_oce + qns_oce ) * ( 1._wp - at_i_b ) + qemp_oce )
255      IF( iom_use('qt_ice'     ) )   CALL iom_put( 'qt_ice'     , SUM( ( qns_ice + qsr_ice ) * a_i_b, dim=3 )     + qemp_ice )
256      IF( iom_use('qt_oce_ai'  ) )   CALL iom_put( 'qt_oce_ai'  , qt_oce_ai * tmask(:,:,1)                                   )   ! total heat flux at the ocean   surface: interface oce-(ice+atm)
257      IF( iom_use('qt_atm_oi'  ) )   CALL iom_put( 'qt_atm_oi'  , qt_atm_oi * tmask(:,:,1)                                   )   ! total heat flux at the oce-ice surface: interface atm-(ice+oce)
258      IF( iom_use('qemp_oce'   ) )   CALL iom_put( 'qemp_oce'   , qemp_oce                                                   )   ! Downward Heat Flux from E-P over ocean
259      IF( iom_use('qemp_ice'   ) )   CALL iom_put( 'qemp_ice'   , qemp_ice                                                   )   ! Downward Heat Flux from E-P over ice
260
261      ! heat fluxes from ice transformations
262      !                            ! hfxdhc = hfxbog + hfxbom + hfxsum + hfxopw + hfxdif + hfxsnw - ( hfxthd + hfxdyn + hfxres + hfxsub + hfxspr )
263      CALL iom_put ('hfxbog'     , hfx_bog     )   ! heat flux used for ice bottom growth
264      CALL iom_put ('hfxbom'     , hfx_bom     )   ! heat flux used for ice bottom melt
265      CALL iom_put ('hfxsum'     , hfx_sum     )   ! heat flux used for ice surface melt
266      CALL iom_put ('hfxopw'     , hfx_opw     )   ! heat flux used for ice formation in open water
267      CALL iom_put ('hfxdif'     , hfx_dif     )   ! heat flux used for ice temperature change
268      CALL iom_put ('hfxsnw'     , hfx_snw     )   ! heat flux used for snow melt
269      CALL iom_put ('hfxerr'     , hfx_err_dif )   ! heat flux error after heat diffusion
270
271      ! heat fluxes associated with mass exchange (freeze/melt/precip...)
272      CALL iom_put ('hfxthd'     , hfx_thd     )   
273      CALL iom_put ('hfxdyn'     , hfx_dyn     )   
274      CALL iom_put ('hfxres'     , hfx_res     )   
275      CALL iom_put ('hfxsub'     , hfx_sub     )   
276      CALL iom_put ('hfxspr'     , hfx_spr     )   ! Heat flux from snow precip heat content
277
278      ! other heat fluxes
279      IF( iom_use('hfxsensib'  ) )   CALL iom_put( 'hfxsensib'  ,     -qsb_ice_bot * at_i_b         )   ! Sensible oceanic heat flux
280      IF( iom_use('hfxcndbot'  ) )   CALL iom_put( 'hfxcndbot'  , SUM( qcn_ice_bot * a_i_b, dim=3 ) )   ! Bottom conduction flux
281      IF( iom_use('hfxcndtop'  ) )   CALL iom_put( 'hfxcndtop'  , SUM( qcn_ice_top * a_i_b, dim=3 ) )   ! Surface conduction flux
282
283      ! controls
284      !---------
285#if ! defined key_agrif
286      IF( ln_icediachk )   CALL ice_cons_final('iceupdate')                                       ! conservation
287#endif
288      IF( ln_icectl    )   CALL ice_prt       (kt, iiceprt, jiceprt, 3, 'Final state ice_update') ! prints
289      IF( ln_ctl       )   CALL ice_prt3D     ('iceupdate')                                       ! prints
290      IF( ln_timing    )   CALL timing_stop   ('ice_update')                                      ! timing
291      !
292   END SUBROUTINE ice_update_flx
293
294
295   SUBROUTINE ice_update_tau( kt, pu_oce, pv_oce )
296      !!-------------------------------------------------------------------
297      !!                ***  ROUTINE ice_update_tau ***
298      !! 
299      !! ** Purpose : Update the ocean surface stresses due to the ice
300      !!         
301      !! ** Action  : * at each ice time step (every nn_fsbc time step):
302      !!                - compute the modulus of ice-ocean relative velocity
303      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
304      !!                      tmod_io = rhoco * | U_ice-U_oce |
305      !!                - update the modulus of stress at ocean surface
306      !!                      taum = (1-a) * taum + a * tmod_io * | U_ice-U_oce |
307      !!              * at each ocean time step (every kt):
308      !!                  compute linearized ice-ocean stresses as
309      !!                      Utau = tmod_io * | U_ice - pU_oce |
310      !!                using instantaneous current ocean velocity (usually before)
311      !!
312      !!    NB: - ice-ocean rotation angle no more allowed
313      !!        - here we make an approximation: taum is only computed every ice time step
314      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
315      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
316      !!
317      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
318      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
319      !!---------------------------------------------------------------------
320      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
321      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
322      !
323      INTEGER  ::   ji, jj   ! dummy loop indices
324      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
325      REAL(wp) ::   zat_v, zvtau_ice, zv_t, zrhoco  !   -      -
326      REAL(wp) ::   zflagi                          !   -      -
327      !!---------------------------------------------------------------------
328      IF( ln_timing )   CALL timing_start('ice_update_tau')
329
330      IF( kt == nit000 .AND. lwp ) THEN
331         WRITE(numout,*)
332         WRITE(numout,*)'ice_update_tau: update stress at the ice-ocean interface'
333         WRITE(numout,*)'~~~~~~~~~~~~~~'
334      ENDIF
335
336      zrhoco = rau0 * rn_cio
337      !
338      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
339         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
340            DO ji = fs_2, fs_jpim1
341               !                                               ! 2*(U_ice-U_oce) at T-point
342               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
343               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
344               !                                              ! |U_ice-U_oce|^2
345               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
346               !                                               ! update the ocean stress modulus
347               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt
348               tmod_io(ji,jj) = zrhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
349            END DO
350         END DO
351         CALL lbc_lnk_multi( 'iceupdate', taum, 'T', 1., tmod_io, 'T', 1. )
352         !
353         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
354         vtau_oce(:,:) = vtau(:,:)
355         !
356      ENDIF
357      !
358      !                                      !==  every ocean time-step  ==!
359      IF ( ln_drgice_imp ) THEN
360         ! Save drag with right sign to update top drag in the ocean implicit friction
361         rCdU_ice(:,:) = -r1_rau0 * tmod_io(:,:) * at_i(:,:) * tmask(:,:,1) 
362         zflagi = 0._wp
363      ELSE
364         zflagi = 1._wp
365      ENDIF
366      !
367      DO jj = 2, jpjm1                                !* update the stress WITHOUT an ice-ocean rotation angle
368         DO ji = fs_2, fs_jpim1   ! Vect. Opt.   
369            ! ice area at u and v-points
370            zat_u  = ( at_i(ji,jj) * tmask(ji,jj,1) + at_i (ji+1,jj    ) * tmask(ji+1,jj  ,1) )  &
371               &     / MAX( 1.0_wp , tmask(ji,jj,1) + tmask(ji+1,jj  ,1) )
372            zat_v  = ( at_i(ji,jj) * tmask(ji,jj,1) + at_i (ji  ,jj+1  ) * tmask(ji  ,jj+1,1) )  &
373               &     / MAX( 1.0_wp , tmask(ji,jj,1) + tmask(ji  ,jj+1,1) )
374            !                                                   ! linearized quadratic drag formulation
375            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - zflagi * pu_oce(ji,jj) )
376            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - zflagi * pv_oce(ji,jj) )
377            !                                                   ! stresses at the ocean surface
378            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
379            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
380         END DO
381      END DO
382      CALL lbc_lnk_multi( 'iceupdate', utau, 'U', -1., vtau, 'V', -1. )   ! lateral boundary condition
383      !
384      IF( ln_timing )   CALL timing_stop('ice_update_tau')
385     
386   END SUBROUTINE ice_update_tau
387
388
389   SUBROUTINE ice_update_init
390      !!-------------------------------------------------------------------
391      !!                  ***  ROUTINE ice_update_init  ***
392      !!             
393      !! ** Purpose :   allocate ice-ocean stress fields and read restarts
394      !!                containing the snow & ice mass
395      !!
396      !!-------------------------------------------------------------------
397      INTEGER  ::   ji, jj, jk               ! dummy loop indices
398      REAL(wp) ::   zcoefu, zcoefv, zcoeff   ! local scalar
399      !!-------------------------------------------------------------------
400      !
401      IF(lwp) WRITE(numout,*)
402      IF(lwp) WRITE(numout,*) 'ice_update_init: ice-ocean stress init'
403      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
404      !
405      !                                      ! allocate ice_update array
406      IF( ice_update_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'ice_update_init : unable to allocate standard arrays' )
407      !
408      CALL update_rst( 'READ' )  !* read or initialize all required files
409      !
410   END SUBROUTINE ice_update_init
411
412
413   SUBROUTINE update_rst( cdrw, kt )
414      !!---------------------------------------------------------------------
415      !!                   ***  ROUTINE rhg_evp_rst  ***
416      !!                     
417      !! ** Purpose :   Read or write RHG file in restart file
418      !!
419      !! ** Method  :   use of IOM library
420      !!----------------------------------------------------------------------
421      CHARACTER(len=*) , INTENT(in) ::   cdrw   ! 'READ'/'WRITE' flag
422      INTEGER, OPTIONAL, INTENT(in) ::   kt     ! ice time-step
423      !
424      INTEGER  ::   iter   ! local integer
425      INTEGER  ::   id1    ! local integer
426      !!----------------------------------------------------------------------
427      !
428      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialize
429         !                                   ! ---------------
430         IF( ln_rstart ) THEN                   !* Read the restart file
431            !
432            id1 = iom_varid( numrir, 'snwice_mass' , ldstop = .FALSE. )
433            !
434            IF( id1 > 0 ) THEN                       ! fields exist
435               CALL iom_get( numrir, jpdom_autoglo, 'snwice_mass'  , snwice_mass   )
436               CALL iom_get( numrir, jpdom_autoglo, 'snwice_mass_b', snwice_mass_b )
437            ELSE                                     ! start from rest
438               IF(lwp) WRITE(numout,*) '   ==>>   previous run without snow-ice mass output then set it'
439               snwice_mass  (:,:) = tmask(:,:,1) * ( rhos * vt_s(:,:) + rhoi * vt_i(:,:) )
440               snwice_mass_b(:,:) = snwice_mass(:,:)
441            ENDIF
442         ELSE                                   !* Start from rest
443            IF(lwp) WRITE(numout,*) '   ==>>   start from rest: set the snow-ice mass'
444            snwice_mass  (:,:) = tmask(:,:,1) * ( rhos * vt_s(:,:) + rhoi * vt_i(:,:) )
445            snwice_mass_b(:,:) = snwice_mass(:,:)
446         ENDIF
447         !
448      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
449         !                                   ! -------------------
450         IF(lwp) WRITE(numout,*) '---- update-rst ----'
451         iter = kt + nn_fsbc - 1             ! ice restarts are written at kt == nitrst - nn_fsbc + 1
452         !
453         CALL iom_rstput( iter, nitrst, numriw, 'snwice_mass'  , snwice_mass   )
454         CALL iom_rstput( iter, nitrst, numriw, 'snwice_mass_b', snwice_mass_b )
455         !
456      ENDIF
457      !
458   END SUBROUTINE update_rst
459
460#else
461   !!----------------------------------------------------------------------
462   !!   Default option         Dummy module           NO SI3 sea-ice model
463   !!----------------------------------------------------------------------
464#endif 
465
466   !!======================================================================
467END MODULE iceupdate
Note: See TracBrowser for help on using the repository browser.