New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/UKMO/dev_r12866_HPC-02_Daley_Tiling_trial_extra_halo/src/OCE/TRA – NEMO

source: NEMO/branches/UKMO/dev_r12866_HPC-02_Daley_Tiling_trial_extra_halo/src/OCE/TRA/traadv_fct.F90 @ 13409

Last change on this file since 13409 was 13409, checked in by hadcv, 3 years ago

Remaining changes prior to trunk merge
  • Property svn:keywords set to Id
File size: 34.2 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   ! TEMP: This change not necessary after trd_tra is tiled
18   USE domain, ONLY : dom_tile
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE trd_oce        ! trends: ocean variables
21   USE trdtra         ! tracers trends
22   USE diaptr         ! poleward transport diagnostics
23   USE diaar5         ! AR5 diagnostics
24   USE phycst  , ONLY : rho0_rcp
25   USE zdf_oce , ONLY : ln_zad_Aimp
26   !
27   USE in_out_manager ! I/O manager
28   USE iom            !
29   USE lib_mpp        ! MPP library
30   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
31   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv_fct        ! called by traadv.F90
37   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
38
39   LOGICAL  ::   l_trd   ! flag to compute trends
40   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
41   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
42   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
43
44   !                                        ! tridiag solver associated indices:
45   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
46   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
52   !! $Id$
53   !! Software governed by the CeCILL license (see ./LICENSE)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
58      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
59      !!----------------------------------------------------------------------
60      !!                  ***  ROUTINE tra_adv_fct  ***
61      !!
62      !! **  Purpose :   Compute the now trend due to total advection of tracers
63      !!               and add it to the general trend of tracer equations
64      !!
65      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
66      !!               (choice through the value of kn_fct)
67      !!               - on the vertical the 4th order is a compact scheme
68      !!               - corrected flux (monotonic correction)
69      !!
70      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
71      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
72      !!             - poleward advective heat and salt transport (ln_diaptr=T)
73      !!----------------------------------------------------------------------
74      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
75      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
76      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
77      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
78      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
79      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
80      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
81      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
82      ! TEMP: This can be A2D after trd_tra is tiled
83      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
85      !
86      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
87      ! TEMP: This change not necessary after trd_tra is tiled
88      INTEGER  ::   itile
89      REAL(wp) ::   ztra                                     ! local scalar
90      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
91      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
92      REAL(wp), DIMENSION(A2D,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
93      ! TEMP: This change not necessary after trd_tra is tiled
94      REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   ztrdx, ztrdy, ztrdz
95      REAL(wp), DIMENSION(:,:,:)      , ALLOCATABLE ::   zptry
96      REAL(wp), DIMENSION(:,:,:)      , ALLOCATABLE ::   zwinf, zwdia, zwsup
97      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
98      !!----------------------------------------------------------------------
99      ! TEMP: This change not necessary after trd_tra is tiled
100      itile = ntile
101      !
102      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
103         IF( kt == kit000 )  THEN
104            IF(lwp) WRITE(numout,*)
105            IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
106            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
107         ENDIF
108         !
109         l_trd = .FALSE.            ! set local switches
110         l_hst = .FALSE.
111         l_ptr = .FALSE.
112         ll_zAimp = .FALSE.
113         IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
114         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE.
115         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
116            &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
117         !
118         ! TEMP: This can be A2D after trd_tra is tiled
119         IF( kt == kit000 .AND. (l_trd .OR. l_hst) )  THEN
120            ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
121         ENDIF
122      ENDIF
123      !
124      IF( l_ptr ) THEN 
125         ALLOCATE( zptry(A2D,jpk) )
126         zptry(:,:,:) = 0._wp
127      ENDIF
128      !                          ! surface & bottom value : flux set to zero one for all
129      zwz(:,:, 1 ) = 0._wp           
130      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
131      !
132      zwi(:,:,:) = 0._wp       
133      !
134      ! If adaptive vertical advection, check if it is needed on this PE at this time
135      IF( ln_zad_Aimp ) THEN
136         IF( MAXVAL( ABS( wi(A2D,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
137      END IF
138      ! If active adaptive vertical advection, build tridiagonal matrix
139      IF( ll_zAimp ) THEN
140         ALLOCATE(zwdia(A2D,jpk), zwinf(A2D,jpk), zwsup(A2D,jpk))
141         DO_3D_00_00( 1, jpkm1 )
142            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) ) / e3t(ji,jj,jk,Krhs)
143            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
144            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
145         END_3D
146      END IF
147      !
148      DO jn = 1, kjpt            !==  loop over the tracers  ==!
149         !
150         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
151         !                    !* upstream tracer flux in the i and j direction
152         DO_3D_10_10( 1, jpkm1 )
153            ! upstream scheme
154            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
155            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
156            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
157            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
158            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
159            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
160         END_3D
161         !                    !* upstream tracer flux in the k direction *!
162         DO_3D_11_11( 2, jpkm1 )
163            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
164            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
165            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
166         END_3D
167         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
168            ! TODO: NOT TESTED- requires isf
169            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
170               DO_2D_11_11
171                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
172               END_2D
173            ELSE                             ! no cavities: only at the ocean surface
174               DO_2D_11_11
175                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
176               END_2D
177            ENDIF
178         ENDIF
179         !               
180         DO_3D_00_00( 1, jpkm1 )
181            !                             ! total intermediate advective trends
182            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
183               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
184               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
185            !                             ! update and guess with monotonic sheme
186            pt(ji,jj,jk,jn,Krhs) =                     pt(ji,jj,jk,jn,Krhs) +        ztra   / e3t(ji,jj,jk,Kmm) * tmask(ji,jj,jk)
187            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
188         END_3D
189         
190         IF ( ll_zAimp ) THEN
191            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
192            !
193            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
194            DO_3D_00_00( 2, jpkm1 )
195               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
196               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
197               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
198               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
199            END_3D
200            DO_3D_00_00( 1, jpkm1 )
201               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
202                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
203            END_3D
204            !
205         END IF
206         !               
207         ! TEMP: This change not necessary after trd_tra is tiled
208         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
209            DO_3D_11_11( 1, jpk )
210               ztrdx(ji,jj,jk) = zwx(ji,jj,jk)   ;   ztrdy(ji,jj,jk) = zwy(ji,jj,jk)   ;   ztrdz(ji,jj,jk) = zwz(ji,jj,jk)
211            END_3D
212         END IF
213         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
214         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
215         !
216         !        !==  anti-diffusive flux : high order minus low order  ==!
217         !
218         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
219         !
220         CASE(  2  )                   !- 2nd order centered
221            DO_3D_10_10( 1, jpkm1 )
222               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
223               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
224            END_3D
225            !
226         CASE(  4  )                   !- 4th order centered
227            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
228            zltv(:,:,jpk) = 0._wp
229            DO jk = 1, jpkm1                 ! Laplacian
230               DO_2D_10_10
231                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
232                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
233               END_2D
234               DO_2D_00_00
235                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
236                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
237               END_2D
238            END DO
239            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1. , zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
240            !
241            DO_3D_10_10( 1, jpkm1 )
242               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
243               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
244               !                                                  ! C4 minus upstream advective fluxes
245               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
246               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
247            END_3D
248            !
249         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
250            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
251            ztv(:,:,jpk) = 0._wp
252            DO_3D_10_10( 1, jpkm1 )
253               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
254               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
255            END_3D
256            CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1. , ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
257            !
258            DO_3D_00_00( 1, jpkm1 )
259               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
260               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
261               !                                                  ! C4 interpolation of T at u- & v-points (x2)
262               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
263               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
264               !                                                  ! C4 minus upstream advective fluxes
265               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
266               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
267            END_3D
268            !
269         END SELECT
270         !                     
271         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
272         !
273         CASE(  2  )                   !- 2nd order centered
274            DO_3D_00_00( 2, jpkm1 )
275               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
276                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
277            END_3D
278            !
279         CASE(  4  )                   !- 4th order COMPACT
280            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
281            DO_3D_00_00( 2, jpkm1 )
282               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
283            END_3D
284            !
285         END SELECT
286         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
287            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
288         ENDIF
289         !         
290         IF ( ll_zAimp ) THEN
291            DO_3D_00_00( 1, jpkm1 )
292               !                             ! total intermediate advective trends
293               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
294                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
295                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
296               ztw(ji,jj,jk)  = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
297            END_3D
298            !
299            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
300            !
301            DO_3D_00_00( 2, jpkm1 )
302               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
303               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
304               zwz(ji,jj,jk) =  zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
305            END_3D
306         END IF
307         !
308         CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1., zwx, 'U', -1. , zwy, 'V', -1.,  zwz, 'W',  1. )
309         !
310         !        !==  monotonicity algorithm  ==!
311         !
312         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
313         !
314         !        !==  final trend with corrected fluxes  ==!
315         !
316         DO_3D_00_00( 1, jpkm1 )
317            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
318               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
319               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
320            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
321            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
322         END_3D
323         !
324         IF ( ll_zAimp ) THEN
325            !
326            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
327            DO_3D_00_00( 2, jpkm1 )
328               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
329               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
330               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
331               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
332            END_3D
333            DO_3D_00_00( 1, jpkm1 )
334               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
335                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
336            END_3D
337         END IF         
338         !
339         ! TEMP: These changes not necessary after trd_tra is tiled
340         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
341            DO_3D_11_11( 1, jpk )
342               ztrdx(ji,jj,jk) = ztrdx(ji,jj,jk) + zwx(ji,jj,jk)  ! <<< add anti-diffusive fluxes
343               ztrdy(ji,jj,jk) = ztrdy(ji,jj,jk) + zwy(ji,jj,jk)  !     to upstream fluxes
344               ztrdz(ji,jj,jk) = ztrdz(ji,jj,jk) + zwz(ji,jj,jk)  !
345            END_3D
346            !
347            IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
348               IF( l_trd ) THEN              ! trend diagnostics
349                  IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )         ! Use full domain
350
351                  ! TODO: TO BE TILED- trd_tra
352                  CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
353                  CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
354                  CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
355
356                  IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = itile )     ! Revert to tile domain
357               ENDIF
358            ENDIF
359            !                             ! heat/salt transport
360            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(A2D,:), ztrdy(A2D,:) )
361            !
362         ENDIF
363         IF( l_ptr ) THEN              ! "Poleward" transports
364            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
365            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
366         ENDIF
367         !
368      END DO                     ! end of tracer loop
369      !
370      IF ( ll_zAimp ) THEN
371         DEALLOCATE( zwdia, zwinf, zwsup )
372      ENDIF
373      ! TEMP: These changes not necessary after trd_tra is tiled
374!      IF( l_trd .OR. l_hst ) THEN
375!         DEALLOCATE( ztrdx, ztrdy, ztrdz )
376!      ENDIF
377      IF( l_ptr ) THEN
378         DEALLOCATE( zptry )
379      ENDIF
380      !
381   END SUBROUTINE tra_adv_fct
382
383
384   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
385      !!---------------------------------------------------------------------
386      !!                    ***  ROUTINE nonosc  ***
387      !!     
388      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
389      !!       scheme and the before field by a nonoscillatory algorithm
390      !!
391      !! **  Method  :   ... ???
392      !!       warning : pbef and paft must be masked, but the boundaries
393      !!       conditions on the fluxes are not necessary zalezak (1979)
394      !!       drange (1995) multi-dimensional forward-in-time and upstream-
395      !!       in-space based differencing for fluid
396      !!----------------------------------------------------------------------
397      INTEGER                         , INTENT(in   ) ::   Kmm             ! time level index
398      REAL(wp)                        , INTENT(in   ) ::   p2dt            ! tracer time-step
399      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pbef            ! before field
400      REAL(wp), DIMENSION(A2D    ,jpk), INTENT(in   ) ::   paft            ! after field
401      REAL(wp), DIMENSION(A2D    ,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
402      !
403      INTEGER  ::   ji, jj, jk   ! dummy loop indices
404      INTEGER  ::   ikm1         ! local integer
405      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
406      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
407      REAL(wp), DIMENSION(A2D,jpk) :: zbetup, zbetdo, zbup, zbdo
408      !!----------------------------------------------------------------------
409      !
410      zbig  = 1.e+40_wp
411      zrtrn = 1.e-15_wp
412      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
413
414      ! Search local extrema
415      ! --------------------
416      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
417      DO_3D_11_11( 1, jpk )
418         zbup(ji,jj,jk) = MAX( pbef(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
419            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) )  )
420         zbdo(ji,jj,jk) = MIN( pbef(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
421            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) )  )
422      END_3D
423
424      DO jk = 1, jpkm1
425         ikm1 = MAX(jk-1,1)
426         DO_2D_00_00
427
428            ! search maximum in neighbourhood
429            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
430               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
431               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
432               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
433
434            ! search minimum in neighbourhood
435            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
436               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
437               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
438               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
439
440            ! positive part of the flux
441            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
442               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
443               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
444
445            ! negative part of the flux
446            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
447               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
448               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
449
450            ! up & down beta terms
451            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
452            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
453            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
454         END_2D
455      END DO
456      CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1. , zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
457
458      ! 3. monotonic flux in the i & j direction (paa & pbb)
459      ! ----------------------------------------
460      DO_3D_00_00( 1, jpkm1 )
461         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
462         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
463         zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
464         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
465
466         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
467         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
468         zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
469         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
470
471! monotonic flux in the k direction, i.e. pcc
472! -------------------------------------------
473         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
474         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
475         zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
476         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
477      END_3D
478      CALL lbc_lnk_multi( 'traadv_fct', paa, 'U', -1. , pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
479      !
480   END SUBROUTINE nonosc
481
482
483   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
484      !!----------------------------------------------------------------------
485      !!                  ***  ROUTINE interp_4th_cpt_org  ***
486      !!
487      !! **  Purpose :   Compute the interpolation of tracer at w-point
488      !!
489      !! **  Method  :   4th order compact interpolation
490      !!----------------------------------------------------------------------
491      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
492      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
493      !
494      INTEGER :: ji, jj, jk   ! dummy loop integers
495      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
496      !!----------------------------------------------------------------------
497     
498      DO_3D_11_11( 3, jpkm1 )
499         zwd (ji,jj,jk) = 4._wp
500         zwi (ji,jj,jk) = 1._wp
501         zws (ji,jj,jk) = 1._wp
502         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
503         !
504         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
505            zwd (ji,jj,jk) = 1._wp
506            zwi (ji,jj,jk) = 0._wp
507            zws (ji,jj,jk) = 0._wp
508            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
509         ENDIF
510      END_3D
511      !
512      jk = 2                                          ! Switch to second order centered at top
513      DO_2D_11_11
514         zwd (ji,jj,jk) = 1._wp
515         zwi (ji,jj,jk) = 0._wp
516         zws (ji,jj,jk) = 0._wp
517         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
518      END_2D
519      !
520      !                       !==  tridiagonal solve  ==!
521      DO_2D_11_11
522         zwt(ji,jj,2) = zwd(ji,jj,2)
523      END_2D
524      DO_3D_11_11( 3, jpkm1 )
525         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
526      END_3D
527      !
528      DO_2D_11_11
529         pt_out(ji,jj,2) = zwrm(ji,jj,2)
530      END_2D
531      DO_3D_11_11( 3, jpkm1 )
532         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
533      END_3D
534
535      DO_2D_11_11
536         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
537      END_2D
538      DO_3DS_11_11( jpk-2, 2, -1 )
539         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
540      END_3D
541      !   
542   END SUBROUTINE interp_4th_cpt_org
543   
544
545   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
546      !!----------------------------------------------------------------------
547      !!                  ***  ROUTINE interp_4th_cpt  ***
548      !!
549      !! **  Purpose :   Compute the interpolation of tracer at w-point
550      !!
551      !! **  Method  :   4th order compact interpolation
552      !!----------------------------------------------------------------------
553      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
554      REAL(wp),DIMENSION(A2D    ,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
555      !
556      INTEGER ::   ji, jj, jk   ! dummy loop integers
557      INTEGER ::   ikt, ikb     ! local integers
558      REAL(wp),DIMENSION(A2D,jpk) :: zwd, zwi, zws, zwrm, zwt
559      !!----------------------------------------------------------------------
560      !
561      !                      !==  build the three diagonal matrix & the RHS  ==!
562      !
563      DO_3D_00_00( 3, jpkm1 )
564         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
565         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
566         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
567         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
568            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
569      END_3D
570      !
571!!gm
572!      SELECT CASE( kbc )               !* boundary condition
573!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
574!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
575!      END SELECT
576!!gm 
577      !
578      ! TODO: NOT TESTED- requires isf
579      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
580         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
581      END IF
582      !
583      DO_2D_00_00
584         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
585         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
586         !
587         zwd (ji,jj,ikt) = 1._wp          ! top
588         zwi (ji,jj,ikt) = 0._wp
589         zws (ji,jj,ikt) = 0._wp
590         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
591         !
592         zwd (ji,jj,ikb) = 1._wp          ! bottom
593         zwi (ji,jj,ikb) = 0._wp
594         zws (ji,jj,ikb) = 0._wp
595         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
596      END_2D
597      !
598      !                       !==  tridiagonal solver  ==!
599      !
600      DO_2D_00_00
601         zwt(ji,jj,2) = zwd(ji,jj,2)
602      END_2D
603      DO_3D_00_00( 3, jpkm1 )
604         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
605      END_3D
606      !
607      DO_2D_00_00
608         pt_out(ji,jj,2) = zwrm(ji,jj,2)
609      END_2D
610      DO_3D_00_00( 3, jpkm1 )
611         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
612      END_3D
613
614      DO_2D_00_00
615         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
616      END_2D
617      DO_3DS_00_00( jpk-2, 2, -1 )
618         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
619      END_3D
620      !   
621   END SUBROUTINE interp_4th_cpt
622
623
624   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
625      !!----------------------------------------------------------------------
626      !!                  ***  ROUTINE tridia_solver  ***
627      !!
628      !! **  Purpose :   solve a symmetric 3diagonal system
629      !!
630      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
631      !!     
632      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
633      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
634      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
635      !!             (        ...          )( ... )   ( ...  )
636      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
637      !!     
638      !!        M is decomposed in the product of an upper and lower triangular matrix.
639      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
640      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
641      !!        The solution is pta.
642      !!        The 3d array zwt is used as a work space array.
643      !!----------------------------------------------------------------------
644      REAL(wp),DIMENSION(A2D,jpk), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
645      REAL(wp),DIMENSION(A2D,jpk), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
646      REAL(wp),DIMENSION(A2D,jpk), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
647      INTEGER                    , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
648      !                                                             ! =0 pt at t-level
649      INTEGER ::   ji, jj, jk   ! dummy loop integers
650      INTEGER ::   kstart       ! local indices
651      REAL(wp),DIMENSION(A2D,jpk) ::   zwt   ! 3D work array
652      !!----------------------------------------------------------------------
653      !
654      kstart =  1  + klev
655      !
656      DO_2D_00_00
657         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
658      END_2D
659      DO_3D_00_00( kstart+1, jpkm1 )
660         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
661      END_3D
662      !
663      DO_2D_00_00
664         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
665      END_2D
666      DO_3D_00_00( kstart+1, jpkm1 )
667         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
668      END_3D
669
670      DO_2D_00_00
671         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
672      END_2D
673      DO_3DS_00_00( jpk-2, kstart, -1 )
674         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
675      END_3D
676      !
677   END SUBROUTINE tridia_solver
678
679   !!======================================================================
680END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.