New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in NEMO/branches/UKMO/dev_r12866_HPC-02_Daley_Tiling_trial_extra_halo/src/OCE/TRA – NEMO

source: NEMO/branches/UKMO/dev_r12866_HPC-02_Daley_Tiling_trial_extra_halo/src/OCE/TRA/traldf_iso.F90 @ 13409

Last change on this file since 13409 was 13409, checked in by hadcv, 3 years ago

Remaining changes prior to trunk merge
  • Property svn:keywords set to Id
File size: 21.4 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  ! 1994-08  (G. Madec, M. Imbard)
7   !!            8.0  ! 1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO ! 2002-08  (G. Madec)  Free form, F90
9   !!            1.0  ! 2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  ! 2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.7  ! 2014-01  (G. Madec, S. Masson)  restructuration/simplification of aht/aeiv specification
12   !!             -   ! 2014-02  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso   : update the tracer trend with the horizontal component of a iso-neutral laplacian operator
17   !!                   and with the vertical part of the isopycnal or geopotential s-coord. operator
18   !!----------------------------------------------------------------------
19   USE oce            ! ocean dynamics and active tracers
20   USE dom_oce        ! ocean space and time domain
21   USE domutl, ONLY : is_tile
22   USE trc_oce        ! share passive tracers/Ocean variables
23   USE zdf_oce        ! ocean vertical physics
24   USE ldftra         ! lateral diffusion: tracer eddy coefficients
25   USE ldfslp         ! iso-neutral slopes
26   USE diaptr         ! poleward transport diagnostics
27   USE diaar5         ! AR5 diagnostics
28   !
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O library
31   USE phycst         ! physical constants
32   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf_iso   ! routine called by step.F90
38
39   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
40   LOGICAL  ::   l_hst   ! flag to compute heat transport
41
42   !! * Substitutions
43#  include "do_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_ldf_iso( kt, Kmm, kit000, cdtype, pahu, pahv,             &
52      &                                             pgu , pgv , pgui, pgvi, &
53      &                                             pt, pt2, pt_rhs, kjpt, kpass )
54      !!
55      INTEGER                     , INTENT(in   ) ::   kt         ! ocean time-step index
56      INTEGER                     , INTENT(in   ) ::   kit000     ! first time step index
57      CHARACTER(len=3)            , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
58      INTEGER                     , INTENT(in   ) ::   kjpt       ! number of tracers
59      INTEGER                     , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
60      INTEGER                     , INTENT(in   ) ::   Kmm        ! ocean time level index
61      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
64      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pt         ! tracer (kpass=1) or laplacian of tracer (kpass=2)
65      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pt2        ! tracer (only used in kpass=2)
66      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pt_rhs     ! tracer trend
67      !!
68      CALL tra_ldf_iso_t( kt, Kmm, kit000, cdtype, pahu, pahv, is_tile(pahu),                             &
69         &                                         pgu , pgv , is_tile(pgu) , pgui, pgvi, is_tile(pgui),  &
70         &                                         pt, is_tile(pt), pt2, is_tile(pt2), pt_rhs, is_tile(pt_rhs), kjpt, kpass )
71   END SUBROUTINE tra_ldf_iso
72
73
74  SUBROUTINE tra_ldf_iso_t( kt, Kmm, kit000, cdtype, pahu, pahv, ktah,                    &
75      &                                              pgu , pgv , ktg , pgui, pgvi, ktgi,  &
76      &                                              pt, ktt, pt2, ktt2, pt_rhs, ktt_rhs, kjpt, kpass )
77      !!----------------------------------------------------------------------
78      !!                  ***  ROUTINE tra_ldf_iso  ***
79      !!
80      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
81      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
82      !!      add it to the general trend of tracer equation.
83      !!
84      !! ** Method  :   The horizontal component of the lateral diffusive trends
85      !!      is provided by a 2nd order operator rotated along neural or geopo-
86      !!      tential surfaces to which an eddy induced advection can be added
87      !!      It is computed using before fields (forward in time) and isopyc-
88      !!      nal or geopotential slopes computed in routine ldfslp.
89      !!
90      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
91      !!      ========    with partial cell update if ln_zps=T
92      !!                  with top     cell update if ln_isfcav
93      !!
94      !!      2nd part :  horizontal fluxes of the lateral mixing operator
95      !!      ========   
96      !!         zftu =  pahu e2u*e3u/e1u di[ tb ]
97      !!               - pahu e2u*uslp    dk[ mi(mk(tb)) ]
98      !!         zftv =  pahv e1v*e3v/e2v dj[ tb ]
99      !!               - pahv e2u*vslp    dk[ mj(mk(tb)) ]
100      !!      take the horizontal divergence of the fluxes:
101      !!         difft = 1/(e1e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
102      !!      Add this trend to the general trend (ta,sa):
103      !!         ta = ta + difft
104      !!
105      !!      3rd part: vertical trends of the lateral mixing operator
106      !!      ========  (excluding the vertical flux proportional to dk[t] )
107      !!      vertical fluxes associated with the rotated lateral mixing:
108      !!         zftw = - {  mi(mk(pahu)) * e2t*wslpi di[ mi(mk(tb)) ]
109      !!                   + mj(mk(pahv)) * e1t*wslpj dj[ mj(mk(tb)) ]  }
110      !!      take the horizontal divergence of the fluxes:
111      !!         difft = 1/(e1e2t*e3t) dk[ zftw ]
112      !!      Add this trend to the general trend (ta,sa):
113      !!         pt_rhs = pt_rhs + difft
114      !!
115      !! ** Action :   Update pt_rhs arrays with the before rotated diffusion
116      !!----------------------------------------------------------------------
117      INTEGER                                   , INTENT(in   ) ::   kt         ! ocean time-step index
118      INTEGER                                   , INTENT(in   ) ::   kit000     ! first time step index
119      CHARACTER(len=3)                          , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
120      INTEGER                                   , INTENT(in   ) ::   kjpt       ! number of tracers
121      INTEGER                                   , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
122      INTEGER                                   , INTENT(in   ) ::   Kmm        ! ocean time level index
123      INTEGER                                   , INTENT(in   ) ::   ktah, ktg, ktgi, ktt, ktt2, ktt_rhs
124      REAL(wp), DIMENSION(T2D(ktah)   ,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
125      REAL(wp), DIMENSION(T2D(ktg)        ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
126      REAL(wp), DIMENSION(T2D(ktgi)       ,kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
127      REAL(wp), DIMENSION(T2D(ktt)    ,jpk,kjpt), INTENT(in   ) ::   pt         ! tracer (kpass=1) or laplacian of tracer (kpass=2)
128      REAL(wp), DIMENSION(T2D(ktt2)   ,jpk,kjpt), INTENT(in   ) ::   pt2        ! tracer (only used in kpass=2)
129      REAL(wp), DIMENSION(T2D(ktt_rhs),jpk,kjpt), INTENT(inout) ::   pt_rhs     ! tracer trend
130      !
131      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
132      INTEGER  ::  ikt
133      INTEGER  ::  ierr             ! local integer
134      REAL(wp) ::  zmsku, zahu_w, zabe1, zcof1, zcoef3   ! local scalars
135      REAL(wp) ::  zmskv, zahv_w, zabe2, zcof2, zcoef4   !   -      -
136      REAL(wp) ::  zcoef0, ze3w_2, zsign                 !   -      -
137      REAL(wp), DIMENSION(A2D)     ::   zdkt, zdk1t, z2d
138      REAL(wp), DIMENSION(A2D,jpk) ::   zdit, zdjt, zftu, zftv, ztfw
139      !!----------------------------------------------------------------------
140      !
141      IF( kpass == 1 .AND. kt == kit000 )  THEN
142         IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
143            IF(lwp) WRITE(numout,*)
144            IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
145            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
146         ENDIF
147         !
148         DO_3D_00_00( 1, jpk )
149            akz     (ji,jj,jk) = 0._wp
150            ah_wslp2(ji,jj,jk) = 0._wp
151         END_3D
152      ENDIF
153      !
154      IF( ntile == 0 .OR. ntile == 1 )  THEN                           ! Do only on the first tile
155         l_hst = .FALSE.
156         l_ptr = .FALSE.
157         IF( cdtype == 'TRA' .AND. ( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf' ) ) )     l_ptr = .TRUE.
158         IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
159            &                        iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )   l_hst = .TRUE.
160      ENDIF
161      !
162      !
163      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
164      ELSE                    ;   zsign = -1._wp
165      ENDIF
166         
167      !!----------------------------------------------------------------------
168      !!   0 - calculate  ah_wslp2 and akz
169      !!----------------------------------------------------------------------
170      !
171      IF( kpass == 1 ) THEN                  !==  first pass only  ==!
172         !
173         DO_3D_00_00( 2, jpkm1 )
174            !
175            zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
176               &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
177            zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
178               &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
179               !
180            zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
181               &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
182            zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
183               &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
184               !
185            ah_wslp2(ji,jj,jk) = zahu_w * wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
186               &               + zahv_w * wslpj(ji,jj,jk) * wslpj(ji,jj,jk)
187         END_3D
188         !
189         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
190            DO_3D_00_00( 2, jpkm1 )
191               akz(ji,jj,jk) = 0.25_wp * (                                                                     &
192                  &              ( pahu(ji  ,jj,jk) + pahu(ji  ,jj,jk-1) ) / ( e1u(ji  ,jj) * e1u(ji  ,jj) )   &
193                  &            + ( pahu(ji-1,jj,jk) + pahu(ji-1,jj,jk-1) ) / ( e1u(ji-1,jj) * e1u(ji-1,jj) )   &
194                  &            + ( pahv(ji,jj  ,jk) + pahv(ji,jj  ,jk-1) ) / ( e2v(ji,jj  ) * e2v(ji,jj  ) )   &
195                  &            + ( pahv(ji,jj-1,jk) + pahv(ji,jj-1,jk-1) ) / ( e2v(ji,jj-1) * e2v(ji,jj-1) )   )
196            END_3D
197            !
198            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
199               DO_3D_00_00( 2, jpkm1 )
200                  akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
201                     &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) )  )
202               END_3D
203            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
204               DO_3D_00_00( 2, jpkm1 )
205                  ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm)
206                  zcoef0 = rDt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
207                  akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt
208               END_3D
209           ENDIF
210           !
211         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
212            DO_3D_00_00( 1, jpk )
213               akz(ji,jj,jk) = ah_wslp2(ji,jj,jk)
214            END_3D
215         ENDIF
216      ENDIF
217      !
218      !                                                          ! ===========
219      DO jn = 1, kjpt                                            ! tracer loop
220         !                                                       ! ===========
221         !                                               
222         !!----------------------------------------------------------------------
223         !!   I - masked horizontal derivative
224         !!----------------------------------------------------------------------
225!!gm : bug.... why (x,:,:)?   (1,jpj,:) and (jpi,1,:) should be sufficient....
226         zdit (Ntis2,:,:) = 0._wp     ;     zdit (Ntie2,:,:) = 0._wp
227         zdjt (Ntis2,:,:) = 0._wp     ;     zdjt (Ntie2,:,:) = 0._wp
228         !!end
229
230         ! Horizontal tracer gradient
231         DO_3D_10_10( 1, jpkm1 )
232            zdit(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk)
233            zdjt(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
234         END_3D
235         ! TODO: NOT TESTED- requires zps
236         IF( ln_zps ) THEN      ! botton and surface ocean correction of the horizontal gradient
237            DO_2D_10_10
238               zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
239               zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
240            END_2D
241            ! TODO: NOT TESTED- requires isf
242            IF( ln_isfcav ) THEN      ! first wet level beneath a cavity
243               DO_2D_10_10
244                  IF( miku(ji,jj) > 1 )   zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
245                  IF( mikv(ji,jj) > 1 )   zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
246               END_2D
247            ENDIF
248         ENDIF
249         !
250         !!----------------------------------------------------------------------
251         !!   II - horizontal trend  (full)
252         !!----------------------------------------------------------------------
253         !
254         DO jk = 1, jpkm1                                 ! Horizontal slab
255            !
256            DO_2D_11_11
257               !                             !== Vertical tracer gradient
258               zdk1t(ji,jj) = ( pt(ji,jj,jk,jn) - pt(ji,jj,jk+1,jn) ) * wmask(ji,jj,jk+1)     ! level jk+1
259               !
260               IF( jk == 1 ) THEN   ;   zdkt(ji,jj) = zdk1t(ji,jj)                            ! surface: zdkt(jk=1)=zdkt(jk=2)
261               ELSE                 ;   zdkt(ji,jj) = ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) * wmask(ji,jj,jk)
262               ENDIF
263            END_2D
264            !
265            DO_2D_10_10
266               zabe1 = pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u(ji,jj,jk,Kmm)
267               zabe2 = pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
268               !
269               zmsku = 1. / MAX(  wmask(ji+1,jj,jk  ) + wmask(ji,jj,jk+1)   &
270                  &             + wmask(ji+1,jj,jk+1) + wmask(ji,jj,jk  ), 1. )
271               !
272               zmskv = 1. / MAX(  wmask(ji,jj+1,jk  ) + wmask(ji,jj,jk+1)   &
273                  &             + wmask(ji,jj+1,jk+1) + wmask(ji,jj,jk  ), 1. )
274               !
275               zcof1 = - pahu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
276               zcof2 = - pahv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
277               !
278               zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
279                  &               + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
280                  &                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
281               zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
282                  &               + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
283                  &                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
284            END_2D
285            !
286            DO_2D_00_00
287               pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + zsign * (  zftu(ji,jj,jk) - zftu(ji-1,jj,jk)      &
288                  &                                                 + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )   &
289                  &                                              * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
290            END_2D
291         END DO                                        !   End of slab 
292
293         !!----------------------------------------------------------------------
294         !!   III - vertical trend (full)
295         !!----------------------------------------------------------------------
296         !
297         ! Vertical fluxes
298         ! ---------------
299         !                          ! Surface and bottom vertical fluxes set to zero
300         ztfw(:,:, 1 ) = 0._wp      ;      ztfw(:,:,jpk) = 0._wp
301         
302         DO_3D_00_00( 2, jpkm1 )
303            !
304            zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
305               &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
306            zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
307               &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
308               !
309            zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
310               &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
311            zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
312               &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
313               !
314            zcoef3 = - zahu_w * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)   !wslpi & j are already w-masked
315            zcoef4 = - zahv_w * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
316            !
317            ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
318               &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
319               &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
320               &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
321         END_3D
322         !                                !==  add the vertical 33 flux  ==!
323         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
324            DO_3D_00_00( 2, jpkm1 )
325               ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)   &
326                  &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )               &
327                  &                            * (  pt(ji,jj,jk-1,jn) -  pt(ji,jj,jk,jn) )
328            END_3D
329            !
330         ELSE                                   ! bilaplacian
331            SELECT CASE( kpass )
332            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
333               DO_3D_00_00( 2, jpkm1 )
334                  ztfw(ji,jj,jk) = ztfw(ji,jj,jk)                       &
335                     &           + ah_wslp2(ji,jj,jk)  * e1e2t(ji,jj)   &
336                     &           * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)
337               END_3D
338            CASE(  2  )                         ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt  and pt2 gradients, resp.
339               DO_3D_00_00( 2, jpkm1 )
340                  ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)                  &
341                     &                            * (  ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) )   &
342                     &                            +         akz(ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) )   )
343               END_3D
344            END SELECT
345         ENDIF
346         !         
347         DO_3D_00_00( 1, jpkm1 )
348            pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + zsign * (  ztfw (ji,jj,jk) - ztfw(ji,jj,jk+1)  )   &
349               &                                              * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
350         END_3D
351         !
352         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
353             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
354            !
355            !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
356               ! note sign is reversed to give down-gradient diffusive transports )
357            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', -zftv(:,:,:)  )
358            !                          ! Diffusive heat transports
359            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', -zftu(:,:,:), -zftv(:,:,:) )
360            !
361         ENDIF                                                    !== end pass selection  ==!
362         !
363         !                                                        ! ===============
364      END DO                                                      ! end tracer loop
365      !
366   END SUBROUTINE tra_ldf_iso_t
367
368   !!==============================================================================
369END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.