| 1 | MODULE traldf_triad |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traldf_triad *** |
|---|
| 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) Griffies operator (original code) |
|---|
| 7 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) triad operator (Griffies) + Method of Stabilizing Correction |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and active tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | ! TEMP: This change not necessary if lbc_lnk is removed from ldf_eiv_dia and XIOS has subdomain support |
|---|
| 16 | USE domain, ONLY : dom_tile |
|---|
| 17 | USE domutl, ONLY : is_tile |
|---|
| 18 | USE phycst ! physical constants |
|---|
| 19 | USE trc_oce ! share passive tracers/Ocean variables |
|---|
| 20 | USE zdf_oce ! ocean vertical physics |
|---|
| 21 | USE ldftra ! lateral physics: eddy diffusivity |
|---|
| 22 | USE ldfslp ! lateral physics: iso-neutral slopes |
|---|
| 23 | USE traldf_iso ! lateral diffusion (Madec operator) (tra_ldf_iso routine) |
|---|
| 24 | USE diaptr ! poleward transport diagnostics |
|---|
| 25 | USE diaar5 ! AR5 diagnostics |
|---|
| 26 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 27 | ! |
|---|
| 28 | USE in_out_manager ! I/O manager |
|---|
| 29 | USE iom ! I/O library |
|---|
| 30 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 31 | USE lib_mpp ! MPP library |
|---|
| 32 | |
|---|
| 33 | IMPLICIT NONE |
|---|
| 34 | PRIVATE |
|---|
| 35 | |
|---|
| 36 | PUBLIC tra_ldf_triad ! routine called by traldf.F90 |
|---|
| 37 | |
|---|
| 38 | LOGICAL :: l_ptr ! flag to compute poleward transport |
|---|
| 39 | LOGICAL :: l_hst ! flag to compute heat transport |
|---|
| 40 | |
|---|
| 41 | |
|---|
| 42 | !! * Substitutions |
|---|
| 43 | # include "do_loop_substitute.h90" |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 46 | !! $Id$ |
|---|
| 47 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | CONTAINS |
|---|
| 50 | |
|---|
| 51 | SUBROUTINE tra_ldf_triad( kt, Kmm, kit000, cdtype, pahu, pahv, & |
|---|
| 52 | & pgu , pgv , pgui, pgvi, & |
|---|
| 53 | & pt, pt2, pt_rhs, kjpt, kpass ) |
|---|
| 54 | !! |
|---|
| 55 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 56 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 57 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 58 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 59 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 60 | INTEGER , INTENT(in ) :: Kmm ! ocean time level indices |
|---|
| 61 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 62 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 63 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 64 | REAL(wp), DIMENSION(:,:,:,:), INTENT(in ) :: pt ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 65 | REAL(wp), DIMENSION(:,:,:,:), INTENT(in ) :: pt2 ! tracer (only used in kpass=2) |
|---|
| 66 | REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) :: pt_rhs ! tracer trend |
|---|
| 67 | !! |
|---|
| 68 | CALL tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, is_tile(pahu), & |
|---|
| 69 | & pgu , pgv , is_tile(pgu) , pgui, pgvi, is_tile(pgui), & |
|---|
| 70 | & pt, is_tile(pt), pt2, is_tile(pt2), pt_rhs, is_tile(pt_rhs), kjpt, kpass ) |
|---|
| 71 | END SUBROUTINE tra_ldf_triad |
|---|
| 72 | |
|---|
| 73 | |
|---|
| 74 | SUBROUTINE tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, ktah, & |
|---|
| 75 | & pgu , pgv , ktg , pgui, pgvi, ktgi, & |
|---|
| 76 | & pt, ktt, pt2, ktt2, pt_rhs, ktt_rhs, kjpt, kpass ) |
|---|
| 77 | !!---------------------------------------------------------------------- |
|---|
| 78 | !! *** ROUTINE tra_ldf_triad *** |
|---|
| 79 | !! |
|---|
| 80 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
|---|
| 81 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
|---|
| 82 | !! add it to the general trend of tracer equation. |
|---|
| 83 | !! |
|---|
| 84 | !! ** Method : The horizontal component of the lateral diffusive trends |
|---|
| 85 | !! is provided by a 2nd order operator rotated along neural or geopo- |
|---|
| 86 | !! tential surfaces to which an eddy induced advection can be added |
|---|
| 87 | !! It is computed using before fields (forward in time) and isopyc- |
|---|
| 88 | !! nal or geopotential slopes computed in routine ldfslp. |
|---|
| 89 | !! |
|---|
| 90 | !! see documentation for the desciption |
|---|
| 91 | !! |
|---|
| 92 | !! ** Action : pt_rhs updated with the before rotated diffusion |
|---|
| 93 | !! ah_wslp2 .... |
|---|
| 94 | !! akz stabilizing vertical diffusivity coefficient (used in trazdf_imp) |
|---|
| 95 | !!---------------------------------------------------------------------- |
|---|
| 96 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 97 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 98 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 99 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 100 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 101 | INTEGER , INTENT(in) :: Kmm ! ocean time level indices |
|---|
| 102 | INTEGER , INTENT(in ) :: ktah, ktg, ktgi, ktt, ktt2, ktt_rhs |
|---|
| 103 | REAL(wp), DIMENSION(T2D(ktah), jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 104 | REAL(wp), DIMENSION(T2D(ktg), kjpt), INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 105 | REAL(wp), DIMENSION(T2D(ktgi), kjpt), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 106 | REAL(wp), DIMENSION(T2D(ktt), jpk,kjpt), INTENT(in ) :: pt ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 107 | REAL(wp), DIMENSION(T2D(ktt2), jpk,kjpt), INTENT(in ) :: pt2 ! tracer (only used in kpass=2) |
|---|
| 108 | REAL(wp), DIMENSION(T2D(ktt_rhs),jpk,kjpt), INTENT(inout) :: pt_rhs ! tracer trend |
|---|
| 109 | ! |
|---|
| 110 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 111 | INTEGER :: ip,jp,kp ! dummy loop indices |
|---|
| 112 | INTEGER :: ierr ! local integer |
|---|
| 113 | REAL(wp) :: zmsku, zabe1, zcof1, zcoef3 ! local scalars |
|---|
| 114 | REAL(wp) :: zmskv, zabe2, zcof2, zcoef4 ! - - |
|---|
| 115 | REAL(wp) :: zcoef0, ze3w_2, zsign ! - - |
|---|
| 116 | ! |
|---|
| 117 | REAL(wp) :: zslope_skew, zslope_iso, zslope2, zbu, zbv |
|---|
| 118 | REAL(wp) :: ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt |
|---|
| 119 | REAL(wp) :: zah, zah_slp, zaei_slp |
|---|
| 120 | REAL(wp), DIMENSION(A2D,0:1) :: zdkt3d ! vertical tracer gradient at 2 levels |
|---|
| 121 | REAL(wp), DIMENSION(A2D ) :: z2d ! 2D workspace |
|---|
| 122 | REAL(wp), DIMENSION(A2D ,jpk) :: zdit, zdjt, zftu, zftv, ztfw ! 3D - |
|---|
| 123 | ! TEMP: This can be A2D if lbc_lnk is removed from ldf_eiv_dia and XIOS has subdomain support |
|---|
| 124 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpsi_uw, zpsi_vw |
|---|
| 125 | !!---------------------------------------------------------------------- |
|---|
| 126 | ! |
|---|
| 127 | IF( ntile == 0 .OR. ntile == 1 ) THEN ! Do only on the first tile |
|---|
| 128 | IF( kpass == 1 .AND. kt == kit000 ) THEN |
|---|
| 129 | IF(lwp) WRITE(numout,*) |
|---|
| 130 | IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype |
|---|
| 131 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~' |
|---|
| 132 | ENDIF |
|---|
| 133 | ! |
|---|
| 134 | l_hst = .FALSE. |
|---|
| 135 | l_ptr = .FALSE. |
|---|
| 136 | IF( cdtype == 'TRA' ) THEN |
|---|
| 137 | IF( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf') ) l_ptr = .TRUE. |
|---|
| 138 | IF( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. & |
|---|
| 139 | & iom_use("uadv_salttr") .OR. iom_use("vadv_salttr") ) l_hst = .TRUE. |
|---|
| 140 | ENDIF |
|---|
| 141 | ENDIF |
|---|
| 142 | ! |
|---|
| 143 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
|---|
| 144 | ELSE ; zsign = -1._wp |
|---|
| 145 | ENDIF |
|---|
| 146 | ! |
|---|
| 147 | !!---------------------------------------------------------------------- |
|---|
| 148 | !! 0 - calculate ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw |
|---|
| 149 | !!---------------------------------------------------------------------- |
|---|
| 150 | ! |
|---|
| 151 | IF( kpass == 1 ) THEN !== first pass only and whatever the tracer is ==! |
|---|
| 152 | ! |
|---|
| 153 | DO_3D_00_00( 1, jpk ) |
|---|
| 154 | akz (ji,jj,jk) = 0._wp |
|---|
| 155 | ah_wslp2(ji,jj,jk) = 0._wp |
|---|
| 156 | END_3D |
|---|
| 157 | ! |
|---|
| 158 | DO ip = 0, 1 ! i-k triads |
|---|
| 159 | DO kp = 0, 1 |
|---|
| 160 | DO_3D_00_00( 1, jpkm1 ) |
|---|
| 161 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 162 | zbu = e1e2u(ji-ip,jj) * e3u(ji-ip,jj,jk,Kmm) |
|---|
| 163 | zah = 0.25_wp * pahu(ji-ip,jj,jk) |
|---|
| 164 | zslope_skew = triadi_g(ji,jj,jk,1-ip,kp) |
|---|
| 165 | ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth) |
|---|
| 166 | zslope2 = zslope_skew + ( gdept(ji-ip+1,jj,jk,Kmm) - gdept(ji-ip,jj,jk,Kmm) ) * r1_e1u(ji-ip,jj) * umask(ji-ip,jj,jk+kp) |
|---|
| 167 | zslope2 = zslope2 *zslope2 |
|---|
| 168 | ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji,jj) * zslope2 |
|---|
| 169 | akz (ji,jj,jk+kp) = akz (ji,jj,jk+kp) + zah * r1_e1u(ji-ip,jj) & |
|---|
| 170 | & * r1_e1u(ji-ip,jj) * umask(ji-ip,jj,jk+kp) |
|---|
| 171 | ! |
|---|
| 172 | END_3D |
|---|
| 173 | END DO |
|---|
| 174 | END DO |
|---|
| 175 | ! |
|---|
| 176 | DO jp = 0, 1 ! j-k triads |
|---|
| 177 | DO kp = 0, 1 |
|---|
| 178 | DO_3D_00_00( 1, jpkm1 ) |
|---|
| 179 | ze3wr = 1.0_wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 180 | zbv = e1e2v(ji,jj-jp) * e3v(ji,jj-jp,jk,Kmm) |
|---|
| 181 | zah = 0.25_wp * pahv(ji,jj-jp,jk) |
|---|
| 182 | zslope_skew = triadj_g(ji,jj,jk,1-jp,kp) |
|---|
| 183 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
|---|
| 184 | ! (do this by *adding* gradient of depth) |
|---|
| 185 | zslope2 = zslope_skew + ( gdept(ji,jj-jp+1,jk,Kmm) - gdept(ji,jj-jp,jk,Kmm) ) * r1_e2v(ji,jj-jp) * vmask(ji,jj-jp,jk+kp) |
|---|
| 186 | zslope2 = zslope2 * zslope2 |
|---|
| 187 | ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj) * zslope2 |
|---|
| 188 | akz (ji,jj,jk+kp) = akz (ji,jj,jk+kp) + zah * r1_e2v(ji,jj-jp) & |
|---|
| 189 | & * r1_e2v(ji,jj-jp) * vmask(ji,jj-jp,jk+kp) |
|---|
| 190 | ! |
|---|
| 191 | END_3D |
|---|
| 192 | END DO |
|---|
| 193 | END DO |
|---|
| 194 | ! |
|---|
| 195 | IF( ln_traldf_msc ) THEN ! stabilizing vertical diffusivity coefficient |
|---|
| 196 | ! |
|---|
| 197 | IF( ln_traldf_blp ) THEN ! bilaplacian operator |
|---|
| 198 | DO_3D_00_00( 2, jpkm1 ) |
|---|
| 199 | akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk) & |
|---|
| 200 | & * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) ) ) |
|---|
| 201 | END_3D |
|---|
| 202 | ELSEIF( ln_traldf_lap ) THEN ! laplacian operator |
|---|
| 203 | DO_3D_00_00( 2, jpkm1 ) |
|---|
| 204 | ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) |
|---|
| 205 | zcoef0 = rDt * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2 ) |
|---|
| 206 | akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt |
|---|
| 207 | END_3D |
|---|
| 208 | ENDIF |
|---|
| 209 | ! |
|---|
| 210 | ELSE ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit |
|---|
| 211 | DO_3D_00_00( 1, jpk ) |
|---|
| 212 | akz(ji,jj,jk) = ah_wslp2(ji,jj,jk) |
|---|
| 213 | END_3D |
|---|
| 214 | ENDIF |
|---|
| 215 | ! |
|---|
| 216 | ! TEMP: These changes not necessary if lbc_lnk is removed from ldf_eiv_dia and XIOS has subdomain support |
|---|
| 217 | IF( ntile == 0 .OR. ntile == nijtile ) THEN ! Do only for the full domain |
|---|
| 218 | IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) THEN |
|---|
| 219 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 ) |
|---|
| 220 | |
|---|
| 221 | zpsi_uw(:,:,:) = 0._wp |
|---|
| 222 | zpsi_vw(:,:,:) = 0._wp |
|---|
| 223 | |
|---|
| 224 | DO jp = 0, 1 |
|---|
| 225 | DO kp = 0, 1 |
|---|
| 226 | DO_3D_10_10( 1, jpkm1 ) |
|---|
| 227 | zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) & |
|---|
| 228 | & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * triadi_g(ji+jp,jj,jk,1-jp,kp) |
|---|
| 229 | zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) & |
|---|
| 230 | & + 0.25_wp * aeiv(ji,jj,jk) * e1v(ji,jj) * triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 231 | END_3D |
|---|
| 232 | END DO |
|---|
| 233 | END DO |
|---|
| 234 | CALL ldf_eiv_dia( zpsi_uw, zpsi_vw, Kmm ) |
|---|
| 235 | |
|---|
| 236 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = nijtile ) |
|---|
| 237 | ENDIF |
|---|
| 238 | ENDIF |
|---|
| 239 | ! |
|---|
| 240 | ENDIF !== end 1st pass only ==! |
|---|
| 241 | ! |
|---|
| 242 | ! ! =========== |
|---|
| 243 | DO jn = 1, kjpt ! tracer loop |
|---|
| 244 | ! ! =========== |
|---|
| 245 | ! Zero fluxes for each tracer |
|---|
| 246 | !!gm this should probably be done outside the jn loop |
|---|
| 247 | ztfw(:,:,:) = 0._wp |
|---|
| 248 | zftu(:,:,:) = 0._wp |
|---|
| 249 | zftv(:,:,:) = 0._wp |
|---|
| 250 | ! |
|---|
| 251 | DO_3D_10_10( 1, jpkm1 ) |
|---|
| 252 | zdit(ji,jj,jk) = ( pt(ji+1,jj ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
|---|
| 253 | zdjt(ji,jj,jk) = ( pt(ji ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
|---|
| 254 | END_3D |
|---|
| 255 | ! TODO: NOT TESTED- requires zps |
|---|
| 256 | IF( ln_zps .AND. l_grad_zps ) THEN ! partial steps: correction at top/bottom ocean level |
|---|
| 257 | DO_2D_10_10 |
|---|
| 258 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
|---|
| 259 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
|---|
| 260 | END_2D |
|---|
| 261 | ! TODO: NOT TESTED- requires isf |
|---|
| 262 | IF( ln_isfcav ) THEN ! top level (ocean cavities only) |
|---|
| 263 | DO_2D_10_10 |
|---|
| 264 | IF( miku(ji,jj) > 1 ) zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) |
|---|
| 265 | IF( mikv(ji,jj) > 1 ) zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) |
|---|
| 266 | END_2D |
|---|
| 267 | ENDIF |
|---|
| 268 | ENDIF |
|---|
| 269 | ! |
|---|
| 270 | !!---------------------------------------------------------------------- |
|---|
| 271 | !! II - horizontal trend (full) |
|---|
| 272 | !!---------------------------------------------------------------------- |
|---|
| 273 | ! |
|---|
| 274 | DO jk = 1, jpkm1 |
|---|
| 275 | ! !== Vertical tracer gradient at level jk and jk+1 |
|---|
| 276 | DO_2D_11_11 |
|---|
| 277 | zdkt3d(ji,jj,1) = ( pt(ji,jj,jk,jn) - pt(ji,jj,jk+1,jn) ) * tmask(ji,jj,jk+1) |
|---|
| 278 | END_2D |
|---|
| 279 | ! |
|---|
| 280 | ! ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1) |
|---|
| 281 | IF( jk == 1 ) THEN ; zdkt3d(:,:,0) = zdkt3d(:,:,1) |
|---|
| 282 | ELSE |
|---|
| 283 | DO_2D_11_11 |
|---|
| 284 | zdkt3d(ji,jj,0) = ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) * tmask(ji,jj,jk) |
|---|
| 285 | END_2D |
|---|
| 286 | ENDIF |
|---|
| 287 | ! |
|---|
| 288 | zaei_slp = 0._wp |
|---|
| 289 | ! |
|---|
| 290 | IF( ln_botmix_triad ) THEN |
|---|
| 291 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 292 | DO kp = 0, 1 |
|---|
| 293 | DO_2D_10_10 |
|---|
| 294 | ze1ur = r1_e1u(ji,jj) |
|---|
| 295 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 296 | ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm) |
|---|
| 297 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 298 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 299 | zslope_iso = triadi (ji+ip,jj,jk,1-ip,kp) |
|---|
| 300 | ! |
|---|
| 301 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 302 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 303 | zah = pahu(ji,jj,jk) |
|---|
| 304 | zah_slp = zah * zslope_iso |
|---|
| 305 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew |
|---|
| 306 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 307 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 308 | END_2D |
|---|
| 309 | END DO |
|---|
| 310 | END DO |
|---|
| 311 | ! |
|---|
| 312 | DO jp = 0, 1 |
|---|
| 313 | DO kp = 0, 1 |
|---|
| 314 | DO_2D_10_10 |
|---|
| 315 | ze2vr = r1_e2v(ji,jj) |
|---|
| 316 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 317 | ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm) |
|---|
| 318 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 319 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 320 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 321 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 322 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahv is masked... |
|---|
| 323 | zah = pahv(ji,jj,jk) |
|---|
| 324 | zah_slp = zah * zslope_iso |
|---|
| 325 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew |
|---|
| 326 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 327 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt * zbv * ze3wr |
|---|
| 328 | END_2D |
|---|
| 329 | END DO |
|---|
| 330 | END DO |
|---|
| 331 | ! |
|---|
| 332 | ELSE |
|---|
| 333 | ! |
|---|
| 334 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 335 | DO kp = 0, 1 |
|---|
| 336 | DO_2D_10_10 |
|---|
| 337 | ze1ur = r1_e1u(ji,jj) |
|---|
| 338 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 339 | ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm) |
|---|
| 340 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 341 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 342 | zslope_iso = triadi(ji+ip,jj,jk,1-ip,kp) |
|---|
| 343 | ! |
|---|
| 344 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 345 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 346 | zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp) ! pahu(ji+ip,jj,jk) ===>> ???? |
|---|
| 347 | zah_slp = zah * zslope_iso |
|---|
| 348 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew ! aeit(ji+ip,jj,jk)*zslope_skew |
|---|
| 349 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 350 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 351 | END_2D |
|---|
| 352 | END DO |
|---|
| 353 | END DO |
|---|
| 354 | ! |
|---|
| 355 | DO jp = 0, 1 |
|---|
| 356 | DO kp = 0, 1 |
|---|
| 357 | DO_2D_10_10 |
|---|
| 358 | ze2vr = r1_e2v(ji,jj) |
|---|
| 359 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 360 | ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm) |
|---|
| 361 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 362 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 363 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 364 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 365 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 366 | zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 367 | zah_slp = zah * zslope_iso |
|---|
| 368 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew ! aeit(ji,jj+jp,jk)*zslope_skew |
|---|
| 369 | zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 370 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr |
|---|
| 371 | END_2D |
|---|
| 372 | END DO |
|---|
| 373 | END DO |
|---|
| 374 | ENDIF |
|---|
| 375 | ! !== horizontal divergence and add to the general trend ==! |
|---|
| 376 | DO_2D_00_00 |
|---|
| 377 | pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + zsign * ( zftu(ji-1,jj,jk) - zftu(ji,jj,jk) & |
|---|
| 378 | & + zftv(ji,jj-1,jk) - zftv(ji,jj,jk) ) & |
|---|
| 379 | & / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) ) |
|---|
| 380 | END_2D |
|---|
| 381 | ! |
|---|
| 382 | END DO |
|---|
| 383 | ! |
|---|
| 384 | ! !== add the vertical 33 flux ==! |
|---|
| 385 | IF( ln_traldf_lap ) THEN ! laplacian case: eddy coef = ah_wslp2 - akz |
|---|
| 386 | DO_3D_10_00( 2, jpkm1 ) |
|---|
| 387 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 388 | & * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) ) & |
|---|
| 389 | & * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) |
|---|
| 390 | END_3D |
|---|
| 391 | ELSE ! bilaplacian |
|---|
| 392 | SELECT CASE( kpass ) |
|---|
| 393 | CASE( 1 ) ! 1st pass : eddy coef = ah_wslp2 |
|---|
| 394 | DO_3D_10_00( 2, jpkm1 ) |
|---|
| 395 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 396 | & * ah_wslp2(ji,jj,jk) * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) |
|---|
| 397 | END_3D |
|---|
| 398 | CASE( 2 ) ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt and pt2 gradients, resp. |
|---|
| 399 | DO_3D_10_00( 2, jpkm1 ) |
|---|
| 400 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 401 | & * ( ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) ) & |
|---|
| 402 | & + akz (ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) ) ) |
|---|
| 403 | END_3D |
|---|
| 404 | END SELECT |
|---|
| 405 | ENDIF |
|---|
| 406 | ! |
|---|
| 407 | DO_3D_00_00( 1, jpkm1 ) |
|---|
| 408 | pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + zsign * ( ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk) ) & |
|---|
| 409 | & / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) ) |
|---|
| 410 | END_3D |
|---|
| 411 | ! |
|---|
| 412 | IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR. & !== first pass only ( laplacian) ==! |
|---|
| 413 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass (bilaplacian) ==! |
|---|
| 414 | ! |
|---|
| 415 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
|---|
| 416 | IF( l_ptr ) CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:) ) |
|---|
| 417 | ! ! Diffusive heat transports |
|---|
| 418 | IF( l_hst ) CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) ) |
|---|
| 419 | ! |
|---|
| 420 | ENDIF !== end pass selection ==! |
|---|
| 421 | ! |
|---|
| 422 | ! ! =============== |
|---|
| 423 | END DO ! end tracer loop |
|---|
| 424 | ! ! =============== |
|---|
| 425 | END SUBROUTINE tra_ldf_triad_t |
|---|
| 426 | |
|---|
| 427 | !!============================================================================== |
|---|
| 428 | END MODULE traldf_triad |
|---|
