source: NEMO/branches/UKMO/dev_r9885_proto_GO8_package/src/OCE/ICB/icbrst.F90 @ 9893

Last change on this file since 9893 was 9893, checked in by davestorkey, 3 years ago

UKMO/dev_r9885_proto_GO8_package branch: restart datestamping and MLD diagnostic.

File size: 19.5 KB
Line 
1MODULE icbrst
2   !!======================================================================
3   !!                       ***  MODULE  icbrst  ***
4   !! Ocean physics:  read and write iceberg restart files
5   !!======================================================================
6   !! History : 3.3.1 !  2010-01  (Martin&Adcroft) Original code
7   !!            -    !  2011-03  (Madec)          Part conversion to NEMO form
8   !!            -    !                            Removal of mapping from another grid
9   !!            -    !  2011-04  (Alderson)       Split into separate modules
10   !!            -    !  2011-04  (Alderson)       Restore restart routine
11   !!            -    !                            Currently needs a fixed processor
12   !!            -    !                            layout between restarts
13   !!            -    !  2015-11  Dave Storkey     Convert icb_rst_read to use IOM so can
14   !!                                              read single restart files
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   icb_rst_read    : read restart file
19   !!   icb_rst_write   : write restart file
20   !!----------------------------------------------------------------------
21   USE par_oce        ! NEMO parameters
22   USE dom_oce        ! NEMO domain
23   USE in_out_manager ! NEMO IO routines
24   USE lib_mpp        ! NEMO MPI library, lk_mpp in particular
25   USE netcdf         ! netcdf routines for IO
26   USE iom
27   USE ioipsl, ONLY : ju2ymds    ! for calendar
28   USE icb_oce        ! define iceberg arrays
29   USE icbutl         ! iceberg utility routines
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   icb_rst_read    ! routine called in icbini.F90 module
35   PUBLIC   icb_rst_write   ! routine called in icbstp.F90 module
36   
37   INTEGER ::   nlonid, nlatid, nxid, nyid, nuvelid, nvvelid
38   INTEGER ::   nmassid, nthicknessid, nwidthid, nlengthid
39   INTEGER ::   nyearid, ndayid
40   INTEGER ::   nscaling_id, nmass_of_bits_id, nheat_density_id, numberid
41   INTEGER ::   nsiceid, nsheatid, ncalvid, ncalvhid, nkountid
42   INTEGER ::   nret, ncid, nc_dim
43   
44   INTEGER,  DIMENSION(3)                  :: nstrt3, nlngth3
45
46   !!----------------------------------------------------------------------
47   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE icb_rst_read()
54      !!----------------------------------------------------------------------
55      !!                 ***  SUBROUTINE icb_rst_read  ***
56      !!
57      !! ** Purpose :   read a iceberg restart file
58      !!      NB: for this version, we just read back in the restart for this processor
59      !!      so we cannot change the processor layout currently with iceberg code
60      !!----------------------------------------------------------------------
61      INTEGER                      ::   idim, ivar, iatt
62      INTEGER                      ::   jn, iunlim_dim, ibergs_in_file
63      INTEGER                      ::   ii,ij,iclass
64      REAL(wp), DIMENSION(nkounts) ::   zdata     
65      LOGICAL                      ::   ll_found_restart
66      CHARACTER(len=256)           ::   cl_path
67      CHARACTER(len=256)           ::   cl_filename
68      CHARACTER(len=NF90_MAX_NAME) ::   cl_dname
69      TYPE(iceberg)                ::   localberg ! NOT a pointer but an actual local variable
70      TYPE(point)                  ::   localpt   ! NOT a pointer but an actual local variable
71      !!----------------------------------------------------------------------
72
73      ! Find a restart file. Assume iceberg restarts in same directory as ocean restarts
74      ! and are called TRIM(cn_ocerst)//'_icebergs'
75      cl_path = TRIM(cn_ocerst_indir)
76      IF( cl_path(LEN_TRIM(cl_path):) /= '/' ) cl_path = TRIM(cl_path) // '/'
77      cl_filename = TRIM(cn_ocerst_in)//'_icebergs'
78      CALL iom_open( TRIM(cl_path)//cl_filename, ncid )
79
80      IF( iom_file(ncid)%iduld .GE. 0) THEN
81
82         ibergs_in_file = iom_file(ncid)%lenuld
83         DO jn = 1,ibergs_in_file
84
85            ! iom_get treats the unlimited dimension as time. Here the unlimited dimension
86            ! is the iceberg index, but we can still use the ktime keyword to get the iceberg we want.
87
88            CALL iom_get( ncid, 'xi'     ,localpt%xi  , ktime=jn )
89            CALL iom_get( ncid, 'yj'     ,localpt%yj  , ktime=jn )
90
91            ii = INT( localpt%xi + 0.5 )
92            ij = INT( localpt%yj + 0.5 )
93            ! Only proceed if this iceberg is on the local processor (excluding halos).
94            IF ( ii .GE. nldi+nimpp-1 .AND. ii .LE. nlei+nimpp-1 .AND. &
95           &     ij .GE. nldj+njmpp-1 .AND. ij .LE. nlej+njmpp-1 ) THEN           
96
97               CALL iom_get( ncid, jpdom_unknown, 'number'       , zdata(:) , ktime=jn, kstart=(/1/), kcount=(/nkounts/) )
98               localberg%number(:) = INT(zdata(:))
99               CALL iom_get( ncid, 'mass_scaling' , localberg%mass_scaling, ktime=jn )
100               CALL iom_get( ncid, 'lon'          , localpt%lon           , ktime=jn )
101               CALL iom_get( ncid, 'lat'          , localpt%lat           , ktime=jn )
102               CALL iom_get( ncid, 'uvel'         , localpt%uvel          , ktime=jn )
103               CALL iom_get( ncid, 'vvel'         , localpt%vvel          , ktime=jn )
104               CALL iom_get( ncid, 'mass'         , localpt%mass          , ktime=jn )
105               CALL iom_get( ncid, 'thickness'    , localpt%thickness     , ktime=jn )
106               CALL iom_get( ncid, 'width'        , localpt%width         , ktime=jn )
107               CALL iom_get( ncid, 'length'       , localpt%length        , ktime=jn )
108               CALL iom_get( ncid, 'year'         , zdata(1)              , ktime=jn )
109               localpt%year = INT(zdata(1))
110               CALL iom_get( ncid, 'day'          , localpt%day           , ktime=jn )
111               CALL iom_get( ncid, 'mass_of_bits' , localpt%mass_of_bits  , ktime=jn )
112               CALL iom_get( ncid, 'heat_density' , localpt%heat_density  , ktime=jn )
113               !
114               CALL icb_utl_add( localberg, localpt )
115               !
116            ENDIF
117            !
118         END DO
119         !
120      ENDIF 
121
122      ! Gridded variables
123      CALL iom_get( ncid, jpdom_autoglo,    'calving'     , src_calving  )
124      CALL iom_get( ncid, jpdom_autoglo,    'calving_hflx', src_calving_hflx  )
125      CALL iom_get( ncid, jpdom_autoglo,    'stored_heat' , berg_grid%stored_heat  )
126      CALL iom_get( ncid, jpdom_autoglo_xy, 'stored_ice'  , berg_grid%stored_ice, kstart=(/1,1,1/), kcount=(/1,1,nclasses/) )
127     
128      CALL iom_get( ncid, jpdom_unknown, 'kount' , zdata(:) )
129      num_bergs(:) = INT(zdata(:))
130
131      ! Sanity check
132      jn = icb_utl_count()
133      IF (nn_verbose_level >= 0)   &
134         WRITE(numout,'(2(a,i5))') 'icebergs, read_restart_bergs: # bergs =',jn,' on PE',narea-1
135      IF( lk_mpp ) THEN
136         ! Only mpp_sum ibergs_in_file if we are reading from multiple restart files.
137         IF( INDEX(iom_file(ncid)%name,'icebergs.nc' ) .EQ. 0 ) CALL mpp_sum(ibergs_in_file)
138         CALL mpp_sum(jn)
139      ENDIF
140      IF(lwp)   WRITE(numout,'(a,i5,a,i5,a)') 'icebergs, read_restart_bergs: there were',ibergs_in_file,   &
141         &                                    ' bergs in the restart file and', jn,' bergs have been read'
142      !
143      ! Finish up
144      CALL iom_close( ncid )
145      !
146      IF( lwp .AND. nn_verbose_level >= 0)  WRITE(numout,'(a)') 'icebergs, read_restart_bergs: completed'
147      !
148   END SUBROUTINE icb_rst_read
149
150
151   SUBROUTINE icb_rst_write( kt )
152      !!----------------------------------------------------------------------
153      !!                 ***  SUBROUTINE icb_rst_write  ***
154      !!
155      !!----------------------------------------------------------------------
156      INTEGER, INTENT( in ) :: kt
157      !
158      INTEGER ::   jn   ! dummy loop index
159      INTEGER ::   ix_dim, iy_dim, ik_dim, in_dim
160      INTEGER             ::   iyear, imonth, iday
161      REAL (wp)           ::   zsec
162      REAL (wp)           ::   zfjulday
163      CHARACTER(len=256)  :: cl_path
164      CHARACTER(len=256)  :: cl_filename
165      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
166      TYPE(iceberg), POINTER :: this
167      TYPE(point)  , POINTER :: pt
168      !!----------------------------------------------------------------------
169
170      ! Assume we write iceberg restarts to same directory as ocean restarts.
171      cl_path = TRIM(cn_ocerst_outdir)
172      IF( cl_path(LEN_TRIM(cl_path):) /= '/' ) cl_path = TRIM(cl_path) // '/'
173      IF ( ln_rstdate ) THEN
174         zfjulday = fjulday + rdt / rday
175         IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday )   zfjulday = REAL(NINT(zfjulday),wp)   ! avoid truncation error
176         CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )           
177         WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
178      ELSE
179         IF( kt > 999999999 ) THEN   ;   WRITE(clkt, *       ) kt
180         ELSE                        ;   WRITE(clkt, '(i8.8)') kt
181         ENDIF
182      ENDIF
183      IF( lk_mpp ) THEN
184         WRITE(cl_filename,'(A,"_icebergs_",A,"_restart_",I4.4,".nc")') TRIM(cexper), TRIM(ADJUSTL(clkt)), narea-1
185      ELSE
186         WRITE(cl_filename,'(A,"_icebergs_",A,"_restart.nc")') TRIM(cexper), TRIM(ADJUSTL(clkt))
187      ENDIF
188      IF (nn_verbose_level >= 0) WRITE(numout,'(2a)') 'icebergs, write_restart: creating ',TRIM(cl_path)//TRIM(cl_filename)
189
190      nret = NF90_CREATE(TRIM(cl_path)//TRIM(cl_filename), NF90_CLOBBER, ncid)
191      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_create failed')
192
193      ! Dimensions
194      nret = NF90_DEF_DIM(ncid, 'x', jpi, ix_dim)
195      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim x failed')
196
197      nret = NF90_DEF_DIM(ncid, 'y', jpj, iy_dim)
198      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim y failed')
199
200      nret = NF90_DEF_DIM(ncid, 'c', nclasses, nc_dim)
201      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim c failed')
202
203      nret = NF90_DEF_DIM(ncid, 'k', nkounts, ik_dim)
204      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim k failed')
205
206      ! global attributes
207      IF( lk_mpp ) THEN
208         ! Set domain parameters (assume jpdom_local_full)
209         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              )
210         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            )
211         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) )
212         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) )
213         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_size_local'     , (/jpi   , jpj   /) )
214         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_position_first' , (/nimpp , njmpp /) )
215         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_position_last'  , (/nimpp + jpi - 1 , njmpp + jpj - 1  /) )
216         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_halo_size_start', (/nldi - 1        , nldj - 1         /) )
217         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , (/jpi - nlei      , jpj - nlej       /) )
218         nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              )
219      ENDIF
220     
221      IF (associated(first_berg)) then
222         nret = NF90_DEF_DIM(ncid, 'n', NF90_UNLIMITED, in_dim)
223         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim n failed')
224      ENDIF
225
226      ! Variables
227      nret = NF90_DEF_VAR(ncid, 'kount'       , NF90_INT   , (/ ik_dim /), nkountid)
228      nret = NF90_DEF_VAR(ncid, 'calving'     , NF90_DOUBLE, (/ ix_dim, iy_dim /), ncalvid)
229      nret = NF90_DEF_VAR(ncid, 'calving_hflx', NF90_DOUBLE, (/ ix_dim, iy_dim /), ncalvhid)
230      nret = NF90_DEF_VAR(ncid, 'stored_ice'  , NF90_DOUBLE, (/ ix_dim, iy_dim, nc_dim /), nsiceid)
231      nret = NF90_DEF_VAR(ncid, 'stored_heat' , NF90_DOUBLE, (/ ix_dim, iy_dim /), nsheatid)
232
233      ! Attributes
234      nret = NF90_PUT_ATT(ncid, ncalvid , 'long_name', 'iceberg calving')
235      nret = NF90_PUT_ATT(ncid, ncalvid , 'units', 'some')
236      nret = NF90_PUT_ATT(ncid, ncalvhid, 'long_name', 'heat flux associated with iceberg calving')
237      nret = NF90_PUT_ATT(ncid, ncalvhid, 'units', 'some')
238      nret = NF90_PUT_ATT(ncid, nsiceid , 'long_name', 'stored ice used to calve icebergs')
239      nret = NF90_PUT_ATT(ncid, nsiceid , 'units', 'kg/s')
240      nret = NF90_PUT_ATT(ncid, nsheatid, 'long_name', 'heat in stored ice used to calve icebergs')
241      nret = NF90_PUT_ATT(ncid, nsheatid, 'units', 'J/kg/s')
242
243      IF ( ASSOCIATED(first_berg) ) THEN
244
245         ! Only add berg variables for this PE if we have anything to say
246
247         ! Variables
248         nret = NF90_DEF_VAR(ncid, 'lon', NF90_DOUBLE, in_dim, nlonid)
249         nret = NF90_DEF_VAR(ncid, 'lat', NF90_DOUBLE, in_dim, nlatid)
250         nret = NF90_DEF_VAR(ncid, 'xi', NF90_DOUBLE, in_dim, nxid)
251         nret = NF90_DEF_VAR(ncid, 'yj', NF90_DOUBLE, in_dim, nyid)
252         nret = NF90_DEF_VAR(ncid, 'uvel', NF90_DOUBLE, in_dim, nuvelid)
253         nret = NF90_DEF_VAR(ncid, 'vvel', NF90_DOUBLE, in_dim, nvvelid)
254         nret = NF90_DEF_VAR(ncid, 'mass', NF90_DOUBLE, in_dim, nmassid)
255         nret = NF90_DEF_VAR(ncid, 'thickness', NF90_DOUBLE, in_dim, nthicknessid)
256         nret = NF90_DEF_VAR(ncid, 'width', NF90_DOUBLE, in_dim, nwidthid)
257         nret = NF90_DEF_VAR(ncid, 'length', NF90_DOUBLE, in_dim, nlengthid)
258         nret = NF90_DEF_VAR(ncid, 'number', NF90_INT, (/ik_dim,in_dim/), numberid)
259         nret = NF90_DEF_VAR(ncid, 'year', NF90_INT, in_dim, nyearid)
260         nret = NF90_DEF_VAR(ncid, 'day', NF90_DOUBLE, in_dim, ndayid)
261         nret = NF90_DEF_VAR(ncid, 'mass_scaling', NF90_DOUBLE, in_dim, nscaling_id)
262         nret = NF90_DEF_VAR(ncid, 'mass_of_bits', NF90_DOUBLE, in_dim, nmass_of_bits_id)
263         nret = NF90_DEF_VAR(ncid, 'heat_density', NF90_DOUBLE, in_dim, nheat_density_id)
264
265         ! Attributes
266         nret = NF90_PUT_ATT(ncid, nlonid, 'long_name', 'longitude')
267         nret = NF90_PUT_ATT(ncid, nlonid, 'units', 'degrees_E')
268         nret = NF90_PUT_ATT(ncid, nlatid, 'long_name', 'latitude')
269         nret = NF90_PUT_ATT(ncid, nlatid, 'units', 'degrees_N')
270         nret = NF90_PUT_ATT(ncid, nxid, 'long_name', 'x grid box position')
271         nret = NF90_PUT_ATT(ncid, nxid, 'units', 'fractional')
272         nret = NF90_PUT_ATT(ncid, nyid, 'long_name', 'y grid box position')
273         nret = NF90_PUT_ATT(ncid, nyid, 'units', 'fractional')
274         nret = NF90_PUT_ATT(ncid, nuvelid, 'long_name', 'zonal velocity')
275         nret = NF90_PUT_ATT(ncid, nuvelid, 'units', 'm/s')
276         nret = NF90_PUT_ATT(ncid, nvvelid, 'long_name', 'meridional velocity')
277         nret = NF90_PUT_ATT(ncid, nvvelid, 'units', 'm/s')
278         nret = NF90_PUT_ATT(ncid, nmassid, 'long_name', 'mass')
279         nret = NF90_PUT_ATT(ncid, nmassid, 'units', 'kg')
280         nret = NF90_PUT_ATT(ncid, nthicknessid, 'long_name', 'thickness')
281         nret = NF90_PUT_ATT(ncid, nthicknessid, 'units', 'm')
282         nret = NF90_PUT_ATT(ncid, nwidthid, 'long_name', 'width')
283         nret = NF90_PUT_ATT(ncid, nwidthid, 'units', 'm')
284         nret = NF90_PUT_ATT(ncid, nlengthid, 'long_name', 'length')
285         nret = NF90_PUT_ATT(ncid, nlengthid, 'units', 'm')
286         nret = NF90_PUT_ATT(ncid, numberid, 'long_name', 'iceberg number on this processor')
287         nret = NF90_PUT_ATT(ncid, numberid, 'units', 'count')
288         nret = NF90_PUT_ATT(ncid, nyearid, 'long_name', 'calendar year of calving event')
289         nret = NF90_PUT_ATT(ncid, nyearid, 'units', 'years')
290         nret = NF90_PUT_ATT(ncid, ndayid, 'long_name', 'year day of calving event')
291         nret = NF90_PUT_ATT(ncid, ndayid, 'units', 'days')
292         nret = NF90_PUT_ATT(ncid, nscaling_id, 'long_name', 'scaling factor for mass of calving berg')
293         nret = NF90_PUT_ATT(ncid, nscaling_id, 'units', 'none')
294         nret = NF90_PUT_ATT(ncid, nmass_of_bits_id, 'long_name', 'mass of bergy bits')
295         nret = NF90_PUT_ATT(ncid, nmass_of_bits_id, 'units', 'kg')
296         nret = NF90_PUT_ATT(ncid, nheat_density_id, 'long_name', 'heat density')
297         nret = NF90_PUT_ATT(ncid, nheat_density_id, 'units', 'J/kg')
298
299      ENDIF ! associated(first_berg)
300
301      ! End define mode
302      nret = NF90_ENDDEF(ncid)
303
304      ! --------------------------------
305      ! now write some data
306
307      nstrt3(1) = 1
308      nstrt3(2) = 1
309      nlngth3(1) = jpi
310      nlngth3(2) = jpj
311      nlngth3(3) = 1
312
313      DO jn=1,nclasses
314         griddata(:,:,1) = berg_grid%stored_ice(:,:,jn)
315         nstrt3(3) = jn
316         nret = NF90_PUT_VAR( ncid, nsiceid, griddata, nstrt3, nlngth3 )
317         IF (nret .ne. NF90_NOERR) THEN
318            IF( lwp ) WRITE(numout,*) TRIM(NF90_STRERROR( nret ))
319            CALL ctl_stop('icebergs, write_restart: nf_put_var stored_ice failed')
320         ENDIF
321      ENDDO
322      IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: stored_ice  written'
323
324      nret = NF90_PUT_VAR( ncid, nkountid, num_bergs(:) )
325      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var kount failed')
326
327      nret = NF90_PUT_VAR( ncid, nsheatid, berg_grid%stored_heat(:,:) )
328      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var stored_heat failed')
329      IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: stored_heat written'
330
331      nret = NF90_PUT_VAR( ncid, ncalvid , src_calving(:,:) )
332      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var calving failed')
333      nret = NF90_PUT_VAR( ncid, ncalvhid, src_calving_hflx(:,:) )
334      IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var calving_hflx failed')
335      IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: calving written'
336
337      IF ( ASSOCIATED(first_berg) ) THEN
338
339         ! Write variables
340         ! just write out the current point of the trajectory
341
342         this => first_berg
343         jn = 0
344         DO WHILE (ASSOCIATED(this))
345            pt => this%current_point
346            jn=jn+1
347
348            nret = NF90_PUT_VAR(ncid, numberid, this%number, (/1,jn/), (/nkounts,1/) )
349            nret = NF90_PUT_VAR(ncid, nscaling_id, this%mass_scaling, (/ jn /) )
350
351            nret = NF90_PUT_VAR(ncid, nlonid, pt%lon, (/ jn /) )
352            nret = NF90_PUT_VAR(ncid, nlatid, pt%lat, (/ jn /) )
353            nret = NF90_PUT_VAR(ncid, nxid, pt%xi, (/ jn /) )
354            nret = NF90_PUT_VAR(ncid, nyid, pt%yj, (/ jn /) )
355            nret = NF90_PUT_VAR(ncid, nuvelid, pt%uvel, (/ jn /) )
356            nret = NF90_PUT_VAR(ncid, nvvelid, pt%vvel, (/ jn /) )
357            nret = NF90_PUT_VAR(ncid, nmassid, pt%mass, (/ jn /) )
358            nret = NF90_PUT_VAR(ncid, nthicknessid, pt%thickness, (/ jn /) )
359            nret = NF90_PUT_VAR(ncid, nwidthid, pt%width, (/ jn /) )
360            nret = NF90_PUT_VAR(ncid, nlengthid, pt%length, (/ jn /) )
361            nret = NF90_PUT_VAR(ncid, nyearid, pt%year, (/ jn /) )
362            nret = NF90_PUT_VAR(ncid, ndayid, pt%day, (/ jn /) )
363            nret = NF90_PUT_VAR(ncid, nmass_of_bits_id, pt%mass_of_bits, (/ jn /) )
364            nret = NF90_PUT_VAR(ncid, nheat_density_id, pt%heat_density, (/ jn /) )
365
366            this=>this%next
367         END DO
368         !
369      ENDIF ! associated(first_berg)
370
371      ! Finish up
372      nret = NF90_CLOSE(ncid)
373      IF (nret /= NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_close failed')
374      !
375   END SUBROUTINE icb_rst_write
376   !
377   !!======================================================================
378END MODULE icbrst
Note: See TracBrowser for help on using the repository browser.