New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/UKMO/r12083_coupling_sequence/src/OCE – NEMO

source: NEMO/branches/UKMO/r12083_coupling_sequence/src/OCE/nemogcm.F90 @ 12465

Last change on this file since 12465 was 12465, checked in by jcastill, 2 years ago

Changes as in the original branch but updated to vn4.1

File size: 36.1 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE diaharm        ! tidal harmonics diagnostics  (dia_harm_init routine)
62   USE step           ! NEMO time-stepping                 (stp     routine)
63   USE icbini         ! handle bergs, initialisation
64   USE icbstp         ! handle bergs, calving, themodynamics and transport
65   USE cpl_oasis3     ! OASIS3 coupling
66   USE c1d            ! 1D configuration
67   USE step_c1d       ! Time stepping loop for the 1D configuration
68   USE dyndmp         ! Momentum damping
69   USE stopar         ! Stochastic param.: ???
70   USE stopts         ! Stochastic param.: ???
71   USE diurnal_bulk   ! diurnal bulk SST
72   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
73   USE crsini         ! initialise grid coarsening utility
74   USE diatmb         ! Top,middle,bottom output
75   USE dia25h         ! 25h mean output
76   USE sbc_oce , ONLY : lk_oasis
77   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
78#if defined key_top
79   USE trcini         ! passive tracer initialisation
80#endif
81#if defined key_nemocice_decomp
82   USE ice_domain_size, only: nx_global, ny_global
83#endif
84   !
85   USE lib_mpp        ! distributed memory computing
86   USE mppini         ! shared/distributed memory setting (mpp_init routine)
87   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
88   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
89   USE sbccpl
90#if defined key_iomput
91   USE xios           ! xIOserver
92#endif
93#if defined key_agrif
94   USE agrif_all_update   ! Master Agrif update
95#endif
96
97   IMPLICIT NONE
98   PRIVATE
99
100   PUBLIC   nemo_gcm    ! called by model.F90
101   PUBLIC   nemo_init   ! needed by AGRIF
102   PUBLIC   nemo_alloc  ! needed by TAM
103
104   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
105
106#if defined key_mpp_mpi
107   ! need MPI_Wtime
108   INCLUDE 'mpif.h'
109#endif
110
111   !!----------------------------------------------------------------------
112   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
113   !! $Id$
114   !! Software governed by the CeCILL license (see ./LICENSE)
115   !!----------------------------------------------------------------------
116CONTAINS
117
118   SUBROUTINE nemo_gcm
119      !!----------------------------------------------------------------------
120      !!                     ***  ROUTINE nemo_gcm  ***
121      !!
122      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
123      !!              curvilinear mesh on the sphere.
124      !!
125      !! ** Method  : - model general initialization
126      !!              - launch the time-stepping (stp routine)
127      !!              - finalize the run by closing files and communications
128      !!
129      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
130      !!              Madec, 2008, internal report, IPSL.
131      !!----------------------------------------------------------------------
132      INTEGER ::   istp   ! time step index
133      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
134      !!----------------------------------------------------------------------
135      !
136#if defined key_agrif
137      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
138#endif
139      !                            !-----------------------!
140      CALL nemo_init               !==  Initialisations  ==!
141      !                            !-----------------------!
142#if defined key_agrif
143      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
144      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
145# if defined key_top
146      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
147# endif
148# if defined key_si3
149      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
150# endif
151#endif
152      ! check that all process are still there... If some process have an error,
153      ! they will never enter in step and other processes will wait until the end of the cpu time!
154      CALL mpp_max( 'nemogcm', nstop )
155
156      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
157
158      !                            !-----------------------!
159      !                            !==   time stepping   ==!
160      !                            !-----------------------!
161      istp = nit000
162      !
163#if defined key_c1d
164      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
165         CALL stp_c1d( istp )
166         istp = istp + 1
167      END DO
168#else
169      !
170# if defined key_agrif
171      !                                               !==  AGRIF time-stepping  ==!
172      CALL Agrif_Regrid()
173      !
174      ! Recursive update from highest nested level to lowest:
175      CALL Agrif_step_child_adj(Agrif_Update_All)
176      !
177      DO WHILE( istp <= nitend .AND. nstop == 0 )
178         CALL stp
179         istp = istp + 1
180      END DO
181      !
182      IF( .NOT. Agrif_Root() ) THEN
183         CALL Agrif_ParentGrid_To_ChildGrid()
184         IF( ln_diaobs )   CALL dia_obs_wri
185         IF( ln_timing )   CALL timing_finalize
186         CALL Agrif_ChildGrid_To_ParentGrid()
187      ENDIF
188      !
189# else
190      !
191      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
192         !
193         DO WHILE( istp <= nitend .AND. nstop == 0 )
194
195            ncom_stp = istp
196            IF( ln_timing ) THEN
197               zstptiming = MPI_Wtime()
198               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
199               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
200            ENDIF
201           
202            IF (lk_oasis) CALL sbc_cpl_snd( istp )  ! Coupling to atmos
203            CALL stp        ( istp ) 
204            ! We don't couple on the final timestep because 
205            ! our restart file has already been written 
206            ! and contains all the necessary data for a 
207            ! restart. sbc_cpl_snd could be called here 
208            ! but it would require 
209            ! a) A test to ensure it was not performed 
210            !    on the very last time-step 
211            ! b) the presence of another call to 
212            !    sbc_cpl_snd call prior to the main DO loop 
213            ! This solution produces identical results 
214            ! with fewer lines of code.
215            istp = istp + 1
216
217            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
218
219         END DO
220         !
221      ELSE                                            !==  diurnal SST time-steeping only  ==!
222         !
223         DO WHILE( istp <= nitend .AND. nstop == 0 )
224            CALL stp_diurnal( istp )   ! time step only the diurnal SST
225            istp = istp + 1
226         END DO
227         !
228      ENDIF
229      !
230# endif
231      !
232#endif
233      !
234      IF( ln_diaobs   )   CALL dia_obs_wri
235      !
236      IF( ln_icebergs )   CALL icb_end( nitend )
237
238      !                            !------------------------!
239      !                            !==  finalize the run  ==!
240      !                            !------------------------!
241      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
242      !
243      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
244         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
245         CALL ctl_stop( ctmp1 )
246      ENDIF
247      !
248      IF( ln_timing )   CALL timing_finalize
249      !
250      CALL nemo_closefile
251      !
252#if defined key_iomput
253                                    CALL xios_finalize  ! end mpp communications with xios
254      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
255#else
256      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
257      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop      ! end mpp communications
258      ENDIF
259#endif
260      !
261      IF(lwm) THEN
262         IF( nstop == 0 ) THEN   ;   STOP 0
263         ELSE                    ;   STOP 123
264         ENDIF
265      ENDIF
266      !
267   END SUBROUTINE nemo_gcm
268
269
270   SUBROUTINE nemo_init
271      !!----------------------------------------------------------------------
272      !!                     ***  ROUTINE nemo_init  ***
273      !!
274      !! ** Purpose :   initialization of the NEMO GCM
275      !!----------------------------------------------------------------------
276      INTEGER ::   ios, ilocal_comm   ! local integers
277      !!
278      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
279         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
280         &             ln_timing, ln_diacfl
281      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
282      !!----------------------------------------------------------------------
283      !
284      cxios_context = 'nemo'
285      !
286      !                             !-------------------------------------------------!
287      !                             !     set communicator & select the local rank    !
288      !                             !  must be done as soon as possible to get narea  !
289      !                             !-------------------------------------------------!
290      !
291#if defined key_iomput
292      IF( Agrif_Root() ) THEN
293         IF( lk_oasis ) THEN
294            CALL cpl_init( "toyoce", ilocal_comm )                               ! nemo local communicator given by oasis
295            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
296         ELSE
297            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
298         ENDIF
299      ENDIF
300      CALL mpp_start( ilocal_comm )
301#else
302      IF( lk_oasis ) THEN
303         IF( Agrif_Root() ) THEN
304            CALL cpl_init( "toyoce", ilocal_comm )          ! nemo local communicator given by oasis
305         ENDIF
306         CALL mpp_start( ilocal_comm )
307      ELSE
308         CALL mpp_start( )
309      ENDIF
310#endif
311      !
312      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
313      lwm = (narea == 1)                ! control of output namelists
314      !
315      !                             !---------------------------------------------------------------!
316      !                             ! Open output files, reference and configuration namelist files !
317      !                             !---------------------------------------------------------------!
318      !
319      ! open ocean.output as soon as possible to get all output prints (including errors messages)
320      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
321      ! open reference and configuration namelist files
322                  CALL ctl_opn( numnam_ref,        'namelist_ref',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
323                  CALL ctl_opn( numnam_cfg,        'namelist_cfg',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
324      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
325      ! open /dev/null file to be able to supress output write easily
326                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
327      !
328      !                             !--------------------!
329      !                             ! Open listing units !  -> need ln_ctl from namctl to define lwp
330      !                             !--------------------!
331      !
332      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
333      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
334901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
335      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
336      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
337902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
338      !
339      lwp = (narea == 1) .OR. ln_ctl    ! control of all listing output print
340      !
341      IF(lwp) THEN                      ! open listing units
342         !
343         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
344            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
345         !
346         WRITE(numout,*)
347         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
348         WRITE(numout,*) '                       NEMO team'
349         WRITE(numout,*) '            Ocean General Circulation Model'
350         WRITE(numout,*) '                NEMO version 4.0  (2019) '
351         WRITE(numout,*)
352         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
353         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
354         WRITE(numout,*)
355         WRITE(numout,*) "           o         _,           _,             "
356         WRITE(numout,*) "            o      .' (        .-' /             "
357         WRITE(numout,*) "           o     _/..._'.    .'   /              "
358         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
359         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
360         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
361         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
362         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
363         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
364         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
365         WRITE(numout,*)
366         !
367         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
368         !
369      ENDIF
370      !
371      ! finalize the definition of namctl variables
372      IF( sn_cfctl%l_config ) THEN
373         ! Activate finer control of report outputs
374         ! optionally switch off output from selected areas (note this only
375         ! applies to output which does not involve global communications)
376         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
377           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
378           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
379      ELSE
380         ! Use ln_ctl to turn on or off all options.
381         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
382      ENDIF
383      !
384      IF(lwm) WRITE( numond, namctl )
385      !
386      !                             !------------------------------------!
387      !                             !  Set global domain size parameters !
388      !                             !------------------------------------!
389      !
390      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
391      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
392903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
393      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
394      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
395904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
396      !
397      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
398         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
399      ELSE                              ! user-defined namelist
400         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
401      ENDIF
402      !
403      IF(lwm)   WRITE( numond, namcfg )
404      !
405      !                             !-----------------------------------------!
406      !                             ! mpp parameters and domain decomposition !
407      !                             !-----------------------------------------!
408      CALL mpp_init
409
410      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
411      CALL nemo_alloc()
412
413      !                             !-------------------------------!
414      !                             !  NEMO general initialization  !
415      !                             !-------------------------------!
416
417      CALL nemo_ctl                          ! Control prints
418      !
419      !                                      ! General initialization
420      IF( ln_timing    )   CALL timing_init     ! timing
421      IF( ln_timing    )   CALL timing_start( 'nemo_init')
422      !
423                           CALL     phy_cst         ! Physical constants
424                           CALL     eos_init        ! Equation of state
425      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
426                           CALL     wad_init        ! Wetting and drying options
427                           CALL     dom_init("OPA") ! Domain
428      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
429      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
430     
431      CALL diurnal_sst_bulk_init                ! diurnal sst
432      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
433      !                           
434      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
435         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
436         CALL     sbc_init                            ! Forcings : surface module
437         CALL tra_qsr_init                            ! penetrative solar radiation qsr
438         IF( ln_diaobs ) THEN                         ! Observation & model comparison
439            CALL dia_obs_init                            ! Initialize observational data
440            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
441         ENDIF     
442         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
443         !
444         RETURN                                       ! end of initialization
445      ENDIF
446     
447                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
448
449      !                                      ! external forcing
450                           CALL    tide_init    ! tidal harmonics
451                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
452                           CALL     bdy_init    ! Open boundaries initialisation
453
454      !                                      ! Ocean physics
455                           CALL zdf_phy_init    ! Vertical physics
456                                     
457      !                                         ! Lateral physics
458                           CALL ldf_tra_init      ! Lateral ocean tracer physics
459                           CALL ldf_eiv_init      ! eddy induced velocity param.
460                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
461
462      !                                      ! Active tracers
463      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
464                           CALL tra_bbc_init      ! bottom heat flux
465                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
466                           CALL tra_dmp_init      ! internal tracer damping
467                           CALL tra_adv_init      ! horizontal & vertical advection
468                           CALL tra_ldf_init      ! lateral mixing
469
470      !                                      ! Dynamics
471      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
472                           CALL dyn_adv_init      ! advection (vector or flux form)
473                           CALL dyn_vor_init      ! vorticity term including Coriolis
474                           CALL dyn_ldf_init      ! lateral mixing
475                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
476                           CALL dyn_spg_init      ! surface pressure gradient
477
478#if defined key_top
479      !                                      ! Passive tracers
480                           CALL     trc_init
481#endif
482      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
483
484      !                                      ! Icebergs
485                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
486
487      !                                      ! Misc. options
488                           CALL sto_par_init    ! Stochastic parametrization
489      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
490     
491      !                                      ! Diagnostics
492                           CALL     flo_init    ! drifting Floats
493      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
494                           CALL dia_ptr_init    ! Poleward TRansports initialization
495                           CALL dia_dct_init    ! Sections tranports
496                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
497                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
498                           CALL dia_obs_init    ! Initialize observational data
499                           CALL dia_tmb_init    ! TMB outputs
500                           CALL dia_25h_init    ! 25h mean  outputs
501                           CALL dia_harm_init   ! tidal harmonics outputs
502     IF( ln_diaobs    )    CALL dia_obs( nit000-1 )   ! Observation operator for restart
503
504      !                                      ! Assimilation increments
505      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
506      !
507      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
508      !
509      IF (nstop > 0) THEN 
510        CALL CTL_STOP('STOP','Critical errors in NEMO initialisation') 
511      END IF
512      !
513      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
514      !
515   END SUBROUTINE nemo_init
516
517
518   SUBROUTINE nemo_ctl
519      !!----------------------------------------------------------------------
520      !!                     ***  ROUTINE nemo_ctl  ***
521      !!
522      !! ** Purpose :   control print setting
523      !!
524      !! ** Method  : - print namctl and namcfg information and check some consistencies
525      !!----------------------------------------------------------------------
526      !
527      IF(lwp) THEN                  ! control print
528         WRITE(numout,*)
529         WRITE(numout,*) 'nemo_ctl: Control prints'
530         WRITE(numout,*) '~~~~~~~~'
531         WRITE(numout,*) '   Namelist namctl'
532         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
533         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
534         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
535         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
536         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
537         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
538         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
539         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
540         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
541         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
542         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
543         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
544         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
545         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
546         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
547         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
548         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
549         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
550         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
551         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
552         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
553      ENDIF
554      !
555      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
556      nictls    = nn_ictls
557      nictle    = nn_ictle
558      njctls    = nn_jctls
559      njctle    = nn_jctle
560      isplt     = nn_isplt
561      jsplt     = nn_jsplt
562
563      IF(lwp) THEN                  ! control print
564         WRITE(numout,*)
565         WRITE(numout,*) '   Namelist namcfg'
566         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
567         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
568         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
569         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
570         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
571         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
572      ENDIF
573      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
574      !
575      !                             ! Parameter control
576      !
577      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
578         IF( lk_mpp .AND. jpnij > 1 ) THEN
579            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
580         ELSE
581            IF( isplt == 1 .AND. jsplt == 1  ) THEN
582               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
583                  &           ' - the print control will be done over the whole domain' )
584            ENDIF
585            ijsplt = isplt * jsplt            ! total number of processors ijsplt
586         ENDIF
587         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
588         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
589         !
590         !                              ! indices used for the SUM control
591         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
592            lsp_area = .FALSE.
593         ELSE                                             ! print control done over a specific  area
594            lsp_area = .TRUE.
595            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
596               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
597               nictls = 1
598            ENDIF
599            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
600               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
601               nictle = jpiglo
602            ENDIF
603            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
604               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
605               njctls = 1
606            ENDIF
607            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
608               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
609               njctle = jpjglo
610            ENDIF
611         ENDIF
612      ENDIF
613      !
614      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
615         &                                                'Compile with key_nosignedzero enabled:',   &
616         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
617      !
618#if defined key_agrif
619      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
620#endif
621      !
622   END SUBROUTINE nemo_ctl
623
624
625   SUBROUTINE nemo_closefile
626      !!----------------------------------------------------------------------
627      !!                     ***  ROUTINE nemo_closefile  ***
628      !!
629      !! ** Purpose :   Close the files
630      !!----------------------------------------------------------------------
631      !
632      IF( lk_mpp )   CALL mppsync
633      !
634      CALL iom_close                                 ! close all input/output files managed by iom_*
635      !
636      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
637      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
638      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
639      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
640      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
641      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
642      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
643      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
644      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
645      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
646      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
647      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
648      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
649      !
650      numout = 6                                     ! redefine numout in case it is used after this point...
651      !
652   END SUBROUTINE nemo_closefile
653
654
655   SUBROUTINE nemo_alloc
656      !!----------------------------------------------------------------------
657      !!                     ***  ROUTINE nemo_alloc  ***
658      !!
659      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
660      !!
661      !! ** Method  :
662      !!----------------------------------------------------------------------
663      USE diawri    , ONLY : dia_wri_alloc
664      USE dom_oce   , ONLY : dom_oce_alloc
665      USE trc_oce   , ONLY : trc_oce_alloc
666      USE bdy_oce   , ONLY : bdy_oce_alloc
667      !
668      INTEGER :: ierr
669      !!----------------------------------------------------------------------
670      !
671      ierr =        oce_alloc    ()    ! ocean
672      ierr = ierr + dia_wri_alloc()
673      ierr = ierr + dom_oce_alloc()    ! ocean domain
674      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
675      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
676      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
677      !
678      CALL mpp_sum( 'nemogcm', ierr )
679      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
680      !
681   END SUBROUTINE nemo_alloc
682
683   
684   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
685      !!----------------------------------------------------------------------
686      !!                     ***  ROUTINE nemo_set_cfctl  ***
687      !!
688      !! ** Purpose :   Set elements of the output control structure to setto.
689      !!                for_all should be .false. unless all areas are to be
690      !!                treated identically.
691      !!
692      !! ** Method  :   Note this routine can be used to switch on/off some
693      !!                types of output for selected areas but any output types
694      !!                that involve global communications (e.g. mpp_max, glob_sum)
695      !!                should be protected from selective switching by the
696      !!                for_all argument
697      !!----------------------------------------------------------------------
698      LOGICAL :: setto, for_all
699      TYPE(sn_ctl) :: sn_cfctl
700      !!----------------------------------------------------------------------
701      IF( for_all ) THEN
702         sn_cfctl%l_runstat = setto
703         sn_cfctl%l_trcstat = setto
704      ENDIF
705      sn_cfctl%l_oceout  = setto
706      sn_cfctl%l_layout  = setto
707      sn_cfctl%l_mppout  = setto
708      sn_cfctl%l_mpptop  = setto
709   END SUBROUTINE nemo_set_cfctl
710
711   !!======================================================================
712END MODULE nemogcm
713
Note: See TracBrowser for help on using the repository browser.