New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in NEMO/branches/UKMO/r12083_cpl-pressure/src/OCE/SBC – NEMO

source: NEMO/branches/UKMO/r12083_cpl-pressure/src/OCE/SBC/sbcssm.F90 @ 12461

Last change on this file since 12461 was 12461, checked in by jcastill, 2 years ago

Changes as the original branch updated to vn4.1

File size: 18.3 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   USE traqsr, ONLY: ln_traqsr
21   !
22   USE in_out_manager ! I/O manager
23   USE prtctl         ! Print control
24   USE iom            ! IOM library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_ssm        ! routine called by step.F90
30   PUBLIC   sbc_ssm_cpl    ! routine called by sbccpl.F90
31   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
32
33   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
34   
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE sbc_ssm( kt )
43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE sbc_oce  ***
45      !!                     
46      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
47      !!                condition computation
48      !!               
49      !! ** Method  :   compute mean surface velocity (2 components at U and
50      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
51      !!      the periode (kt - nn_fsbc) to kt
52      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
53      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
54      !!---------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt   ! ocean time step
56      !
57      INTEGER  ::   ji, jj               ! loop index
58      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
59      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
60      !!---------------------------------------------------------------------
61      !
62      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
63      DO jj = 1, jpj
64         DO ji = 1, jpi
65            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
66            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
67         END DO
68      END DO
69      !
70      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
71         !                                                ! ---------------------------------------- !
72         ssu_m(:,:) = ub(:,:,1)
73         ssv_m(:,:) = vb(:,:,1)
74         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
75         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
76         ENDIF
77         sss_m(:,:) = zts(:,:,jp_sal)
78         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
79         IF( .NOT. cpl_mslp ) THEN
80            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) 
81            ELSE                    ;   ssh_m(:,:) = sshn(:,:) 
82            ENDIF
83         ENDIF
84         !
85         e3t_m(:,:) = e3t_n(:,:,1)
86         !
87         frq_m(:,:) = fraqsr_1lev(:,:)
88         !
89      ELSE
90         !                                                ! ----------------------------------------------- !
91         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
92            !                                             ! ----------------------------------------------- !
93            IF(lwp) WRITE(numout,*)
94            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
95            IF(lwp) WRITE(numout,*) '~~~~~~~   '
96            zcoef = REAL( nn_fsbc - 1, wp )
97            ssu_m(:,:) = zcoef * ub(:,:,1)
98            ssv_m(:,:) = zcoef * vb(:,:,1)
99            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
100            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
101            ENDIF
102            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
103            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
104            IF( .NOT. cpl_mslp ) THEN
105               IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) ) 
106               ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:) 
107               ENDIF
108            ENDIF
109            !
110            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
111            !
112            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
113            !                                             ! ---------------------------------------- !
114         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
115            !                                             ! ---------------------------------------- !
116            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
117            ssv_m(:,:) = 0._wp
118            sst_m(:,:) = 0._wp
119            sss_m(:,:) = 0._wp
120            IF( .NOT. cpl_mslp ) ssh_m(:,:) = 0._wp
121            e3t_m(:,:) = 0._wp
122            frq_m(:,:) = 0._wp
123         ENDIF
124         !                                                ! ---------------------------------------- !
125         !                                                !        Cumulate at each time step        !
126         !                                                ! ---------------------------------------- !
127         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
128         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
129         IF( l_useCT )  THEN     ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
130         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
131         ENDIF
132         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
133         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
134         IF( .NOT. cpl_mslp ) THEN
135            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) 
136            ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) 
137            ENDIF
138         ENDIF
139         !
140         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
141         !
142         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
143
144         !                                                ! ---------------------------------------- !
145         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
146            !                                             ! ---------------------------------------- !
147            zcoef = 1. / REAL( nn_fsbc, wp )
148            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
149            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
150            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
151            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
152            IF( .NOT. cpl_mslp ) ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
153            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
154            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
155            !
156         ENDIF
157         !                                                ! ---------------------------------------- !
158         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
159            !                                             ! ---------------------------------------- !
160            IF(lwp) WRITE(numout,*)
161            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
162               &                    'at it= ', kt,' date= ', ndastp
163            IF(lwp) WRITE(numout,*) '~~~~~~~'
164            zf_sbc = REAL( nn_fsbc, wp )
165            IF( lwxios ) CALL iom_swap(      cwxios_context          )
166            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc, ldxios = lwxios )    ! sbc frequency
167            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m, ldxios = lwxios  )    ! sea surface mean fields
168            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m, ldxios = lwxios  )
169            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m, ldxios = lwxios  )
170            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m, ldxios = lwxios  )
171            IF( .NOT. cpl_mslp ) CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m, ldxios = lwxios  )
172            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m, ldxios = lwxios  )
173            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m, ldxios = lwxios  )
174            !
175            IF( lwxios ) CALL iom_swap(      cxios_context          )
176         ENDIF
177         !
178      ENDIF
179      !
180      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
181         CALL iom_put( 'ssu_m', ssu_m )
182         CALL iom_put( 'ssv_m', ssv_m )
183         CALL iom_put( 'sst_m', sst_m )
184         CALL iom_put( 'sss_m', sss_m )
185         CALL iom_put( 'ssh_m', ssh_m )
186         CALL iom_put( 'e3t_m', e3t_m )
187         CALL iom_put( 'frq_m', frq_m )
188      ENDIF
189      !
190   END SUBROUTINE sbc_ssm
191
192   SUBROUTINE sbc_ssm_cpl( kt ) 
193      !!--------------------------------------------------------------------- 
194      !!                   ***  ROUTINE sbc_ssm_cpl  *** 
195      !!                       
196      !! ** Purpose :   provide ocean surface variable to sea-surface boundary 
197      !!                condition computation when pressure is read from coupling 
198      !!                 
199      !! ** Method  :   The inverse barometer ssh (i.e. ssh associated with Patm) 
200      !!                is added to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics. 
201      !!--------------------------------------------------------------------- 
202      INTEGER, INTENT(in) ::   kt   ! ocean time step 
203     
204      REAL(wp) ::   zcoef       ! local scalar 
205      !!--------------------------------------------------------------------- 
206     
207      IF( nn_fsbc == 1 ) THEN                             ! Instantaneous surface fields        ! 
208         !                                                ! ---------------------------------------- ! 
209         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) 
210         ELSE                    ;   ssh_m(:,:) = sshn(:,:) 
211         ENDIF 
212      ELSE 
213         !                                                ! ----------------------------------------------- ! 
214         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   ! Initialisation: 1st time-step, no input means ! 
215            !                                             ! ----------------------------------------------- ! 
216            IF(lwp) WRITE(numout,*) 
217            IF(lwp) WRITE(numout,*) '~~~~~~~   mean ssh field initialised to instantaneous values' 
218            zcoef = REAL( nn_fsbc - 1, wp ) 
219            zcoef = REAL( nn_fsbc - 1, wp ) 
220            IF( ln_apr_dyn ) THEN    ;  ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) ) 
221            ELSE                     ;  ssh_m(:,:) = zcoef * sshn(:,:) 
222            ENDIF 
223            !                                             ! ---------------------------------------- ! 
224         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      ! Initialisation: New mean computation   ! 
225            !                                             ! ---------------------------------------- ! 
226            ssh_m(:,:) = 0.e0 
227         ENDIF 
228   
229         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) 
230         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) 
231         ENDIF 
232         !                                                ! ---------------------------------------- ! 
233         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          ! Mean value at each nn_fsbc time-step   ! 
234            !                                             ! ---------------------------------------- ! 
235            zcoef = 1. / REAL( nn_fsbc, wp ) 
236            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH [m] 
237         ENDIF 
238         !                                                ! ---------------------------------------- ! 
239         IF( lrst_oce ) THEN                              ! Write in the ocean restart file     ! 
240            !                                             ! ---------------------------------------- ! 
241            IF(lwp) WRITE(numout,*) 
242            IF(lwp) WRITE(numout,*) 'sbc_ssm_cpl : ssh mean field written in ocean restart file ',   & 
243               &                    'at it= ', kt,' date= ', ndastp 
244            IF(lwp) WRITE(numout,*) '~~~~~~~' 
245            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  ) 
246         ENDIF 
247      ENDIF 
248     
249      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   ! 
250         CALL iom_put( 'ssh_m', ssh_m ) 
251      ENDIF 
252     
253   END SUBROUTINE sbc_ssm_cpl
254
255
256   SUBROUTINE sbc_ssm_init
257      !!----------------------------------------------------------------------
258      !!                  ***  ROUTINE sbc_ssm_init  ***
259      !!
260      !! ** Purpose :   Initialisation of the sbc data
261      !!
262      !! ** Action  : - read parameters
263      !!----------------------------------------------------------------------
264      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
265      !!----------------------------------------------------------------------
266      !
267      IF( nn_fsbc == 1 ) THEN
268         !
269         IF(lwp) WRITE(numout,*)
270         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
271         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
272         !
273      ELSE
274         !               
275         IF(lwp) WRITE(numout,*)
276         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
277         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
278         !
279         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
280            l_ssm_mean = .TRUE.
281            CALL iom_get( numror               , 'nn_fsbc', zf_sbc, ldxios = lrxios )    ! sbc frequency of previous run
282            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m, ldxios = lrxios  )    ! sea surface mean velocity    (U-point)
283            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m, ldxios = lrxios  )    !   "         "    velocity    (V-point)
284            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m, ldxios = lrxios  )    !   "         "    temperature (T-point)
285            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m, ldxios = lrxios  )    !   "         "    salinity    (T-point)
286            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m, ldxios = lrxios  )    !   "         "    height      (T-point)
287            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m, ldxios = lrxios  )    ! 1st level thickness          (T-point)
288            ! fraction of solar net radiation absorbed in 1st T level
289            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
290               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m, ldxios = lrxios  )
291            ELSE
292               frq_m(:,:) = 1._wp   ! default definition
293            ENDIF
294            !
295            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
296               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
297               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
298               ssu_m(:,:) = zcoef * ssu_m(:,:) 
299               ssv_m(:,:) = zcoef * ssv_m(:,:)
300               sst_m(:,:) = zcoef * sst_m(:,:)
301               sss_m(:,:) = zcoef * sss_m(:,:)
302               ssh_m(:,:) = zcoef * ssh_m(:,:)
303               e3t_m(:,:) = zcoef * e3t_m(:,:)
304               frq_m(:,:) = zcoef * frq_m(:,:)
305            ELSE
306               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
307            ENDIF
308         ENDIF
309      ENDIF
310      !
311      IF( .NOT.l_ssm_mean ) THEN   ! default initialisation. needed by iceistate
312         !
313         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
314         ssu_m(:,:) = ub(:,:,1)
315         ssv_m(:,:) = vb(:,:,1)
316         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
317         ELSE                   ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
318         ENDIF
319         sss_m(:,:) = tsn  (:,:,1,jp_sal)
320         ssh_m(:,:) = sshn (:,:)
321         e3t_m(:,:) = e3t_n(:,:,1)
322         frq_m(:,:) = 1._wp
323         !
324      ENDIF
325      !
326      IF( .NOT. ln_traqsr )   fraqsr_1lev(:,:) = 1._wp   ! default definition: qsr 100% in the fisrt level
327      !
328      IF( lwxios.AND.nn_fsbc > 1 ) THEN
329         CALL iom_set_rstw_var_active('nn_fsbc')
330         CALL iom_set_rstw_var_active('ssu_m')
331         CALL iom_set_rstw_var_active('ssv_m')
332         CALL iom_set_rstw_var_active('sst_m')
333         CALL iom_set_rstw_var_active('sss_m')
334         CALL iom_set_rstw_var_active('ssh_m')
335         CALL iom_set_rstw_var_active('e3t_m')
336         CALL iom_set_rstw_var_active('frq_m')
337      ENDIF
338
339   END SUBROUTINE sbc_ssm_init
340
341   !!======================================================================
342END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.