New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in NEMO/branches/UKMO/r14075_India_uncoupled/src/OCE/DOM – NEMO

source: NEMO/branches/UKMO/r14075_India_uncoupled/src/OCE/DOM/dtatsd.F90 @ 15465

Last change on this file since 15465 was 15465, checked in by jcastill, 8 months ago

Small fix: add some parameters to a namelist

File size: 16.2 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + remove CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE phycst          ! physical constants
19   USE dom_oce         ! ocean space and time domain
20   USE fldread         ! read input fields
21   !
22   USE in_out_manager  ! I/O manager
23   USE iom             ! IOM library
24   USE lib_mpp         ! MPP library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dta_tsd_init   ! called by opa.F90
30   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
31
32   !                                  !!* namtsd  namelist : Temperature & Salinity Data *
33   LOGICAL , PUBLIC ::   ln_tsd_init   !: T & S data flag
34   LOGICAL , PUBLIC ::   ln_tsd_interp !: vertical interpolation flag
35   LOGICAL , PUBLIC ::   ln_tsd_dmp    !: internal damping toward input data flag
36
37   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
38   INTEGER                              ::   jpk_init, inum_dta 
39   INTEGER                              ::   id, linum   ! local integers 
40   INTEGER                              ::   zdim(4)
41
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE dta_tsd_init( ld_tradmp )
50      !!----------------------------------------------------------------------
51      !!                   ***  ROUTINE dta_tsd_init  ***
52      !!                   
53      !! ** Purpose :   initialisation of T & S input data
54      !!
55      !! ** Method  : - Read namtsd namelist
56      !!              - allocates T & S data structure
57      !!----------------------------------------------------------------------
58      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
59      !
60      INTEGER ::   ios, ierr0, ierr1, ierr2, ierr3, ierr4, ierr5   ! local integers
61      !!
62      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
63      TYPE(FLD_N), DIMENSION(jpts+2)::   slf_i           ! array of namelist informations on the fields to read 
64      TYPE(FLD_N)                   ::   sn_tem, sn_sal, sn_dep, sn_msk 
65      !!
66      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_interp, ln_tsd_dmp, cn_dir, sn_tem, sn_sal, sn_dep, sn_msk 
67      !!----------------------------------------------------------------------
68      !
69      !  Initialisation
70      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0  ; ierr4 = 0  ;  ierr5 = 0
71      !
72      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
73      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
74901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtsd in reference namelist' )
75      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
76      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
77902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtsd in configuration namelist' )
78      IF(lwm) WRITE ( numond, namtsd )
79
80      IF( PRESENT( ld_tradmp ) )   ln_tsd_dmp = .TRUE.     ! forces the initialization when tradmp is used
81     
82      IF(lwp) THEN                  ! control print
83         WRITE(numout,*)
84         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
85         WRITE(numout,*) '~~~~~~~~~~~~ '
86         WRITE(numout,*) '   Namelist namtsd'
87         WRITE(numout,*) '      Initialisation of ocean T & S with T & S input data  ln_tsd_init   = ', ln_tsd_init 
88         WRITE(numout,*) '      Interpolation of initial conditions in the vertical  ln_tsd_interp = ', ln_tsd_interp 
89         WRITE(numout,*) '      damping of ocean T & S toward T & S input data       ln_tsd_dmp    = ', ln_tsd_dmp
90         WRITE(numout,*)
91         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_dmp ) THEN
92            WRITE(numout,*)
93            WRITE(numout,*) '   ===>>   T & S data not used'
94         ENDIF
95      ENDIF
96      !
97      IF( ln_rstart .AND. ln_tsd_init ) THEN
98         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
99            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
100         ln_tsd_init = .FALSE.
101      ENDIF
102      IF( ln_tsd_interp .AND. ln_tsd_dmp ) THEN 
103            CALL ctl_stop( 'dta_tsd_init: Tracer damping and vertical interpolation not yet configured' )   ;   RETURN 
104      ENDIF 
105      IF( ln_tsd_interp .AND. LEN(TRIM(sn_msk%wname)) > 0 ) THEN 
106            CALL ctl_stop( 'dta_tsd_init: Using vertical interpolation and weights files not recommended' )   ;   RETURN 
107      ENDIF
108      !
109      !                             ! allocate the arrays (if necessary)
110      IF( ln_tsd_init .OR. ln_tsd_dmp ) THEN
111         !
112         IF( ln_tsd_interp ) THEN 
113           ALLOCATE( sf_tsd(jpts+2), STAT=ierr0 ) ! to carry the addtional depth information 
114         ELSE 
115           ALLOCATE( sf_tsd(jpts  ), STAT=ierr0 )   
116         ENDIF
117         IF( ierr0 > 0 ) THEN
118            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
119         ENDIF
120         !
121         IF( ln_tsd_interp ) THEN 
122            CALL iom_open ( trim(cn_dir) // trim(sn_dep%clname), inum_dta )   
123            id = iom_varid( inum_dta, sn_dep%clvar, zdim ) 
124            jpk_init = zdim(3) 
125            IF(lwp) WRITE(numout,*) 'Dimension of vertical coordinate in ICs: ', jpk_init 
126            CALL iom_close( inum_dta )   ! Close the input file 
127           
128                                 ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk_init  ) , STAT=ierr0 ) 
129            IF( sn_tem%ln_tint ) ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk_init,2) , STAT=ierr1 ) 
130                                 ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk_init  ) , STAT=ierr2 ) 
131            IF( sn_sal%ln_tint ) ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk_init,2) , STAT=ierr3 )   
132                                 ALLOCATE( sf_tsd(jp_dep)%fnow(jpi,jpj,jpk_init  ) , STAT=ierr4 ) 
133                                 ALLOCATE( sf_tsd(jp_msk)%fnow(jpi,jpj,jpk_init  ) , STAT=ierr5 ) 
134         ELSE 
135                                 ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 ) 
136            IF( sn_tem%ln_tint ) ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 ) 
137                                 ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 ) 
138            IF( sn_sal%ln_tint ) ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )   
139         ENDIF ! ln_tsd_interp 
140         
141         IF( ierr0 + ierr1 + ierr2 + ierr3 + ierr4 + ierr5 > 0 ) THEN
142            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
143         ENDIF
144         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
145         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
146         IF( ln_tsd_interp ) slf_i(jp_dep) = sn_dep   ;   slf_i(jp_msk) = sn_msk
147         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd', no_print )
148         !
149      ENDIF
150      !
151   END SUBROUTINE dta_tsd_init
152
153
154   SUBROUTINE dta_tsd( kt, ptsd )
155      !!----------------------------------------------------------------------
156      !!                   ***  ROUTINE dta_tsd  ***
157      !!                   
158      !! ** Purpose :   provides T and S data at kt
159      !!
160      !! ** Method  : - call fldread routine
161      !!              - ORCA_R2: add some hand made alteration to read data 
162      !!              - 'key_orca_lev10' interpolates on 10 times more levels
163      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
164      !!              - ln_tsd_dmp=F: deallocates the T-S data structure
165      !!                as T-S data are no are used
166      !!
167      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
168      !!----------------------------------------------------------------------
169      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
170      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
171      !
172      INTEGER ::   ji, jj, jk, jl, jk_init   ! dummy loop indices 
173      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1        ! local integers
174      REAL(wp)::   zl, zi                             ! local scalars
175      !!----------------------------------------------------------------------
176      !
177      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
178      !
179      !
180!!gm  This should be removed from the code   ===>>>>  T & S files has to be changed
181      !
182      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
183      IF( cn_cfg == "orca" .OR. cn_cfg == "ORCA" ) THEN
184         IF( nn_cfg == 2 .AND. ln_tsd_dmp ) THEN    ! some hand made alterations
185            !
186            ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
187            ii0 = 141   ;   ii1 = 155
188            DO jj = mj0(ij0), mj1(ij1)
189               DO ji = mi0(ii0), mi1(ii1)
190                  sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
191                  sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
192                  sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
193                  !
194                  sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
195                  sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
196                  sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
197                  sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
198               END DO
199            END DO
200            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
201            ii0 = 148   ;   ii1 = 160
202            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
203            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
204            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
205         ENDIF
206      ENDIF
207!!gm end
208      !
209      IF( kt == nit000 .AND. lwp )THEN 
210         WRITE(numout,*) 
211         WRITE(numout,*) 'dta_tsd: interpolates T & S data onto current mesh' 
212      ENDIF 
213     
214      IF( ln_tsd_interp ) THEN                 ! probably should use pointers in the following to make more readable 
215     
216         DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points 
217            DO jj= 1, jpj 
218               DO ji= 1, jpi
219                  zl = gdept_0(ji,jj,jk)
220                  IF( zl < sf_tsd(jp_dep)%fnow(ji,jj,1) ) THEN                     ! above the first level of data 
221                     ptsd(ji,jj,jk,jp_tem) = sf_tsd(jp_tem)%fnow(ji,jj,1)   
222                     ptsd(ji,jj,jk,jp_sal) = sf_tsd(jp_sal)%fnow(ji,jj,1) 
223                  ELSEIF( zl > sf_tsd(jp_dep)%fnow(ji,jj,jpk_init) ) THEN          ! below the last level of data 
224                     ptsd(ji,jj,jk,jp_tem) = sf_tsd(jp_tem)%fnow(ji,jj,jpk_init) 
225                     ptsd(ji,jj,jk,jp_sal) = sf_tsd(jp_sal)%fnow(ji,jj,jpk_init) 
226                  ELSE                                                             ! inbetween : vertical interpolation between jk_init & jk_init+1 
227                     DO jk_init = 1, jpk_init-1                                    ! when  gdept(jk_init) < zl < gdept(jk_init+1) 
228                        IF( sf_tsd(jp_msk)%fnow(ji,jj,jk_init+1) == 0 ) THEN       ! if there is no data fill down 
229                           sf_tsd(jp_tem)%fnow(ji,jj,jk_init+1) = sf_tsd(jp_tem)%fnow(ji,jj,jk_init) 
230                           sf_tsd(jp_sal)%fnow(ji,jj,jk_init+1) = sf_tsd(jp_sal)%fnow(ji,jj,jk_init) 
231                        ENDIF 
232                        IF((zl-sf_tsd(jp_dep)%fnow(ji,jj,jk_init)) * (zl-sf_tsd(jp_dep)%fnow(ji,jj,jk_init+1)) <= 0._wp ) THEN 
233                           zi = ( zl - sf_tsd(jp_dep)%fnow(ji,jj,jk_init) ) / & 
234                        &       (sf_tsd(jp_dep)%fnow(ji,jj,jk_init+1)-sf_tsd(jp_dep)%fnow(ji,jj,jk_init)) 
235                           ptsd(ji,jj,jk,jp_tem) = sf_tsd(jp_tem)%fnow(ji,jj,jk_init) + & 
236                        &                         (sf_tsd(jp_tem)%fnow(ji,jj,jk_init+1)-sf_tsd(jp_tem)%fnow(ji,jj,jk_init)) * zi 
237                           ptsd(ji,jj,jk,jp_sal) = sf_tsd(jp_sal)%fnow(ji,jj,jk_init) + & 
238                        &                         (sf_tsd(jp_sal)%fnow(ji,jj,jk_init+1)-sf_tsd(jp_sal)%fnow(ji,jj,jk_init)) * zi
239                        ENDIF
240                     END DO
241                  ENDIF
242               END DO
243            END DO
244         END DO
245         !
246         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) *tmask(:,:,:) 
247         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) *tmask(:,:,:)
248      ELSE                                !==   z- or zps- coordinate   ==!
249         !                             
250         ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:) * tmask(:,:,:)  ! Mask 
251         ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) * tmask(:,:,:)
252         !
253         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
254            DO jj = 1, jpj
255               DO ji = 1, jpi
256                  ik = mbkt(ji,jj) 
257                  IF( ik > 1 ) THEN
258                     zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
259                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
260                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
261                  ENDIF
262                  ik = mikt(ji,jj)
263                  IF( ik > 1 ) THEN
264                     zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) 
265                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem)
266                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal)
267                  END IF
268               END DO
269            END DO
270         ENDIF
271         !
272      ENDIF
273      !
274      IF( .NOT.ln_tsd_dmp ) THEN                   !==   deallocate T & S structure   ==!
275         !                                              (data used only for initialisation)
276         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
277                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
278         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
279                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
280         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
281         IF( ln_tsd_interp )            DEALLOCATE( sf_tsd(jp_dep)%fnow )     ! T arrays in the structure 
282         IF( ln_tsd_interp )            DEALLOCATE( sf_tsd(jp_msk)%fnow )     ! T arrays in the structure
283                                        DEALLOCATE( sf_tsd              )     ! the structure itself
284      ENDIF
285      !
286   END SUBROUTINE dta_tsd
287
288   !!======================================================================
289END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.