New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/UKMO/r8395_coupling_sequence/NEMOGCM/NEMO/OPA_SRC – NEMO

source: NEMO/branches/UKMO/r8395_coupling_sequence/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 10764

Last change on this file since 10764 was 10764, checked in by jcastill, 3 years ago

Minimal set of changes for coupling order

File size: 41.6 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
36   !!----------------------------------------------------------------------
37
38   !!----------------------------------------------------------------------
39   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
40   !!   nemo_init     : initialization of the NEMO system
41   !!   nemo_ctl      : initialisation of the contol print
42   !!   nemo_closefile: close remaining open files
43   !!   nemo_alloc    : dynamical allocation
44   !!   nemo_partition: calculate MPP domain decomposition
45   !!   factorise     : calculate the factors of the no. of MPI processes
46   !!----------------------------------------------------------------------
47   USE step_oce       ! module used in the ocean time stepping module (step.F90)
48   USE phycst         ! physical constant                  (par_cst routine)
49   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
50   USE usrdef_nam     ! user defined configuration
51   USE tideini        ! tidal components initialization   (tide_ini routine)
52   USE bdy_oce,   ONLY: ln_bdy
53   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
54   USE istate         ! initial state setting          (istate_init routine)
55   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
56   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
57   USE zdfini         ! vertical physics setting          (zdf_init routine)
58   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
59   USE asminc         ! assimilation increments     
60   USE asmbkg         ! writing out state trajectory
61   USE diaptr         ! poleward transports           (dia_ptr_init routine)
62   USE diadct         ! sections transports           (dia_dct_init routine)
63   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
64   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
65   USE step           ! NEMO time-stepping                 (stp     routine)
66   USE icbini         ! handle bergs, initialisation
67   USE icbstp         ! handle bergs, calving, themodynamics and transport
68   USE cpl_oasis3     ! OASIS3 coupling
69   USE c1d            ! 1D configuration
70   USE step_c1d       ! Time stepping loop for the 1D configuration
71   USE dyndmp         ! Momentum damping
72   USE stopar         ! Stochastic param.: ???
73   USE stopts         ! Stochastic param.: ???
74   USE diurnal_bulk   ! diurnal bulk SST
75   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
76   USE crsini         ! initialise grid coarsening utility
77   USE diatmb         ! Top,middle,bottom output
78   USE dia25h         ! 25h mean output
79   USE sbc_oce , ONLY : lk_oasis
80   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
81#if defined key_top
82   USE trcini         ! passive tracer initialisation
83#endif
84#if defined key_nemocice_decomp
85   USE ice_domain_size, only: nx_global, ny_global
86#endif
87   !
88   USE lib_mpp        ! distributed memory computing
89   USE mppini         ! shared/distributed memory setting (mpp_init routine)
90   USE lbcnfd , ONLY  : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
91   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
92   USE sbccpl
93#if defined key_iomput
94   USE xios           ! xIOserver
95#endif
96
97   IMPLICIT NONE
98   PRIVATE
99
100   PUBLIC   nemo_gcm    ! called by model.F90
101   PUBLIC   nemo_init   ! needed by AGRIF
102   PUBLIC   nemo_alloc  ! needed by TAM
103
104   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
105
106   !!----------------------------------------------------------------------
107   !! NEMO/OPA 3.7 , NEMO Consortium (2016)
108   !! $Id$
109   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
110   !!----------------------------------------------------------------------
111CONTAINS
112
113   SUBROUTINE nemo_gcm
114      !!----------------------------------------------------------------------
115      !!                     ***  ROUTINE nemo_gcm  ***
116      !!
117      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
118      !!              curvilinear mesh on the sphere.
119      !!
120      !! ** Method  : - model general initialization
121      !!              - launch the time-stepping (stp routine)
122      !!              - finalize the run by closing files and communications
123      !!
124      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
125      !!              Madec, 2008, internal report, IPSL.
126      !!----------------------------------------------------------------------
127      INTEGER ::   istp   ! time step index
128      !!----------------------------------------------------------------------
129      !
130#if defined key_agrif
131      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
132#endif
133      !
134      !                            !-----------------------!
135      CALL nemo_init               !==  Initialisations  ==!
136      !                            !-----------------------!
137#if defined key_agrif
138      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
139      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
140# if defined key_top
141      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
142# endif
143# if defined key_lim2
144      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM2
145# endif
146# if defined key_lim3
147      CALL Agrif_Declare_Var_lim3  !  "      "   "   "      "  LIM3
148# endif
149#endif
150      ! check that all process are still there... If some process have an error,
151      ! they will never enter in step and other processes will wait until the end of the cpu time!
152      IF( lk_mpp )   CALL mpp_max( nstop )
153
154      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
155
156      !                            !-----------------------!
157      !                            !==   time stepping   ==!
158      !                            !-----------------------!
159      istp = nit000
160#if defined key_c1d
161         DO WHILE ( istp <= nitend .AND. nstop == 0 )
162            CALL stp_c1d( istp )
163            istp = istp + 1
164         END DO
165#else
166          IF( lk_asminc ) THEN
167             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
168             IF( ln_asmdin ) THEN                        ! Direct initialization
169                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
170                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
171                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
172             ENDIF
173          ENDIF
174
175#if defined key_agrif
176          CALL Agrif_Regrid()
177#endif
178
179         DO WHILE ( istp <= nitend .AND. nstop == 0 )
180#if defined key_agrif
181            CALL stp                         ! AGRIF: time stepping
182#else
183            IF ( .NOT. ln_diurnal_only ) THEN
184               IF (lk_oasis) CALL sbc_cpl_snd( istp )  ! Coupling to atmos
185               CALL stp( istp )                 ! standard time stepping
186               ! We don't couple on the final timestep because
187               ! our restart file has already been written
188               ! and contains all the necessary data for a
189               ! restart. sbc_cpl_snd could be called here
190               ! but it would require
191               ! a) A test to ensure it was not performed
192               !    on the very last time-step
193               ! b) the presence of another call to
194               !    sbc_cpl_snd call prior to the main DO loop
195               ! This solution produces identical results
196               ! with fewer lines of code.
197            ELSE
198               CALL stp_diurnal( istp )        ! time step only the diurnal SST
199            ENDIF 
200#endif
201            istp = istp + 1
202            IF( lk_mpp )   CALL mpp_max( nstop )
203         END DO
204#endif
205
206      IF( ln_diaobs   )   CALL dia_obs_wri
207      !
208      IF( ln_icebergs )   CALL icb_end( nitend )
209
210      !                            !------------------------!
211      !                            !==  finalize the run  ==!
212      !                            !------------------------!
213      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
214      !
215      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
216         WRITE(numout,cform_err)
217         WRITE(numout,*) nstop, ' error have been found'
218      ENDIF
219      !
220#if defined key_agrif
221      IF( .NOT. Agrif_Root() ) THEN
222                         CALL Agrif_ParentGrid_To_ChildGrid()
223         IF( ln_diaobs ) CALL dia_obs_wri
224         IF( nn_timing == 1 )   CALL timing_finalize
225                                CALL Agrif_ChildGrid_To_ParentGrid()
226      ENDIF
227#endif
228      IF( nn_timing == 1 )   CALL timing_finalize
229      !
230      CALL nemo_closefile
231      !
232#if defined key_iomput
233      CALL xios_finalize                     ! end mpp communications with xios
234      IF( lk_oasis )   CALL cpl_finalize     ! end coupling and mpp communications with OASIS
235#else
236      IF( lk_oasis ) THEN
237         CALL cpl_finalize                   ! end coupling and mpp communications with OASIS
238      ELSE
239         IF( lk_mpp )   CALL mppstop         ! end mpp communications
240      ENDIF
241#endif
242      !
243   END SUBROUTINE nemo_gcm
244
245
246   SUBROUTINE nemo_init
247      !!----------------------------------------------------------------------
248      !!                     ***  ROUTINE nemo_init  ***
249      !!
250      !! ** Purpose :   initialization of the NEMO GCM
251      !!----------------------------------------------------------------------
252      INTEGER  ::   ji                 ! dummy loop indices
253      INTEGER  ::   ios, ilocal_comm   ! local integer
254      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
255      !
256      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
257         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
258         &             nn_timing, nn_diacfl
259      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
260      !!----------------------------------------------------------------------
261      !
262      cltxt  = ''
263      cltxt2 = ''
264      clnam  = '' 
265      cxios_context = 'nemo'
266      !
267      !                             ! Open reference namelist and configuration namelist files
268      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
269      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
270      !
271      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints
272      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
273901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
274      !
275      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
276      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
277902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
278      !
279      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints
280      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
281903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
282
283      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
284      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
285904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
286
287      !                             !--------------------------!
288      !                             !  Set global domain size  !   (control print return in cltxt2)
289      !                             !--------------------------!
290      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
291         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
292         !
293      ELSE                                ! user-defined namelist
294         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
295      ENDIF
296      !
297      jpk = jpkglo
298      !
299#if defined key_agrif
300      IF( .NOT. Agrif_Root() ) THEN       ! AGRIF children: specific setting (cf. agrif_user.F90)
301         jpiglo  = nbcellsx + 2 + 2*nbghostcells
302         jpjglo  = nbcellsy + 2 + 2*nbghostcells
303         jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
304         jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
305         nperio  = 0
306         jperio  = 0
307         ln_use_jattr = .false.
308      ENDIF
309#endif
310      !
311      !                             !--------------------------------------------!
312      !                             !  set communicator & select the local node  !
313      !                             !  NB: mynode also opens output.namelist.dyn !
314      !                             !      on unit number numond on first proc   !
315      !                             !--------------------------------------------!
316#if defined key_iomput
317      IF( Agrif_Root() ) THEN
318         IF( lk_oasis ) THEN
319            CALL cpl_init( "toyoce", ilocal_comm )                               ! nemo local communicator given by oasis
320            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
321         ELSE
322            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
323         ENDIF
324      ENDIF
325      ! Nodes selection (control print return in cltxt)
326      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
327#else
328      IF( lk_oasis ) THEN
329         IF( Agrif_Root() ) THEN
330            CALL cpl_init( "toyoce", ilocal_comm )          ! nemo local communicator given by oasis
331         ENDIF
332         ! Nodes selection (control print return in cltxt)
333         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
334      ELSE
335         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
336         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
337      ENDIF
338#endif
339
340      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
341
342      lwm = (narea == 1)                                    ! control of output namelists
343      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
344
345      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
346         !                       ! now that the file has been opened in call to mynode.
347         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
348         WRITE( numond, namctl )
349         WRITE( numond, namcfg )
350         IF( .NOT.ln_read_cfg ) THEN
351            DO ji = 1, SIZE(clnam)
352               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
353            END DO
354         ENDIF
355      ENDIF
356
357      ! If dimensions of processor grid weren't specified in the namelist file
358      ! then we calculate them here now that we have our communicator size
359      IF( jpni < 1 .OR. jpnj < 1 ) THEN
360#if   defined key_mpp_mpi
361         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
362#else
363         jpni  = 1
364         jpnj  = 1
365         jpnij = jpni*jpnj
366#endif
367      ENDIF
368
369      IF( Agrif_Root() ) THEN       ! AGRIF mother: specific setting from jpni and jpnj
370#if defined key_nemocice_decomp
371         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
372         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
373#else
374         jpi = ( jpiglo     -2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
375         jpj = ( jpjglo     -2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
376#endif
377      ENDIF
378
379!!gm ???    why here  it has already been done in line 301 !
380      jpk = jpkglo                                             ! third dim
381!!gm end
382
383#if defined key_agrif
384      ! simple trick to use same vertical grid as parent but different number of levels:
385      ! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
386      ! Suppress once vertical online interpolation is ok
387      IF(.NOT.Agrif_Root())   jpkglo = Agrif_Parent( jpkglo )
388#endif
389      jpim1 = jpi-1                                            ! inner domain indices
390      jpjm1 = jpj-1                                            !   "           "
391      jpkm1 = MAX( 1, jpk-1 )                                  !   "           "
392      jpij  = jpi*jpj                                          !  jpi x j
393
394      IF(lwp) THEN                            ! open listing units
395         !
396         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
397         !
398         WRITE(numout,*)
399         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
400         WRITE(numout,*) '                       NEMO team'
401         WRITE(numout,*) '            Ocean General Circulation Model'
402         WRITE(numout,*) '                NEMO version 3.7  (2016) '
403         WRITE(numout,*)
404         WRITE(numout,*)
405         DO ji = 1, SIZE(cltxt)
406            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
407         END DO
408         WRITE(numout,*)
409         WRITE(numout,*)
410         DO ji = 1, SIZE(cltxt2)
411            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
412         END DO
413         !
414         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
415         !
416      ENDIF
417
418      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
419      CALL nemo_alloc()
420
421      !                             !-------------------------------!
422      !                             !  NEMO general initialization  !
423      !                             !-------------------------------!
424
425      CALL nemo_ctl                          ! Control prints
426
427      !                                      ! Domain decomposition
428      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
429      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
430      ENDIF
431      !
432      IF( nn_timing == 1 )  CALL timing_init
433      !
434      !                                      ! General initialization
435                            CALL     phy_cst    ! Physical constants
436                            CALL     eos_init   ! Equation of state
437      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
438                            CALL     wad_init   ! Wetting and drying options
439                            CALL     dom_init   ! Domain
440      IF( ln_crs        )   CALL     crs_init   ! coarsened grid: domain initialization
441      IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
442      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
443     
444      CALL diurnal_sst_bulk_init            ! diurnal sst
445      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
446     
447      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
448      IF ( ln_diurnal_only ) THEN
449         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
450         CALL     sbc_init   ! Forcings : surface module
451         CALL tra_qsr_init   ! penetrative solar radiation qsr
452         IF( ln_diaobs     ) THEN                  ! Observation & model comparison
453            CALL dia_obs_init            ! Initialize observational data
454            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
455         ENDIF     
456         !                                     ! Assimilation increments
457         IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
458                 
459         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
460         RETURN
461      ENDIF
462     
463                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
464
465      !                                      ! external forcing
466!!gm to be added : creation and call of sbc_apr_init
467                            CALL    tide_init   ! tidal harmonics
468                            CALL     sbc_init   ! surface boundary conditions (including sea-ice)
469                            CALL     bdy_init   ! Open boundaries initialisation
470      !                                      ! Ocean physics
471      !                                         ! Vertical physics
472                            CALL     zdf_init      ! namelist read
473                            CALL zdf_bfr_init      ! bottom friction
474      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
475      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
476      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
477      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
478      IF( lk_zdfddm     )   CALL zdf_ddm_init      ! double diffusive mixing
479         
480      !                                         ! Lateral physics
481                            CALL ldf_tra_init      ! Lateral ocean tracer physics
482                            CALL ldf_eiv_init      ! eddy induced velocity param.
483                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
484
485      !                                         ! Active tracers
486                            CALL tra_qsr_init      ! penetrative solar radiation qsr
487                            CALL tra_bbc_init      ! bottom heat flux
488      IF( lk_trabbl     )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
489                            CALL tra_dmp_init      ! internal tracer damping
490                            CALL tra_adv_init      ! horizontal & vertical advection
491                            CALL tra_ldf_init      ! lateral mixing
492                            CALL tra_zdf_init      ! vertical mixing and after tracer fields
493
494      !                                         ! Dynamics
495      IF( lk_c1d        )   CALL dyn_dmp_init      ! internal momentum damping
496                            CALL dyn_adv_init      ! advection (vector or flux form)
497                            CALL dyn_vor_init      ! vorticity term including Coriolis
498                            CALL dyn_ldf_init      ! lateral mixing
499                            CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
500                            CALL dyn_zdf_init      ! vertical diffusion
501                            CALL dyn_spg_init      ! surface pressure gradient
502
503#if defined key_top
504      !                                      ! Passive tracers
505                            CALL     trc_init
506#endif
507      IF( l_ldfslp      )   CALL ldf_slp_init   ! slope of lateral mixing
508
509      !                                      ! Icebergs
510                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
511
512      !                                      ! Misc. options
513                            CALL sto_par_init   ! Stochastic parametrization
514      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
515     
516      !                                      ! Diagnostics
517      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
518                            CALL dia_cfl_init   ! Initialise CFL diagnostics
519                            CALL dia_ptr_init   ! Poleward TRansports initialization
520      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
521                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
522                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
523                            CALL dia_obs_init            ! Initialize observational data
524      IF( ln_diaobs     )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
525
526      !                                         ! Assimilation increments
527      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
528      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
529                            CALL dia_tmb_init  ! TMB outputs
530                            CALL dia_25h_init  ! 25h mean  outputs
531     
532      IF (nstop > 0) THEN
533        CALL CTL_STOP('STOP','Critical errors in NEMO initialisation') 
534      END IF 
535      !
536   END SUBROUTINE nemo_init
537
538
539   SUBROUTINE nemo_ctl
540      !!----------------------------------------------------------------------
541      !!                     ***  ROUTINE nemo_ctl  ***
542      !!
543      !! ** Purpose :   control print setting
544      !!
545      !! ** Method  : - print namctl information and check some consistencies
546      !!----------------------------------------------------------------------
547      !
548      IF(lwp) THEN                  ! control print
549         WRITE(numout,*)
550         WRITE(numout,*) 'nemo_ctl: Control prints'
551         WRITE(numout,*) '~~~~~~~ '
552         WRITE(numout,*) '   Namelist namctl'
553         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
554         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
555         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
556         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
557         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
558         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
559         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
560         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
561         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
562      ENDIF
563      !
564      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
565      nictls    = nn_ictls
566      nictle    = nn_ictle
567      njctls    = nn_jctls
568      njctle    = nn_jctle
569      isplt     = nn_isplt
570      jsplt     = nn_jsplt
571
572      IF(lwp) THEN                  ! control print
573         WRITE(numout,*)
574         WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
575         WRITE(numout,*) '~~~~~~ '
576         WRITE(numout,*) '   Namelist namcfg'
577         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
578         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
579         WRITE(numout,*) '      write configuration definition file           ln_write_cfg     = ', ln_write_cfg
580         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
581         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
582      ENDIF
583      !                             ! Parameter control
584      !
585      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
586         IF( lk_mpp .AND. jpnij > 1 ) THEN
587            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
588         ELSE
589            IF( isplt == 1 .AND. jsplt == 1  ) THEN
590               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
591                  &           ' - the print control will be done over the whole domain' )
592            ENDIF
593            ijsplt = isplt * jsplt            ! total number of processors ijsplt
594         ENDIF
595         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
596         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
597         !
598         !                              ! indices used for the SUM control
599         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
600            lsp_area = .FALSE.
601         ELSE                                             ! print control done over a specific  area
602            lsp_area = .TRUE.
603            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
604               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
605               nictls = 1
606            ENDIF
607            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
608               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
609               nictle = jpiglo
610            ENDIF
611            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
612               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
613               njctls = 1
614            ENDIF
615            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
616               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
617               njctle = jpjglo
618            ENDIF
619         ENDIF
620      ENDIF
621      !
622      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
623         &                                               'f2003 standard. '                              ,  &
624         &                                               'Compile with key_nosignedzero enabled' )
625      !
626   END SUBROUTINE nemo_ctl
627
628
629   SUBROUTINE nemo_closefile
630      !!----------------------------------------------------------------------
631      !!                     ***  ROUTINE nemo_closefile  ***
632      !!
633      !! ** Purpose :   Close the files
634      !!----------------------------------------------------------------------
635      !
636      IF( lk_mpp )   CALL mppsync
637      !
638      CALL iom_close                                 ! close all input/output files managed by iom_*
639      !
640      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
641      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
642      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
643      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
644      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
645      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
646      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
647      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
648      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
649      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
650      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
651      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
652      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
653      !
654      numout = 6                                     ! redefine numout in case it is used after this point...
655      !
656   END SUBROUTINE nemo_closefile
657
658
659   SUBROUTINE nemo_alloc
660      !!----------------------------------------------------------------------
661      !!                     ***  ROUTINE nemo_alloc  ***
662      !!
663      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
664      !!
665      !! ** Method  :
666      !!----------------------------------------------------------------------
667      USE diawri    , ONLY: dia_wri_alloc
668      USE dom_oce   , ONLY: dom_oce_alloc
669      USE trc_oce   , ONLY: trc_oce_alloc
670#if defined key_diadct 
671      USE diadct    , ONLY: diadct_alloc 
672#endif
673      USE bdy_oce   , ONLY: bdy_oce_alloc
674      !
675      INTEGER :: ierr
676      !!----------------------------------------------------------------------
677      !
678      ierr =        oce_alloc       ()          ! ocean
679      ierr = ierr + dia_wri_alloc   ()
680      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
681      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
682      !
683      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
684      !
685#if defined key_diadct 
686      ierr = ierr + diadct_alloc    ()          !
687#endif
688      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
689      !
690      IF( lk_mpp    )   CALL mpp_sum( ierr )
691      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
692      !
693   END SUBROUTINE nemo_alloc
694
695
696   SUBROUTINE nemo_partition( num_pes )
697      !!----------------------------------------------------------------------
698      !!                 ***  ROUTINE nemo_partition  ***
699      !!
700      !! ** Purpose :
701      !!
702      !! ** Method  :
703      !!----------------------------------------------------------------------
704      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
705      !
706      INTEGER, PARAMETER :: nfactmax = 20
707      INTEGER :: nfact ! The no. of factors returned
708      INTEGER :: ierr  ! Error flag
709      INTEGER :: ji
710      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
711      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
712      !!----------------------------------------------------------------------
713      !
714      ierr = 0
715      !
716      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
717      !
718      IF( nfact <= 1 ) THEN
719         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
720         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
721         jpnj = 1
722         jpni = num_pes
723      ELSE
724         ! Search through factors for the pair that are closest in value
725         mindiff = 1000000
726         imin    = 1
727         DO ji = 1, nfact-1, 2
728            idiff = ABS( ifact(ji) - ifact(ji+1) )
729            IF( idiff < mindiff ) THEN
730               mindiff = idiff
731               imin = ji
732            ENDIF
733         END DO
734         jpnj = ifact(imin)
735         jpni = ifact(imin + 1)
736      ENDIF
737      !
738      jpnij = jpni*jpnj
739      !
740   END SUBROUTINE nemo_partition
741
742
743   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
744      !!----------------------------------------------------------------------
745      !!                     ***  ROUTINE factorise  ***
746      !!
747      !! ** Purpose :   return the prime factors of n.
748      !!                knfax factors are returned in array kfax which is of
749      !!                maximum dimension kmaxfax.
750      !! ** Method  :
751      !!----------------------------------------------------------------------
752      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
753      INTEGER                    , INTENT(  out) ::   kerr, knfax
754      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
755      !
756      INTEGER :: ifac, jl, inu
757      INTEGER, PARAMETER :: ntest = 14
758      INTEGER, DIMENSION(ntest) ::   ilfax
759      !!----------------------------------------------------------------------
760      !
761      ! lfax contains the set of allowed factors.
762      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
763      !
764      ! Clear the error flag and initialise output vars
765      kerr  = 0
766      kfax  = 1
767      knfax = 0
768      !
769      ! Find the factors of n.
770      IF( kn == 1 )   GOTO 20
771
772      ! nu holds the unfactorised part of the number.
773      ! knfax holds the number of factors found.
774      ! l points to the allowed factor list.
775      ! ifac holds the current factor.
776      !
777      inu   = kn
778      knfax = 0
779      !
780      DO jl = ntest, 1, -1
781         !
782         ifac = ilfax(jl)
783         IF( ifac > inu )   CYCLE
784
785         ! Test whether the factor will divide.
786
787         IF( MOD(inu,ifac) == 0 ) THEN
788            !
789            knfax = knfax + 1            ! Add the factor to the list
790            IF( knfax > kmaxfax ) THEN
791               kerr = 6
792               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
793               return
794            ENDIF
795            kfax(knfax) = ifac
796            ! Store the other factor that goes with this one
797            knfax = knfax + 1
798            kfax(knfax) = inu / ifac
799            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
800         ENDIF
801         !
802      END DO
803      !
804   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
805      !
806   END SUBROUTINE factorise
807
808#if defined key_mpp_mpi
809
810   SUBROUTINE nemo_northcomms
811      !!----------------------------------------------------------------------
812      !!                     ***  ROUTINE  nemo_northcomms  ***
813      !! ** Purpose :   Setup for north fold exchanges with explicit
814      !!                point-to-point messaging
815      !!
816      !! ** Method :   Initialization of the northern neighbours lists.
817      !!----------------------------------------------------------------------
818      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
819      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
820      !!----------------------------------------------------------------------
821      INTEGER  ::   sxM, dxM, sxT, dxT, jn
822      INTEGER  ::   njmppmax
823      !!----------------------------------------------------------------------
824      !
825      njmppmax = MAXVAL( njmppt )
826      !
827      !initializes the north-fold communication variables
828      isendto(:) = 0
829      nsndto     = 0
830      !
831      !if I am a process in the north
832      IF ( njmpp == njmppmax ) THEN
833          !sxM is the first point (in the global domain) needed to compute the
834          !north-fold for the current process
835          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
836          !dxM is the last point (in the global domain) needed to compute the
837          !north-fold for the current process
838          dxM = jpiglo - nimppt(narea) + 2
839
840          !loop over the other north-fold processes to find the processes
841          !managing the points belonging to the sxT-dxT range
842 
843          DO jn = 1, jpni
844                !sxT is the first point (in the global domain) of the jn
845                !process
846                sxT = nfiimpp(jn, jpnj)
847                !dxT is the last point (in the global domain) of the jn
848                !process
849                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
850                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
851                   nsndto = nsndto + 1
852                   isendto(nsndto) = jn
853                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
854                   nsndto = nsndto + 1
855                   isendto(nsndto) = jn
856                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
857                   nsndto = nsndto + 1
858                   isendto(nsndto) = jn
859                ENDIF
860          END DO
861          nfsloop = 1
862          nfeloop = nlci
863          DO jn = 2,jpni-1
864           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
865              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
866                 nfsloop = nldi
867              ENDIF
868              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
869                 nfeloop = nlei
870              ENDIF
871           ENDIF
872        END DO
873
874      ENDIF
875      l_north_nogather = .TRUE.
876   END SUBROUTINE nemo_northcomms
877
878#else
879   SUBROUTINE nemo_northcomms      ! Dummy routine
880      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
881   END SUBROUTINE nemo_northcomms
882#endif
883
884   !!======================================================================
885END MODULE nemogcm
886
Note: See TracBrowser for help on using the repository browser.