New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in NEMO/releases/r4.0/r4.0-HEAD/src/OCE/DOM – NEMO

source: NEMO/releases/r4.0/r4.0-HEAD/src/OCE/DOM/dtatsd.F90 @ 14185

Last change on this file since 14185 was 14185, checked in by hadcv, 3 years ago

#2564: Fix ORCA2 hand edits in dta_tsd being applied cumulatively

  • Property svn:keywords set to Id
File size: 14.1 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + remove CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE phycst          ! physical constants
19   USE dom_oce         ! ocean space and time domain
20   USE fldread         ! read input fields
21   !
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! MPP library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   dta_tsd_init   ! called by opa.F90
29   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
30
31   !                                  !!* namtsd  namelist : Temperature & Salinity Data *
32   LOGICAL , PUBLIC ::   ln_tsd_init   !: T & S data flag
33   LOGICAL , PUBLIC ::   ln_tsd_dmp    !: internal damping toward input data flag
34
35   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
36
37   !!----------------------------------------------------------------------
38   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE dta_tsd_init( ld_tradmp )
45      !!----------------------------------------------------------------------
46      !!                   ***  ROUTINE dta_tsd_init  ***
47      !!                   
48      !! ** Purpose :   initialisation of T & S input data
49      !!
50      !! ** Method  : - Read namtsd namelist
51      !!              - allocates T & S data structure
52      !!----------------------------------------------------------------------
53      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
54      !
55      INTEGER ::   ios, ierr0, ierr1, ierr2, ierr3   ! local integers
56      !!
57      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
58      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
59      TYPE(FLD_N)                   ::   sn_tem, sn_sal
60      !!
61      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_dmp, cn_dir, sn_tem, sn_sal
62      !!----------------------------------------------------------------------
63      !
64      !  Initialisation
65      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
66      !
67      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
68      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
69901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtsd in reference namelist' )
70      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
71      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
72902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtsd in configuration namelist' )
73      IF(lwm) WRITE ( numond, namtsd )
74
75      IF( PRESENT( ld_tradmp ) )   ln_tsd_dmp = .TRUE.     ! forces the initialization when tradmp is used
76     
77      IF(lwp) THEN                  ! control print
78         WRITE(numout,*)
79         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
80         WRITE(numout,*) '~~~~~~~~~~~~ '
81         WRITE(numout,*) '   Namelist namtsd'
82         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init = ', ln_tsd_init
83         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_dmp  = ', ln_tsd_dmp
84         WRITE(numout,*)
85         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_dmp ) THEN
86            WRITE(numout,*)
87            WRITE(numout,*) '   ===>>   T & S data not used'
88         ENDIF
89      ENDIF
90      !
91      IF( ln_rstart .AND. ln_tsd_init ) THEN
92         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
93            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
94         ln_tsd_init = .FALSE.
95      ENDIF
96      !
97      !                             ! allocate the arrays (if necessary)
98      IF( ln_tsd_init .OR. ln_tsd_dmp ) THEN
99         !
100         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
101         IF( ierr0 > 0 ) THEN
102            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
103         ENDIF
104         !
105                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
106         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
107                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
108         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
109         !
110         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
111            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
112         ENDIF
113         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
114         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
115         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd', no_print )
116         !
117      ENDIF
118      !
119   END SUBROUTINE dta_tsd_init
120
121
122   SUBROUTINE dta_tsd( kt, ptsd )
123      !!----------------------------------------------------------------------
124      !!                   ***  ROUTINE dta_tsd  ***
125      !!                   
126      !! ** Purpose :   provides T and S data at kt
127      !!
128      !! ** Method  : - call fldread routine
129      !!              - ORCA_R2: add some hand made alteration to read data 
130      !!              - 'key_orca_lev10' interpolates on 10 times more levels
131      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
132      !!              - ln_tsd_dmp=F: deallocates the T-S data structure
133      !!                as T-S data are no are used
134      !!
135      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
136      !!----------------------------------------------------------------------
137      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
138      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
139      !
140      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
141      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
142      INTEGER, DIMENSION(jpts), SAVE :: irec_b, irec_n
143      REAL(wp)::   zl, zi                             ! local scalars
144      REAL(wp), DIMENSION(jpk) ::  ztp, zsp   ! 1D workspace
145      !!----------------------------------------------------------------------
146      !
147      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
148      !
149      !
150!!gm  This should be removed from the code   ===>>>>  T & S files has to be changed
151      !
152      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
153      IF( cn_cfg == "orca" .OR. cn_cfg == "ORCA" ) THEN
154         IF( nn_cfg == 2 .AND. ln_tsd_dmp ) THEN    ! some hand made alterations
155            irec_n(jp_tem) = sf_tsd(jp_tem)%nrec_a(2)            ! Determine if there is new data (ln_tint = F)
156            irec_n(jp_sal) = sf_tsd(jp_sal)%nrec_a(2)            ! If not, then do not apply the increments
157            IF( kt == nit000 ) irec_b(:) = -1
158            !
159            ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
160            ii0 = 141   ;   ii1 = 155
161            IF( sf_tsd(jp_tem)%ln_tint .OR. irec_n(jp_tem) /= irec_b(jp_tem) ) THEN
162               DO jj = mj0(ij0), mj1(ij1)
163                  DO ji = mi0(ii0), mi1(ii1)
164                     sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
165                     sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
166                     sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
167                  END DO
168               END DO
169               irec_b(jp_tem) = irec_n(jp_tem)
170            ENDIF
171            !
172            IF( sf_tsd(jp_sal)%ln_tint .OR. irec_n(jp_sal) /= irec_b(jp_sal) ) THEN
173               DO jj = mj0(ij0), mj1(ij1)
174                  DO ji = mi0(ii0), mi1(ii1)
175                     sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
176                     sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
177                     sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
178                     sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
179                  END DO
180               END DO
181               irec_b(jp_sal) = irec_n(jp_sal)
182            ENDIF
183            !
184            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
185            ii0 = 148   ;   ii1 = 160
186            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
187            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
188            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
189         ENDIF
190      ENDIF
191!!gm end
192      !
193      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
194      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
195      !
196      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
197         !
198         IF( kt == nit000 .AND. lwp )THEN
199            WRITE(numout,*)
200            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
201         ENDIF
202         !
203         DO jj = 1, jpj                         ! vertical interpolation of T & S
204            DO ji = 1, jpi
205               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
206                  zl = gdept_0(ji,jj,jk)
207                  IF(     zl < gdept_1d(1  ) ) THEN          ! above the first level of data
208                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
209                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
210                  ELSEIF( zl > gdept_1d(jpk) ) THEN          ! below the last level of data
211                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
212                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
213                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
214                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
215                        IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
216                           zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
217                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
218                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
219                        ENDIF
220                     END DO
221                  ENDIF
222               END DO
223               DO jk = 1, jpkm1
224                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
225                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
226               END DO
227               ptsd(ji,jj,jpk,jp_tem) = 0._wp
228               ptsd(ji,jj,jpk,jp_sal) = 0._wp
229            END DO
230         END DO
231         !
232      ELSE                                !==   z- or zps- coordinate   ==!
233         !                             
234         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
235         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
236         !
237         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
238            DO jj = 1, jpj
239               DO ji = 1, jpi
240                  ik = mbkt(ji,jj) 
241                  IF( ik > 1 ) THEN
242                     zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
243                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
244                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
245                  ENDIF
246                  ik = mikt(ji,jj)
247                  IF( ik > 1 ) THEN
248                     zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) 
249                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem)
250                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal)
251                  END IF
252               END DO
253            END DO
254         ENDIF
255         !
256      ENDIF
257      !
258      IF( .NOT.ln_tsd_dmp ) THEN                   !==   deallocate T & S structure   ==!
259         !                                              (data used only for initialisation)
260         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
261                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
262         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
263                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
264         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
265                                        DEALLOCATE( sf_tsd              )     ! the structure itself
266      ENDIF
267      !
268   END SUBROUTINE dta_tsd
269
270   !!======================================================================
271END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.