source: NEMO/releases/r4.0/r4.0-HEAD/src/SAO/nemogcm.F90 @ 12640

Last change on this file since 12640 was 12640, checked in by smasson, 18 months ago

r4.0-HEAD: numnul with Agrif, see #2378

  • Property svn:keywords set to Id
File size: 22.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  3.6  ! 2015-12  (A. Ryan) Original code   (from OCE/)
7   !!            4.0  ! 2016-11  (G. Madec, S. Flavoni)  domain configuration / user defined interface
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
12   !!   nemo_init     : initialization of the NEMO system
13   !!   nemo_ctl      : initialisation of the contol print
14   !!   nemo_closefile: close remaining open files
15   !!   nemo_alloc    : dynamical allocation
16   !!----------------------------------------------------------------------
17   USE step_oce       ! module used in the ocean time stepping module (step.F90)
18   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
19   USE istate         ! initial state setting          (istate_init routine)
20   USE phycst         ! physical constant                  (par_cst routine)
21   USE step           ! NEMO time-stepping                 (stp     routine)
22   USE cpl_oasis3     ! OASIS3 coupling
23   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
24#if defined key_nemocice_decomp
25   USE ice_domain_size, only: nx_global, ny_global
26#endif
27   !           ! Stand Alone Observation operator modules
28   USE sao_data
29   USE sao_intp
30   !
31   USE in_out_manager ! I/O manager
32   USE lib_mpp        ! distributed memory computing
33   USE mppini         ! shared/distributed memory setting (mpp_init routine)
34   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
36#if defined key_iomput
37   USE xios           ! xIOserver
38#endif
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   nemo_gcm    ! called by model.F90
44   PUBLIC   nemo_init   ! needed by AGRIF
45   PUBLIC   nemo_alloc  ! needed by TAM
46
47   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
48
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE nemo_gcm
57         !!----------------------------------------------------------------------
58         !!                    ***  SUBROUTINE offline_obs_oper ***
59         !!
60         !! ** Purpose : To use NEMO components to interpolate model fields
61         !!              to observation space.
62         !!
63         !! ** Method : 1. Initialise NEMO
64         !!             2. Initialise offline obs_oper
65         !!             3. Cycle through match ups
66         !!             4. Write results to file
67         !!----------------------------------------------------------------------
68         !
69         CALL nemo_init       ! Initialise NEMO
70         !
71         CALL sao_data_init   ! Initialise Stand Alone Observation operator data
72         !
73         CALL dia_obs_init    ! Initialise obs_operator
74         !
75         CALL sao_interp      ! Interpolate to observation space
76         !
77         CALL dia_obs_wri     ! Pipe to output files
78         !
79         CALL dia_obs_dealloc ! Reset the obs_oper between
80         !
81         IF(lk_mpp)   CALL mppstop  ! Safely stop MPI (end mpp communications)
82         !
83   END SUBROUTINE nemo_gcm
84
85
86   SUBROUTINE nemo_init
87      !!----------------------------------------------------------------------
88      !!                     ***  ROUTINE nemo_init  ***
89      !!
90      !! ** Purpose :   initialization of the NEMO GCM
91      !!----------------------------------------------------------------------
92      INTEGER ::   ios, ilocal_comm   ! local integer
93      !
94      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
95         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
96         &             ln_timing, ln_diacfl
97      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
98      !!----------------------------------------------------------------------
99      !
100      cxios_context = 'nemo'
101      !
102      !                             !-------------------------------------------------!
103      !                             !     set communicator & select the local rank    !
104      !                             !  must be done as soon as possible to get narea  !
105      !                             !-------------------------------------------------!
106      !
107#if defined key_iomput
108      IF( Agrif_Root() ) THEN
109         IF( lk_oasis ) THEN
110            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
111            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
112         ELSE
113            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
114         ENDIF
115      ENDIF
116      CALL mpp_start( ilocal_comm )
117#else
118      IF( lk_oasis ) THEN
119         IF( Agrif_Root() ) THEN
120            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
121         ENDIF
122         CALL mpp_start( ilocal_comm )
123      ELSE
124         CALL mpp_start( )
125      ENDIF
126#endif
127      !
128      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
129      lwm = (narea == 1)                ! control of output namelists
130      !
131      !                             !---------------------------------------------------------------!
132      !                             ! Open output files, reference and configuration namelist files !
133      !                             !---------------------------------------------------------------!
134      !
135      ! open ocean.output as soon as possible to get all output prints (including errors messages)
136      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
137      ! open reference and configuration namelist files
138                  CALL ctl_opn( numnam_ref,        'namelist_ref',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
139                  CALL ctl_opn( numnam_cfg,        'namelist_cfg',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
140      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
141      ! open /dev/null file to be able to supress output write easily
142      IF( Agrif_Root() ) THEN
143                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
144#ifdef key_agrif
145      ELSE
146                  numnul = Agrif_Parent(numnul)
147#endif
148      ENDIF
149      !
150      !                             !--------------------!
151      !                             ! Open listing units !  -> need ln_ctl from namctl to define lwp
152      !                             !--------------------!
153      !
154      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
155      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
156901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
157      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
158      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
159902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
160      !
161      lwp = (narea == 1) .OR. ln_ctl    ! control of all listing output print
162      !
163      IF(lwp) THEN                      ! open listing units
164         !
165         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
166            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
167         !
168         WRITE(numout,*)
169         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
170         WRITE(numout,*) '                       NEMO team'
171         WRITE(numout,*) '            Stand Alone Observation operator'
172         WRITE(numout,*) '                NEMO version 4.0  (2019) '
173         WRITE(numout,*)
174         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
175         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
176         WRITE(numout,*)
177         WRITE(numout,*) "           o         _,           _,             "
178         WRITE(numout,*) "            o      .' (        .-' /             "
179         WRITE(numout,*) "           o     _/..._'.    .'   /              "
180         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
181         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
182         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
183         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
184         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
185         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
186         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
187         WRITE(numout,*)
188         !
189         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
190         !
191      ENDIF
192      !
193      ! finalize the definition of namctl variables
194      IF( sn_cfctl%l_config ) THEN
195         ! Activate finer control of report outputs
196         ! optionally switch off output from selected areas (note this only
197         ! applies to output which does not involve global communications)
198         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
199           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
200           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
201      ELSE
202         ! Use ln_ctl to turn on or off all options.
203         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
204      ENDIF
205      !
206      IF(lwm) WRITE( numond, namctl )
207      !
208      !                             !------------------------------------!
209      !                             !  Set global domain size parameters !
210      !                             !------------------------------------!
211      !
212      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
213      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
214903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
215      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
216      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
217904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
218      !
219      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
220         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
221      ELSE                              ! user-defined namelist
222         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
223      ENDIF
224      !
225      IF(lwm)   WRITE( numond, namcfg )
226      !
227      !                             !-----------------------------------------!
228      !                             ! mpp parameters and domain decomposition !
229      !                             !-----------------------------------------!
230      CALL mpp_init
231
232      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
233      CALL nemo_alloc()
234
235      !                             !-------------------------------!
236      !                             !  NEMO general initialization  !
237      !                             !-------------------------------!
238
239      CALL nemo_ctl                          ! Control prints
240      !
241      !                                         ! General initialization
242      IF( ln_timing    )   CALL timing_init     ! timing
243      IF( ln_timing    )   CALL timing_start( 'nemo_init')
244      !
245                           CALL phy_cst            ! Physical constants
246                           CALL eos_init           ! Equation of state
247                           CALL dom_init('SAO')    ! Domain
248
249
250      IF( ln_ctl       )   CALL prt_ctl_init    ! Print control
251
252                           CALL istate_init     ! ocean initial state (Dynamics and tracers)
253   END SUBROUTINE nemo_init
254
255
256   SUBROUTINE nemo_ctl
257      !!----------------------------------------------------------------------
258      !!                     ***  ROUTINE nemo_ctl  ***
259      !!
260      !! ** Purpose :   control print setting
261      !!
262      !! ** Method  : - print namctl information and check some consistencies
263      !!----------------------------------------------------------------------
264      !
265      IF(lwp) THEN                  ! control print
266         WRITE(numout,*)
267         WRITE(numout,*) 'nemo_ctl: Control prints'
268         WRITE(numout,*) '~~~~~~~~'
269         WRITE(numout,*) '   Namelist namctl'
270         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
271         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
272         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
273         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
274         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
275         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
276         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
277         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
278         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
279         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
280         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
281         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
282         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
283         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
284         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
285         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
286         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
287         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
288         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
289         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
290         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
291      ENDIF
292      !
293      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
294      nictls    = nn_ictls
295      nictle    = nn_ictle
296      njctls    = nn_jctls
297      njctle    = nn_jctle
298      isplt     = nn_isplt
299      jsplt     = nn_jsplt
300
301      IF(lwp) THEN                  ! control print
302         WRITE(numout,*)
303         WRITE(numout,*) '   Namelist namcfg'
304         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
305         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
306         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
307         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
308         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
309         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
310      ENDIF
311      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
312      !
313      !                             ! Parameter control
314      !
315      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
316         IF( lk_mpp .AND. jpnij > 1 ) THEN
317            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
318         ELSE
319            IF( isplt == 1 .AND. jsplt == 1  ) THEN
320               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
321                  &           ' - the print control will be done over the whole domain' )
322            ENDIF
323            ijsplt = isplt * jsplt            ! total number of processors ijsplt
324         ENDIF
325         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
326         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
327         !
328         !                              ! indices used for the SUM control
329         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
330            lsp_area = .FALSE.
331         ELSE                                             ! print control done over a specific  area
332            lsp_area = .TRUE.
333            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
334               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
335               nictls = 1
336            ENDIF
337            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
338               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
339               nictle = jpiglo
340            ENDIF
341            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
342               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
343               njctls = 1
344            ENDIF
345            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
346               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
347               njctle = jpjglo
348            ENDIF
349         ENDIF
350      ENDIF
351      !
352      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
353         &                                                'Compile with key_nosignedzero enabled:',   &
354         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
355      !
356   END SUBROUTINE nemo_ctl
357
358
359   SUBROUTINE nemo_closefile
360      !!----------------------------------------------------------------------
361      !!                     ***  ROUTINE nemo_closefile  ***
362      !!
363      !! ** Purpose :   Close the files
364      !!----------------------------------------------------------------------
365      !
366      IF( lk_mpp )   CALL mppsync
367      !
368      CALL iom_close                                 ! close all input/output files managed by iom_*
369      !
370      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
371      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
372      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
373      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
374      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
375      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
376      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
377      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
378      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
379      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
380      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
381      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
382      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
383      !
384      numout = 6                                     ! redefine numout in case it is used after this point...
385      !
386   END SUBROUTINE nemo_closefile
387
388
389   SUBROUTINE nemo_alloc
390      !!----------------------------------------------------------------------
391      !!                     ***  ROUTINE nemo_alloc  ***
392      !!
393      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
394      !!
395      !! ** Method  :
396      !!----------------------------------------------------------------------
397      USE diawri    , ONLY: dia_wri_alloc
398      USE dom_oce   , ONLY: dom_oce_alloc
399      !
400      INTEGER :: ierr
401      !!----------------------------------------------------------------------
402      !
403      ierr =        oce_alloc       ()          ! ocean
404      ierr = ierr + dia_wri_alloc   ()
405      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
406      !
407      CALL mpp_sum( 'nemogcm', ierr )
408      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
409      !
410   END SUBROUTINE nemo_alloc
411
412   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
413      !!----------------------------------------------------------------------
414      !!                     ***  ROUTINE nemo_set_cfctl  ***
415      !!
416      !! ** Purpose :   Set elements of the output control structure to setto.
417      !!                for_all should be .false. unless all areas are to be
418      !!                treated identically.
419      !!
420      !! ** Method  :   Note this routine can be used to switch on/off some
421      !!                types of output for selected areas but any output types
422      !!                that involve global communications (e.g. mpp_max, glob_sum)
423      !!                should be protected from selective switching by the
424      !!                for_all argument
425      !!----------------------------------------------------------------------
426      LOGICAL :: setto, for_all
427      TYPE(sn_ctl) :: sn_cfctl
428      !!----------------------------------------------------------------------
429      IF( for_all ) THEN
430         sn_cfctl%l_runstat = setto
431         sn_cfctl%l_trcstat = setto
432      ENDIF
433      sn_cfctl%l_oceout  = setto
434      sn_cfctl%l_layout  = setto
435      sn_cfctl%l_mppout  = setto
436      sn_cfctl%l_mpptop  = setto
437   END SUBROUTINE nemo_set_cfctl
438
439   !!======================================================================
440END MODULE nemogcm
441
Note: See TracBrowser for help on using the repository browser.