New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icecor.F90 in NEMO/releases/release-4.0/src/ICE – NEMO

source: NEMO/releases/release-4.0/src/ICE/icecor.F90 @ 10993

Last change on this file since 10993 was 10993, checked in by clem, 6 years ago

couple of commits to 1) deal with ice concentration reaching 1 (so, no more limitations in the max ice concentration imposed in the namelist), 2) deal with very small negative values that can occur due to roundoff errors
  • Property svn:keywords set to Id
File size: 10.3 KB
Line 
1MODULE icecor
2   !!======================================================================
3   !!                     ***  MODULE  icecor  ***
4   !!   sea-ice: Corrections on sea-ice variables at the end of the time step
5   !!======================================================================
6   !! History :  3.0  !  2006-04  (M. Vancoppenolle) Original code
7   !!            3.5  !  2014-06  (C. Rousset)       Complete rewriting/cleaning
8   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
9   !!----------------------------------------------------------------------
10#if defined key_si3
11   !!----------------------------------------------------------------------
12   !!   'key_si3'                                       SI3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!    ice_cor      : corrections on sea-ice variables
15   !!----------------------------------------------------------------------
16   USE dom_oce        ! ocean domain
17   USE phycst         ! physical constants
18   USE ice            ! sea-ice: variable
19   USE ice1D          ! sea-ice: thermodynamic sea-ice variables
20   USE iceitd         ! sea-ice: rebining
21   USE icevar         ! sea-ice: operations
22   USE icectl         ! sea-ice: control prints
23   !
24   USE in_out_manager ! I/O manager
25   USE iom            ! I/O manager library
26   USE lib_mpp        ! MPP library
27   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
28   USE lbclnk         ! lateral boundary conditions (or mpp links)
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   ice_cor   ! called by icestp.F90
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
40   !! $Id$
41   !! Software governed by the CeCILL license (see ./LICENSE)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ice_cor( kt, kn )
46      !!----------------------------------------------------------------------
47      !!               ***  ROUTINE ice_cor  ***
48      !!               
49      !! ** Purpose :   Computes corrections on sea-ice global variables at
50      !!              the end of the dynamics (kn=1) and thermodynamics (kn=2)
51      !!----------------------------------------------------------------------
52      INTEGER, INTENT(in) ::   kt    ! number of iteration
53      INTEGER, INTENT(in) ::   kn    ! 1 = after dyn ; 2 = after thermo
54      !
55      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
56      REAL(wp) ::   zsal, zzc
57      REAL(wp), DIMENSION(jpi,jpj) ::   zafx   ! concentration trends diag
58      !!----------------------------------------------------------------------
59      ! controls
60      IF( ln_timing    )   CALL timing_start('icecor')                                                             ! timing
61      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icecor', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
62      !
63      IF( kt == nit000 .AND. lwp .AND. kn == 2 ) THEN
64         WRITE(numout,*)
65         WRITE(numout,*) 'ice_cor:  correct sea ice variables if out of bounds ' 
66         WRITE(numout,*) '~~~~~~~'
67      ENDIF
68      !                             !-----------------------------------------------------
69      !                             !  ice thickness must exceed himin (for temp. diff.) !
70      !                             !-----------------------------------------------------
71      WHERE( a_i(:,:,:) >= epsi20 )   ;   h_i(:,:,:) = v_i(:,:,:) / a_i(:,:,:)
72      ELSEWHERE                       ;   h_i(:,:,:) = 0._wp
73      END WHERE
74      WHERE( h_i(:,:,:) < rn_himin )      a_i(:,:,:) = a_i(:,:,:) * h_i(:,:,:) / rn_himin
75      !
76      !                             !-----------------------------------------------------
77      !                             !  ice concentration should not exceed amax          !
78      !                             !-----------------------------------------------------
79      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
80      DO jl  = 1, jpl
81         WHERE( at_i(:,:) > rn_amax_2d(:,:) )   a_i(:,:,jl) = a_i(:,:,jl) * rn_amax_2d(:,:) / at_i(:,:)
82      END DO
83   
84      !                             !-----------------------------------------------------
85      IF ( nn_icesal == 2 ) THEN    !  salinity must stay in bounds [Simin,Simax]        !
86      !                             !-----------------------------------------------------
87         zzc = rhoi * r1_rdtice
88         DO jl = 1, jpl
89            DO jj = 1, jpj 
90               DO ji = 1, jpi
91                  zsal = sv_i(ji,jj,jl)
92                  sv_i(ji,jj,jl) = MIN(  MAX( rn_simin*v_i(ji,jj,jl) , sv_i(ji,jj,jl) ) , rn_simax*v_i(ji,jj,jl)  )
93                  sfx_res(ji,jj) = sfx_res(ji,jj) - ( sv_i(ji,jj,jl) - zsal ) * zzc   ! associated salt flux
94               END DO
95            END DO
96         END DO
97      ENDIF
98      !                             !-----------------------------------------------------
99      !                             !  Rebin categories with thickness out of bounds     !
100      !                             !-----------------------------------------------------
101      IF ( jpl > 1 )   CALL ice_itd_reb( kt )
102
103      !                             !-----------------------------------------------------
104      CALL ice_var_zapsmall         !  Zap small values                                  !
105      !                             !-----------------------------------------------------
106
107      !                             !-----------------------------------------------------
108      IF( kn == 2 ) THEN            !  Ice drift case: Corrections to avoid wrong values !
109         DO jj = 2, jpjm1           !-----------------------------------------------------
110            DO ji = 2, jpim1
111               IF ( at_i(ji,jj) == 0._wp ) THEN    ! what to do if there is no ice
112                  IF ( at_i(ji+1,jj) == 0._wp )   u_ice(ji  ,jj) = 0._wp   ! right side
113                  IF ( at_i(ji-1,jj) == 0._wp )   u_ice(ji-1,jj) = 0._wp   ! left side
114                  IF ( at_i(ji,jj+1) == 0._wp )   v_ice(ji,jj  ) = 0._wp   ! upper side
115                  IF ( at_i(ji,jj-1) == 0._wp )   v_ice(ji,jj-1) = 0._wp   ! bottom side
116               ENDIF
117            END DO
118         END DO
119         CALL lbc_lnk_multi( 'icecor', u_ice, 'U', -1., v_ice, 'V', -1. )            ! lateral boundary conditions
120      ENDIF
121
122!!gm I guess the trends are only out on demand
123!!   So please, only do this is it exite an iom_use of on a these variables
124!!   furthermore, only allocate the diag_ arrays in this case
125!!   and do the iom_put here so that it is only a local allocation
126!!gm
127      !                             !-----------------------------------------------------
128      SELECT CASE( kn )             !  Diagnostics                                       !
129      !                             !-----------------------------------------------------
130      CASE( 1 )                        !--- dyn trend diagnostics
131         !
132!!gm   here I think the number of ice cat is too small to use a SUM instruction...
133         DO jj = 1, jpj
134            DO ji = 1, jpi           
135               !                 ! heat content variation (W.m-2)
136               diag_heat(ji,jj) = - (  SUM( e_i(ji,jj,1:nlay_i,:) - e_i_b(ji,jj,1:nlay_i,:) )    & 
137                  &                  + SUM( e_s(ji,jj,1:nlay_s,:) - e_s_b(ji,jj,1:nlay_s,:) )  ) * r1_rdtice
138               !                 ! salt, volume
139               diag_sice(ji,jj) = SUM( sv_i(ji,jj,:) - sv_i_b(ji,jj,:) ) * rhoi * r1_rdtice
140               diag_vice(ji,jj) = SUM( v_i (ji,jj,:) - v_i_b (ji,jj,:) ) * rhoi * r1_rdtice
141               diag_vsnw(ji,jj) = SUM( v_s (ji,jj,:) - v_s_b (ji,jj,:) ) * rhos * r1_rdtice
142            END DO
143         END DO
144         !                       ! concentration tendency (dynamics)
145         zafx   (:,:) = SUM( a_i(:,:,:) - a_i_b(:,:,:), dim=3 ) * r1_rdtice 
146         afx_tot(:,:) = zafx(:,:)
147         IF( iom_use('afxdyn') )   CALL iom_put( 'afxdyn' , zafx(:,:) )
148         !
149      CASE( 2 )                        !--- thermo trend diagnostics & ice aging
150         !
151         oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * rdt_ice   ! ice natural aging incrementation
152         !
153!!gm   here I think the number of ice cat is too small to use a SUM instruction...
154         DO jj = 1, jpj
155            DO ji = 1, jpi           
156               !                 ! heat content variation (W.m-2)
157               diag_heat(ji,jj) = diag_heat(ji,jj) - (  SUM( e_i(ji,jj,1:nlay_i,:) - e_i_b(ji,jj,1:nlay_i,:) )    & 
158                  &                                   + SUM( e_s(ji,jj,1:nlay_s,:) - e_s_b(ji,jj,1:nlay_s,:) )  ) * r1_rdtice
159               !                 ! salt, volume
160               diag_sice(ji,jj) = diag_sice(ji,jj) + SUM( sv_i(ji,jj,:) - sv_i_b(ji,jj,:) ) * rhoi * r1_rdtice
161               diag_vice(ji,jj) = diag_vice(ji,jj) + SUM( v_i (ji,jj,:) - v_i_b (ji,jj,:) ) * rhoi * r1_rdtice
162               diag_vsnw(ji,jj) = diag_vsnw(ji,jj) + SUM( v_s (ji,jj,:) - v_s_b (ji,jj,:) ) * rhos * r1_rdtice
163            END DO
164         END DO
165         !                       ! concentration tendency (total + thermo)
166         zafx   (:,:) = SUM( a_i(:,:,:) - a_i_b(:,:,:), dim=3 ) * r1_rdtice
167         afx_tot(:,:) = afx_tot(:,:) + zafx(:,:)
168         IF( iom_use('afxthd') )   CALL iom_put( 'afxthd' , zafx(:,:) )
169         IF( iom_use('afxtot') )   CALL iom_put( 'afxtot' , afx_tot(:,:) )
170         !
171      END SELECT
172      !
173      ! controls
174      IF( ln_icediachk   )   CALL ice_cons_hsm(1, 'icecor', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
175      IF( ln_ctl         )   CALL ice_prt3D   ('icecor')                                                             ! prints
176      IF( ln_icectl .AND. kn == 2 )   CALL ice_prt( kt, iiceprt, jiceprt, 2, ' - Final state - ' )                   ! prints
177      IF( ln_timing      )   CALL timing_stop ('icecor')                                                             ! timing
178      !
179   END SUBROUTINE ice_cor
180
181#else
182   !!----------------------------------------------------------------------
183   !!   Default option           Dummy module         NO SI3 sea-ice model
184   !!----------------------------------------------------------------------
185#endif
186
187   !!======================================================================
188END MODULE icecor
Note: See TracBrowser for help on using the repository browser.