New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd.F90 in NEMO/trunk/src/ICE – NEMO

source: NEMO/trunk/src/ICE/icethd.F90 @ 15374

Last change on this file since 15374 was 15374, checked in by clem, 12 months ago

rearrange (slightly) ice thermo routine

  • Property svn:keywords set to Id
File size: 40.5 KB
Line 
1MODULE icethd
2   !!======================================================================
3   !!                  ***  MODULE icethd   ***
4   !!   sea-ice : master routine for thermodynamics
5   !!======================================================================
6   !! History :  1.0  !  2000-01  (M.A. Morales Maqueda, H. Goosse, T. Fichefet) original code 1D
7   !!            4.0  !  2018     (many people)       SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd       : thermodynamics of sea ice
14   !!   ice_thd_init  : initialisation of sea-ice thermodynamics
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constants
17   USE dom_oce        ! ocean space and time domain variables
18   USE ice            ! sea-ice: variables
19!!gm list trop longue ==>>> why not passage en argument d'appel ?
20   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, sprecip, ln_cpl
21   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
22      &                 qml_ice, qcn_ice, qtr_ice_top, utau_ice, vtau_ice
23   USE ice1D          ! sea-ice: thermodynamics variables
24   USE icethd_zdf     ! sea-ice: vertical heat diffusion
25   USE icethd_dh      ! sea-ice: ice-snow growth and melt
26   USE icethd_da      ! sea-ice: lateral melting
27   USE icethd_sal     ! sea-ice: salinity
28   USE icethd_ent     ! sea-ice: enthalpy redistribution
29   USE icethd_do      ! sea-ice: growth in open water
30   USE icethd_pnd     ! sea-ice: melt ponds
31   USE iceitd         ! sea-ice: remapping thickness distribution
32   USE icecor         ! sea-ice: corrections
33   USE icetab         ! sea-ice: 1D <==> 2D transformation
34   USE icevar         ! sea-ice: operations
35   USE icectl         ! sea-ice: control print
36   !
37   USE in_out_manager ! I/O manager
38   USE iom            ! I/O manager library
39   USE lib_mpp        ! MPP library
40   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
41   USE lbclnk         ! lateral boundary conditions (or mpp links)
42   USE timing         ! Timing
43
44   IMPLICIT NONE
45   PRIVATE
46
47   PUBLIC   ice_thd         ! called by limstp module
48   PUBLIC   ice_thd_init    ! called by ice_init
49
50   !!** namelist (namthd) **
51   LOGICAL ::   ln_icedH         ! activate ice thickness change from growing/melting (T) or not (F)
52   LOGICAL ::   ln_icedA         ! activate lateral melting param. (T) or not (F)
53   LOGICAL ::   ln_icedO         ! activate ice growth in open-water (T) or not (F)
54   LOGICAL ::   ln_icedS         ! activate gravity drainage and flushing (T) or not (F)
55   LOGICAL ::   ln_leadhfx       ! heat in the leads is used to melt sea-ice before warming the ocean
56
57   !! for convergence tests
58   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztice_cvgerr, ztice_cvgstp
59
60   !! * Substitutions
61#  include "do_loop_substitute.h90"
62   !!----------------------------------------------------------------------
63   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
64   !! $Id$
65   !! Software governed by the CeCILL license (see ./LICENSE)
66   !!----------------------------------------------------------------------
67CONTAINS
68
69   SUBROUTINE ice_thd( kt )
70      !!-------------------------------------------------------------------
71      !!                ***  ROUTINE ice_thd  ***
72      !!
73      !! ** Purpose : This routine manages ice thermodynamics
74      !!
75      !! ** Action : - computation of oceanic sensible heat flux at the ice base
76      !!                              energy budget in the leads
77      !!                              net fluxes on top of ice and of ocean
78      !!             - selection of grid cells with ice
79      !!                - call ice_thd_zdf  for vertical heat diffusion
80      !!                - call ice_thd_dh   for vertical ice growth and melt
81      !!                - call ice_thd_pnd  for melt ponds
82      !!                - call ice_thd_ent  for enthalpy remapping
83      !!                - call ice_thd_sal  for ice desalination
84      !!                - call ice_thd_temp to  retrieve temperature from ice enthalpy
85      !!                - call ice_thd_mono for extra lateral ice melt if active virtual thickness distribution
86      !!                - call ice_thd_da   for lateral ice melt
87      !!             - back to the geographic grid
88      !!                - call ice_thd_rem  for remapping thickness distribution
89      !!                - call ice_thd_do   for ice growth in leads
90      !!-------------------------------------------------------------------
91      INTEGER, INTENT(in) :: kt    ! number of iteration
92      !
93      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
94      !!-------------------------------------------------------------------
95      ! controls
96      IF( ln_timing    )   CALL timing_start('icethd')                                                             ! timing
97      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
98      IF( ln_icediachk )   CALL ice_cons2D  (0, 'icethd',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft) ! conservation
99
100      IF( kt == nit000 .AND. lwp ) THEN
101         WRITE(numout,*)
102         WRITE(numout,*) 'ice_thd: sea-ice thermodynamics'
103         WRITE(numout,*) '~~~~~~~'
104      ENDIF
105
106      ! convergence tests
107      IF( ln_zdf_chkcvg ) THEN
108         ALLOCATE( ztice_cvgerr(jpi,jpj,jpl) , ztice_cvgstp(jpi,jpj,jpl) )
109         ztice_cvgerr = 0._wp ; ztice_cvgstp = 0._wp
110      ENDIF
111
112      ! --- calculate (some) heat fluxes and frazil ice --- !
113      ! out => sensible heat (qsb_ice_bot) & heat budget in the leads (fhld & qlead)
114      ! out => ice collection thickness (ht_i_new) and fraction of frazil (fraz_frac)
115      CALL thd_prep
116     
117      !-------------------------------------------------------------------------------------------!
118      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
119      !-------------------------------------------------------------------------------------------!
120      DO jl = 1, jpl
121
122         ! select ice covered grid points
123         npti = 0 ; nptidx(:) = 0
124         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
125            IF ( a_i(ji,jj,jl) > epsi10 ) THEN
126               npti         = npti  + 1
127               nptidx(npti) = (jj - 1) * jpi + ji
128            ENDIF
129         END_2D
130
131         IF( npti > 0 ) THEN  ! If there is no ice, do nothing.
132            !
133                              CALL ice_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
134            !                                                       ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
135            !
136            s_i_new   (1:npti) = 0._wp ; dh_s_tot(1:npti) = 0._wp   ! --- some init --- !  (important to have them here)
137            dh_i_sum  (1:npti) = 0._wp ; dh_i_bom(1:npti) = 0._wp ; dh_i_itm  (1:npti) = 0._wp
138            dh_i_sub  (1:npti) = 0._wp ; dh_i_bog(1:npti) = 0._wp
139            dh_snowice(1:npti) = 0._wp ; dh_s_mlt(1:npti) = 0._wp
140            !
141                              CALL ice_thd_zdf                      ! --- Ice-Snow temperature --- !
142            !
143            IF( ln_icedH ) THEN                                     ! --- Growing/Melting --- !
144                              CALL ice_thd_dh                           ! Ice-Snow thickness
145                              CALL ice_thd_ent( e_i_1d(1:npti,:) )      ! Ice enthalpy remapping
146            ENDIF
147                              CALL ice_thd_sal( ln_icedS )          ! --- Ice salinity --- !
148            !
149                              CALL ice_thd_temp                     ! --- Temperature update --- !
150            !
151            IF( ln_icedH .AND. ln_virtual_itd ) &
152               &              CALL ice_thd_mono                     ! --- Extra lateral melting if virtual_itd --- !
153            !
154            IF( ln_icedA )    CALL ice_thd_da                       ! --- Lateral melting --- !
155            !
156                              CALL ice_thd_1d2d( jl, 2 )            ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
157            !                                                       ! --- & Move to 2D arrays --- !
158         ENDIF
159         !
160      END DO
161      !
162      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
163      IF( ln_icediachk )   CALL ice_cons2D  (1, 'icethd',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft)
164      !
165      IF ( ln_pnd .AND. ln_icedH ) &
166         &                    CALL ice_thd_pnd                      ! --- Melt ponds --- !
167      !
168      IF( jpl > 1  )          CALL ice_itd_rem( kt )                ! --- Transport ice between thickness categories --- !
169      !
170      IF( ln_icedO )          CALL ice_thd_do                       ! --- Frazil ice growth in leads --- !
171      !
172                              CALL ice_cor( kt , 2 )                ! --- Corrections --- !
173      !
174      oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * rDt_ice              ! --- Ice natural aging incrementation
175      !
176      DO_2D( 0, 0, 0, 0 )                                           ! --- Ice velocity corrections
177         IF( at_i(ji,jj) == 0._wp ) THEN   ! if ice has melted
178            IF( at_i(ji+1,jj) == 0._wp )   u_ice(ji  ,jj) = 0._wp   ! right side
179            IF( at_i(ji-1,jj) == 0._wp )   u_ice(ji-1,jj) = 0._wp   ! left side
180            IF( at_i(ji,jj+1) == 0._wp )   v_ice(ji,jj  ) = 0._wp   ! upper side
181            IF( at_i(ji,jj-1) == 0._wp )   v_ice(ji,jj-1) = 0._wp   ! bottom side
182         ENDIF
183      END_2D
184      CALL lbc_lnk( 'icecor', u_ice, 'U', -1.0_wp, v_ice, 'V', -1.0_wp )
185      !
186      ! convergence tests
187      IF( ln_zdf_chkcvg ) THEN
188         CALL iom_put( 'tice_cvgerr', ztice_cvgerr ) ; DEALLOCATE( ztice_cvgerr )
189         CALL iom_put( 'tice_cvgstp', ztice_cvgstp ) ; DEALLOCATE( ztice_cvgstp )
190      ENDIF
191      !
192      ! controls
193      IF( ln_icectl )   CALL ice_prt    (kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ') ! prints
194      IF( sn_cfctl%l_prtctl )   &
195        &               CALL ice_prt3D  ('icethd')                                        ! prints
196      IF( ln_timing )   CALL timing_stop('icethd')                                        ! timing
197      !
198   END SUBROUTINE ice_thd
199
200
201   SUBROUTINE ice_thd_temp
202      !!-----------------------------------------------------------------------
203      !!                   ***  ROUTINE ice_thd_temp ***
204      !!
205      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
206      !!
207      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
208      !!-------------------------------------------------------------------
209      INTEGER  ::   ji, jk   ! dummy loop indices
210      REAL(wp) ::   ztmelts, zbbb, zccc  ! local scalar
211      !!-------------------------------------------------------------------
212      ! Recover ice temperature
213      DO jk = 1, nlay_i
214         DO ji = 1, npti
215            ztmelts       = -rTmlt * sz_i_1d(ji,jk)
216            ! Conversion q(S,T) -> T (second order equation)
217            zbbb          = ( rcp - rcpi ) * ztmelts + e_i_1d(ji,jk) * r1_rhoi - rLfus
218            zccc          = SQRT( MAX( zbbb * zbbb - 4._wp * rcpi * rLfus * ztmelts, 0._wp ) )
219            t_i_1d(ji,jk) = rt0 - ( zbbb + zccc ) * 0.5_wp * r1_rcpi
220
221            ! mask temperature
222            rswitch       = 1._wp - MAX( 0._wp , SIGN( 1._wp , - h_i_1d(ji) ) )
223            t_i_1d(ji,jk) = rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
224         END DO
225      END DO
226      !
227   END SUBROUTINE ice_thd_temp
228
229
230   SUBROUTINE ice_thd_mono
231      !!-----------------------------------------------------------------------
232      !!                   ***  ROUTINE ice_thd_mono ***
233      !!
234      !! ** Purpose :   Lateral melting in case virtual_itd
235      !!                          ( dA = A/2h dh )
236      !!-----------------------------------------------------------------------
237      INTEGER  ::   ji                 ! dummy loop indices
238      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
239      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
240      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
241      !!-----------------------------------------------------------------------
242      !
243      DO ji = 1, npti
244         zdh_mel = MIN( 0._wp, dh_i_itm(ji) + dh_i_sum(ji) + dh_i_bom(ji) + dh_snowice(ji) + dh_i_sub(ji) )
245         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
246            zvi          = a_i_1d(ji) * h_i_1d(ji)
247            zvs          = a_i_1d(ji) * h_s_1d(ji)
248            ! lateral melting = concentration change
249            zhi_bef     = h_i_1d(ji) - zdh_mel
250            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
251            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
252            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel )
253            ! adjust thickness
254            h_i_1d(ji) = zvi / a_i_1d(ji)
255            h_s_1d(ji) = zvs / a_i_1d(ji)
256            ! retrieve total concentration
257            at_i_1d(ji) = a_i_1d(ji)
258         END IF
259      END DO
260      !
261   END SUBROUTINE ice_thd_mono
262
263   SUBROUTINE thd_prep
264      !!-----------------------------------------------------------------------
265      !!                   ***  ROUTINE thd_prep ***
266      !!
267      !! ** Purpose :   prepare necessary fields for thermo calculations
268      !!
269      !! For the fluxes
270      !! ** Inputs  :   u_ice, v_ice, ssu_m, ssv_m, utau, vtau
271      !!                frq_m, qsr_oce, qns_oce, qemp_oce, e3t_m, sst_m
272      !! ** Outputs :   qsb_ice_bot, fhld, qlead
273      !!
274      !! For the collection thickness (frazil)
275      !! ** Inputs  :   u_ice, v_ice, utau_ice, vtau_ice
276      !! ** Ouputs  :   ht_i_new, fraz_frac
277      !!-----------------------------------------------------------------------
278      INTEGER  ::   ji, jj             ! dummy loop indices
279      REAL(wp) ::   zfric_u, zqld, zqfr, zqfr_neg, zqfr_pos, zu_io, zv_io, zu_iom1, zv_iom1
280      REAL(wp), PARAMETER ::   zfric_umin = 0._wp       ! lower bound for the friction velocity (cice value=5.e-04)
281      REAL(wp), PARAMETER ::   zch        = 0.0057_wp   ! heat transfer coefficient
282      REAL(wp), DIMENSION(jpi,jpj) ::  zfric, zvel      ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
283      !
284      ! for frazil ice
285      INTEGER  ::   iter
286      REAL(wp) ::   zvfrx, zvgx, ztaux, zf, ztenagm, zvfry, zvgy, ztauy, zvrel2, zfp, ztwogp
287      REAL(wp), PARAMETER ::   zcai    = 1.4e-3_wp                       ! ice-air drag (clem: should be dependent on coupling/forcing used)
288      REAL(wp), PARAMETER ::   zhicrit = 0.04_wp                         ! frazil ice thickness
289      REAL(wp), PARAMETER ::   zsqcd   = 1.0_wp / SQRT( 1.3_wp * zcai )  ! 1/SQRT(airdensity*drag)
290      REAL(wp), PARAMETER ::   zgamafr = 0.03_wp
291      !!-----------------------------------------------------------------------
292      !
293      ! computation of friction velocity at T points
294      IF( ln_icedyn ) THEN
295         DO_2D( 0, 0, 0, 0 )
296            zu_io   = u_ice(ji  ,jj  ) - ssu_m(ji  ,jj  )
297            zu_iom1 = u_ice(ji-1,jj  ) - ssu_m(ji-1,jj  )
298            zv_io   = v_ice(ji  ,jj  ) - ssv_m(ji  ,jj  )
299            zv_iom1 = v_ice(ji  ,jj-1) - ssv_m(ji  ,jj-1)
300            !
301            zfric(ji,jj) = rn_cio * ( 0.5_wp * ( zu_io*zu_io + zu_iom1*zu_iom1 + zv_io*zv_io + zv_iom1*zv_iom1 ) ) * tmask(ji,jj,1)
302            zvel (ji,jj) = 0.5_wp * SQRT( ( u_ice(ji-1,jj  ) + u_ice(ji,jj) ) * ( u_ice(ji-1,jj  ) + u_ice(ji,jj) ) + &
303               &                          ( v_ice(ji  ,jj-1) + v_ice(ji,jj) ) * ( v_ice(ji  ,jj-1) + v_ice(ji,jj) ) )
304         END_2D
305      ELSE      !  if no ice dynamics => transfer directly the atmospheric stress to the ocean
306         DO_2D( 0, 0, 0, 0 )
307            zfric(ji,jj) = r1_rho0 * SQRT( 0.5_wp *  &
308               &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
309               &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
310            zvel(ji,jj) = 0._wp
311         END_2D
312      ENDIF
313      CALL lbc_lnk( 'icethd', zfric, 'T',  1.0_wp, zvel, 'T', 1.0_wp )
314      !
315      !--------------------------------------------------------------------!
316      ! Partial computation of forcing for the thermodynamic sea ice model
317      !--------------------------------------------------------------------!
318      DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )   ! needed for qlead
319         rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
320         !
321         ! --- Energy received in the lead from atm-oce exchanges, zqld is defined everywhere (J.m-2) --- !
322         zqld =  tmask(ji,jj,1) * rDt_ice *  &
323            &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
324            &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
325
326         ! --- Energy needed to bring ocean surface layer until its freezing, zqfr is defined everywhere (J.m-2) --- !
327         !     (mostly<0 but >0 if supercooling)
328         zqfr     = rho0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ) * tmask(ji,jj,1)  ! both < 0 (t_bo < sst) and > 0 (t_bo > sst)
329         zqfr_neg = MIN( zqfr , 0._wp )                                                                    ! only < 0
330         zqfr_pos = MAX( zqfr , 0._wp )                                                                    ! only > 0
331
332         ! --- Sensible ocean-to-ice heat flux (W/m2) --- !
333         !     (mostly>0 but <0 if supercooling)
334         zfric_u            = MAX( SQRT( zfric(ji,jj) ), zfric_umin )
335         qsb_ice_bot(ji,jj) = rswitch * rho0 * rcp * zch * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) )
336
337         ! upper bound for qsb_ice_bot: the heat retrieved from the ocean must be smaller than the heat necessary to reach
338         !                              the freezing point, so that we do not have SST < T_freeze
339         !                              This implies: qsb_ice_bot(ji,jj) * at_i(ji,jj) * rtdice <= - zqfr_neg
340         !                              The following formulation is ok for both normal conditions and supercooling
341         qsb_ice_bot(ji,jj) = rswitch * MIN( qsb_ice_bot(ji,jj), - zqfr_neg * r1_Dt_ice / MAX( at_i(ji,jj), epsi10 ) )
342
343         ! If conditions are always supercooled (such as at the mouth of ice-shelves), then ice grows continuously
344         ! ==> stop ice formation by artificially setting up the turbulent fluxes to 0 when volume > 20m (arbitrary)
345         IF( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ) > 0._wp .AND. vt_i(ji,jj) >= 20._wp ) THEN
346            zqfr               = 0._wp
347            zqfr_pos           = 0._wp
348            qsb_ice_bot(ji,jj) = 0._wp
349         ENDIF
350         !
351         ! --- Energy Budget of the leads (qlead, J.m-2) --- !
352         !     qlead is the energy received from the atm. in the leads.
353         !     If warming (zqld >= 0), then the energy in the leads is used to melt ice (bottom melting) => fhld  (W/m2)
354         !     If cooling (zqld <  0), then the energy in the leads is used to grow ice in open water    => qlead (J.m-2)
355         IF( zqld >= 0._wp .AND. at_i(ji,jj) > 0._wp ) THEN
356            ! upper bound for fhld: fhld should be equal to zqld
357            !                        but we have to make sure that this heat will not make the sst drop below the freezing point
358            !                        so the max heat that can be pulled out of the ocean is zqld - qsb - zqfr_pos
359            !                        The following formulation is ok for both normal conditions and supercooling
360            fhld (ji,jj) = rswitch * MAX( 0._wp, ( zqld - zqfr_pos ) * r1_Dt_ice / MAX( at_i(ji,jj), epsi10 ) &  ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
361               &                                 - qsb_ice_bot(ji,jj) )
362            qlead(ji,jj) = 0._wp
363         ELSE
364            fhld (ji,jj) = 0._wp
365            ! upper bound for qlead: qlead should be equal to zqld
366            !                        but before using this heat for ice formation, we suppose that the ocean cools down till the freezing point.
367            !                        The energy for this cooling down is zqfr. Also some heat will be removed from the ocean from turbulent fluxes (qsb)
368            !                        and freezing point is reached if zqfr = zqld - qsb*a/dt
369            !                        so the max heat that can be pulled out of the ocean is zqld - qsb - zqfr
370            !                        The following formulation is ok for both normal conditions and supercooling
371            qlead(ji,jj) = MIN( 0._wp , zqld - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rDt_ice ) - zqfr )
372         ENDIF
373         !
374         ! If ice is landfast and ice concentration reaches its max
375         ! => stop ice formation in open water
376         IF(  zvel(ji,jj) <= 5.e-04_wp .AND. at_i(ji,jj) >= rn_amax_2d(ji,jj)-epsi06 )   qlead(ji,jj) = 0._wp
377         !
378         ! If the grid cell is almost fully covered by ice (no leads)
379         ! => stop ice formation in open water
380         IF( at_i(ji,jj) >= (1._wp - epsi10) )   qlead(ji,jj) = 0._wp
381         !
382         ! If ln_leadhfx is false
383         ! => do not use energy of the leads to melt sea-ice
384         IF( .NOT.ln_leadhfx )   fhld(ji,jj) = 0._wp
385         !
386      END_2D
387
388      ! In case we bypass open-water ice formation
389      IF( .NOT. ln_icedO )  qlead(:,:) = 0._wp
390      ! In case we bypass growing/melting from top and bottom
391      IF( .NOT. ln_icedH ) THEN
392         qsb_ice_bot(:,:) = 0._wp
393         fhld       (:,:) = 0._wp
394      ENDIF
395
396      !---------------------------------------------------------!
397      ! Collection thickness of ice formed in leads and polynyas
398      !---------------------------------------------------------!   
399      ! ht_i_new is the thickness of new ice formed in open water
400      ! ht_i_new can be either prescribed (ln_frazil=F) or computed (ln_frazil=T)
401      ! Frazil ice forms in open water, is transported by wind, accumulates at the edge of the consolidated ice edge
402      ! where it forms aggregates of a specific thickness called collection thickness.
403      !
404      fraz_frac(:,:) = 0._wp
405      !
406      ! Default new ice thickness
407      WHERE( qlead(:,:) < 0._wp ) ! cooling
408         ht_i_new(:,:) = rn_hinew
409      ELSEWHERE
410         ht_i_new(:,:) = 0._wp
411      END WHERE
412
413      IF( ln_frazil ) THEN
414         ztwogp  = 2._wp * rho0 / ( grav * 0.3_wp * ( rho0 - rhoi ) )  ! reduced grav
415         !
416         DO_2D( 0, 0, 0, 0 )
417            IF ( qlead(ji,jj) < 0._wp ) THEN ! cooling
418               ! -- Wind stress -- !
419               ztaux = ( utau_ice(ji-1,jj  ) * umask(ji-1,jj  ,1) + utau_ice(ji,jj) * umask(ji,jj,1) ) * 0.5_wp
420               ztauy = ( vtau_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1) + vtau_ice(ji,jj) * vmask(ji,jj,1) ) * 0.5_wp
421               ! Square root of wind stress
422               ztenagm = SQRT( SQRT( ztaux * ztaux + ztauy * ztauy ) )
423
424               ! -- Frazil ice velocity -- !
425               rswitch = MAX( 0._wp, SIGN( 1._wp , ztenagm - epsi10 ) )
426               zvfrx   = rswitch * zgamafr * zsqcd * ztaux / MAX( ztenagm, epsi10 )
427               zvfry   = rswitch * zgamafr * zsqcd * ztauy / MAX( ztenagm, epsi10 )
428
429               ! -- Pack ice velocity -- !
430               zvgx    = ( u_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)  + u_ice(ji,jj) * umask(ji,jj,1) ) * 0.5_wp
431               zvgy    = ( v_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)  + v_ice(ji,jj) * vmask(ji,jj,1) ) * 0.5_wp
432
433               ! -- Relative frazil/pack ice velocity -- !
434               rswitch = MAX( 0._wp, SIGN( 1._wp , at_i(ji,jj) - epsi10 ) )
435               zvrel2  = MAX( (zvfrx - zvgx)*(zvfrx - zvgx) + (zvfry - zvgy)*(zvfry - zvgy), 0.15_wp*0.15_wp ) * rswitch
436
437               ! -- fraction of frazil ice -- !
438               fraz_frac(ji,jj) = rswitch * ( TANH( rn_Cfraz * ( SQRT(zvrel2) - rn_vfraz ) ) + 1._wp ) * 0.5_wp * rn_maxfraz
439               
440               ! -- new ice thickness (iterative loop) -- !
441               ht_i_new(ji,jj) = zhicrit +   ( zhicrit + 0.1_wp )    &
442                  &                      / ( ( zhicrit + 0.1_wp ) * ( zhicrit + 0.1_wp ) -  zhicrit * zhicrit ) * ztwogp * zvrel2
443               iter = 1
444               DO WHILE ( iter < 20 ) 
445                  zf  = ( ht_i_new(ji,jj) - zhicrit ) * ( ht_i_new(ji,jj) * ht_i_new(ji,jj) - zhicrit * zhicrit ) -   &
446                     &    ht_i_new(ji,jj) * zhicrit * ztwogp * zvrel2
447                  zfp = ( ht_i_new(ji,jj) - zhicrit ) * ( 3.0_wp * ht_i_new(ji,jj) + zhicrit ) - zhicrit * ztwogp * zvrel2
448
449                  ht_i_new(ji,jj) = ht_i_new(ji,jj) - zf / MAX( zfp, epsi20 )
450                  iter = iter + 1
451               END DO
452               !
453               ! bound ht_i_new (though I don't see why it should be necessary)
454               ht_i_new(ji,jj) = MAX( 0.01_wp, MIN( ht_i_new(ji,jj), hi_max(jpl) ) )
455               !
456            ELSE
457               ht_i_new(ji,jj) = 0._wp
458            ENDIF
459            !
460         END_2D
461         !
462         CALL lbc_lnk( 'icethd', fraz_frac, 'T', 1.0_wp, ht_i_new, 'T', 1.0_wp  )
463
464      ENDIF
465     
466   END SUBROUTINE thd_prep
467
468   SUBROUTINE ice_thd_1d2d( kl, kn )
469      !!-----------------------------------------------------------------------
470      !!                   ***  ROUTINE ice_thd_1d2d ***
471      !!
472      !! ** Purpose :   move arrays from 1d to 2d and the reverse
473      !!-----------------------------------------------------------------------
474      INTEGER, INTENT(in) ::   kl   ! index of the ice category
475      INTEGER, INTENT(in) ::   kn   ! 1= from 2D to 1D   ;   2= from 1D to 2D
476      !
477      INTEGER ::   jk   ! dummy loop indices
478      !!-----------------------------------------------------------------------
479      !
480      SELECT CASE( kn )
481      !                    !---------------------!
482      CASE( 1 )            !==  from 2D to 1D  ==!
483         !                 !---------------------!
484         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
485         CALL tab_2d_1d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
486         CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
487         CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
488         CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
489         CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
490         DO jk = 1, nlay_s
491            CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
492            CALL tab_2d_1d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
493         END DO
494         DO jk = 1, nlay_i
495            CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
496            CALL tab_2d_1d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
497            CALL tab_2d_1d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
498         END DO
499         !
500         CALL tab_2d_1d( npti, nptidx(1:npti), qprec_ice_1d  (1:npti), qprec_ice            )
501         CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_1d    (1:npti), qsr_ice (:,:,kl)     )
502         CALL tab_2d_1d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice (:,:,kl)     )
503         CALL tab_2d_1d( npti, nptidx(1:npti), evap_ice_1d   (1:npti), evap_ice(:,:,kl)     )
504         CALL tab_2d_1d( npti, nptidx(1:npti), dqns_ice_1d   (1:npti), dqns_ice(:,:,kl)     )
505         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d       (1:npti), t_bo                 )
506         CALL tab_2d_1d( npti, nptidx(1:npti), sprecip_1d    (1:npti), sprecip              )
507         CALL tab_2d_1d( npti, nptidx(1:npti), qsb_ice_bot_1d(1:npti), qsb_ice_bot          )
508         CALL tab_2d_1d( npti, nptidx(1:npti), fhld_1d       (1:npti), fhld                 )
509
510         CALL tab_2d_1d( npti, nptidx(1:npti), qml_ice_1d    (1:npti), qml_ice    (:,:,kl) )
511         CALL tab_2d_1d( npti, nptidx(1:npti), qcn_ice_1d    (1:npti), qcn_ice    (:,:,kl) )
512         CALL tab_2d_1d( npti, nptidx(1:npti), qtr_ice_top_1d(1:npti), qtr_ice_top(:,:,kl) )
513         !
514         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni   )
515         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum   )
516         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub       )
517         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub   )
518         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub   )
519         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub   )
520         !
521         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog          )
522         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom          )
523         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum          )
524         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni          )
525         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res          )
526         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr          )
527         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam          )
528         !
529         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog          )
530         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom          )
531         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum          )
532         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni          )
533         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri          )
534         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res          )
535         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub          )
536         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam          )
537         !
538         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd       )
539         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr       )
540         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum       )
541         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom       )
542         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog       )
543         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif       )
544         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw       )
545         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw       )
546         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub       )
547         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res       )
548         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif   )
549         !
550         ! ocean surface fields
551         CALL tab_2d_1d( npti, nptidx(1:npti), sst_1d(1:npti), sst_m )
552         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d(1:npti), sss_m )
553         CALL tab_2d_1d( npti, nptidx(1:npti), frq_m_1d(1:npti), frq_m )
554         !
555         ! to update ice age
556         CALL tab_2d_1d( npti, nptidx(1:npti), o_i_1d (1:npti), o_i (:,:,kl) )
557         CALL tab_2d_1d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
558         !
559         ! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
560         DO jk = 1, nlay_i
561            WHERE( h_i_1d(1:npti)>0._wp ) e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) / (h_i_1d(1:npti) * a_i_1d(1:npti)) * nlay_i
562         END DO
563         DO jk = 1, nlay_s
564            WHERE( h_s_1d(1:npti)>0._wp ) e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) / (h_s_1d(1:npti) * a_i_1d(1:npti)) * nlay_s
565         END DO
566         !
567         !                 !---------------------!
568      CASE( 2 )            !==  from 1D to 2D  ==!
569         !                 !---------------------!
570         ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
571         DO jk = 1, nlay_i
572            e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) * h_i_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_i
573         END DO
574         DO jk = 1, nlay_s
575            e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) * h_s_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_s
576         END DO
577         !
578         ! Change thickness to volume (replaces routine ice_var_eqv2glo)
579         v_i_1d (1:npti) = h_i_1d (1:npti) * a_i_1d (1:npti)
580         v_s_1d (1:npti) = h_s_1d (1:npti) * a_i_1d (1:npti)
581         sv_i_1d(1:npti) = s_i_1d (1:npti) * v_i_1d (1:npti)
582         oa_i_1d(1:npti) = o_i_1d (1:npti) * a_i_1d (1:npti)
583
584         CALL tab_1d_2d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
585         CALL tab_1d_2d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
586         CALL tab_1d_2d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
587         CALL tab_1d_2d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
588         CALL tab_1d_2d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
589         CALL tab_1d_2d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
590         DO jk = 1, nlay_s
591            CALL tab_1d_2d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
592            CALL tab_1d_2d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
593         END DO
594         DO jk = 1, nlay_i
595            CALL tab_1d_2d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
596            CALL tab_1d_2d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
597            CALL tab_1d_2d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
598         END DO
599         !
600         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
601         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
602         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub     )
603         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
604         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
605         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
606         !
607         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog        )
608         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom        )
609         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum        )
610         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni        )
611         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res        )
612         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr        )
613         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam        )
614         !
615         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog        )
616         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom        )
617         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum        )
618         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni        )
619         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri        )
620         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res        )
621         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub        )
622         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam        )
623         !
624         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd     )
625         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr     )
626         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum     )
627         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom     )
628         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog     )
629         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif     )
630         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw     )
631         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw     )
632         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub     )
633         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res     )
634         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
635         !
636         CALL tab_1d_2d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice    (:,:,kl) )
637         CALL tab_1d_2d( npti, nptidx(1:npti), qtr_ice_bot_1d(1:npti), qtr_ice_bot(:,:,kl) )
638         ! effective conductivity and 1st layer temperature (ln_cndflx=T)
639         CALL tab_1d_2d( npti, nptidx(1:npti), cnd_ice_1d(1:npti), cnd_ice(:,:,kl) )
640         CALL tab_1d_2d( npti, nptidx(1:npti), t1_ice_1d (1:npti), t1_ice (:,:,kl) )
641         ! Melt ponds
642         CALL tab_1d_2d( npti, nptidx(1:npti), dh_i_sum  (1:npti) , dh_i_sum_2d(:,:,kl) )
643         CALL tab_1d_2d( npti, nptidx(1:npti), dh_s_mlt  (1:npti) , dh_s_mlt_2d(:,:,kl) )
644         ! SIMIP diagnostics
645         CALL tab_1d_2d( npti, nptidx(1:npti), t_si_1d       (1:npti), t_si       (:,:,kl) )
646         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_bot_1d(1:npti), qcn_ice_bot(:,:,kl) )
647         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_top_1d(1:npti), qcn_ice_top(:,:,kl) )
648         CALL tab_1d_2d( npti, nptidx(1:npti), qml_ice_1d    (1:npti), qml_ice    (:,:,kl) )
649         ! extensive variables
650         CALL tab_1d_2d( npti, nptidx(1:npti), v_i_1d (1:npti), v_i (:,:,kl) )
651         CALL tab_1d_2d( npti, nptidx(1:npti), v_s_1d (1:npti), v_s (:,:,kl) )
652         CALL tab_1d_2d( npti, nptidx(1:npti), sv_i_1d(1:npti), sv_i(:,:,kl) )
653         CALL tab_1d_2d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
654         ! check convergence of heat diffusion scheme
655         IF( ln_zdf_chkcvg ) THEN
656            CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgerr_1d(1:npti), ztice_cvgerr(:,:,kl) )
657            CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgstp_1d(1:npti), ztice_cvgstp(:,:,kl) )
658         ENDIF
659         !
660      END SELECT
661      !
662   END SUBROUTINE ice_thd_1d2d
663
664
665   SUBROUTINE ice_thd_init
666      !!-------------------------------------------------------------------
667      !!                   ***  ROUTINE ice_thd_init ***
668      !!
669      !! ** Purpose :   Physical constants and parameters associated with
670      !!                ice thermodynamics
671      !!
672      !! ** Method  :   Read the namthd namelist and check the parameters
673      !!                called at the first timestep (nit000)
674      !!
675      !! ** input   :   Namelist namthd
676      !!-------------------------------------------------------------------
677      INTEGER  ::   ios   ! Local integer output status for namelist read
678      !!
679      NAMELIST/namthd/ ln_icedH, ln_icedA, ln_icedO, ln_icedS, ln_leadhfx
680      !!-------------------------------------------------------------------
681      !
682      READ  ( numnam_ice_ref, namthd, IOSTAT = ios, ERR = 901)
683901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd in reference namelist' )
684      READ  ( numnam_ice_cfg, namthd, IOSTAT = ios, ERR = 902 )
685902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd in configuration namelist' )
686      IF(lwm) WRITE( numoni, namthd )
687      !
688      IF(lwp) THEN                          ! control print
689         WRITE(numout,*)
690         WRITE(numout,*) 'ice_thd_init: Ice Thermodynamics'
691         WRITE(numout,*) '~~~~~~~~~~~~'
692         WRITE(numout,*) '   Namelist namthd:'
693         WRITE(numout,*) '      activate ice thick change from top/bot (T) or not (F)                ln_icedH   = ', ln_icedH
694         WRITE(numout,*) '      activate lateral melting (T) or not (F)                              ln_icedA   = ', ln_icedA
695         WRITE(numout,*) '      activate ice growth in open-water (T) or not (F)                     ln_icedO   = ', ln_icedO
696         WRITE(numout,*) '      activate gravity drainage and flushing (T) or not (F)                ln_icedS   = ', ln_icedS
697         WRITE(numout,*) '      heat in the leads is used to melt sea-ice before warming the ocean   ln_leadhfx = ', ln_leadhfx
698     ENDIF
699      !
700                       CALL ice_thd_zdf_init   ! set ice heat diffusion parameters
701      IF( ln_icedA )   CALL ice_thd_da_init    ! set ice lateral melting parameters
702      IF( ln_icedO )   CALL ice_thd_do_init    ! set ice growth in open water parameters
703                       CALL ice_thd_sal_init   ! set ice salinity parameters
704                       CALL ice_thd_pnd_init   ! set melt ponds parameters
705      !
706   END SUBROUTINE ice_thd_init
707
708#else
709   !!----------------------------------------------------------------------
710   !!   Default option         Dummy module          NO  SI3 sea-ice model
711   !!----------------------------------------------------------------------
712#endif
713
714   !!======================================================================
715END MODULE icethd
Note: See TracBrowser for help on using the repository browser.