New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in NEMO/trunk/src/OCE/BDY – NEMO

source: NEMO/trunk/src/OCE/BDY/bdydta.F90 @ 15368

Last change on this file since 15368 was 15368, checked in by smasson, 12 months ago

trunk: final version (hopefully) for ticket #2731

  • Property svn:keywords set to Id
File size: 42.3 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!            3.6  !  2012-01  (C. Rousset) add ice boundary conditions for sea ice
14   !!            4.0  !  2018     (C. Rousset) SI3 compatibility
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!    bdy_dta      : read external data along open boundaries from file
19   !!    bdy_dta_init : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE oce            ! ocean dynamics and tracers
22   USE dom_oce        ! ocean space and time domain
23   USE phycst         ! physical constants
24   USE sbcapr         ! atmospheric pressure forcing
25   USE tide_mod, ONLY: ln_tide ! tidal forcing
26   USE bdy_oce        ! ocean open boundary conditions 
27   USE bdytides       ! tidal forcing at boundaries
28#if defined key_si3
29   USE ice            ! sea-ice variables
30   USE icevar         ! redistribute ice input into categories
31#endif
32   !
33   USE lib_mpp, ONLY: ctl_stop, ctl_nam
34   USE fldread        ! read input fields
35   USE iom            ! IOM library
36   USE in_out_manager ! I/O logical units
37   USE timing         ! Timing
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
43   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
44
45   INTEGER , PARAMETER ::   jpbdyfld  = 17    ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_bdyssh = 1     !
47   INTEGER , PARAMETER ::   jp_bdyu2d = 2     !
48   INTEGER , PARAMETER ::   jp_bdyv2d = 3     !
49   INTEGER , PARAMETER ::   jp_bdyu3d = 4     !
50   INTEGER , PARAMETER ::   jp_bdyv3d = 5     !
51   INTEGER , PARAMETER ::   jp_bdytem = 6     !
52   INTEGER , PARAMETER ::   jp_bdysal = 7     !
53   INTEGER , PARAMETER ::   jp_bdya_i = 8     !
54   INTEGER , PARAMETER ::   jp_bdyh_i = 9     !
55   INTEGER , PARAMETER ::   jp_bdyh_s = 10    !
56   INTEGER , PARAMETER ::   jp_bdyt_i = 11    !
57   INTEGER , PARAMETER ::   jp_bdyt_s = 12    !
58   INTEGER , PARAMETER ::   jp_bdytsu = 13    !
59   INTEGER , PARAMETER ::   jp_bdys_i = 14    !
60   INTEGER , PARAMETER ::   jp_bdyaip = 15    !
61   INTEGER , PARAMETER ::   jp_bdyhip = 16    !
62   INTEGER , PARAMETER ::   jp_bdyhil = 17    !
63#if ! defined key_si3
64   INTEGER , PARAMETER ::   jpl = 1
65#endif
66
67!$AGRIF_DO_NOT_TREAT
68   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:,:), TARGET ::   bf   ! structure of input fields (file informations, fields read)
69!$AGRIF_END_DO_NOT_TREAT
70
71   !! * Substitutions
72#  include "do_loop_substitute.h90"
73#  include "domzgr_substitute.h90"
74   !!----------------------------------------------------------------------
75   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
76   !! $Id$
77   !! Software governed by the CeCILL license (see ./LICENSE)
78   !!----------------------------------------------------------------------
79CONTAINS
80
81   SUBROUTINE bdy_dta( kt, Kmm )
82      !!----------------------------------------------------------------------
83      !!                   ***  SUBROUTINE bdy_dta  ***
84      !!                   
85      !! ** Purpose :   Update external data for open boundary conditions
86      !!
87      !! ** Method  :   Use fldread.F90
88      !!               
89      !!----------------------------------------------------------------------
90      INTEGER, INTENT(in)           ::   kt           ! ocean time-step index
91      INTEGER, INTENT(in)           ::   Kmm          ! ocean time level index
92      !
93      INTEGER ::  jbdy, jfld, jstart, jend, ib, jl    ! dummy loop indices
94      INTEGER ::  ii, ij, ik, igrd, ipl               ! local integers
95      TYPE(OBC_DATA)         , POINTER ::   dta_alias        ! short cut
96      TYPE(FLD), DIMENSION(:), POINTER ::   bf_alias
97      !!---------------------------------------------------------------------------
98      !
99      IF( ln_timing )   CALL timing_start('bdy_dta')
100      !
101      ! Initialise data arrays once for all from initial conditions where required
102      !---------------------------------------------------------------------------
103      IF( kt == nit000 ) THEN
104
105         ! Calculate depth-mean currents
106         !-----------------------------
107
108         DO jbdy = 1, nb_bdy
109            !
110            IF( nn_dyn2d_dta(jbdy) == 0 ) THEN
111               IF( dta_bdy(jbdy)%lneed_ssh ) THEN
112                  igrd = 1
113                  DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is allocated and used only on the rim
114                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
115                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
116                     dta_bdy(jbdy)%ssh(ib) = ssh(ii,ij,Kmm) * tmask(ii,ij,1)         
117                  END DO
118               ENDIF
119               IF( ASSOCIATED(dta_bdy(jbdy)%u2d) ) THEN   ! no SIZE with a unassociated pointer. v2d and u2d can differ on subdomain
120                  igrd = 2
121                  DO ib = 1, SIZE(dta_bdy(jbdy)%u2d)      ! u2d is used either over the whole bdy or only on the rim
122                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
123                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
124                     dta_bdy(jbdy)%u2d(ib) = uu_b(ii,ij,Kmm) * umask(ii,ij,1)         
125                  END DO
126               ENDIF
127               IF( ASSOCIATED(dta_bdy(jbdy)%v2d) ) THEN   ! no SIZE with a unassociated pointer. v2d and u2d can differ on subdomain
128                  igrd = 3
129                  DO ib = 1, SIZE(dta_bdy(jbdy)%v2d)      ! v2d is used either over the whole bdy or only on the rim
130                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
131                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
132                     dta_bdy(jbdy)%v2d(ib) = vv_b(ii,ij,Kmm) * vmask(ii,ij,1)         
133                  END DO
134               ENDIF
135            ENDIF
136            !
137            IF( nn_dyn3d_dta(jbdy) == 0 ) THEN
138               IF( dta_bdy(jbdy)%lneed_dyn3d ) THEN
139                  igrd = 2 
140                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
141                     DO ik = 1, jpkm1
142                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
143                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
144                        dta_bdy(jbdy)%u3d(ib,ik) =  ( uu(ii,ij,ik,Kmm) - uu_b(ii,ij,Kmm) ) * umask(ii,ij,ik)         
145                     END DO
146                  END DO
147                  igrd = 3 
148                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
149                     DO ik = 1, jpkm1
150                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
151                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
152                        dta_bdy(jbdy)%v3d(ib,ik) =  ( vv(ii,ij,ik,Kmm) - vv_b(ii,ij,Kmm) ) * vmask(ii,ij,ik)         
153                     END DO
154                  END DO
155               ENDIF
156            ENDIF
157
158            IF( nn_tra_dta(jbdy) == 0 ) THEN
159               IF( dta_bdy(jbdy)%lneed_tra ) THEN
160                  igrd = 1 
161                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
162                     DO ik = 1, jpkm1
163                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
164                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
165                        dta_bdy(jbdy)%tem(ib,ik) = ts(ii,ij,ik,jp_tem,Kmm) * tmask(ii,ij,ik)         
166                        dta_bdy(jbdy)%sal(ib,ik) = ts(ii,ij,ik,jp_sal,Kmm) * tmask(ii,ij,ik)         
167                     END DO
168                  END DO
169               ENDIF
170            ENDIF
171
172#if defined key_si3
173            IF( nn_ice_dta(jbdy) == 0 ) THEN    ! set ice to initial values
174               IF( dta_bdy(jbdy)%lneed_ice ) THEN
175                  igrd = 1   
176                  DO jl = 1, jpl
177                     DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
178                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
179                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
180                        dta_bdy(jbdy)%a_i(ib,jl) =  a_i (ii,ij,jl) * tmask(ii,ij,1) 
181                        dta_bdy(jbdy)%h_i(ib,jl) =  h_i (ii,ij,jl) * tmask(ii,ij,1) 
182                        dta_bdy(jbdy)%h_s(ib,jl) =  h_s (ii,ij,jl) * tmask(ii,ij,1) 
183                        dta_bdy(jbdy)%t_i(ib,jl) =  SUM(t_i (ii,ij,:,jl)) * r1_nlay_i * tmask(ii,ij,1) 
184                        dta_bdy(jbdy)%t_s(ib,jl) =  SUM(t_s (ii,ij,:,jl)) * r1_nlay_s * tmask(ii,ij,1)
185                        dta_bdy(jbdy)%tsu(ib,jl) =  t_su(ii,ij,jl) * tmask(ii,ij,1) 
186                        dta_bdy(jbdy)%s_i(ib,jl) =  s_i (ii,ij,jl) * tmask(ii,ij,1)
187                        ! melt ponds
188                        dta_bdy(jbdy)%aip(ib,jl) =  a_ip(ii,ij,jl) * tmask(ii,ij,1) 
189                        dta_bdy(jbdy)%hip(ib,jl) =  h_ip(ii,ij,jl) * tmask(ii,ij,1) 
190                        dta_bdy(jbdy)%hil(ib,jl) =  h_il(ii,ij,jl) * tmask(ii,ij,1) 
191                     END DO
192                  END DO
193               ENDIF
194            ENDIF
195#endif
196         END DO ! jbdy
197         !
198      ENDIF ! kt == nit000
199
200      ! update external data from files
201      !--------------------------------
202
203      DO jbdy = 1, nb_bdy
204
205         dta_alias => dta_bdy(jbdy)
206         bf_alias  => bf(:,jbdy)
207
208         ! read/update all bdy data
209         ! ------------------------
210         ! BDY: use pt_offset=0.5 as applied at the end of the step and fldread is referenced at the middle of the step
211         CALL fld_read( kt, 1, bf_alias, pt_offset = 0.5_wp, Kmm = Kmm )
212         ! apply some corrections in some specific cases...
213         ! --------------------------------------------------
214         !
215         ! if runoff condition: change river flow we read (in m3/s) into barotropic velocity (m/s)
216         IF( cn_tra(jbdy) == 'runoff' ) THEN   ! runoff
217            !
218            IF( ASSOCIATED(dta_bdy(jbdy)%u2d) ) THEN   ! no SIZE with a unassociated pointer. v2d and u2d can differ on subdomain
219               igrd = 2                         ! zonal flow (m3/s) to barotropic zonal velocity (m/s)
220               DO ib = 1, SIZE(dta_alias%u2d)   ! u2d is used either over the whole bdy or only on the rim
221                  ii   = idx_bdy(jbdy)%nbi(ib,igrd)
222                  ij   = idx_bdy(jbdy)%nbj(ib,igrd)
223                  dta_alias%u2d(ib) = dta_alias%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
224               END DO
225            ENDIF
226            IF( ASSOCIATED(dta_bdy(jbdy)%v2d) ) THEN   ! no SIZE with a unassociated pointer. v2d and u2d can differ on subdomain
227               igrd = 3                         ! meridional flow (m3/s) to barotropic meridional velocity (m/s)
228               DO ib = 1, SIZE(dta_alias%v2d)   ! v2d is used either over the whole bdy or only on the rim
229                  ii   = idx_bdy(jbdy)%nbi(ib,igrd)
230                  ij   = idx_bdy(jbdy)%nbj(ib,igrd)
231                  dta_alias%v2d(ib) = dta_alias%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
232               END DO
233            ENDIF
234         ENDIF
235
236         ! tidal harmonic forcing ONLY: initialise arrays
237         IF( nn_dyn2d_dta(jbdy) == 2 ) THEN   ! we did not read ssh, u/v2d
238            IF( ASSOCIATED(dta_alias%ssh) ) dta_alias%ssh(:) = 0._wp
239            IF( ASSOCIATED(dta_alias%u2d) ) dta_alias%u2d(:) = 0._wp
240            IF( ASSOCIATED(dta_alias%v2d) ) dta_alias%v2d(:) = 0._wp
241         ENDIF
242
243         ! If full velocities in boundary data, then split it into barotropic and baroclinic component
244         IF( bf_alias(jp_bdyu3d)%ltotvel ) THEN     ! if we read 3D total velocity (can be true only if u3d was read)
245            igrd = 2                       ! zonal velocity
246            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
247               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
248               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
249               dta_alias%u2d(ib) = 0._wp   ! compute barotrope zonal velocity and put it in u2d
250               DO ik = 1, jpkm1
251                  dta_alias%u2d(ib) = dta_alias%u2d(ib)   &
252                     &              + e3u(ii,ij,ik,Kmm) * umask(ii,ij,ik) * dta_alias%u3d(ib,ik)
253               END DO
254               dta_alias%u2d(ib) =  dta_alias%u2d(ib) * r1_hu(ii,ij,Kmm)
255               DO ik = 1, jpkm1            ! compute barocline zonal velocity and put it in u3d
256                  dta_alias%u3d(ib,ik) = dta_alias%u3d(ib,ik) - dta_alias%u2d(ib)
257               END DO
258            END DO
259         ENDIF   ! ltotvel
260         IF( bf_alias(jp_bdyv3d)%ltotvel ) THEN     ! if we read 3D total velocity (can be true only if v3d was read)
261            igrd = 3                       ! meridional velocity
262            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
263               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
264               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
265               dta_alias%v2d(ib) = 0._wp   ! compute barotrope meridional velocity and put it in v2d
266               DO ik = 1, jpkm1
267                  dta_alias%v2d(ib) = dta_alias%v2d(ib)   &
268                     &              + e3v(ii,ij,ik,Kmm) * vmask(ii,ij,ik) * dta_alias%v3d(ib,ik)
269               END DO
270               dta_alias%v2d(ib) =  dta_alias%v2d(ib) * r1_hv(ii,ij,Kmm)
271               DO ik = 1, jpkm1            ! compute barocline meridional velocity and put it in v3d
272                  dta_alias%v3d(ib,ik) = dta_alias%v3d(ib,ik) - dta_alias%v2d(ib)
273               END DO
274            END DO
275         ENDIF   ! ltotvel
276
277         !  atm surface pressure : add inverted barometer effect to ssh if it was read
278         IF ( ln_apr_obc .AND. TRIM(bf_alias(jp_bdyssh)%clrootname) /= 'NOT USED' ) THEN
279            igrd = 1
280            DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is used only on the rim
281               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
282               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
283               dta_alias%ssh(ib) = dta_alias%ssh(ib) + ssh_ib(ii,ij)
284            END DO
285         ENDIF
286
287#if defined key_si3
288         IF( dta_alias%lneed_ice .AND. idx_bdy(jbdy)%nblen(1) > 0 ) THEN
289            ! fill temperature and salinity arrays
290            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_i)%fnow(:,1,:) = rice_tem (jbdy)
291            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_s)%fnow(:,1,:) = rice_tem (jbdy)
292            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' )   bf_alias(jp_bdytsu)%fnow(:,1,:) = rice_tem (jbdy)
293            IF( TRIM(bf_alias(jp_bdys_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdys_i)%fnow(:,1,:) = rice_sal (jbdy)
294            IF( TRIM(bf_alias(jp_bdyaip)%clrootname) == 'NOT USED' )   &               ! rice_apnd is the pond fraction
295               &   bf_alias(jp_bdyaip)%fnow(:,1,:) = rice_apnd(jbdy) * bf_alias(jp_bdya_i)%fnow(:,1,:)   ! ( a_ip = rice_apnd*a_i )
296            IF( TRIM(bf_alias(jp_bdyhip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyhip)%fnow(:,1,:) = rice_hpnd(jbdy)
297            IF( TRIM(bf_alias(jp_bdyhil)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyhil)%fnow(:,1,:) = rice_hlid(jbdy)
298
299            ! if T_i is read and not T_su, set T_su = T_i
300            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' ) &
301               &   bf_alias(jp_bdytsu)%fnow(:,1,:) = bf_alias(jp_bdyt_i)%fnow(:,1,:)
302            ! if T_s is read and not T_su, set T_su = T_s
303            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' ) &
304               &   bf_alias(jp_bdytsu)%fnow(:,1,:) = bf_alias(jp_bdyt_s)%fnow(:,1,:)
305            ! if T_i is read and not T_s, set T_s = T_i
306            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' ) &
307               &   bf_alias(jp_bdyt_s)%fnow(:,1,:) = bf_alias(jp_bdyt_i)%fnow(:,1,:)
308            ! if T_su is read and not T_s, set T_s = T_su
309            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' ) &
310               &   bf_alias(jp_bdyt_s)%fnow(:,1,:) = bf_alias(jp_bdytsu)%fnow(:,1,:)
311            ! if T_su is read and not T_i, set T_i = (T_su + T_freeze)/2
312            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
313               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdytsu)%fnow(:,1,:) + 271.15 )
314            ! if T_s is read and not T_i, set T_i = (T_s + T_freeze)/2
315            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
316               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdyt_s)%fnow(:,1,:) + 271.15 )
317
318            ! make sure ponds = 0 if no ponds scheme
319            IF ( .NOT.ln_pnd ) THEN
320               bf_alias(jp_bdyaip)%fnow(:,1,:) = 0._wp
321               bf_alias(jp_bdyhip)%fnow(:,1,:) = 0._wp
322               bf_alias(jp_bdyhil)%fnow(:,1,:) = 0._wp
323            ENDIF
324            IF ( .NOT.ln_pnd_lids ) THEN
325               bf_alias(jp_bdyhil)%fnow(:,1,:) = 0._wp
326            ENDIF
327           
328            ! convert N-cat fields (input) into jpl-cat (output)
329            ipl = SIZE(bf_alias(jp_bdya_i)%fnow, 3)           
330            IF( ipl /= jpl ) THEN      ! ice: convert N-cat fields (input) into jpl-cat (output)
331               CALL ice_var_itd( bf_alias(jp_bdyh_i)%fnow(:,1,:), bf_alias(jp_bdyh_s)%fnow(:,1,:), bf_alias(jp_bdya_i)%fnow(:,1,:), & ! in
332                  &              dta_alias%h_i                  , dta_alias%h_s                  , dta_alias%a_i                  , & ! out
333                  &              bf_alias(jp_bdyt_i)%fnow(:,1,:), bf_alias(jp_bdyt_s)%fnow(:,1,:), &                                  ! in (optional)
334                  &              bf_alias(jp_bdytsu)%fnow(:,1,:), bf_alias(jp_bdys_i)%fnow(:,1,:), &                                  ! in     -
335                  &              bf_alias(jp_bdyaip)%fnow(:,1,:), bf_alias(jp_bdyhip)%fnow(:,1,:), bf_alias(jp_bdyhil)%fnow(:,1,:), & ! in     -
336                  &              dta_alias%t_i                  , dta_alias%t_s                  , &                                  ! out    -
337                  &              dta_alias%tsu                  , dta_alias%s_i                  , &                                  ! out    -
338                  &              dta_alias%aip                  , dta_alias%hip                  , dta_alias%hil )                    ! out    -
339            ENDIF
340         ENDIF
341#endif
342      END DO  ! jbdy
343
344      IF ( ln_tide ) THEN
345         IF (ln_dynspg_ts) THEN      ! Fill temporary arrays with slow-varying bdy data                           
346            DO jbdy = 1, nb_bdy      ! Tidal component added in ts loop
347               IF ( nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
348                  IF( ASSOCIATED(dta_bdy(jbdy)%ssh) ) dta_bdy_s(jbdy)%ssh(:) = dta_bdy(jbdy)%ssh(:)
349                  IF( ASSOCIATED(dta_bdy(jbdy)%u2d) ) dta_bdy_s(jbdy)%u2d(:) = dta_bdy(jbdy)%u2d(:)
350                  IF( ASSOCIATED(dta_bdy(jbdy)%v2d) ) dta_bdy_s(jbdy)%v2d(:) = dta_bdy(jbdy)%v2d(:)
351               ENDIF
352            END DO
353         ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
354            !
355            CALL bdy_dta_tides( kt=kt, pt_offset = 1._wp )
356         ENDIF
357      ENDIF
358      !
359      IF( ln_timing )   CALL timing_stop('bdy_dta')
360      !
361   END SUBROUTINE bdy_dta
362   
363
364   SUBROUTINE bdy_dta_init
365      !!----------------------------------------------------------------------
366      !!                   ***  SUBROUTINE bdy_dta_init  ***
367      !!                   
368      !! ** Purpose :   Initialise arrays for reading of external data
369      !!                for open boundary conditions
370      !!
371      !! ** Method  :   
372      !!               
373      !!----------------------------------------------------------------------
374      INTEGER ::   jbdy, jfld    ! Local integers
375      INTEGER ::   ierror, ios     !
376      !
377      INTEGER ::   nbdy_rdstart, nbdy_loc
378      CHARACTER(LEN=50)                      ::   cerrmsg       ! error string
379      CHARACTER(len=3)                       ::   cl3           !
380      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
381      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
382      !                                                         ! =F => baroclinic velocities in 3D boundary data
383      LOGICAL                                ::   ln_zinterp    ! =T => requires a vertical interpolation of the bdydta
384      REAL(wp)                               ::   rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd, rn_ice_hlid
385      INTEGER                                ::   ipk,ipl       !
386      INTEGER                                ::   idvar         ! variable ID
387      INTEGER                                ::   indims        ! number of dimensions of the variable
388      INTEGER                                ::   iszdim        ! number of dimensions of the variable
389      INTEGER, DIMENSION(4)                  ::   i4dimsz       ! size of variable dimensions
390      INTEGER                                ::   igrd          ! index for grid type (1,2,3 = T,U,V)
391      LOGICAL                                ::   lluld         ! is the variable using the unlimited dimension
392      LOGICAL                                ::   llneed        !
393      LOGICAL                                ::   llread        !
394      LOGICAL                                ::   llfullbdy     !
395      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_tem, bn_sal, bn_u3d, bn_v3d   ! must be an array to be used with fld_fill
396      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
397      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip, bn_hil       
398      TYPE(FLD_N), DIMENSION(:), POINTER ::   bn_alias                        ! must be an array to be used with fld_fill
399      TYPE(FLD  ), DIMENSION(:), POINTER ::   bf_alias
400      !
401      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d,                 &
402                         & bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip, bn_hil, &
403                         & rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd, rn_ice_hlid,      &
404                         & ln_full_vel, ln_zinterp
405      !!---------------------------------------------------------------------------
406      !
407      IF(lwp) WRITE(numout,*)
408      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
409      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
410      IF(lwp) WRITE(numout,*) ''
411
412      ALLOCATE( bf(jpbdyfld,nb_bdy), STAT=ierror )
413      IF( ierror > 0 ) THEN   
414         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
415      ENDIF
416      bf(:,:)%clrootname = 'NOT USED'   ! default definition used as a flag in fld_read to do nothing.
417      bf(:,:)%lzint      = .FALSE.      ! default definition
418      bf(:,:)%ltotvel    = .FALSE.      ! default definition
419 
420      ! Read namelists
421      ! --------------
422      nbdy_rdstart = 1
423      DO jbdy = 1, nb_bdy
424
425         WRITE(ctmp1, '(a,i2)') 'BDY number ', jbdy
426         WRITE(ctmp2, '(a,i2)') 'block nambdy_dta number ', jbdy
427
428         ! There is only one nambdy_dta block in namelist_ref -> use it for each bdy so we read from the beginning
429         READ  ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
430901      IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in reference namelist' )
431
432         !   by-pass nambdy_dta reading if no input data used in this bdy   
433         IF(       ( dta_bdy(jbdy)%lneed_dyn2d .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1 )   &
434            & .OR. ( dta_bdy(jbdy)%lneed_dyn3d .AND.     nn_dyn3d_dta(jbdy)    == 1 )   &
435            & .OR. ( dta_bdy(jbdy)%lneed_tra   .AND.       nn_tra_dta(jbdy)    == 1 )   &
436            & .OR. ( dta_bdy(jbdy)%lneed_ice   .AND.       nn_ice_dta(jbdy)    == 1 )   )   THEN
437            !
438            ! Need to support possibility of reading more than one
439            ! nambdy_dta from the namelist_cfg internal file.
440            ! Do this by finding the jbdy'th occurence of nambdy_dta in the
441            ! character buffer as the starting point.
442            !
443            nbdy_loc = INDEX( numnam_cfg( nbdy_rdstart: ), 'nambdy_dta' )
444            IF( nbdy_loc .GT. 0 ) THEN
445               nbdy_rdstart = nbdy_rdstart + nbdy_loc
446            ELSE
447               WRITE(cerrmsg,'(A,I4,A)') 'Error: entry number ',jbdy,' of nambdy_dta not found'
448               ios = -1
449               CALL ctl_nam ( ios , cerrmsg )
450            ENDIF
451            READ  ( numnam_cfg( MAX( 1, nbdy_rdstart - 2 ): ), nambdy_dta, IOSTAT = ios, ERR = 902)
452902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist' )
453            IF(lwm) WRITE( numond, nambdy_dta )           
454         ENDIF
455
456         ! get the number of ice categories in bdy data file (use a_i information to do this)
457         ipl = jpl   ! default definition
458         IF( dta_bdy(jbdy)%lneed_ice ) THEN    ! if we need ice bdy data
459            IF( nn_ice_dta(jbdy) == 1 ) THEN   ! if we get ice bdy data from netcdf file
460               CALL fld_fill(  bf(jp_bdya_i,jbdy:jbdy), bn_a_i, cn_dir, 'bdy_dta', 'a_i'//' '//ctmp1, ctmp2 )   ! use namelist info
461               CALL fld_def( bf(jp_bdya_i,jbdy) )
462               CALL iom_open( bf(jp_bdya_i,jbdy)%clname, bf(jp_bdya_i,jbdy)%num )
463               idvar = iom_varid( bf(jp_bdya_i,jbdy)%num, bf(jp_bdya_i,jbdy)%clvar, kndims=indims, kdimsz=i4dimsz, lduld=lluld )
464               IF( indims == 4 .OR. ( indims == 3 .AND. .NOT. lluld ) ) THEN   ;   ipl = i4dimsz(3)   ! xylt or xyl
465               ELSE                                                            ;   ipl = 1            ! xy or xyt
466               ENDIF
467               CALL iom_close( bf(jp_bdya_i,jbdy)%num )
468               bf(jp_bdya_i,jbdy)%clrootname = 'NOT USED'   ! reset to default value as this subdomain may not need to read this bdy
469            ENDIF
470         ENDIF
471
472#if defined key_si3
473         IF( .NOT.ln_pnd ) THEN
474            rn_ice_apnd = 0. ; rn_ice_hpnd = 0. ; rn_ice_hlid = 0.
475            CALL ctl_warn( 'rn_ice_apnd & rn_ice_hpnd = 0 & rn_ice_hlid = 0 when no ponds' )
476         ENDIF
477         IF( .NOT.ln_pnd_lids ) THEN
478            rn_ice_hlid = 0.
479         ENDIF
480#endif
481
482         ! temp, salt, age and ponds of incoming ice
483         rice_tem (jbdy) = rn_ice_tem
484         rice_sal (jbdy) = rn_ice_sal
485         rice_age (jbdy) = rn_ice_age
486         rice_apnd(jbdy) = rn_ice_apnd
487         rice_hpnd(jbdy) = rn_ice_hpnd
488         rice_hlid(jbdy) = rn_ice_hlid
489
490         
491         DO jfld = 1, jpbdyfld
492
493            ! =====================
494            !          ssh
495            ! =====================
496            IF( jfld == jp_bdyssh ) THEN
497               cl3 = 'ssh'
498               igrd = 1                                                    ! T point
499               ipk = 1                                                     ! surface data
500               llneed = dta_bdy(jbdy)%lneed_ssh                            ! dta_bdy(jbdy)%ssh will be needed
501               llread = MOD(nn_dyn2d_dta(jbdy),2) == 1                     ! get data from NetCDF file
502               bf_alias => bf(jp_bdyssh,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
503               bn_alias => bn_ssh                                          ! alias for ssh structure of nambdy_dta
504               iszdim = idx_bdy(jbdy)%nblenrim(igrd)                       ! length of this bdy on this MPI processus : used only on the rim
505            ENDIF
506            ! =====================
507            !         dyn2d
508            ! =====================
509            IF( jfld == jp_bdyu2d ) THEN
510               cl3 = 'u2d'
511               igrd = 2                                                    ! U point
512               ipk = 1                                                     ! surface data
513               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%u2d will be needed
514               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get u2d from u3d and read NetCDF file
515               bf_alias => bf(jp_bdyu2d,jbdy:jbdy)                         ! alias for u2d structure of bdy number jbdy
516               bn_alias => bn_u2d                                          ! alias for u2d structure of nambdy_dta
517               llfullbdy = ln_full_vel .OR. cn_dyn2d(jbdy) == 'frs'        ! need u2d over the whole bdy or only over the rim?
518               IF( llfullbdy ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)
519               ELSE                  ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)
520               ENDIF
521            ENDIF
522            IF( jfld == jp_bdyv2d ) THEN
523               cl3 = 'v2d'
524               igrd = 3                                                    ! V point
525               ipk = 1                                                     ! surface data
526               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%v2d will be needed
527               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get v2d from v3d and read NetCDF file
528               bf_alias => bf(jp_bdyv2d,jbdy:jbdy)                         ! alias for v2d structure of bdy number jbdy
529               bn_alias => bn_v2d                                          ! alias for v2d structure of nambdy_dta
530               llfullbdy = ln_full_vel .OR. cn_dyn2d(jbdy) == 'frs'        ! need v2d over the whole bdy or only over the rim?
531               IF( llfullbdy ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)
532               ELSE                  ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)
533               ENDIF
534            ENDIF
535            ! =====================
536            !         dyn3d
537            ! =====================
538            IF( jfld == jp_bdyu3d ) THEN
539               cl3 = 'u3d'
540               igrd = 2                                                    ! U point
541               ipk = jpk                                                   ! 3d data
542               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%u3d will be needed
543                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   u3d needed to compute u2d
544               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
545               bf_alias => bf(jp_bdyu3d,jbdy:jbdy)                         ! alias for u3d structure of bdy number jbdy
546               bn_alias => bn_u3d                                          ! alias for u3d structure of nambdy_dta
547               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
548           ENDIF
549            IF( jfld == jp_bdyv3d ) THEN
550               cl3 = 'v3d'
551               igrd = 3                                                    ! V point
552               ipk = jpk                                                   ! 3d data
553               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%v3d will be needed
554                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   v3d needed to compute v2d
555               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
556               bf_alias => bf(jp_bdyv3d,jbdy:jbdy)                         ! alias for v3d structure of bdy number jbdy
557               bn_alias => bn_v3d                                          ! alias for v3d structure of nambdy_dta
558               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
559           ENDIF
560
561            ! =====================
562            !          tra
563            ! =====================
564            IF( jfld == jp_bdytem ) THEN
565               cl3 = 'tem'
566               igrd = 1                                                    ! T point
567               ipk = jpk                                                   ! 3d data
568               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%tem will be needed
569               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
570               bf_alias => bf(jp_bdytem,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
571               bn_alias => bn_tem                                          ! alias for ssh structure of nambdy_dta
572               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
573            ENDIF
574            IF( jfld == jp_bdysal ) THEN
575               cl3 = 'sal'
576               igrd = 1                                                    ! T point
577               ipk = jpk                                                   ! 3d data
578               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%sal will be needed
579               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
580               bf_alias => bf(jp_bdysal,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
581               bn_alias => bn_sal                                          ! alias for ssh structure of nambdy_dta
582               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
583            ENDIF
584
585            ! =====================
586            !          ice
587            ! =====================
588            IF(  jfld == jp_bdya_i .OR. jfld == jp_bdyh_i .OR. jfld == jp_bdyh_s .OR. &
589               & jfld == jp_bdyt_i .OR. jfld == jp_bdyt_s .OR. jfld == jp_bdytsu .OR. &
590               & jfld == jp_bdys_i .OR. jfld == jp_bdyaip .OR. jfld == jp_bdyhip .OR. jfld == jp_bdyhil ) THEN
591               igrd = 1                                                    ! T point
592               ipk = ipl                                                   ! jpl-cat data
593               llneed = dta_bdy(jbdy)%lneed_ice                            ! ice will be needed
594               llread = nn_ice_dta(jbdy) == 1                              ! get data from NetCDF file
595               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
596            ENDIF
597            IF( jfld == jp_bdya_i ) THEN
598               cl3 = 'a_i'
599               bf_alias => bf(jp_bdya_i,jbdy:jbdy)                         ! alias for a_i structure of bdy number jbdy
600               bn_alias => bn_a_i                                          ! alias for a_i structure of nambdy_dta
601            ENDIF
602            IF( jfld == jp_bdyh_i ) THEN
603               cl3 = 'h_i'
604               bf_alias => bf(jp_bdyh_i,jbdy:jbdy)                         ! alias for h_i structure of bdy number jbdy
605               bn_alias => bn_h_i                                          ! alias for h_i structure of nambdy_dta
606            ENDIF
607            IF( jfld == jp_bdyh_s ) THEN
608               cl3 = 'h_s'
609               bf_alias => bf(jp_bdyh_s,jbdy:jbdy)                         ! alias for h_s structure of bdy number jbdy
610               bn_alias => bn_h_s                                          ! alias for h_s structure of nambdy_dta
611            ENDIF
612            IF( jfld == jp_bdyt_i ) THEN
613               cl3 = 't_i'
614               bf_alias => bf(jp_bdyt_i,jbdy:jbdy)                         ! alias for t_i structure of bdy number jbdy
615               bn_alias => bn_t_i                                          ! alias for t_i structure of nambdy_dta
616            ENDIF
617            IF( jfld == jp_bdyt_s ) THEN
618               cl3 = 't_s'
619               bf_alias => bf(jp_bdyt_s,jbdy:jbdy)                         ! alias for t_s structure of bdy number jbdy
620               bn_alias => bn_t_s                                          ! alias for t_s structure of nambdy_dta
621            ENDIF
622            IF( jfld == jp_bdytsu ) THEN
623               cl3 = 'tsu'
624               bf_alias => bf(jp_bdytsu,jbdy:jbdy)                         ! alias for tsu structure of bdy number jbdy
625               bn_alias => bn_tsu                                          ! alias for tsu structure of nambdy_dta
626            ENDIF
627            IF( jfld == jp_bdys_i ) THEN
628               cl3 = 's_i'
629               bf_alias => bf(jp_bdys_i,jbdy:jbdy)                         ! alias for s_i structure of bdy number jbdy
630               bn_alias => bn_s_i                                          ! alias for s_i structure of nambdy_dta
631            ENDIF
632            IF( jfld == jp_bdyaip ) THEN
633               cl3 = 'aip'
634               bf_alias => bf(jp_bdyaip,jbdy:jbdy)                         ! alias for aip structure of bdy number jbdy
635               bn_alias => bn_aip                                          ! alias for aip structure of nambdy_dta
636            ENDIF
637            IF( jfld == jp_bdyhip ) THEN
638               cl3 = 'hip'
639               bf_alias => bf(jp_bdyhip,jbdy:jbdy)                         ! alias for hip structure of bdy number jbdy
640               bn_alias => bn_hip                                          ! alias for hip structure of nambdy_dta
641            ENDIF
642            IF( jfld == jp_bdyhil ) THEN
643               cl3 = 'hil'
644               bf_alias => bf(jp_bdyhil,jbdy:jbdy)                         ! alias for hil structure of bdy number jbdy
645               bn_alias => bn_hil                                          ! alias for hil structure of nambdy_dta
646            ENDIF
647
648            IF( llneed .AND. iszdim > 0 ) THEN                             ! dta_bdy(jbdy)%xxx will be needed
649               !                                                           !   -> must be associated with an allocated target
650               ALLOCATE( bf_alias(1)%fnow( iszdim, 1, ipk ) )              ! allocate the target
651               !
652               IF( llread ) THEN                                           ! get data from NetCDF file
653                  CALL fld_fill( bf_alias, bn_alias, cn_dir, 'bdy_dta', cl3//' '//ctmp1, ctmp2 )   ! use namelist info
654                  IF( bf_alias(1)%ln_tint ) ALLOCATE( bf_alias(1)%fdta( iszdim, 1, ipk, 2 ) )
655                  bf_alias(1)%imap    => idx_bdy(jbdy)%nbmap(1:iszdim,igrd)   ! associate the mapping used for this bdy
656                  bf_alias(1)%igrd    = igrd                                  ! used only for vertical integration of 3D arrays
657                  bf_alias(1)%ibdy    = jbdy                                  !  "    "    "     "          "      "  "    "   
658                  bf_alias(1)%ltotvel = ln_full_vel                           ! T if u3d is full velocity
659                  bf_alias(1)%lzint   = ln_zinterp                            ! T if it requires a vertical interpolation
660               ENDIF
661
662               ! associate the pointer and get rid of the dimensions with a size equal to 1
663               IF( jfld == jp_bdyssh )        dta_bdy(jbdy)%ssh => bf_alias(1)%fnow(:,1,1)
664               IF( jfld == jp_bdyu2d )        dta_bdy(jbdy)%u2d => bf_alias(1)%fnow(:,1,1)
665               IF( jfld == jp_bdyv2d )        dta_bdy(jbdy)%v2d => bf_alias(1)%fnow(:,1,1)
666               IF( jfld == jp_bdyu3d )        dta_bdy(jbdy)%u3d => bf_alias(1)%fnow(:,1,:)
667               IF( jfld == jp_bdyv3d )        dta_bdy(jbdy)%v3d => bf_alias(1)%fnow(:,1,:)
668               IF( jfld == jp_bdytem )        dta_bdy(jbdy)%tem => bf_alias(1)%fnow(:,1,:)
669               IF( jfld == jp_bdysal )        dta_bdy(jbdy)%sal => bf_alias(1)%fnow(:,1,:)
670               IF( jfld == jp_bdya_i ) THEN
671                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%a_i => bf_alias(1)%fnow(:,1,:)
672                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%a_i(iszdim,jpl) )
673                  ENDIF
674               ENDIF
675               IF( jfld == jp_bdyh_i ) THEN
676                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_i => bf_alias(1)%fnow(:,1,:)
677                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_i(iszdim,jpl) )
678                  ENDIF
679               ENDIF
680               IF( jfld == jp_bdyh_s ) THEN
681                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_s => bf_alias(1)%fnow(:,1,:)
682                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_s(iszdim,jpl) )
683                  ENDIF
684               ENDIF
685               IF( jfld == jp_bdyt_i ) THEN
686                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_i => bf_alias(1)%fnow(:,1,:)
687                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_i(iszdim,jpl) )
688                  ENDIF
689               ENDIF
690               IF( jfld == jp_bdyt_s ) THEN
691                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_s => bf_alias(1)%fnow(:,1,:)
692                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_s(iszdim,jpl) )
693                  ENDIF
694               ENDIF
695               IF( jfld == jp_bdytsu ) THEN
696                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%tsu => bf_alias(1)%fnow(:,1,:)
697                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%tsu(iszdim,jpl) )
698                  ENDIF
699               ENDIF
700               IF( jfld == jp_bdys_i ) THEN
701                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%s_i => bf_alias(1)%fnow(:,1,:)
702                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%s_i(iszdim,jpl) )
703                  ENDIF
704               ENDIF
705               IF( jfld == jp_bdyaip ) THEN
706                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%aip => bf_alias(1)%fnow(:,1,:)
707                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%aip(iszdim,jpl) )
708                  ENDIF
709               ENDIF
710               IF( jfld == jp_bdyhip ) THEN
711                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%hip => bf_alias(1)%fnow(:,1,:)
712                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%hip(iszdim,jpl) )
713                  ENDIF
714               ENDIF
715               IF( jfld == jp_bdyhil ) THEN
716                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%hil => bf_alias(1)%fnow(:,1,:)
717                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%hil(iszdim,jpl) )
718                  ENDIF
719               ENDIF
720            ENDIF
721
722         END DO   ! jpbdyfld
723         !
724      END DO ! jbdy
725      !
726   END SUBROUTINE bdy_dta_init
727   
728   !!==============================================================================
729END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.