source: NEMO/trunk/src/OCE/C1D/step_c1d.F90 @ 12740

Last change on this file since 12740 was 12740, checked in by smasson, 8 months ago

trunk: update/debug of tests and C1D, see #2442

  • Property svn:keywords set to Id
File size: 9.3 KB
Line 
1MODULE step_c1d
2   !!======================================================================
3   !!                       ***  MODULE step_c1d  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping - c1d case
5   !!======================================================================
6   !! History :   2.0  !  2004-04  (C. Ethe)  adapted from step.F90 for C1D
7   !!             3.0  !  2008-04  (G. Madec)  redo the adaptation to include SBC
8   !!             4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
9   !!----------------------------------------------------------------------
10#if defined key_c1d
11   !!----------------------------------------------------------------------
12   !!   'key_c1d'                                       1D Configuration
13   !!---------------------------------------------------------------------- 
14   !!   stp_c1d        : NEMO system time-stepping in c1d case
15   !!----------------------------------------------------------------------
16   USE step_oce        ! time stepping definition modules
17   USE step, ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices
18#if defined key_top
19   USE trcstp          ! passive tracer time-stepping      (trc_stp routine)
20#endif
21   USE dyncor_c1d      ! Coriolis term (c1d case)         (dyn_cor_1d     )
22   USE dynatf          ! time filtering                   (dyn_atf routine)
23   USE dyndmp          ! U & V momentum damping           (dyn_dmp routine)
24   USE restart         ! restart
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC stp_c1d      ! called by nemogcm.F90
30
31   !!----------------------------------------------------------------------
32   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
33   !! $Id$
34   !! Software governed by the CeCILL license (see ./LICENSE)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE stp_c1d( kstp )
39      !!----------------------------------------------------------------------
40      !!                     ***  ROUTINE stp_c1d  ***
41      !!                     
42      !! ** Purpose :  - Time stepping of SBC including sea ice (dynamic and thermodynamic eqs.)
43      !!               - Time stepping of OPA (momentum and active tracer eqs.)
44      !!               - Time stepping of TOP (passive tracer eqs.)
45      !!
46      !! ** Method  : -1- Update forcings and data 
47      !!              -2- Update vertical ocean physics
48      !!              -3- Compute the t and s trends
49      !!              -4- Update t and s
50      !!              -5- Compute the momentum trends
51      !!              -6- Update the horizontal velocity
52      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
53      !!              -8- Outputs and diagnostics
54      !!----------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
56      !
57      INTEGER ::   jk       ! dummy loop indice
58      INTEGER ::   indic    ! error indicator if < 0
59      !! ---------------------------------------------------------------------
60
61                             indic = 0                ! reset to no error condition
62      IF( kstp == nit000 )   CALL iom_init( "nemo")   ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
63      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
64                             CALL iom_setkt( kstp - nit000 + 1, "nemo" )   ! say to iom that we are at time step kstp
65
66      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
67      ! Update data, open boundaries, surface boundary condition (including sea-ice)
68      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
69                         CALL sbc    ( kstp, Nbb, Nnn )  ! Sea Boundary Condition (including sea-ice)
70
71      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
72      ! Ocean physics update       
73      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
74                         CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn )  ! before local thermal/haline expension ratio at T-points
75                         CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn )  ! now    local thermal/haline expension ratio at T-points
76                         CALL bn2( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency
77                         CALL bn2( ts(:,:,:,:,Nnn), rab_n, rn2 , Nnn ) ! now    Brunt-Vaisala frequency
78     
79      !  VERTICAL PHYSICS
80                         CALL zdf_phy( kstp, Nbb, Nnn, Nrhs  )    ! vertical physics update (bfr, avt, avs, avm + MLD)
81
82      IF(.NOT.ln_linssh )   CALL ssh_nxt       ( kstp, Nbb, Nnn, ssh, Naa )  ! after ssh (includes call to div_hor)
83      IF(.NOT.ln_linssh )   CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn,      Naa )  ! after vertical scale factors
84
85      IF(.NOT.ln_linssh )   CALL wzv           ( kstp, Nbb, Nnn, ww,  Naa )  ! now cross-level velocity
86      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
87      ! diagnostics and outputs       
88      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
89                         CALL dia_wri( kstp, Nnn )  ! ocean model: outputs
90                         CALL dia_hth( kstp, Nnn )  ! Thermocline depth (20°C)
91
92
93#if defined key_top
94      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
95      ! Passive Tracer Model
96      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
97                        CALL trc_stp( kstp, Nbb, Nnn, Nrhs, Naa  )   ! time-stepping
98#endif
99
100      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
101      ! Active tracers                              (uu(:,:,:,Nrhs), vv(:,:,:,Nrhs) used as workspace)
102      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
103                        ts(:,:,:,:,Nrhs) = 0._wp       ! set tracer trends to zero
104
105                        CALL tra_sbc( kstp,      Nnn, ts, Nrhs  )  ! surface boundary condition
106      IF( ln_traqsr )   CALL tra_qsr( kstp,      Nnn, ts, Nrhs  )  ! penetrative solar radiation qsr
107      IF( ln_tradmp )   CALL tra_dmp( kstp, Nbb, Nnn, ts, Nrhs  )  ! internal damping trends- tracers
108      IF(.NOT.ln_linssh)CALL tra_adv( kstp, Nbb, Nnn, ts, Nrhs  )  ! horizontal & vertical advection
109      IF( ln_zdfosm  )  CALL tra_osm( kstp, Nnn     , ts, Nrhs  )  ! OSMOSIS non-local tracer fluxes
110                        CALL tra_zdf( kstp, Nbb, Nnn, Nrhs, ts, Naa   )         ! vertical mixing
111                        CALL eos( ts(:,:,:,:,Nnn), rhd, rhop, gdept_0(:,:,:) )  ! now potential density for zdfmxl
112      IF( ln_zdfnpc )   CALL tra_npc( kstp,      Nnn, Nrhs, ts, Naa   )         ! applied non penetrative convective adjustment on (t,s)
113                        CALL tra_atf( kstp, Nbb, Nnn, Naa, ts )                 ! time filtering of "now" tracer arrays
114
115      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
116      ! Dynamics                                    (ta, sa used as workspace)
117      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
118                        uu(:,:,:,Nrhs) = 0._wp          ! set dynamics trends to zero
119                        vv(:,:,:,Nrhs) = 0._wp
120
121      IF( ln_dyndmp )   CALL dyn_dmp    ( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! internal damping trends- momentum
122                        CALL dyn_cor_c1d( kstp,      Nnn      , uu, vv, Nrhs )  ! vorticity term including Coriolis
123      IF( ln_zdfosm  )  CALL dyn_osm    ( kstp,      Nnn      , uu, vv, Nrhs )  ! OSMOSIS non-local velocity fluxes
124                        CALL dyn_zdf    ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa  )  ! vertical diffusion
125                        CALL dyn_atf    ( kstp, Nbb, Nnn, Naa , uu, vv, e3t, e3u, e3v )  ! time filtering of "now" fields
126      IF(.NOT.ln_linssh)CALL ssh_atf    ( kstp, Nbb, Nnn, Naa , ssh )                    ! time filtering of "now" sea surface height
127      !
128      ! Swap time levels
129      Nrhs = Nbb
130      Nbb = Nnn
131      Nnn = Naa
132      Naa = Nrhs
133      !
134      IF(.NOT.ln_linssh)CALL dom_vvl_sf_update( kstp, Nbb, Nnn, Naa )                    ! update of vertical scale factors
135
136      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
137      ! Control and restarts
138      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
139                             CALL stp_ctl( kstp, Nbb, Nnn, indic )
140      IF( kstp == nit000 )   CALL iom_close( numror )          ! close input  ocean restart file
141      IF( lrst_oce       )   CALL rst_write( kstp, Nbb, Nnn )  ! write output ocean restart file
142      !
143#if defined key_iomput
144      IF( kstp == nitend .OR. indic < 0 )   CALL xios_context_finalize()   ! needed for XIOS
145      !
146#endif
147   END SUBROUTINE stp_c1d
148
149#else
150   !!----------------------------------------------------------------------
151   !!   Default key                                            NO 1D Config
152   !!----------------------------------------------------------------------
153CONTAINS
154   SUBROUTINE stp_c1d ( kt )      ! dummy routine
155      IMPLICIT NONE
156      INTEGER, INTENT( in ) :: kt
157      WRITE(*,*) 'stp_c1d: You should not have seen this print! error?', kt
158   END SUBROUTINE stp_c1d
159#endif
160
161   !!======================================================================
162END MODULE step_c1d
Note: See TracBrowser for help on using the repository browser.