New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domzgr.F90 in NEMO/trunk/src/OCE/DOM – NEMO

source: NEMO/trunk/src/OCE/DOM/domzgr.F90 @ 15052

Last change on this file since 15052 was 15052, checked in by smasson, 12 months ago

trunk: call lbc_lnk for variables defined with usr_def_*, #2701

  • Property svn:keywords set to Id
File size: 21.6 KB
Line 
1MODULE domzgr
2   !!==============================================================================
3   !!                       ***  MODULE domzgr   ***
4   !! Ocean domain : definition of the vertical coordinate system
5   !!==============================================================================
6   !! History :  OPA  ! 1995-12  (G. Madec)  Original code : s vertical coordinate
7   !!                 ! 1997-07  (G. Madec)  lbc_lnk call
8   !!                 ! 1997-04  (J.-O. Beismann)
9   !!            8.5  ! 2002-09  (A. Bozec, G. Madec)  F90: Free form and module
10   !!             -   ! 2002-09  (A. de Miranda)  rigid-lid + islands
11   !!  NEMO      1.0  ! 2003-08  (G. Madec)  F90: Free form and module
12   !!             -   ! 2005-10  (A. Beckmann)  modifications for hybrid s-ccordinates & new stretching function
13   !!            2.0  ! 2006-04  (R. Benshila, G. Madec)  add zgr_zco
14   !!            3.0  ! 2008-06  (G. Madec)  insertion of domzgr_zps.h90 & conding style
15   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
16   !!            3.3  ! 2010-11  (G. Madec) add mbk. arrays associated to the deepest ocean level
17   !!            3.4  ! 2012-08  (J. Siddorn) added Siddorn and Furner stretching function
18   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  modify C1D case 
19   !!            3.6  ! 2014-11  (P. Mathiot and C. Harris) add ice shelf capabilitye 
20   !!            3.?  ! 2015-11  (H. Liu) Modifications for Wetting/Drying
21   !!----------------------------------------------------------------------
22
23   !!----------------------------------------------------------------------
24   !!   dom_zgr       : read or set the ocean vertical coordinate system
25   !!   zgr_read      : read the vertical information in the domain configuration file
26   !!   zgr_top_bot   : ocean top and bottom level for t-, u, and v-points with 1 as minimum value
27   !!---------------------------------------------------------------------
28   USE oce            ! ocean variables
29   USE dom_oce        ! ocean domain
30   USE usrdef_zgr     ! user defined vertical coordinate system
31   USE closea         ! closed seas
32   USE depth_e3       ! depth <=> e3
33   USE wet_dry,   ONLY: ll_wd, ssh_ref  ! Wetting and drying
34   !
35   USE in_out_manager ! I/O manager
36   USE iom            ! I/O library
37   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
38   USE lib_mpp        ! distributed memory computing library
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   dom_zgr        ! called by dom_init.F90
44
45  !! * Substitutions
46#  include "do_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS       
53
54   SUBROUTINE dom_zgr( k_top, k_bot )
55      !!----------------------------------------------------------------------
56      !!                ***  ROUTINE dom_zgr  ***
57      !!                   
58      !! ** Purpose :   set the depth of model levels and the resulting
59      !!              vertical scale factors.
60      !!
61      !! ** Method  : - reference 1D vertical coordinate (gdep._1d, e3._1d)
62      !!              - read/set ocean depth and ocean levels (bathy, mbathy)
63      !!              - vertical coordinate (gdep., e3.) depending on the
64      !!                coordinate chosen :
65      !!                   ln_zco=T   z-coordinate   
66      !!                   ln_zps=T   z-coordinate with partial steps
67      !!                   ln_zco=T   s-coordinate
68      !!
69      !! ** Action  :   define gdep., e3., mbathy and bathy
70      !!----------------------------------------------------------------------
71      INTEGER, DIMENSION(:,:), INTENT(out) ::   k_top, k_bot   ! ocean first and last level indices
72      !
73      INTEGER  ::   ji,jj,jk            ! dummy loop index
74      INTEGER  ::   ikt, ikb            ! top/bot index
75      INTEGER  ::   ioptio, ibat, ios   ! local integer
76      REAL(wp) ::   zrefdep             ! depth of the reference level (~10m)
77      REAL(wp), DIMENSION(jpi,jpj  ) ::   zmsk
78      REAL(wp), DIMENSION(jpi,jpj,2) ::   ztopbot
79      !!----------------------------------------------------------------------
80      !
81      IF(lwp) THEN                     ! Control print
82         WRITE(numout,*)
83         WRITE(numout,*) 'dom_zgr : vertical coordinate'
84         WRITE(numout,*) '~~~~~~~'
85      ENDIF
86
87      IF( ln_linssh .AND. lwp) WRITE(numout,*) '   linear free surface: the vertical mesh does not change in time'
88
89
90      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
91         IF(lwp) WRITE(numout,*)
92         IF(lwp) WRITE(numout,*) '   ==>>>   Read vertical mesh in ', TRIM( cn_domcfg ), ' file'
93         !
94         CALL zgr_read   ( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
95            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
96            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
97            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
98            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
99            &              k_top   , k_bot            )                  ! 1st & last ocean level
100            !
101      ELSE                          !==  User defined configuration  ==!
102         IF(lwp) WRITE(numout,*)
103         IF(lwp) WRITE(numout,*) '          User defined vertical mesh (usr_def_zgr)'
104         !
105         CALL usr_def_zgr( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
106            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
107            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
108            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
109            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
110            &              k_top   , k_bot            )                  ! 1st & last ocean level
111         !
112         ! make sure that periodicities are properly applied
113         CALL lbc_lnk( 'dom_zgr', gdept_0, 'T', 1._wp, gdepw_0, 'W', 1._wp,                                         &
114            &                       e3t_0, 'T', 1._wp,   e3u_0, 'U', 1._wp,  e3v_0, 'V', 1._wp, e3f_0, 'F', 1._wp,   &
115            &                       e3w_0, 'W', 1._wp,  e3uw_0, 'U', 1._wp, e3vw_0, 'V', 1._wp,   &   
116            &                     kfillmode = jpfillcopy )   ! do not put 0 over closed boundaries
117         ztopbot(:,:,1) = REAL(k_top, wp)
118         ztopbot(:,:,2) = REAL(k_bot, wp)
119         CALL lbc_lnk( 'dom_zgr', ztopbot, 'T', 1._wp, kfillmode = jpfillcopy )   ! do not put 0 over closed boundaries
120         k_top(:,:) = NINT(ztopbot(:,:,1))
121         k_bot(:,:) = NINT(ztopbot(:,:,2))
122         !
123      ENDIF
124      !
125      ! the following is mandatory
126      ! make sure that closed boundaries are correctly defined in k_top that will be used to compute all mask arrays
127      !
128      zmsk(:,:) = 1._wp                                       ! default: no closed boundaries
129      IF( .NOT. l_Iperio ) THEN                                    ! E-W closed:
130         zmsk(  mi0(     1+nn_hls):mi1(     1+nn_hls),:) = 0._wp   ! first column of inner global domain at 0
131         zmsk(  mi0(jpiglo-nn_hls):mi1(jpiglo-nn_hls),:) = 0._wp   ! last  column of inner global domain at 0
132      ENDIF
133      IF( .NOT. l_Jperio ) THEN                                    ! S closed:
134         zmsk(:,mj0(     1+nn_hls):mj1(     1+nn_hls)  ) = 0._wp   ! first   line of inner global domain at 0
135      ENDIF
136      IF( .NOT. ( l_Jperio .OR. l_NFold ) ) THEN                   ! N closed:
137         zmsk(:,mj0(jpjglo-nn_hls):mj1(jpjglo-nn_hls)  ) = 0._wp   ! last    line of inner global domain at 0
138      ENDIF
139      CALL lbc_lnk( 'usrdef_zgr', zmsk, 'T', 1. )             ! set halos
140      k_top(:,:) = k_top(:,:) * NINT( zmsk(:,:) )
141      !
142!!gm to be remove when removing the OLD definition of e3 scale factors so that gde3w disappears
143      ! Compute gde3w_0 (vertical sum of e3w)
144      gde3w_0(:,:,1) = 0.5_wp * e3w_0(:,:,1)
145      DO jk = 2, jpk
146         gde3w_0(:,:,jk) = gde3w_0(:,:,jk-1) + e3w_0(:,:,jk)
147      END DO
148      !
149      ! Any closed seas (defined by closea_mask > 0 in domain_cfg file) to be filled
150      ! in at runtime if ln_closea=.false.
151      IF( ln_closea ) THEN
152         IF ( ln_maskcs ) THEN
153            ! mask all the closed sea
154            CALL clo_msk( k_top, k_bot, mask_opnsea, 'mask_opensea' )
155         ELSE IF ( ln_mask_csundef ) THEN
156            ! defined closed sea are kept
157            ! mask all the undefined closed sea
158            CALL clo_msk( k_top, k_bot, mask_csundef, 'mask_csundef' )
159         END IF
160      END IF
161      !
162      IF(lwp) THEN                     ! Control print
163         WRITE(numout,*)
164         WRITE(numout,*) '   Type of vertical coordinate (read in ', TRIM( cn_domcfg ), ' file or set in userdef_nam) :'
165         WRITE(numout,*) '      z-coordinate - full steps      ln_zco    = ', ln_zco
166         WRITE(numout,*) '      z-coordinate - partial steps   ln_zps    = ', ln_zps
167         WRITE(numout,*) '      s- or hybrid z-s-coordinate    ln_sco    = ', ln_sco
168         WRITE(numout,*) '      ice shelf cavities             ln_isfcav = ', ln_isfcav
169      ENDIF
170
171      ioptio = 0                       ! Check Vertical coordinate options
172      IF( ln_zco      )   ioptio = ioptio + 1
173      IF( ln_zps      )   ioptio = ioptio + 1
174      IF( ln_sco      )   ioptio = ioptio + 1
175      IF( ioptio /= 1 )   CALL ctl_stop( ' none or several vertical coordinate options used' )
176
177
178      !                                ! top/bottom ocean level indices for t-, u- and v-points (f-point also for top)
179      CALL zgr_top_bot( k_top, k_bot )      ! with a minimum value set to 1
180      !
181      !                                ! ice shelf draft and bathymetry
182      DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
183         ikt = mikt(ji,jj)
184         ikb = mbkt(ji,jj)
185         bathy  (ji,jj) = gdepw_0(ji,jj,ikb+1)
186         risfdep(ji,jj) = gdepw_0(ji,jj,ikt  )
187      END_2D
188      !
189      !                                ! deepest/shallowest W level Above/Below ~10m
190!!gm BUG in s-coordinate this does not work!
191      zrefdep = 10._wp - 0.1_wp * MINVAL( e3w_1d )                   ! ref. depth with tolerance (10% of minimum layer thickness)
192      nlb10 = MINLOC( gdepw_1d, mask = gdepw_1d > zrefdep, dim = 1 ) ! shallowest W level Below ~10m
193      nla10 = nlb10 - 1                                              ! deepest    W level Above ~10m
194!!gm end bug
195      !
196      IF( lwp )   THEN
197         WRITE(numout,*) ' MIN val k_top   ', MINVAL(   k_top(:,:) ), ' MAX ', MAXVAL( k_top(:,:) )
198         WRITE(numout,*) ' MIN val k_bot   ', MINVAL(   k_bot(:,:) ), ' MAX ', MAXVAL( k_bot(:,:) )
199         WRITE(numout,*) ' MIN val depth t ', MINVAL( gdept_0(:,:,:) ),   &
200            &                          ' w ', MINVAL( gdepw_0(:,:,:) ), '3w ', MINVAL( gde3w_0(:,:,:) )
201         WRITE(numout,*) ' MIN val e3    t ', MINVAL(   e3t_0(:,:,:) ), ' f ', MINVAL(   e3f_0(:,:,:) ),  &
202            &                          ' u ', MINVAL(   e3u_0(:,:,:) ), ' u ', MINVAL(   e3v_0(:,:,:) ),  &
203            &                          ' uw', MINVAL(  e3uw_0(:,:,:) ), ' vw', MINVAL(  e3vw_0(:,:,:)),   &
204            &                          ' w ', MINVAL(   e3w_0(:,:,:) )
205
206         WRITE(numout,*) ' MAX val depth t ', MAXVAL( gdept_0(:,:,:) ),   &
207            &                          ' w ', MAXVAL( gdepw_0(:,:,:) ), '3w ', MAXVAL( gde3w_0(:,:,:) )
208         WRITE(numout,*) ' MAX val e3    t ', MAXVAL(   e3t_0(:,:,:) ), ' f ', MAXVAL(   e3f_0(:,:,:) ),  &
209            &                          ' u ', MAXVAL(   e3u_0(:,:,:) ), ' u ', MAXVAL(   e3v_0(:,:,:) ),  &
210            &                          ' uw', MAXVAL(  e3uw_0(:,:,:) ), ' vw', MAXVAL(  e3vw_0(:,:,:) ),  &
211            &                          ' w ', MAXVAL(   e3w_0(:,:,:) )
212      ENDIF
213      !
214   END SUBROUTINE dom_zgr
215
216
217   SUBROUTINE zgr_read( ld_zco  , ld_zps  , ld_sco  , ld_isfcav,   &   ! type of vertical coordinate
218      &                 pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d  ,   &   ! 1D reference vertical coordinate
219      &                 pdept , pdepw ,                            &   ! 3D t & w-points depth
220      &                 pe3t  , pe3u  , pe3v   , pe3f ,            &   ! vertical scale factors
221      &                 pe3w  , pe3uw , pe3vw         ,            &   !     -      -      -
222      &                 k_top  , k_bot    )                            ! top & bottom ocean level
223      !!---------------------------------------------------------------------
224      !!              ***  ROUTINE zgr_read  ***
225      !!
226      !! ** Purpose :   Read the vertical information in the domain configuration file
227      !!
228      !!----------------------------------------------------------------------
229      LOGICAL                   , INTENT(out) ::   ld_zco, ld_zps, ld_sco      ! vertical coordinate flags
230      LOGICAL                   , INTENT(out) ::   ld_isfcav                   ! under iceshelf cavity flag
231      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pdept_1d, pdepw_1d          ! 1D grid-point depth       [m]
232      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pe3t_1d , pe3w_1d           ! 1D vertical scale factors [m]
233      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pdept, pdepw                ! grid-point depth          [m]
234      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3t , pe3u , pe3v , pe3f   ! vertical scale factors    [m]
235      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3w , pe3uw, pe3vw         !    -       -      -
236      INTEGER , DIMENSION(:,:)  , INTENT(out) ::   k_top , k_bot               ! first & last ocean level
237      !
238      INTEGER  ::   jk     ! dummy loop index
239      INTEGER  ::   inum, iatt
240      REAL(WP) ::   z_zco, z_zps, z_sco, z_cav
241      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
242      CHARACTER(len=7) ::   catt   ! 'zco', 'zps, 'sco' or 'UNKNOWN'
243      !!----------------------------------------------------------------------
244      !
245      IF(lwp) THEN
246         WRITE(numout,*)
247         WRITE(numout,*) '   zgr_read : read the vertical coordinates in ', TRIM( cn_domcfg ), ' file'
248         WRITE(numout,*) '   ~~~~~~~~'
249      ENDIF
250      !
251      CALL iom_open( cn_domcfg, inum )
252      !
253      !                          !* type of vertical coordinate
254      CALL iom_getatt( inum, 'VertCoord', catt )   ! returns 'UNKNOWN' if not found
255      ld_zco = catt == 'zco'          ! default = .false.
256      ld_zps = catt == 'zps'          ! default = .false.
257      ld_sco = catt == 'sco'          ! default = .false.
258      !                          !* ocean cavities under iceshelves
259      CALL iom_getatt( inum,    'IsfCav', iatt )   ! returns -999 if not found
260      ld_isfcav = iatt == 1           ! default = .false.
261      !
262      ! ------- keep compatibility with OLD VERSION... start -------
263      IF( catt == 'UNKNOWN' ) THEN
264         CALL iom_get( inum,    'ln_zco', z_zco )   ;   ld_zco = z_zco /= 0._wp
265         CALL iom_get( inum,    'ln_zps', z_zps )   ;   ld_zps = z_zps /= 0._wp
266         CALL iom_get( inum,    'ln_sco', z_sco )   ;   ld_sco = z_sco /= 0._wp
267      ENDIF
268      IF( iatt == -999 ) THEN
269         CALL iom_get( inum, 'ln_isfcav', z_cav )   ;   ld_isfcav = z_cav /= 0._wp
270      ENDIF
271      ! ------- keep compatibility with OLD VERSION... end -------
272      !
273      !                          !* vertical scale factors
274      CALL iom_get( inum, jpdom_unknown, 'e3t_1d'  , pe3t_1d  )                     ! 1D reference coordinate
275      CALL iom_get( inum, jpdom_unknown, 'e3w_1d'  , pe3w_1d  )
276      !
277      CALL iom_get( inum, jpdom_global, 'e3t_0'  , pe3t , cd_type = 'T', psgn = 1._wp, kfill = jpfillcopy )    ! 3D coordinate
278      CALL iom_get( inum, jpdom_global, 'e3u_0'  , pe3u , cd_type = 'U', psgn = 1._wp, kfill = jpfillcopy )
279      CALL iom_get( inum, jpdom_global, 'e3v_0'  , pe3v , cd_type = 'V', psgn = 1._wp, kfill = jpfillcopy )
280      CALL iom_get( inum, jpdom_global, 'e3f_0'  , pe3f , cd_type = 'F', psgn = 1._wp, kfill = jpfillcopy )
281      CALL iom_get( inum, jpdom_global, 'e3w_0'  , pe3w , cd_type = 'W', psgn = 1._wp, kfill = jpfillcopy )
282      CALL iom_get( inum, jpdom_global, 'e3uw_0' , pe3uw, cd_type = 'U', psgn = 1._wp, kfill = jpfillcopy )
283      CALL iom_get( inum, jpdom_global, 'e3vw_0' , pe3vw, cd_type = 'V', psgn = 1._wp, kfill = jpfillcopy )
284      !
285      !                          !* depths
286      !                                   !- old depth definition (obsolescent feature)
287      IF(  iom_varid( inum, 'gdept_1d', ldstop = .FALSE. ) > 0  .AND.  &
288         & iom_varid( inum, 'gdepw_1d', ldstop = .FALSE. ) > 0  .AND.  &
289         & iom_varid( inum, 'gdept_0' , ldstop = .FALSE. ) > 0  .AND.  &
290         & iom_varid( inum, 'gdepw_0' , ldstop = .FALSE. ) > 0    ) THEN
291         CALL ctl_warn( 'zgr_read : old definition of depths and scale factors used ', & 
292            &           '           depths at t- and w-points read in the domain configuration file')
293         CALL iom_get( inum, jpdom_unknown, 'gdept_1d', pdept_1d )   
294         CALL iom_get( inum, jpdom_unknown, 'gdepw_1d', pdepw_1d )
295         CALL iom_get( inum, jpdom_global , 'gdept_0' , pdept, kfill = jpfillcopy )
296         CALL iom_get( inum, jpdom_global , 'gdepw_0' , pdepw, kfill = jpfillcopy )
297         !
298      ELSE                                !- depths computed from e3. scale factors
299         CALL e3_to_depth( pe3t_1d, pe3w_1d, pdept_1d, pdepw_1d )    ! 1D reference depth
300         CALL e3_to_depth( pe3t   , pe3w   , pdept   , pdepw    )    ! 3D depths
301         IF(lwp) THEN
302            WRITE(numout,*)
303            WRITE(numout,*) '              Reference 1D z-coordinate depth and scale factors:'
304            WRITE(numout, "(9x,' level  gdept_1d  gdepw_1d  e3t_1d   e3w_1d  ')" )
305            WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, pdept_1d(jk), pdepw_1d(jk), pe3t_1d(jk), pe3w_1d(jk), jk = 1, jpk )
306         ENDIF
307      ENDIF
308      !
309      !                          !* ocean top and bottom level
310      CALL iom_get( inum, jpdom_global, 'top_level'    , z2d   )   ! 1st wet T-points (ISF)
311      k_top(:,:) = NINT( z2d(:,:) )
312      CALL iom_get( inum, jpdom_global, 'bottom_level' , z2d   )   ! last wet T-points
313      k_bot(:,:) = NINT( z2d(:,:) )
314      !
315      ! reference depth for negative bathy (wetting and drying only)
316      IF( ll_wd )  CALL iom_get( inum,  'rn_wd_ref_depth' , ssh_ref   )
317      !
318      CALL iom_close( inum )
319      !
320   END SUBROUTINE zgr_read
321
322
323   SUBROUTINE zgr_top_bot( k_top, k_bot )
324      !!----------------------------------------------------------------------
325      !!                    ***  ROUTINE zgr_top_bot  ***
326      !!
327      !! ** Purpose :   defines the vertical index of ocean bottom (mbk. arrays)
328      !!
329      !! ** Method  :   computes from k_top and k_bot with a minimum value of 1 over land
330      !!
331      !! ** Action  :   mikt, miku, mikv :   vertical indices of the shallowest
332      !!                                     ocean level at t-, u- & v-points
333      !!                                     (min value = 1)
334      !! ** Action  :   mbkt, mbku, mbkv :   vertical indices of the deeptest
335      !!                                     ocean level at t-, u- & v-points
336      !!                                     (min value = 1 over land)
337      !!----------------------------------------------------------------------
338      INTEGER , DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! top & bottom ocean level indices
339      !
340      INTEGER ::   ji, jj   ! dummy loop indices
341      REAL(wp), DIMENSION(jpi,jpj) ::   zk   ! workspace
342      !!----------------------------------------------------------------------
343      !
344      IF(lwp) WRITE(numout,*)
345      IF(lwp) WRITE(numout,*) '    zgr_top_bot : ocean top and bottom k-index of T-, U-, V- and W-levels '
346      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~'
347      !
348      mikt(:,:) = MAX( k_top(:,:) , 1 )    ! top    ocean k-index of T-level (=1 over land)
349      !
350      mbkt(:,:) = MAX( k_bot(:,:) , 1 )    ! bottom ocean k-index of T-level (=1 over land)
351 
352      !                                    ! N.B.  top     k-index of W-level = mikt
353      !                                    !       bottom  k-index of W-level = mbkt+1
354      DO_2D( 0, 0, 0, 0 )
355         miku(ji,jj) = MAX(  mikt(ji+1,jj  ) , mikt(ji,jj)  )
356         mikv(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj)  )
357         mikf(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj), mikt(ji+1,jj  ), mikt(ji+1,jj+1)  )
358         !
359         mbku(ji,jj) = MIN(  mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
360         mbkv(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
361      END_2D
362      ! converte into REAL to use lbc_lnk ; impose a min value of 1 as a zero can be set in lbclnk
363      DO_2D( 0, 0, 0, 0 )
364         zk(ji,jj) = REAL( miku(ji,jj), wp )
365      END_2D
366      CALL lbc_lnk( 'domzgr', zk, 'U', 1.0_wp )
367      miku(:,:) = MAX( NINT( zk(:,:) ), 1 )
368
369      DO_2D( 0, 0, 0, 0 )
370         zk(ji,jj) = REAL( mikv(ji,jj), wp )
371      END_2D
372      CALL lbc_lnk( 'domzgr', zk, 'V', 1.0_wp )
373      mikv(:,:) = MAX( NINT( zk(:,:) ), 1 )
374     
375      DO_2D( 0, 0, 0, 0 )
376         zk(ji,jj) = REAL( mikf(ji,jj), wp )
377      END_2D
378      CALL lbc_lnk( 'domzgr', zk, 'F', 1.0_wp )
379      mikf(:,:) = MAX( NINT( zk(:,:) ), 1 )
380      !
381      DO_2D( 0, 0, 0, 0 )
382         zk(ji,jj) = REAL( mbku(ji,jj), wp )
383      END_2D
384      CALL lbc_lnk( 'domzgr', zk, 'U', 1.0_wp )
385      mbku(:,:) = MAX( NINT( zk(:,:) ), 1 )
386     
387      DO_2D( 0, 0, 0, 0 )
388         zk(ji,jj) = REAL( mbkv(ji,jj), wp )
389      END_2D
390      CALL lbc_lnk( 'domzgr', zk, 'V', 1.0_wp )
391      mbkv(:,:) = MAX( NINT( zk(:,:) ), 1 )
392      !
393   END SUBROUTINE zgr_top_bot
394
395   !!======================================================================
396END MODULE domzgr
Note: See TracBrowser for help on using the repository browser.