source: NEMO/trunk/src/OCE/DYN/dynhpg.F90 @ 14227

Last change on this file since 14227 was 14227, checked in by smasson, 12 months ago

trunk: replace remaining OPA by OCE

  • Property svn:keywords set to Id
File size: 75.4 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!            4.2  !  2020-12  (M. Bell, A. Young) hpg_djc: revised djc scheme
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   dyn_hpg      : update the momentum trend with the now horizontal
24   !!                  gradient of the hydrostatic pressure
25   !!   dyn_hpg_init : initialisation and control of options
26   !!       hpg_zco  : z-coordinate scheme
27   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
28   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
29   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
30   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
31   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
32   !!----------------------------------------------------------------------
33   USE oce             ! ocean dynamics and tracers
34   USE isf_oce , ONLY : risfload  ! ice shelf  (risfload variable)
35   USE isfload , ONLY : isf_load  ! ice shelf  (isf_load routine )
36   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
37   USE dom_oce         ! ocean space and time domain
38   USE wet_dry         ! wetting and drying
39   USE phycst          ! physical constants
40   USE trd_oce         ! trends: ocean variables
41   USE trddyn          ! trend manager: dynamics
42   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
43   !
44   USE in_out_manager  ! I/O manager
45   USE prtctl          ! Print control
46   USE lbclnk          ! lateral boundary condition
47   USE lib_mpp         ! MPP library
48   USE eosbn2          ! compute density
49   USE timing          ! Timing
50   USE iom
51
52   IMPLICIT NONE
53   PRIVATE
54
55   PUBLIC   dyn_hpg        ! routine called by step module
56   PUBLIC   dyn_hpg_init   ! routine called by opa module
57
58   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
59   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
60   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
61   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
62   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
63   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
64   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
65
66   !                                !! Flag to control the type of hydrostatic pressure gradient
67   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
68   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
69   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
70   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
71   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
72   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
73   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
74   !
75   INTEGER, PUBLIC  ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
76   !
77   LOGICAL          ::   ln_hpg_djc_vnh, ln_hpg_djc_vnv                 ! flag to specify hpg_djc boundary condition type
78   REAL(wp), PUBLIC ::   aco_bc_hor, bco_bc_hor, aco_bc_vrt, bco_bc_vrt !: coefficients for hpg_djc hor and vert boundary conditions
79
80   !! * Substitutions
81#  include "do_loop_substitute.h90"
82#  include "domzgr_substitute.h90"
83
84   !!----------------------------------------------------------------------
85   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
86   !! $Id$
87   !! Software governed by the CeCILL license (see ./LICENSE)
88   !!----------------------------------------------------------------------
89CONTAINS
90
91   SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
92      !!---------------------------------------------------------------------
93      !!                  ***  ROUTINE dyn_hpg  ***
94      !!
95      !! ** Method  :   Call the hydrostatic pressure gradient routine
96      !!              using the scheme defined in the namelist
97      !!
98      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
99      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
100      !!----------------------------------------------------------------------
101      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
102      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
103      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
104      !
105      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
106      !!----------------------------------------------------------------------
107      !
108      IF( ln_timing )   CALL timing_start('dyn_hpg')
109      !
110      IF( l_trddyn ) THEN                    ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
111         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
112         ztrdu(:,:,:) = puu(:,:,:,Krhs)
113         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
114      ENDIF
115      !
116      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
117      CASE ( np_zco )   ;   CALL hpg_zco    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate
118      CASE ( np_zps )   ;   CALL hpg_zps    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate plus partial steps (interpolation)
119      CASE ( np_sco )   ;   CALL hpg_sco    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (standard jacobian formulation)
120      CASE ( np_djc )   ;   CALL hpg_djc    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Density Jacobian with Cubic polynomial)
121      CASE ( np_prj )   ;   CALL hpg_prj    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Pressure Jacobian scheme)
122      CASE ( np_isf )   ;   CALL hpg_isf    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate similar to sco modify for ice shelf
123      END SELECT
124      !
125      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
126         ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
127         ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
128         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
129         DEALLOCATE( ztrdu , ztrdv )
130      ENDIF
131      !
132      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg  - Ua: ', mask1=umask,   &
133         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
134      !
135      IF( ln_timing )   CALL timing_stop('dyn_hpg')
136      !
137   END SUBROUTINE dyn_hpg
138
139
140   SUBROUTINE dyn_hpg_init( Kmm )
141      !!----------------------------------------------------------------------
142      !!                 ***  ROUTINE dyn_hpg_init  ***
143      !!
144      !! ** Purpose :   initializations for the hydrostatic pressure gradient
145      !!              computation and consistency control
146      !!
147      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
148      !!      with the type of vertical coordinate used (zco, zps, sco)
149      !!----------------------------------------------------------------------
150      INTEGER, INTENT( in ) :: Kmm   ! ocean time level index
151      !
152      INTEGER ::   ioptio = 0      ! temporary integer
153      INTEGER ::   ios             ! Local integer output status for namelist read
154      !!
155      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
156      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
157      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
158      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
159      !!
160      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
161         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf,     &
162         &                 ln_hpg_djc_vnh, ln_hpg_djc_vnv
163      !!----------------------------------------------------------------------
164      !
165      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
166901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
167      !
168      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
169902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
170      IF(lwm) WRITE ( numond, namdyn_hpg )
171      !
172      IF(lwp) THEN                   ! Control print
173         WRITE(numout,*)
174         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
175         WRITE(numout,*) '~~~~~~~~~~~~'
176         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
177         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
178         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
179         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
180         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
181         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
182         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
183      ENDIF
184      !
185      IF( .NOT.ln_linssh .AND. (ln_hpg_zco.OR.ln_hpg_zps) )   &
186         &   CALL ctl_stop( 'dyn_hpg_init : non-linear free surface incompatible with hpg_zco or hpg_zps' )
187      !
188      IF( (.NOT.ln_hpg_isf .AND. ln_isfcav) .OR. (ln_hpg_isf .AND. .NOT.ln_isfcav) )                  &
189         &   CALL ctl_stop( 'dyn_hpg_init : ln_hpg_isf=T requires ln_isfcav=T and vice versa' ) 
190      !
191#if defined key_qco
192      IF( ln_hpg_isf ) THEN
193         CALL ctl_stop( 'dyn_hpg_init : key_qco and ln_hpg_isf not yet compatible' )
194      ENDIF
195#endif
196      !
197      !                               ! Set nhpg from ln_hpg_... flags & consistency check
198      nhpg   = np_ERROR
199      ioptio = 0
200      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
201      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
202      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
203      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
204      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
205      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
206      !
207      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
208      !
209      IF(lwp) THEN
210         WRITE(numout,*)
211         SELECT CASE( nhpg )
212         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
213         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
214         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
215         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
216         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
217         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
218         END SELECT
219         WRITE(numout,*)
220      ENDIF
221      !                         
222      IF ( ln_hpg_djc ) THEN
223         IF (ln_hpg_djc_vnh) THEN ! Von Neumann boundary condition
224           IF(lwp) WRITE(numout,*) '           horizontal bc: von Neumann '
225           aco_bc_hor = 6.0_wp/5.0_wp
226           bco_bc_hor = 7.0_wp/15.0_wp
227         ELSE ! Linear extrapolation
228           IF(lwp) WRITE(numout,*) '           horizontal bc: linear extrapolation'
229           aco_bc_hor = 3.0_wp/2.0_wp
230           bco_bc_hor = 1.0_wp/2.0_wp
231         END IF
232         IF (ln_hpg_djc_vnv) THEN ! Von Neumann boundary condition
233           IF(lwp) WRITE(numout,*) '           vertical bc: von Neumann '
234           aco_bc_vrt = 6.0_wp/5.0_wp
235           bco_bc_vrt = 7.0_wp/15.0_wp
236         ELSE ! Linear extrapolation
237           IF(lwp) WRITE(numout,*) '           vertical bc: linear extrapolation'
238           aco_bc_vrt = 3.0_wp/2.0_wp
239           bco_bc_vrt = 1.0_wp/2.0_wp
240         END IF
241      END IF
242      !
243   END SUBROUTINE dyn_hpg_init
244
245
246   SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
247      !!---------------------------------------------------------------------
248      !!                  ***  ROUTINE hpg_zco  ***
249      !!
250      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
251      !!      The now hydrostatic pressure gradient at a given level, jk,
252      !!      is computed by taking the vertical integral of the in-situ
253      !!      density gradient along the model level from the suface to that
254      !!      level:    zhpi = grav .....
255      !!                zhpj = grav .....
256      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
257      !!            puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
258      !!            pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
259      !!
260      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
261      !!----------------------------------------------------------------------
262      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
263      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
264      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
265      !
266      INTEGER  ::   ji, jj, jk       ! dummy loop indices
267      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
268      REAL(wp), DIMENSION(jpi,jpj) ::  zhpi, zhpj
269      !!----------------------------------------------------------------------
270      !
271      IF( kt == nit000 ) THEN
272         IF(lwp) WRITE(numout,*)
273         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
274         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
275      ENDIF
276      !
277      zcoef0 = - grav * 0.5_wp            ! Local constant initialization
278      !
279      DO_2D( 0, 0, 0, 0 )                 ! Surface value
280         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
281         !                                   ! hydrostatic pressure gradient
282         zhpi(ji,jj) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
283         zhpj(ji,jj) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
284         !                                   ! add to the general momentum trend
285         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj)
286         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj)
287      END_2D
288      !
289      DO_3D( 0, 0, 0, 0, 2, jpkm1 )        ! interior value (2=<jk=<jpkm1)
290         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
291         !                                   ! hydrostatic pressure gradient
292         zhpi(ji,jj) = zhpi(ji,jj) + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )  &
293            &                                  - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
294
295         zhpj(ji,jj) = zhpj(ji,jj) + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )  &
296            &                                  - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
297         !                                   ! add to the general momentum trend
298         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj)
299         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj)
300      END_3D
301      !
302   END SUBROUTINE hpg_zco
303
304
305   SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
306      !!---------------------------------------------------------------------
307      !!                 ***  ROUTINE hpg_zps  ***
308      !!
309      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
310      !!
311      !! ** Action  : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
312      !!----------------------------------------------------------------------
313      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
314      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
315      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
316      !!
317      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
318      INTEGER  ::   iku, ikv                         ! temporary integers
319      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
320      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
321      REAL(wp), DIMENSION(jpi,jpj,jpts)   :: zgtsu, zgtsv
322      REAL(wp), DIMENSION(jpi,jpj)     :: zgru, zgrv
323      !!----------------------------------------------------------------------
324      !
325      IF( kt == nit000 ) THEN
326         IF(lwp) WRITE(numout,*)
327         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
328         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
329      ENDIF
330
331      ! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
332      CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
333
334      ! Local constant initialization
335      zcoef0 = - grav * 0.5_wp
336
337      !  Surface value (also valid in partial step case)
338      DO_2D( 0, 0, 0, 0 )
339         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
340         ! hydrostatic pressure gradient
341         zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
342         zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
343         ! add to the general momentum trend
344         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
345         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
346      END_2D
347
348      ! interior value (2=<jk=<jpkm1)
349      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
350         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
351         ! hydrostatic pressure gradient
352         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
353            &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
354            &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
355
356         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
357            &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
358            &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
359         ! add to the general momentum trend
360         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
361         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
362      END_3D
363
364      ! partial steps correction at the last level  (use zgru & zgrv computed in zpshde.F90)
365      DO_2D( 0, 0, 0, 0 )
366         iku = mbku(ji,jj)
367         ikv = mbkv(ji,jj)
368         zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj  ,iku,Kmm) )
369         zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji  ,jj+1,ikv,Kmm) )
370         IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
371            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku)         ! subtract old value
372            zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
373               &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
374            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
375         ENDIF
376         IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
377            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv)         ! subtract old value
378            zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
379               &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
380            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
381         ENDIF
382      END_2D
383      !
384   END SUBROUTINE hpg_zps
385
386
387   SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
388      !!---------------------------------------------------------------------
389      !!                  ***  ROUTINE hpg_sco  ***
390      !!
391      !! ** Method  :   s-coordinate case. Jacobian scheme.
392      !!      The now hydrostatic pressure gradient at a given level, jk,
393      !!      is computed by taking the vertical integral of the in-situ
394      !!      density gradient along the model level from the suface to that
395      !!      level. s-coordinates (ln_sco): a corrective term is added
396      !!      to the horizontal pressure gradient :
397      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
398      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
399      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
400      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
401      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
402      !!
403      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
404      !!----------------------------------------------------------------------
405      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
406      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
407      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
408      !!
409      INTEGER  ::   ji, jj, jk, jii, jjj           ! dummy loop indices
410      REAL(wp) ::   zcoef0, zuap, zvap, ztmp       ! local scalars
411      LOGICAL  ::   ll_tmp1, ll_tmp2               ! local logical variables
412      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
413      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
414      !!----------------------------------------------------------------------
415      !
416      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
417      !
418      IF( kt == nit000 ) THEN
419         IF(lwp) WRITE(numout,*)
420         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
421         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OCE original scheme used'
422      ENDIF
423      !
424      zcoef0 = - grav * 0.5_wp
425      !
426      IF( ln_wd_il ) THEN
427        DO_2D( 0, 0, 0, 0 )
428          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)               ,  ssh(ji+1,jj,Kmm) ) >                &
429               &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
430               &    MAX(  ssh(ji,jj,Kmm) +  ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
431               &                                                       > rn_wdmin1 + rn_wdmin2
432          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)              -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (       &
433               &    MAX(   ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
434               &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
435
436          IF(ll_tmp1) THEN
437            zcpx(ji,jj) = 1.0_wp
438          ELSE IF(ll_tmp2) THEN
439            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
440            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
441                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
442          ELSE
443            zcpx(ji,jj) = 0._wp
444          END IF
445   
446          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
447               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
448               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
449               &                                                      > rn_wdmin1 + rn_wdmin2
450          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
451               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
452               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
453
454          IF(ll_tmp1) THEN
455            zcpy(ji,jj) = 1.0_wp
456          ELSE IF(ll_tmp2) THEN
457            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
458            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
459                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
460          ELSE
461            zcpy(ji,jj) = 0._wp
462          END IF
463        END_2D
464        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
465      END IF
466      !
467      DO_2D( 0, 0, 0, 0 )              ! Surface value
468         !                                   ! hydrostatic pressure gradient along s-surfaces
469         zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj)                      &
470            &          * (  e3w(ji+1,jj  ,1,Kmm) * rhd(ji+1,jj  ,1)  &
471            &             - e3w(ji  ,jj  ,1,Kmm) * rhd(ji  ,jj  ,1)  )
472         zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj)                      &
473            &          * (  e3w(ji  ,jj+1,1,Kmm) * rhd(ji  ,jj+1,1)  &
474            &             - e3w(ji  ,jj  ,1,Kmm) * rhd(ji  ,jj  ,1)  )
475         !                                   ! s-coordinate pressure gradient correction
476         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) )   &
477            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
478         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) )   &
479            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
480         !
481         IF( ln_wd_il ) THEN
482            zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
483            zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
484            zuap = zuap * zcpx(ji,jj)
485            zvap = zvap * zcpy(ji,jj)
486         ENDIF
487         !                                   ! add to the general momentum trend
488         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
489         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
490      END_2D
491      !
492      DO_3D( 0, 0, 0, 0, 2, jpkm1 )    ! interior value (2=<jk=<jpkm1)
493         !                                   ! hydrostatic pressure gradient along s-surfaces
494         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)                         &
495            &           * (  e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )  &
496            &              - e3w(ji  ,jj,jk,Kmm) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  )
497         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)                         &
498            &           * (  e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )  &
499            &              - e3w(ji,jj  ,jk,Kmm) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  )
500         !                                   ! s-coordinate pressure gradient correction
501         zuap = -zcoef0 * ( rhd  (ji+1,jj  ,jk) + rhd  (ji,jj,jk) ) &
502            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
503         zvap = -zcoef0 * ( rhd  (ji  ,jj+1,jk) + rhd  (ji,jj,jk) ) &
504            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
505         !
506         IF( ln_wd_il ) THEN
507            zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
508            zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
509            zuap = zuap * zcpx(ji,jj)
510            zvap = zvap * zcpy(ji,jj)
511         ENDIF
512         !
513         ! add to the general momentum trend
514         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
515         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
516      END_3D
517      !
518      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
519      !
520   END SUBROUTINE hpg_sco
521
522
523   SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
524      !!---------------------------------------------------------------------
525      !!                  ***  ROUTINE hpg_isf  ***
526      !!
527      !! ** Method  :   s-coordinate case. Jacobian scheme.
528      !!      The now hydrostatic pressure gradient at a given level, jk,
529      !!      is computed by taking the vertical integral of the in-situ
530      !!      density gradient along the model level from the suface to that
531      !!      level. s-coordinates (ln_sco): a corrective term is added
532      !!      to the horizontal pressure gradient :
533      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
534      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
535      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
536      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
537      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
538      !!      iceload is added
539      !!     
540      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
541      !!----------------------------------------------------------------------
542      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
543      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
544      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
545      !!
546      INTEGER  ::   ji, jj, jk             ! dummy loop indices
547      INTEGER  ::   ikt ,  ikti1,  iktj1   ! local integer
548      REAL(wp) ::   ze3w, ze3wi1, ze3wj1   ! local scalars
549      REAL(wp) ::   zcoef0, zuap, zvap     !   -      -
550      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
551      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
552      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
553      !!----------------------------------------------------------------------
554      !
555      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
556      !
557      !                          ! iniitialised to 0. zhpi zhpi
558      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
559
560      ! compute rhd at the ice/oce interface (ocean side)
561      ! usefull to reduce residual current in the test case ISOMIP with no melting
562      DO ji = 1, jpi
563        DO jj = 1, jpj
564          ikt = mikt(ji,jj)
565          zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
566          zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
567        END DO
568      END DO
569      CALL eos( zts_top, risfdep, zrhdtop_oce )
570
571      !                     !===========================!
572      !                     !=====  surface value  =====!
573      !                     !===========================!
574      DO_2D( 0, 0, 0, 0 )
575         ikt   = mikt(ji  ,jj  )   ;   ze3w   = e3w(ji  ,jj  ,ikt  ,Kmm)
576         ikti1 = mikt(ji+1,jj  )   ;   ze3wi1 = e3w(ji+1,jj  ,ikti1,Kmm)
577         iktj1 = mikt(ji  ,jj+1)   ;   ze3wj1 = e3w(ji  ,jj+1,iktj1,Kmm)
578         !                          ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
579         !                          ! we assume ISF is in isostatic equilibrium
580         zhpi(ji,jj,1) = zcoef0 * r1_e1u(ji,jj) * (   risfload(ji+1,jj) - risfload(ji,jj)  &
581            &                                       + 0.5_wp * ( ze3wi1 * ( rhd(ji+1,jj,ikti1) + zrhdtop_oce(ji+1,jj) )     &
582            &                                                  - ze3w   * ( rhd(ji  ,jj,ikt  ) + zrhdtop_oce(ji  ,jj) ) )   )
583         zhpj(ji,jj,1) = zcoef0 * r1_e2v(ji,jj) * (   risfload(ji,jj+1) - risfload(ji,jj)  &
584            &                                       + 0.5_wp * ( ze3wj1 * ( rhd(ji,jj+1,iktj1) + zrhdtop_oce(ji,jj+1) )      &
585            &                                                  - ze3w   * ( rhd(ji,jj  ,ikt  ) + zrhdtop_oce(ji,jj  ) ) )   ) 
586         !                          ! s-coordinate pressure gradient correction (=0 if z coordinate)
587         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) )   &
588            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
589         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) )   &
590            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
591         !                          ! add to the general momentum trend
592         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
593         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
594      END_2D
595      !   
596      !                     !=============================!
597      !                     !=====  interior values  =====!
598      !                     !=============================!
599      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
600         ze3w   = e3w(ji  ,jj  ,jk,Kmm)
601         ze3wi1 = e3w(ji+1,jj  ,jk,Kmm)
602         ze3wj1 = e3w(ji  ,jj+1,jk,Kmm)
603         !                          ! hydrostatic pressure gradient along s-surfaces
604         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
605            &           * (  ze3wi1 * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) * wmask(ji+1,jj,jk)   &
606            &              - ze3w   * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) ) * wmask(ji  ,jj,jk)   )
607         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
608            &           * (  ze3wj1 * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) * wmask(ji,jj+1,jk)   &
609            &              - ze3w   * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) ) * wmask(ji,jj  ,jk)   )
610         !                          ! s-coordinate pressure gradient correction
611         zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
612            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
613         zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
614            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
615         !                          ! add to the general momentum trend
616         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
617         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
618      END_3D
619      !
620   END SUBROUTINE hpg_isf
621
622
623   SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
624      !!---------------------------------------------------------------------
625      !!                  ***  ROUTINE hpg_djc  ***
626      !!
627      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
628      !!
629      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
630      !!----------------------------------------------------------------------
631      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
632      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
633      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
634      !!
635      INTEGER  ::   ji, jj, jk          ! dummy loop indices
636      INTEGER  ::   iktb, iktt          ! jk indices at tracer points for top and bottom points
637      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
638      REAL(wp) ::   z_grav_10, z1_12
639      REAL(wp) ::   cffu, cffx          !    "         "
640      REAL(wp) ::   cffv, cffy          !    "         "
641      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
642      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
643 
644      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdzx, zdzy, zdzz                          ! Primitive grid differences ('delta_xyz')
645      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdz_i, zdz_j, zdz_k                       ! Harmonic average of primitive grid differences ('d_xyz')
646      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdrhox, zdrhoy, zdrhoz                    ! Primitive rho differences ('delta_rho')
647      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdrho_i, zdrho_j, zdrho_k                 ! Harmonic average of primitive rho differences ('d_rho')
648      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   z_rho_i, z_rho_j, z_rho_k                 ! Face intergrals
649      REAL(wp), DIMENSION(jpi,jpj)     ::   zz_dz_i, zz_dz_j, zz_drho_i, zz_drho_j    ! temporary arrays
650      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
651      !!----------------------------------------------------------------------
652      !
653      IF( ln_wd_il ) THEN
654         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
655        DO_2D( 0, 0, 0, 0 )
656          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
657               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
658               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
659               &                                                      > rn_wdmin1 + rn_wdmin2
660          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (        &
661               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
662               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
663          IF(ll_tmp1) THEN
664            zcpx(ji,jj) = 1.0_wp
665          ELSE IF(ll_tmp2) THEN
666            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
667            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
668                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
669          ELSE
670            zcpx(ji,jj) = 0._wp
671          END IF
672   
673          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
674               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
675               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
676               &                                                      > rn_wdmin1 + rn_wdmin2
677          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
678               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
679               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
680
681          IF(ll_tmp1) THEN
682            zcpy(ji,jj) = 1.0_wp
683          ELSE IF(ll_tmp2) THEN
684            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
685            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
686                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
687          ELSE
688            zcpy(ji,jj) = 0._wp
689          END IF
690        END_2D
691        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
692      END IF
693
694      IF( kt == nit000 ) THEN
695         IF(lwp) WRITE(numout,*)
696         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
697         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
698      ENDIF
699
700      ! Local constant initialization
701      zcoef0 = - grav * 0.5_wp
702      z_grav_10  = grav / 10._wp
703      z1_12  = 1.0_wp / 12._wp
704
705      !----------------------------------------------------------------------------------------
706      !  1. compute and store elementary vertical differences in provisional arrays
707      !----------------------------------------------------------------------------------------
708
709!!bug gm   Not a true bug, but... zdzz=e3w  for zdzx, zdzy verify what it is really
710
711      DO_3D( 1, 1, 1, 1, 2, jpkm1 ) 
712         zdrhoz(ji,jj,jk) =   rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
713         zdzz  (ji,jj,jk) = - gde3w(ji  ,jj  ,jk) + gde3w(ji,jj,jk-1)
714      END_3D
715
716      !-------------------------------------------------------------------------
717      ! 2. compute harmonic averages for vertical differences using eq. 5.18
718      !-------------------------------------------------------------------------
719      zep = 1.e-15
720
721!! mb zdrho_k, zdz_k, zdrho_i, zdz_i, zdrho_j, zdz_j re-centred about the point (ji,jj,jk)
722      zdrho_k(:,:,:) = 0._wp
723      zdz_k  (:,:,:) = 0._wp
724
725      DO_3D( 1, 1, 1, 1, 2, jpk-2 ) 
726         cffw = 2._wp * zdrhoz(ji  ,jj  ,jk) * zdrhoz(ji,jj,jk+1)
727         IF( cffw > zep) THEN
728            zdrho_k(ji,jj,jk) = cffw / ( zdrhoz(ji,jj,jk) + zdrhoz(ji,jj,jk+1) )
729         ENDIF
730         zdz_k(ji,jj,jk) = 2._wp *   zdzz(ji,jj,jk) * zdzz(ji,jj,jk+1)   &
731            &                  / ( zdzz(ji,jj,jk) + zdzz(ji,jj,jk+1) )
732      END_3D
733
734      !----------------------------------------------------------------------------------
735      ! 3. apply boundary conditions at top and bottom using 5.36-5.37
736      !----------------------------------------------------------------------------------
737
738! mb for sea-ice shelves we will need to re-write this upper boundary condition in the same form as the lower boundary condition
739      zdrho_k(:,:,1) = aco_bc_vrt * ( rhd    (:,:,2) - rhd    (:,:,1) ) - bco_bc_vrt * zdrho_k(:,:,2)
740      zdz_k  (:,:,1) = aco_bc_vrt * (-gde3w(:,:,2) + gde3w(:,:,1) ) - bco_bc_vrt * zdz_k  (:,:,2)
741
742      DO_2D( 1, 1, 1, 1 )
743         IF ( mbkt(ji,jj)>1 ) THEN
744            iktb = mbkt(ji,jj)
745            zdrho_k(ji,jj,iktb) = aco_bc_vrt * (     rhd(ji,jj,iktb) -     rhd(ji,jj,iktb-1) ) - bco_bc_vrt * zdrho_k(ji,jj,iktb-1)
746            zdz_k  (ji,jj,iktb) = aco_bc_vrt * (-gde3w(ji,jj,iktb) + gde3w(ji,jj,iktb-1) ) - bco_bc_vrt * zdz_k  (ji,jj,iktb-1) 
747         END IF
748      END_2D
749
750      !--------------------------------------------------------------
751      ! 4. Compute side face integrals
752      !-------------------------------------------------------------
753
754!! ssh replaces e3w_n ; gde3w is a depth; the formulae involve heights 
755!! rho_k stores grav * FX / rho_0 
756
757      !--------------------------------------------------------------
758      ! 4. a) Upper half of top-most grid box, compute and store
759      !-------------------------------------------------------------
760! *** AY note: ssh(ji,jj,Kmm) + gde3w(ji,jj,1) = e3w(ji,jj,1,Kmm)
761      DO_2D( 0, 1, 0, 1)
762         z_rho_k(ji,jj,1) =  grav * ( ssh(ji,jj,Kmm) + gde3w(ji,jj,1) )                        & 
763            &                     * (  rhd(ji,jj,1)                                        &
764            &                     + 0.5_wp * (   rhd    (ji,jj,2) - rhd    (ji,jj,1) ) &
765            &                              * (   ssh   (ji,jj,Kmm) + gde3w(ji,jj,1) )          &
766            &                              / ( - gde3w(ji,jj,2) + gde3w(ji,jj,1) )  )
767      END_2D
768
769      !--------------------------------------------------------------
770      ! 4. b) Interior faces, compute and store
771      !-------------------------------------------------------------
772
773      DO_3D( 0, 1, 0, 1, 2, jpkm1 )
774         z_rho_k(ji,jj,jk) = zcoef0 * (   rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
775            &                       * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) )                                               &
776            &                       + z_grav_10 * (                                                                           &
777            &     (   zdrho_k  (ji,jj,jk) - zdrho_k  (ji,jj,jk-1) )                                                           &
778            &   * ( - gde3w(ji,jj,jk) + gde3w(ji,jj,jk-1) - z1_12 * ( zdz_k  (ji,jj,jk) + zdz_k  (ji,jj,jk-1) ) )             &
779            &   - ( zdz_k    (ji,jj,jk) - zdz_k    (ji,jj,jk-1) )                                                             &
780            &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( zdrho_k(ji,jj,jk) + zdrho_k(ji,jj,jk-1) ) )   &
781            &                             )
782      END_3D
783
784      !----------------------------------------------------------------------------------------
785      !  5. compute and store elementary horizontal differences in provisional arrays
786      !----------------------------------------------------------------------------------------
787
788      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
789         zdrhox(ji,jj,jk) =   rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
790         zdzx  (ji,jj,jk) = - gde3w(ji+1,jj  ,jk) + gde3w(ji,jj,jk  )
791         zdrhoy(ji,jj,jk) =   rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
792         zdzy  (ji,jj,jk) = - gde3w(ji  ,jj+1,jk) + gde3w(ji,jj,jk  )
793      END_3D
794
795      CALL lbc_lnk_multi( 'dynhpg', zdrhox, 'U', 1., zdzx, 'U', 1., zdrhoy, 'V', 1., zdzy, 'V', 1. ) 
796
797      !-------------------------------------------------------------------------
798      ! 6. compute harmonic averages using eq. 5.18
799      !-------------------------------------------------------------------------
800
801      DO_3D( 0, 1, 0, 1, 1, jpkm1 )
802         cffu = 2._wp * zdrhox(ji-1,jj  ,jk) * zdrhox(ji,jj,jk  )
803         IF( cffu > zep ) THEN
804            zdrho_i(ji,jj,jk) = cffu / ( zdrhox(ji-1,jj,jk) + zdrhox(ji,jj,jk) )
805         ELSE
806            zdrho_i(ji,jj,jk ) = 0._wp
807         ENDIF
808
809         cffx = 2._wp * zdzx  (ji-1,jj  ,jk) * zdzx  (ji,jj,jk  )
810         IF( cffx > zep ) THEN
811            zdz_i(ji,jj,jk) = cffx / ( zdzx(ji-1,jj,jk) + zdzx(ji,jj,jk) )
812         ELSE
813            zdz_i(ji,jj,jk) = 0._wp
814         ENDIF
815
816         cffv = 2._wp * zdrhoy(ji  ,jj-1,jk) * zdrhoy(ji,jj,jk  )
817         IF( cffv > zep ) THEN
818            zdrho_j(ji,jj,jk) = cffv / ( zdrhoy(ji,jj-1,jk) + zdrhoy(ji,jj,jk) )
819         ELSE
820            zdrho_j(ji,jj,jk) = 0._wp
821         ENDIF
822
823         cffy = 2._wp * zdzy  (ji  ,jj-1,jk) * zdzy  (ji,jj,jk  )
824         IF( cffy > zep ) THEN
825            zdz_j(ji,jj,jk) = cffy / ( zdzy(ji,jj-1,jk) + zdzy(ji,jj,jk) )
826         ELSE
827            zdz_j(ji,jj,jk) = 0._wp
828         ENDIF
829      END_3D
830     
831!!! Note that zdzx, zdzy, zdzz, zdrhox, zdrhoy and zdrhoz should NOT be used beyond this point     
832
833      !----------------------------------------------------------------------------------
834      ! 6B. apply boundary conditions at side boundaries using 5.36-5.37
835      !----------------------------------------------------------------------------------
836
837      DO jk = 1, jpkm1
838         zz_drho_i(:,:) = zdrho_i(:,:,jk)
839         zz_dz_i  (:,:) = zdz_i  (:,:,jk)
840         zz_drho_j(:,:) = zdrho_j(:,:,jk)
841         zz_dz_j  (:,:) = zdz_j  (:,:,jk)
842         DO_2D( 0, 1, 0, 1)
843            ! Walls coming from left: should check from 2 to jpi-1 (and jpj=2-jpj)
844            IF (ji < jpi) THEN
845               IF ( umask(ji,jj,jk) > 0.5_wp .AND. umask(ji-1,jj,jk) < 0.5_wp .AND. umask(ji+1,jj,jk) > 0.5_wp)  THEN 
846                  zz_drho_i(ji,jj) = aco_bc_hor * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) ) - bco_bc_hor * zdrho_i(ji+1,jj,jk) 
847                  zz_dz_i  (ji,jj) = aco_bc_hor * (-gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_i  (ji+1,jj,jk)
848               END IF
849            END IF
850            ! Walls coming from right: should check from 3 to jpi (and jpj=2-jpj)
851            IF (ji > 2) THEN
852               IF ( umask(ji,jj,jk) < 0.5_wp .AND. umask(ji-1,jj,jk) > 0.5_wp .AND. umask(ji-2,jj,jk) > 0.5_wp) THEN
853                  zz_drho_i(ji,jj) = aco_bc_hor * ( rhd    (ji,jj,jk) - rhd    (ji-1,jj,jk) ) - bco_bc_hor * zdrho_i(ji-1,jj,jk) 
854                  zz_dz_i  (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji-1,jj,jk) ) - bco_bc_hor * zdz_i  (ji-1,jj,jk)
855               END IF
856            END IF
857            ! Walls coming from left: should check from 2 to jpj-1 (and jpi=2-jpi)
858            IF (jj < jpj) THEN
859               IF ( vmask(ji,jj,jk) > 0.5_wp .AND. vmask(ji,jj-1,jk) < 0.5_wp .AND. vmask(ji,jj+1,jk) > 0.5_wp)  THEN
860                  zz_drho_j(ji,jj) = aco_bc_hor * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) ) - bco_bc_hor * zdrho_j(ji,jj+1,jk)
861                  zz_dz_j  (ji,jj) = aco_bc_hor * (-gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) ) - bco_bc_hor * zdz_j  (ji,jj+1,jk)
862               END IF
863            END IF 
864            ! Walls coming from right: should check from 3 to jpj (and jpi=2-jpi)
865            IF (jj > 2) THEN
866               IF ( vmask(ji,jj,jk) < 0.5_wp .AND. vmask(ji,jj-1,jk) > 0.5_wp .AND. vmask(ji,jj-2,jk) > 0.5_wp) THEN
867                  zz_drho_j(ji,jj) = aco_bc_hor * ( rhd    (ji,jj,jk) - rhd    (ji,jj-1,jk) ) - bco_bc_hor * zdrho_j(ji,jj-1,jk) 
868                  zz_dz_j  (ji,jj) = aco_bc_hor * (-gde3w(ji,jj,jk) + gde3w(ji,jj-1,jk) ) - bco_bc_hor * zdz_j  (ji,jj-1,jk)
869               END IF
870            END IF
871         END_2D
872         zdrho_i(:,:,jk) = zz_drho_i(:,:)
873         zdz_i  (:,:,jk) = zz_dz_i  (:,:)
874         zdrho_j(:,:,jk) = zz_drho_j(:,:)
875         zdz_j  (:,:,jk) = zz_dz_j  (:,:)
876      END DO
877
878      !--------------------------------------------------------------
879      ! 7. Calculate integrals on side faces 
880      !-------------------------------------------------------------
881
882      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
883! two -ve signs cancel in next two lines (within zcoef0 and because gde3w is a depth not a height)
884         z_rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                       &
885             &                    * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )                                   
886         IF ( umask(ji-1, jj, jk) > 0.5 .OR. umask(ji+1, jj, jk) > 0.5 ) THEN
887            z_rho_i(ji,jj,jk) = z_rho_i(ji,jj,jk) - z_grav_10 * (                                                               &
888             &     (   zdrho_i  (ji+1,jj,jk) - zdrho_i  (ji,jj,jk) )                                                            &
889             &   * ( - gde3w(ji+1,jj,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_i  (ji+1,jj,jk) + zdz_i  (ji,jj,jk) ) )              &
890             &   - (   zdz_i    (ji+1,jj,jk) - zdz_i    (ji,jj,jk) )                                                            &
891             &   * (   rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( zdrho_i(ji+1,jj,jk) + zdrho_i(ji,jj,jk) ) )  &
892             &                                               )
893         END IF
894 
895         z_rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                       &
896             &                    * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )                                 
897         IF ( vmask(ji, jj-1, jk) > 0.5 .OR. vmask(ji, jj+1, jk) > 0.5 ) THEN
898            z_rho_j(ji,jj,jk) = z_rho_j(ji,jj,jk) - z_grav_10 * (                                                               &
899             &     (   zdrho_j  (ji,jj+1,jk) - zdrho_j  (ji,jj,jk) )                                                            &
900             &   * ( - gde3w(ji,jj+1,jk) + gde3w(ji,jj,jk) - z1_12 * ( zdz_j  (ji,jj+1,jk) + zdz_j  (ji,jj,jk) ) )              &
901             &   - (   zdz_j    (ji,jj+1,jk) - zdz_j    (ji,jj,jk) )                                                            &
902             &   * (   rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( zdrho_j(ji,jj+1,jk) + zdrho_j(ji,jj,jk) ) )  &
903             &                                                 )
904         END IF
905      END_3D
906
907      !--------------------------------------------------------------
908      ! 8. Integrate in the vertical   
909      !-------------------------------------------------------------
910      !
911      ! ---------------
912      !  Surface value
913      ! ---------------
914      DO_2D( 0, 0, 0, 0 )
915         zhpi(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji+1,jj  ,1) - z_rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
916         zhpj(ji,jj,1) = ( z_rho_k(ji,jj,1) - z_rho_k(ji  ,jj+1,1) - z_rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
917         IF( ln_wd_il ) THEN
918           zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
919           zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
920         ENDIF
921         ! add to the general momentum trend
922         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
923         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
924      END_2D
925
926      ! ----------------
927      !  interior value   (2=<jk=<jpkm1)
928      ! ----------------
929      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
930         ! hydrostatic pressure gradient along s-surfaces
931         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                                     &
932            &           + (  ( z_rho_k(ji,jj,jk) - z_rho_k(ji+1,jj,jk  ) )                     &
933            &              - ( z_rho_i(ji,jj,jk) - z_rho_i(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
934         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                                     &
935            &           + (  ( z_rho_k(ji,jj,jk) - z_rho_k(ji,jj+1,jk  ) )                     &
936            &               -( z_rho_j(ji,jj,jk) - z_rho_j(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
937         IF( ln_wd_il ) THEN
938           zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
939           zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
940         ENDIF
941         ! add to the general momentum trend
942         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
943         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
944      END_3D
945      !
946      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
947      !
948   END SUBROUTINE hpg_djc
949
950
951   SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
952      !!---------------------------------------------------------------------
953      !!                  ***  ROUTINE hpg_prj  ***
954      !!
955      !! ** Method  :   s-coordinate case.
956      !!      A Pressure-Jacobian horizontal pressure gradient method
957      !!      based on the constrained cubic-spline interpolation for
958      !!      all vertical coordinate systems
959      !!
960      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
961      !!----------------------------------------------------------------------
962      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
963      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
964      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
965      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
966      !!
967      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
968      REAL(wp) ::   zcoef0, znad                    ! local scalars
969      !
970      !! The local variables for the correction term
971      INTEGER  :: jk1, jis, jid, jjs, jjd
972      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
973      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
974      REAL(wp) :: zrhdt1
975      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
976      REAL(wp), DIMENSION(jpi,jpj)     ::   zpgu, zpgv   ! 2D workspace
977      REAL(wp), DIMENSION(jpi,jpj)     ::   zsshu_n, zsshv_n
978      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
979      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
980      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
981      !!----------------------------------------------------------------------
982      !
983      IF( kt == nit000 ) THEN
984         IF(lwp) WRITE(numout,*)
985         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
986         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
987      ENDIF
988
989      ! Local constant initialization
990      zcoef0 = - grav
991      znad = 1._wp
992      IF( ln_linssh )   znad = 1._wp
993      !
994      ! ---------------
995      !  Surface pressure gradient to be removed
996      ! ---------------
997      DO_2D( 0, 0, 0, 0 )
998         zpgu(ji,jj) = - grav * ( ssh(ji+1,jj,Kmm) - ssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
999         zpgv(ji,jj) = - grav * ( ssh(ji,jj+1,Kmm) - ssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
1000      END_2D
1001      !
1002      IF( ln_wd_il ) THEN
1003         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
1004         DO_2D( 0, 0, 0, 0 )
1005          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
1006               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
1007               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
1008               &                                                      > rn_wdmin1 + rn_wdmin2
1009          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (         &
1010               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
1011               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
1012
1013          IF(ll_tmp1) THEN
1014            zcpx(ji,jj) = 1.0_wp
1015          ELSE IF(ll_tmp2) THEN
1016            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
1017            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1018                        &    / (ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm)) )
1019           
1020             zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
1021          ELSE
1022            zcpx(ji,jj) = 0._wp
1023          END IF
1024   
1025          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
1026               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
1027               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
1028               &                                                      > rn_wdmin1 + rn_wdmin2
1029          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (      &
1030               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
1031               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
1032
1033          IF(ll_tmp1) THEN
1034            zcpy(ji,jj) = 1.0_wp
1035          ELSE IF(ll_tmp2) THEN
1036            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
1037            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
1038                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
1039             zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1040
1041            ELSE
1042               zcpy(ji,jj) = 0._wp
1043            ENDIF
1044         END_2D
1045         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
1046      ENDIF
1047
1048      ! Clean 3-D work arrays
1049      zhpi(:,:,:) = 0._wp
1050      zrhh(:,:,:) = rhd(:,:,:)
1051
1052      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1053      DO_2D( 1, 1, 1, 1 )
1054       jk = mbkt(ji,jj)
1055       IF(     jk <=  1   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1056       ELSEIF( jk ==  2   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1057       ELSEIF( jk < jpkm1 ) THEN
1058          DO jkk = jk+1, jpk
1059             zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk  ), gde3w(ji,jj,jkk-1),   &
1060                &                      gde3w(ji,jj,jkk-2), zrhh (ji,jj,jkk-1), zrhh(ji,jj,jkk-2))
1061          END DO
1062       ENDIF
1063      END_2D
1064
1065      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1066      DO_2D( 1, 1, 1, 1 )
1067         zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm)
1068      END_2D
1069
1070      DO_3D( 1, 1, 1, 1, 2, jpk )
1071         zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
1072      END_3D
1073
1074      fsp(:,:,:) = zrhh (:,:,:)
1075      xsp(:,:,:) = zdept(:,:,:)
1076
1077      ! Construct the vertical density profile with the
1078      ! constrained cubic spline interpolation
1079      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1080      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1081
1082      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1083      DO_2D( 0, 1, 0, 1 )
1084       zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1085          &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
1086
1087       ! assuming linear profile across the top half surface layer
1088       zhpi(ji,jj,1) =  0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
1089      END_2D
1090
1091      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1092      DO_3D( 0, 1, 0, 1, 2, jpkm1 )
1093      zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1094         &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1095         &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1096         &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1097      END_3D
1098
1099      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1100
1101      ! Prepare zsshu_n and zsshv_n
1102      DO_2D( 0, 0, 0, 0 )
1103!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1104!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1105!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1106!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1107!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1108!!gm not this:
1109       zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1110                      & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1111       zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1112                      & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1113      END_2D
1114
1115      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1.0_wp, zsshv_n, 'V', 1.0_wp )
1116
1117      DO_2D( 0, 0, 0, 0 )
1118       zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) ) 
1119       zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) )
1120      END_2D
1121
1122      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
1123      zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1124      zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1125      END_3D
1126
1127      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1128      zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1129      zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1130      END_3D
1131
1132      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1133      zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1134      zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1135      zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1136      zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1137      END_3D
1138
1139
1140      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
1141      zpwes = 0._wp; zpwed = 0._wp
1142      zpnss = 0._wp; zpnsd = 0._wp
1143      zuijk = zu(ji,jj,jk)
1144      zvijk = zv(ji,jj,jk)
1145
1146      !!!!!     for u equation
1147      IF( jk <= mbku(ji,jj) ) THEN
1148         IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1149           jis = ji + 1; jid = ji
1150         ELSE
1151           jis = ji;     jid = ji +1
1152         ENDIF
1153
1154         ! integrate the pressure on the shallow side
1155         jk1 = jk
1156         DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1157           IF( jk1 == mbku(ji,jj) ) THEN
1158             zuijk = -zdept(jis,jj,jk1)
1159             EXIT
1160           ENDIF
1161           zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1162           zpwes = zpwes +                                    &
1163                integ_spline(zdept(jis,jj,jk1), zdeps,            &
1164                       asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1165                       csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1166           jk1 = jk1 + 1
1167         END DO
1168
1169         ! integrate the pressure on the deep side
1170         jk1 = jk
1171         DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1172           IF( jk1 == 1 ) THEN
1173             zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1174             zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1175                                               bsp(jid,jj,1),   csp(jid,jj,1), &
1176                                               dsp(jid,jj,1)) * zdeps
1177             zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1178             EXIT
1179           ENDIF
1180           zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1181           zpwed = zpwed +                                        &
1182                  integ_spline(zdeps,              zdept(jid,jj,jk1), &
1183                         asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1184                         csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1185           jk1 = jk1 - 1
1186         END DO
1187
1188         ! update the momentum trends in u direction
1189
1190         zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1191         IF( .NOT.ln_linssh ) THEN
1192           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1193              &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1194          ELSE
1195           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1196         ENDIF
1197         IF( ln_wd_il ) THEN
1198            zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1199            zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1200         ENDIF
1201         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2 - zpgu(ji,jj)) * umask(ji,jj,jk) 
1202      ENDIF
1203
1204      !!!!!     for v equation
1205      IF( jk <= mbkv(ji,jj) ) THEN
1206         IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1207           jjs = jj + 1; jjd = jj
1208         ELSE
1209           jjs = jj    ; jjd = jj + 1
1210         ENDIF
1211
1212         ! integrate the pressure on the shallow side
1213         jk1 = jk
1214         DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1215           IF( jk1 == mbkv(ji,jj) ) THEN
1216             zvijk = -zdept(ji,jjs,jk1)
1217             EXIT
1218           ENDIF
1219           zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1220           zpnss = zpnss +                                      &
1221                  integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1222                         asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1223                         csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1224           jk1 = jk1 + 1
1225         END DO
1226
1227         ! integrate the pressure on the deep side
1228         jk1 = jk
1229         DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1230           IF( jk1 == 1 ) THEN
1231             zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1232             zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1233                                               bsp(ji,jjd,1),   csp(ji,jjd,1), &
1234                                               dsp(ji,jjd,1) ) * zdeps
1235             zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1236             EXIT
1237           ENDIF
1238           zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1239           zpnsd = zpnsd +                                        &
1240                  integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1241                         asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1242                         csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1243           jk1 = jk1 - 1
1244         END DO
1245
1246
1247         ! update the momentum trends in v direction
1248
1249         zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1250         IF( .NOT.ln_linssh ) THEN
1251            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1252                    ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1253         ELSE
1254            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1255         ENDIF
1256         IF( ln_wd_il ) THEN
1257            zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1258            zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1259         ENDIF
1260
1261         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2 - zpgv(ji,jj)) * vmask(ji,jj,jk)
1262      ENDIF
1263         !
1264      END_3D
1265      !
1266      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1267      !
1268   END SUBROUTINE hpg_prj
1269
1270
1271   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1272      !!----------------------------------------------------------------------
1273      !!                 ***  ROUTINE cspline  ***
1274      !!
1275      !! ** Purpose :   constrained cubic spline interpolation
1276      !!
1277      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1278      !!
1279      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1280      !!----------------------------------------------------------------------
1281      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1282      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1283      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1284      !
1285      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1286      INTEGER  ::   jpi, jpj, jpkm1
1287      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1288      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1289      REAL(wp) ::   zdf(size(fsp,3))
1290      !!----------------------------------------------------------------------
1291      !
1292!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1293      jpi   = size(fsp,1)
1294      jpj   = size(fsp,2)
1295      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1296      !
1297      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1298         DO ji = 1, jpi
1299            DO jj = 1, jpj
1300           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1301           !    DO jk = 2, jpkm1-1
1302           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1303           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1304           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1305           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1306           !
1307           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1308           !
1309           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1310           !           zdf(jk) = 0._wp
1311           !       ELSE
1312           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1313           !       ENDIF
1314           !    END DO
1315
1316           !!Simply geometric average
1317               DO jk = 2, jpkm1-1
1318                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1319                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1320
1321                  IF(zdf1 * zdf2 <= 0._wp) THEN
1322                     zdf(jk) = 0._wp
1323                  ELSE
1324                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1325                  ENDIF
1326               END DO
1327
1328               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1329                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1330               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1331                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1332
1333               DO jk = 1, jpkm1 - 1
1334                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1335                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1336                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1337                 zddf1  = -2._wp * ztmp1 + ztmp2
1338                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1339                 zddf2  =  2._wp * ztmp1 - ztmp2
1340
1341                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1342                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1343                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1344                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1345                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1346                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1347                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1348                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1349                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1350               END DO
1351            END DO
1352         END DO
1353
1354      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1355         DO ji = 1, jpi
1356            DO jj = 1, jpj
1357               DO jk = 1, jpkm1-1
1358                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1359                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1360
1361                  dsp(ji,jj,jk) = 0._wp
1362                  csp(ji,jj,jk) = 0._wp
1363                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1364                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1365               END DO
1366            END DO
1367         END DO
1368         !
1369      ELSE
1370         CALL ctl_stop( 'invalid polynomial type in cspline' )
1371      ENDIF
1372      !
1373   END SUBROUTINE cspline
1374
1375
1376   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1377      !!----------------------------------------------------------------------
1378      !!                 ***  ROUTINE interp1  ***
1379      !!
1380      !! ** Purpose :   1-d linear interpolation
1381      !!
1382      !! ** Method  :   interpolation is straight forward
1383      !!                extrapolation is also permitted (no value limit)
1384      !!----------------------------------------------------------------------
1385      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1386      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1387      REAL(wp)             ::  zdeltx
1388      !!----------------------------------------------------------------------
1389      !
1390      zdeltx = xr - xl
1391      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1392         f = 0.5_wp * (fl + fr)
1393      ELSE
1394         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1395      ENDIF
1396      !
1397   END FUNCTION interp1
1398
1399
1400   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1401      !!----------------------------------------------------------------------
1402      !!                 ***  ROUTINE interp1  ***
1403      !!
1404      !! ** Purpose :   1-d constrained cubic spline interpolation
1405      !!
1406      !! ** Method  :  cubic spline interpolation
1407      !!
1408      !!----------------------------------------------------------------------
1409      REAL(wp), INTENT(in) ::  x, a, b, c, d
1410      REAL(wp)             ::  f ! value from the interpolation
1411      !!----------------------------------------------------------------------
1412      !
1413      f = a + x* ( b + x * ( c + d * x ) )
1414      !
1415   END FUNCTION interp2
1416
1417
1418   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1419      !!----------------------------------------------------------------------
1420      !!                 ***  ROUTINE interp1  ***
1421      !!
1422      !! ** Purpose :   Calculate the first order of derivative of
1423      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1424      !!
1425      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1426      !!
1427      !!----------------------------------------------------------------------
1428      REAL(wp), INTENT(in) ::  x, a, b, c, d
1429      REAL(wp)             ::  f ! value from the interpolation
1430      !!----------------------------------------------------------------------
1431      !
1432      f = b + x * ( 2._wp * c + 3._wp * d * x)
1433      !
1434   END FUNCTION interp3
1435
1436
1437   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1438      !!----------------------------------------------------------------------
1439      !!                 ***  ROUTINE interp1  ***
1440      !!
1441      !! ** Purpose :   1-d constrained cubic spline integration
1442      !!
1443      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1444      !!
1445      !!----------------------------------------------------------------------
1446      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1447      REAL(wp)             ::  za1, za2, za3
1448      REAL(wp)             ::  f                   ! integration result
1449      !!----------------------------------------------------------------------
1450      !
1451      za1 = 0.5_wp * b
1452      za2 = c / 3.0_wp
1453      za3 = 0.25_wp * d
1454      !
1455      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1456         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1457      !
1458   END FUNCTION integ_spline
1459
1460   !!======================================================================
1461END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.